home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol018 / mactime.asm < prev    next >
Encoding:
Assembly Source File  |  1984-04-29  |  6.4 KB  |  250 lines
  1.  
  2.     title    'MACTIME as of october 20, 1980'
  3.  
  4. ; 
  5. ; 
  6. ;  Here  is  an  interesting  "patch"  to  Digital  Research's 
  7. ; MAC.COM, that incorporates a "real time clock display.  This 
  8. ; patch   works with MAC.COM version 2.0 ONLY.  Merge it  into 
  9. ; MAC.COM as follows:
  10. ; 
  11. ;      A>DDT MAC.COM<cr>
  12. ;      NEXT   PC
  13. ;      2F00  0100
  14. ;      -IMACTIME.HEX<cr>
  15. ;      -R<cr>
  16. ;      NEXT   PC
  17. ;      308E  0000
  18. ;      -^C
  19. ;      A>SAVE 48 MACTIME.COM<cr>
  20. ; 
  21. ;  Now  you have a new "MAC" command file called  MACTIME.COM; 
  22. ; now  re-assemble  MACTIME.ASM (assuming your  clock/calendar 
  23. ; board, and the time is properly set) with MACTIME.COM.
  24. ; 
  25. ;  Notice,  that  the date and time will be displayed  at  the 
  26. ; start  of execution.  Also because the "title" pseudo-op was 
  27. ; used,  the  time  is  listed  in the  ".PRN"  file  that  is 
  28. ; generated, on each page heading.
  29. ; 
  30. ;                         Best regards,
  31. ;           
  32. ;                         Kelly Smith, MP/M-Net (tm) Sysop
  33. ;                         (805) 527-9321 (Modem, 300 Baud)
  34. ;
  35. ;
  36. ;
  37. ; For Compu-Time T-102 TIME/DATE board (With MM 5375 AC)
  38. ;
  39. ; or,
  40. ;
  41. ; QT Computer Systems Inc. "Clock/Calendar +" board
  42. ;
  43. ;
  44. true    equ    -1    ; define true
  45. false    equ    not true; define false
  46. qt    equ    true    ; define QT Computer Systems Inc. board
  47. ct    equ    false    ; define Compu-Time board
  48.  
  49. bdos    equ    5
  50. pbuf    equ    9
  51.  
  52. cr    equ    0dh    ; ASCII carriage return
  53. lf    equ    0ah    ; ASCII line feed
  54.  
  55. mac    equ    128h    ; entry address to MAC.COM
  56.  
  57. overlay    equ    2cd3h    ; overlay area in MAC.COM
  58.  
  59.     if    qt
  60.  
  61. clock    equ    080h    ; real time clock base port address
  62.  
  63.     endif
  64.  
  65.     if    ct
  66.  
  67. clock    equ    024h    ; real time clock base port address
  68.  
  69.     endif
  70.  
  71.     org    100h
  72.  
  73.     jmp    date    ; jump to set date and time
  74.  
  75.     org    2f00h    ; date and time routine
  76.  
  77. date:    lxi    h,month    ; point to month
  78.     mvi    d,8    ; select month tens digit
  79.     call    digit    ; read and store high digit
  80.     rlc ! rlc ! rlc ! rlc    ; shift to high order hex digit
  81.     mov    b,a    ; save in b reg.
  82.     call    digit    ; read and store month units digit
  83.     ora    b    ; or-in the units and tens digit
  84.     mov    b,a    ; save the month in b reg.
  85.     call    digit    ; read and store the day tens digit
  86.     rlc ! rlc ! rlc ! rlc    ; shift to high order hex digit
  87.     mov    c,a    ; save in c reg.
  88.     call    digit    ; read and store day units digit
  89.     ora    c    ; or-in the units and tens digit
  90.     mov    c,a    ; save the day in c reg.
  91.  
  92. ;
  93. ; test the date, and convert it to four year calendar format
  94. ;
  95.  
  96.     cpi    031h    ; 31st day?
  97.     mov    a,b    ; get the month, for next test
  98.     jnz    m2    ; if not the 31st, test for february
  99.     cpi    2    ; test for months < 31 days
  100.     jz    fix    ; ...and fix if needed
  101.     cpi    4
  102.     jz    fix
  103.     cpi    6
  104.     jz    fix
  105.     cpi    9
  106.     jz    fix
  107.     cpi    011h
  108.     jz    fix
  109. m2:    cpi    2    ; test for february
  110.     jnz    time    ; if not february, then read time
  111.     mov    a,c    ; get day for test
  112.     cpi    029h    ; is this the 29th day?
  113.  
  114. ;
  115. ; insert two NOP's over previous instruction, if this is a leap year
  116. ;
  117.     jz    fix    ; fix date...
  118.     cpi    030h    ; 30th day?
  119.     jnz    time    ; if not the 29th or 30th, go read time
  120. fix:    mvi    a,41    ; select month units and fast set
  121.     call    rdigit    ; read the month units digit
  122.     mov    b,a    ; save in b reg.
  123. floop:    in    clock    ; read the months unit digit
  124.     cmp    b    ; test for digit changed
  125.     jz    floop    ; wait until month is bumped (stable data)
  126. time:    lxi    h,hour    ; point to hour
  127.     mvi    d,0    ; select hour tens digit
  128.     call    ddigit    ; read hour tens and units
  129.     inx    h    ; step over ":"
  130.     call    ddigit    ; read minutes tens and units
  131.     inx    h    ; step over ":"
  132.     call    ddigit    ; read second tens and units
  133.     lda    month    ; get high byte of the month
  134.     cpi    ' '    ; in the range of january to september?
  135.     jz    jansept
  136.     lda    month+1    ; must be october to december...
  137.     cpi    '0'    ; october?
  138.     lxi    d,oct
  139.     jz    mmonth    ; move, if so
  140.     cpi    '1'    ; november?
  141.     lxi    d,nov
  142.     jz    mmonth    ; move, if so
  143.     lxi    d,dec    ; december!
  144.     jmp    mmonth    ; move it...
  145. jansept:lda    month+1    ; it's january to september
  146.     cpi    '1'    ; january?
  147.     lxi    d,jan
  148.     jz    mmonth    ; move, if so
  149.     cpi    '2'    ; february?
  150.     lxi    d,feb
  151.     jz    mmonth    ; move, if so
  152.     cpi    '3'    ; march?
  153.     lxi    d,mar
  154.     jz    mmonth    ; move, if so
  155.     cpi    '4'    ; april?
  156.     lxi    d,apr
  157.     jz    mmonth    ; move, if so
  158.     cpi    '5'    ; may?
  159.     lxi    d,may
  160.     jz    mmonth    ; move, if so
  161.     cpi    '6'    ; june?
  162.     lxi    d,jun
  163.     jz    mmonth    ; move month
  164.     cpi    '7'    ; july?
  165.     lxi    d,jul
  166.     jz    mmonth    ; move, if so
  167.     cpi    '8'    ; august?
  168.     lxi    d,aug
  169.     jz    mmonth    ; move, if so
  170.     lxi    d,sep    ; it's september
  171. mmonth:    mvi    b,4    ; four characters to move
  172.     lxi    h,fakem    ; place to move real month
  173. movem:    ldax    d    ; get the character to move
  174.     mov    m,a    ; move it
  175.     inx    h    ; bump both pointers
  176.     inx    d
  177.     dcr    b    ; de-bump the count left to move..
  178.     jnz    movem    ; loop 'till all characters moved
  179.     lxi    h,overlay        ; point to overlay area
  180.     lxi    d,fakem        ; point to stuff to be moved
  181.     mvi    b,end$move-start$move    ; how much to move...
  182. move1:    ldax    d    ; get stuff to move
  183.     mov    m,a    ; move it...
  184.     inx    h    ; bump both pointers
  185.     inx    d
  186.     dcr    b    ; de-bump the move counter
  187.     jnz    move1    ; loop 'till it's all moved
  188. done:    jmp    mac    ; now jump into MAC...
  189.  
  190. ddigit:    call    digit    ; read and store two digits
  191. digit:    mov    a,d    ; move digit select code to a reg.
  192.     call    rdigit    ; read a clock digit
  193.     cpi    0ffh    ; test for board present
  194.     jz    nobrd    ; go print error message
  195.     ori    030h    ; convert digit to ASCII
  196.     cpi    03fh    ; test for blanked leading zero
  197.     jnz    store    ; go store digit, if not blanked
  198.     mvi    a,020h    ; convert to a blank
  199. store:    mov    m,a    ; store the digit in message buffer
  200.     inx    h    ; bump message pointer buffer location
  201.     inr    d    ; step to next digit
  202.     ani    00fh    ; mask off high ASCII nibble
  203.     ret        ; return with digit in a reg.
  204.  
  205. nobrd:    pop    h    ; adjust the stack
  206.     lxi    d,errmsg; point to the error message
  207.     mvi    c,pbuf    ; print buffer function
  208.     call    bdos    ; let CP/M do the work
  209.     jmp    done    ; print error message, and exit to CP/M
  210.  
  211. rdigit:    out    clock    ; select digit
  212.     mvi    a,0    ; ...some delay time for settling
  213. dloop:    dcr    a
  214.     jnz    dloop
  215.     in    clock    ; read a digit
  216.     ret        ; return with digit in a reg.
  217.  
  218. ;
  219. ; message buffers
  220. ;
  221.  
  222. start$move    equ    $    ; start moving from here
  223. fakem:    ds    2    ; storage for faked-out month,
  224.             ; which will overlay the next four bytes
  225. month:    ds    4    ; storage for the real month and date
  226.     db    ',1980 '; the year...
  227. hour:    db    'xx:'    ; the hour...
  228.     db    'xx:'    ; the minute...
  229.     db    'xx'    ; the second...
  230.     db    0dh    ; string delimeter
  231. end$move    equ    $    ; end of move
  232.  
  233. errmsg:    db    cr,lf,'The Clock Board is NOT INSTALLED!',cr,lf,'$'
  234.  
  235. jan:    db    'Jan '
  236. feb:    db    'Feb '
  237. mar:    db    'Mar '
  238. apr:    db    'Apr '
  239. may:    db    'May '
  240. jun:    db    'Jun '
  241. jul:    db    'Jul '
  242. Aug:    db    'Aug '
  243. sep:    db    'Sep '
  244. oct:    db    'Oct '
  245. nov:    db    'Nov '
  246. dec:    db    'Dec '
  247.  
  248.     end
  249.  
  250.