home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol018 / asmtime.asm < prev    next >
Encoding:
Assembly Source File  |  1984-04-29  |  6.2 KB  |  245 lines
  1. ; 
  2. ; 
  3. ;  Here  is  an  interesting  "patch"  to  Digital  Research's 
  4. ; ASM.COM, that incorporates a "real time clock display.  This 
  5. ; patch   works with ASM.COM version 2.0 ONLY.  Merge it  into 
  6. ; ASM.COM as follows:
  7. ; 
  8. ;      A>DDT ASM.COM<cr>
  9. ;      NEXT   PC
  10. ;      2100  0100
  11. ;      -IASMTIME.HEX<cr>
  12. ;      -R<cr>
  13. ;      NEXT   PC
  14. ;      22BE  0000
  15. ;      -^C
  16. ;      A>SAVE 34 ASMTIME.COM<cr>
  17. ; 
  18. ;  Now  you have a new "ASM" command file called  ASMTIME.COM; 
  19. ; now  re-assemble  ASMTIME.ASM (assuming your  clock/calendar 
  20. ; board, and the time is properly set) with ASMTIME.COM.
  21. ; 
  22. ;  Notice,  that  the date and time will be displayed  at  the 
  23. ; start  of execution.
  24. ; 
  25. ;                         Best regards,
  26. ;           
  27. ;                         Kelly Smith, MP/M-Net (tm) Sysop
  28. ;                         (805) 527-9321 (Modem, 300 Baud)
  29. ;
  30. ;
  31. ;
  32. ; For Compu-Time T-102 TIME/DATE board (With MM 5375 AC)
  33. ;
  34. ; or,
  35. ;
  36. ; QT Computer Systems Inc. "Clock/Calendar +" board
  37. ;
  38. ;
  39. true    equ    -1    ; define true
  40. false    equ    not true; define false
  41. qt    equ    true    ; define QT Computer Systems Inc. board
  42. ct    equ    false    ; define Compu-Time board
  43.  
  44. bdos    equ    5
  45. pbuf    equ    9
  46.  
  47. cr    equ    0dh    ; ASCII carriage return
  48. lf    equ    0ah    ; ASCII line feed
  49.  
  50. asm    equ    200h    ; entry address to ASM.COM
  51.  
  52. overlay    equ    0fa0h    ; overlay area in ASM.COM
  53.  
  54.     if    qt
  55.  
  56. clock    equ    080h    ; real time clock base port address
  57.  
  58.     endif
  59.  
  60.     if    ct
  61.  
  62. clock    equ    024h    ; real time clock base port address
  63.  
  64.     endif
  65.  
  66.     org    109h
  67.  
  68.     jmp    date    ; jump to set date and time
  69.  
  70.     org    2100h    ; date and time routine
  71.  
  72. date:    lxi    h,month    ; point to month
  73.     mvi    d,8    ; select month tens digit
  74.     call    digit    ; read and store high digit
  75.     rlc ! rlc ! rlc ! rlc    ; shift to high order hex digit
  76.     mov    b,a    ; save in b reg.
  77.     call    digit    ; read and store month units digit
  78.     ora    b    ; or-in the units and tens digit
  79.     mov    b,a    ; save the month in b reg.
  80.     call    digit    ; read and store the day tens digit
  81.     rlc ! rlc ! rlc ! rlc    ; shift to high order hex digit
  82.     mov    c,a    ; save in c reg.
  83.     call    digit    ; read and store day units digit
  84.     ora    c    ; or-in the units and tens digit
  85.     mov    c,a    ; save the day in c reg.
  86.  
  87. ;
  88. ; test the date, and convert it to four year calendar format
  89. ;
  90.  
  91.     cpi    031h    ; 31st day?
  92.     mov    a,b    ; get the month, for next test
  93.     jnz    m2    ; if not the 31st, test for february
  94.     cpi    2    ; test for months < 31 days
  95.     jz    fix    ; ...and fix if needed
  96.     cpi    4
  97.     jz    fix
  98.     cpi    6
  99.     jz    fix
  100.     cpi    9
  101.     jz    fix
  102.     cpi    011h
  103.     jz    fix
  104. m2:    cpi    2    ; test for february
  105.     jnz    time    ; if not february, then read time
  106.     mov    a,c    ; get day for test
  107.     cpi    029h    ; is this the 29th day?
  108.  
  109. ;
  110. ; insert two NOP's over previous instruction, if this is a leap year
  111. ;
  112.     jz    fix    ; fix date...
  113.     cpi    030h    ; 30th day?
  114.     jnz    time    ; if not the 29th or 30th, go read time
  115. fix:    mvi    a,41    ; select month units and fast set
  116.     call    rdigit    ; read the month units digit
  117.     mov    b,a    ; save in b reg.
  118. floop:    in    clock    ; read the months unit digit
  119.     cmp    b    ; test for digit changed
  120.     jz    floop    ; wait until month is bumped (stable data)
  121. time:    lxi    h,hour    ; point to hour
  122.     mvi    d,0    ; select hour tens digit
  123.     call    ddigit    ; read hour tens and units
  124.     inx    h    ; step over ":"
  125.     call    ddigit    ; read minutes tens and units
  126.     inx    h    ; step over ":"
  127.     call    ddigit    ; read second tens and units
  128.     lda    month    ; get high byte of the month
  129.     cpi    ' '    ; in the range of january to september?
  130.     jz    jansept
  131.     lda    month+1    ; must be october to december...
  132.     cpi    '0'    ; october?
  133.     lxi    d,oct
  134.     jz    mmonth    ; move, if so
  135.     cpi    '1'    ; november?
  136.     lxi    d,nov
  137.     jz    mmonth    ; move, if so
  138.     lxi    d,dec    ; december!
  139.     jmp    mmonth    ; move it...
  140. jansept:lda    month+1    ; it's january to september
  141.     cpi    '1'    ; january?
  142.     lxi    d,jan
  143.     jz    mmonth    ; move, if so
  144.     cpi    '2'    ; february?
  145.     lxi    d,feb
  146.     jz    mmonth    ; move, if so
  147.     cpi    '3'    ; march?
  148.     lxi    d,mar
  149.     jz    mmonth    ; move, if so
  150.     cpi    '4'    ; april?
  151.     lxi    d,apr
  152.     jz    mmonth    ; move, if so
  153.     cpi    '5'    ; may?
  154.     lxi    d,may
  155.     jz    mmonth    ; move, if so
  156.     cpi    '6'    ; june?
  157.     lxi    d,jun
  158.     jz    mmonth    ; move month
  159.     cpi    '7'    ; july?
  160.     lxi    d,jul
  161.     jz    mmonth    ; move, if so
  162.     cpi    '8'    ; august?
  163.     lxi    d,aug
  164.     jz    mmonth    ; move, if so
  165.     lxi    d,sep    ; it's september
  166. mmonth:    mvi    b,4    ; four characters to move
  167.     lxi    h,fakem    ; place to move real month
  168. movem:    ldax    d    ; get the character to move
  169.     mov    m,a    ; move it
  170.     inx    h    ; bump both pointers
  171.     inx    d
  172.     dcr    b    ; de-bump the count left to move..
  173.     jnz    movem    ; loop 'till all characters moved
  174.     lxi    h,overlay        ; point to overlay area
  175.     lxi    d,fakem        ; point to stuff to be moved
  176.     mvi    b,end$move-start$move    ; how much to move...
  177. move1:    ldax    d    ; get stuff to move
  178.     mov    m,a    ; move it...
  179.     inx    h    ; bump both pointers
  180.     inx    d
  181.     dcr    b    ; de-bump the move counter
  182.     jnz    move1    ; loop 'till it's all moved
  183. done:    jmp    asm    ; now jump into ASM...
  184.  
  185. ddigit:    call    digit    ; read and store two digits
  186. digit:    mov    a,d    ; move digit select code to a reg.
  187.     call    rdigit    ; read a clock digit
  188.     cpi    0ffh    ; test for board present
  189.     jz    nobrd    ; go print error message
  190.     ori    030h    ; convert digit to ASCII
  191.     cpi    03fh    ; test for blanked leading zero
  192.     jnz    store    ; go store digit, if not blanked
  193.     mvi    a,020h    ; convert to a blank
  194. store:    mov    m,a    ; store the digit in message buffer
  195.     inx    h    ; bump message pointer buffer location
  196.     inr    d    ; step to next digit
  197.     ani    00fh    ; mask off high ASCII nibble
  198.     ret        ; return with digit in a reg.
  199.  
  200. nobrd:    pop    h    ; adjust the stack
  201.     lxi    d,errmsg; point to the error message
  202.     mvi    c,pbuf    ; print buffer function
  203.     call    bdos    ; let CP/M do the work
  204.     jmp    done    ; print error message, and exit to CP/M
  205.  
  206. rdigit:    out    clock    ; select digit
  207.     mvi    a,0    ; ...some delay time for settling
  208. dloop:    dcr    a
  209.     jnz    dloop
  210.     in    clock    ; read a digit
  211.     ret        ; return with digit in a reg.
  212.  
  213. ;
  214. ; message buffers
  215. ;
  216.  
  217. start$move    equ    $    ; start moving from here
  218. fakem:    ds    2    ; storage for faked-out month,
  219.             ; which will overlay the next four bytes
  220. month:    ds    4    ; storage for the real month and date
  221.     db    ',1980 '; the year...
  222. hour:    db    'xx:'    ; the hour...
  223.     db    'xx:'    ; the minute...
  224.     db    'xx'    ; the second...
  225.     db    0dh    ; string delimeter
  226. end$move    equ    $    ; end of move
  227.  
  228. errmsg:    db    cr,lf,'The Clock Board is NOT INSTALLED!',cr,lf,'$'
  229.  
  230. jan:    db    'Jan '
  231. feb:    db    'Feb '
  232. mar:    db    'Mar '
  233. apr:    db    'Apr '
  234. may:    db    'May '
  235. jun:    db    'Jun '
  236. jul:    db    'Jul '
  237. Aug:    db    'Aug '
  238. sep:    db    'Sep '
  239. oct:    db    'Oct '
  240. nov:    db    'Nov '
  241. dec:    db    'Dec '
  242.  
  243.     end
  244.  
  245.