home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol017 / tfx12-18.asm < prev    next >
Encoding:
Assembly Source File  |  1984-04-29  |  20.1 KB  |  881 lines
  1. ; ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  2. ; +           CP/M to CP/M file transfer utility             +
  3. ; ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  4. ;
  5. ; Revised 12/18/80,  to allow "wild card" filenames and  type,
  6. ; as well as "multi-file transfers"
  7. ; 
  8. ;                    TFX.ASM Version 1.2
  9. ; 
  10. ;                           as of
  11. ; 
  12. ;                     December 18, 1980
  13. ; 
  14. ; 
  15. ;                     HARWARE DEPENDENCE
  16. ;                     ------------------
  17. ; 
  18. ;  The  harware  requirment for inter-system file transfer  is 
  19. ; simply  two disk sub-systems of same or  differing  hardware 
  20. ; requirments  operating under the same host main frame micro-
  21. ; computer,  both  of which are capable of operating  under  a 
  22. ; CP/M environment.
  23. ; 
  24. ;                    SOFTWARE DEPENDENCE
  25. ;                    -------------------
  26. ;  
  27. ;  Both  disk sub-systems must be capable of running the  CP/M 
  28. ; disk  operating system.  Memory size of these systems is  of 
  29. ; little  importance  other  than one system 'MUST' be  of  at 
  30. ; least 5 kilo-bytes larger in size.
  31. ; 
  32. ;                        OPERATION
  33. ;                        ---------
  34. ; 
  35. ;  The  'Resident'  and 'Co-resident' systems are  defined  as 
  36. ; follows:
  37. ; 
  38. ;                     RESIDENT SYSYTEM
  39. ; 
  40. ;  The  resident  CP/M system,  larger in  terms  of  SYSGENed 
  41. ; memory size.
  42. ; 
  43. ;                    CO-RESIDENT SYSTEM
  44. ;    
  45. ;  The  co-resident CP/M system,  smaller in terms of SYSGENed 
  46. ; memory size.
  47. ; 
  48. ;  Initially you start up by booting the co-resident system as 
  49. ; you  normally  do and then transfer control to the  resident 
  50. ; system. There are several ways of doing this, the easiest is 
  51. ; using a file called GO.COM,  it's operation is simple;  type 
  52. ; GO 'XXXX' where XXXX represents the hexadecimal address  you 
  53. ; wish your processor to jump to, others include (with a front 
  54. ; panel  system) STOP,EXAMINE,RUN ( as for a MITS 8800b micro-
  55. ; computer)  the  address refered to is the  "primitive"  boot 
  56. ; address to your resident system.
  57. ; 
  58. ;  After completing the above operation, type:
  59. ;  TFX S:FN.FT D:FN.FT<cr>
  60. ; 
  61. ;  Where:
  62. ; 
  63. ;  TFX  is the com file transfer utility
  64. ;  
  65. ;  S:   is  the source drive reference (RESIDENT  system), A: 
  66. ;       thru P: under CP/M version 2.x
  67. ;  
  68. ;  D:   is  the  destination  drive  reference  (CO-RESIDENT 
  69. ;       system), A: thru P: under CP/M version 2.x
  70. ; 
  71. ;  FN:  is the file name (1 to 8 character)
  72. ;  
  73. ;  FT:  is the file type (1 to 3 character)
  74. ; 
  75. ;  <cr> carriage return, on your console keyboard
  76. ; 
  77. ; 
  78. ;  Note:  D:FN.FT does not have to agree with S:FN.FT; this is 
  79. ; an enventual call to 'make file' function to the co-resident 
  80. ; BDOS in CP/M.  Also, "wild card" filenames and  types may be
  81. ; used.
  82. ; 
  83. ; 
  84. ;                          MESSAGES
  85. ;                          --------
  86. ; 
  87. ; Resident bdos entry = XXXXH (hex address resident)
  88. ; 
  89. ; Co-resident bdos entry = XXXXH (hex  address  co-resident) 
  90. ; 
  91. ; No source file (source file can't be found)
  92. ; 
  93. ; No directory space (directory full on destination disk)
  94. ; 
  95. ; Write protected (destination disk is write protected)
  96. ; 
  97. ; Copy complete (file transfer has completed)
  98. ; 
  99. ; 
  100. ;              PATCH NOTES
  101. ;              -----------
  102. ; 
  103. ;  In   view  of  the  various  CP/M  (versions)  systems  and 
  104. ; programmers implementations (Lifeboat associates,...ugh),  I 
  105. ; have decided not to do any version checking (an attribute of 
  106. ; CP/M  2.x).  In  the TFX.ASM source file,  you  will  see  a 
  107. ; subroutine  that  calculates  the  co-resident  jump  vector 
  108. ; entries,  saves this address and then biases this value by a 
  109. ; constant  to  determine  the bdos entry  - the  address  you 
  110. ; normally  find  at  0005h.  This bias value is based  on  my 
  111. ; system  and  more than likely will have to  be  changed  for 
  112. ; yours.  This  is  simply the difference between 'warm  boot' 
  113. ; (this address is stored at 0000h) and BDOS (this address  is 
  114. ; stored  at 0005h).  I then simply take this address and do a 
  115. ; DAD  (double  add) to this bias,  a  subtraction  operation. 
  116. ; These address references are of cource with respect to  your 
  117. ; co-resident CP/M system. WARNING: DO NOT USE DDT (or SID) to 
  118. ; examine  address  0005h to use in your offset  calculations. 
  119. ; This address will overlayed by either debugger,  and will be 
  120. ; wrong.
  121. ; 
  122. ;  This  is  a  very simple file transfer  function,  in  fact 
  123. ; primitive.  I am in the process of writting a program  which 
  124. ; operates  in similar fashion to PIP.COM,  which is a  common 
  125. ; utility...at  the  time of this writting it's  still  pretty 
  126. ; "buggy".
  127. ; 
  128. ;                         Crable Enterprises - Brent J. Crable
  129. ; 
  130. ;
  131. ;
  132. ;++++++++++++++++++++++++++++++++++++++++++++++++
  133. ;+    CP/M to CP/M inter-system file transfer    +
  134. ;+    written by: Brent J. Crable   12/18/80    +
  135. ;++++++++++++++++++++++++++++++++++++++++++++++++
  136. ;
  137. boot:        equ     0        ;system reboot
  138. bdos:        equ     5        ;bdos entry point
  139. tfcb:        equ     5ch     ;system file control block
  140. disk$buf:   equ     80h     ;system disk buffer
  141. fn:        equ     1        ;file name offset
  142. ft:        equ     9        ;file type offset
  143. ex:        equ     12        ;extent number offset
  144. nr:        equ     32        ;next record offset
  145. ;
  146. cr        equ     0dh
  147. lf        equ     0ah
  148. ;
  149. ;+++++++++++++++++++++++++++++++++++++++++++++++
  150. ;+    CP/M primitive bdos functions           +
  151. ;+++++++++++++++++++++++++++++++++++++++++++++++
  152. ;
  153. read$con:   equ     1        ;read console
  154. write$con:  equ     2        ;print console
  155. printf:     equ     9        ;print buffer
  156. reset:        equ     13        ;reset disk
  157. open:        equ     15        ;open file
  158. close:        equ     16        ;close file
  159. sfirst:     equ     17        ;search first
  160. snext:        equ     18        ;search next
  161. delt:        equ     19        ;delete file
  162. read:        equ     20        ;read record
  163. write:        equ     21        ;write record
  164. make:        equ     22        ;make file
  165. setdma:     equ     26        ;set address
  166. ;
  167. ;**********    macro definitons    ****************
  168. ;
  169. mess    macro    m    ;print message m
  170. ;
  171.     lxi    d,m    ;;point to message
  172.     mvi    c,printf;;load cp/m print code
  173.     call    bdos    ;;disk primitive entry point
  174.     endm
  175. ;
  176. ;**************************************************
  177. ;
  178.     org    100h
  179. ;
  180. tfx:    lxi    sp,stack
  181. ;
  182.     mess    msg0    ;sign on
  183.     mess    msg1
  184.     lhld    bdos+1
  185.     mov    a,h    ;print bdos addr
  186.     call    phex
  187.     mov    a,l
  188.     call    phex
  189.     mvi    a,'H'
  190.     call    pchar
  191.     call    crlf
  192.     xra    a
  193.     sta    inp$buf$flg
  194.     sta    opt$buf$flg
  195. ;
  196. ;++++++++++++++++++++++++++++++++++++++++++++++
  197. ;+ calculate co-resident cp/m system location +
  198. ;++++++++++++++++++++++++++++++++++++++++++++++
  199. ;
  200. fndsys: lxi    h,4a00h ;set a start value
  201. tryag:    push    h    ;set pointer
  202.     mvi    b,15    ;number of jumps to match
  203. match:    mov    a,m
  204.     cpi    0c3h    ;look for jmp instruction
  205.     jz    jmpok    ;yes
  206.     pop    h
  207.     inr    h
  208.     jmp    tryag
  209. ;
  210. jmpok:    inx    h
  211.     inx    h
  212.     inx    h
  213.     dcr    b
  214.     jnz    match
  215. ;+++++++++++++++++++++++++++++++++++++++++++
  216. ;+ we found something that is probably the +
  217. ;+ co-resident CP/M bdos entry           +
  218. ;+++++++++++++++++++++++++++++++++++++++++++
  219.     pop    h    ;recover address
  220.     shld    xentry    ;co-res jmp vectors
  221.     lxi    d,-3578 ;bias to bdos (patchable)
  222.     dad    d
  223.     shld    xbdos
  224.     mess    msg1a
  225.     lhld    xbdos
  226.     mov    a,h    ;print xbdos addr
  227.     call    phex
  228.     mov    a,l
  229.     call    phex
  230.     mvi    a,'H'
  231.     call    pchar
  232.     call    crlf
  233. ;
  234. ;++++++++++++++++++++++++++++++++++++++++++++++++++++
  235. ;+ calculate buffer size =(xbdos-mbuff/modulus 128) +
  236. ;++++++++++++++++++++++++++++++++++++++++++++++++++++
  237. ;
  238.     lhld    xbdos
  239.     lxi    d,-6    ;hl = xbdos-6
  240.     dad    d
  241.     mov    a,l
  242.     ani    80h    ;hl = hl mod 128
  243.     mov    l,a
  244.     lxi    d,mbuf
  245.     mov    a,l
  246.     sub    e
  247.     mov    l,a
  248.     mov    a,h
  249.     sbb    d
  250.     mov    h,a
  251.     dad    h    ;hl = hl / 128
  252.     mov    l,h
  253.     mvi    a,0
  254.     aci    0
  255.     mov    h,a
  256.     dcx    h    ;subtract one
  257.     shld    aval$space   ;save as buffer size
  258.     mess    msg2    ;print buffer size =
  259.     lhld    aval$space   ;print size of buffer
  260.     call    wdwc
  261.     mess    msg3    ;print sectors
  262.     call    crlf
  263. ;+++++++++++++++++++++++++++++++++++++++++++++++++++
  264. ;+  notify user to mount data disk in host system  +
  265. ;+++++++++++++++++++++++++++++++++++++++++++++++++++
  266. ;
  267.     lda    tfcb+1    ;see if file name specified
  268.     cpi    ' '
  269.     jnz    tfx1
  270.     mess    msgz    ;error - no file name
  271.     jmp    boot
  272. ;
  273. tfx1:    mess    msg4
  274.     call    racc    ;read response
  275.     cpi    cr    ;loop if anything but cr
  276.     jnz    tfx1
  277. tfx1a:    call    crlf
  278.     lda    inp$buf$flg   ;jump if input buffer flag set
  279.     ora    a
  280.     jnz    tfx2a
  281. ;+++++++++++++++++++++++++++++++++++++++++++++++
  282. ;+ Move command line image into command buffer +
  283. ;+++++++++++++++++++++++++++++++++++++++++++++++
  284.     lxi    h,disk$buf  ;source
  285.     lxi    d,cmd$buf      ;destination
  286.     mov    b,m    ;fetch command line image length
  287.     inx    h
  288. tfx2:    mov    a,m    ;fetch next byte from cli
  289.     inx    h
  290.     stax    d
  291.     inx    d
  292.     dcr    b    ;decrement count
  293.     jnz    tfx2    ;loop untill zero
  294.     xra    a    ;store zero byte at end
  295.     stax    d
  296.     lxi    h,cmd$buf  ;reset cmd$bufp
  297.     shld    cmd$pt$buf
  298.     call    cfnt    ;create file name table
  299.     lxi    h,file$nt   ;reset file$nt pointers
  300.     shld    inp$fil$ntp
  301.     shld    opt$fil$ntp
  302. tfx2a:    lxi    h,mbuf    ;reset mbuf pointer
  303.     shld    mem$pt$buf
  304.     lhld    aval$space   ;reset msize
  305.     shld    mem$size
  306.     lda    inp$buf$flg   ;jump if inp$buf$flg not set
  307.     ora    a
  308.     jz    tfx3
  309.     lxi    h,input$fcb  ;copy input$fcb into tfcb
  310.     lxi    d,tfcb
  311.     mvi    b,33
  312.     call    move
  313.     xra    a    ;clear inp$buf$flg
  314.     sta    inp$buf$flg
  315.     mvi    a,1    ;set opt$buf$flg
  316.     sta    opt$buf$flg
  317.     lhld    inp$fil$ntp   ;back inp$fil$ntp up 4 bytes
  318.     lxi    d,-4
  319.     dad    d
  320.     shld    inp$fil$ntp
  321.     lxi    h,tfcb+fn ;print file name
  322.     call    wasc
  323.     mess    msg6    ;print -
  324.     lhld    inp$fil$ntp   ;de = inp$fil$ntp
  325.     xchg
  326.     jmp    tfx4    ;continue reading previous file
  327. ;++++++++++++++++++++++++++++++++++++++++++++++
  328. ;+ process next file name from command buffer +
  329. ;++++++++++++++++++++++++++++++++++++++++++++++
  330. ;
  331. tfx3:    lhld    inp$fil$ntp   ;fetch input fnt pointer
  332.     mov    a,m    ;jump if end of table
  333.     cpi    0ffh
  334.     jz    tfx9
  335.     mvi    m,1    ;set 'file read' flag
  336.     inx    h
  337.     lxi    d,tfcb+fn  ;copy filename into tfcb
  338.     mvi    b,11
  339.     call    move
  340.     shld    inp$fil$ntp   ;save input fnt pointer
  341.     lxi    h,tfcb+fn  ;print file name
  342.     call    wasc
  343.     mess    msg6
  344.     xra    a    ;setup tfcb
  345.     sta    tfcb
  346.     sta    tfcb+ex
  347.     sta    tfcb+nr
  348.     lxi    d,tfcb
  349.     mvi    c,open    ;open file
  350.     call    bdos
  351.     lhld    inp$fil$ntp
  352.     xchg
  353. tfx4:    lhld    mem$pt$buf
  354.     mov    a,h    ;copy into fnt entry
  355.     stax    d
  356.     inx    d
  357.     mov    a,l
  358.     stax    d
  359.     inx    d
  360.     xchg        ;save fnt pointer
  361.     shld    inp$fil$ntp
  362.     lxi    h,0    ;file size (in sectors) = 0
  363.     shld    file$size
  364. ;
  365. ; read next file from input disk
  366. ;
  367. tfx6:    lhld    mem$pt$buf
  368.     xchg
  369.     mvi    c,setdma
  370.     call    bdos
  371.     lxi    d,tfcb    ;read next sector (8)
  372.     mvi    c,read
  373.     call    bdos
  374.     ora    a    ;jump if normal transfer
  375.     jz    tfx7
  376.     cpi    1    ;jump if eof
  377.     jz    tfx8
  378.     mess    msg8    ;print read error - '
  379.     jmp    tfx8    ;continue as if eof
  380. ;
  381. tfx7:    lhld    mem$pt$buf   ;mem$pt$buf = mem$pt$buf + 128
  382.     lxi    d,128
  383.     dad    d
  384.     shld    mem$pt$buf
  385.     lhld    file$size   ;file$size = file$size + 1
  386.     inx    h
  387.     shld    file$size
  388.     lhld    mem$size
  389.     dcx    h
  390.     shld    mem$size
  391.     mov    a,h    ;loop if still positive
  392.     ora    l
  393.     jnz    tfx6
  394.     lxi    h,tfcb    ;copy tfcb into input$fcb
  395.     lxi    d,input$fcb
  396.     mvi    b,33
  397.     call    move
  398.     mvi    a,1    ;set inp$buf$flg
  399.     sta    inp$buf$flg
  400. tfx8:    lxi    d,disk$buf  ;reset dma pointer
  401.     mvi    c,setdma
  402.     call    bdos
  403.     lxi    d,tfcb
  404.     mvi    c,close  ;close file (8)
  405.     call    bdos
  406.     lhld    file$size   ;print file size
  407.     call    wdwc
  408.     mess    msg9    ;print sectors read'
  409. ;
  410. ; update file$nt, loop
  411. ;
  412.     lhld    file$size   ;de = file size
  413.     xchg
  414.     lhld    inp$fil$ntp   ;store file size in fnt entry
  415.     mov    m,d
  416.     inx    h
  417.     mov    m,e
  418.     inx    h
  419.     shld    inp$fil$ntp   ;save fnt pointer
  420.     lda    inp$buf$flg   ;loop if inp$buf$flg not set
  421.     ora    a
  422.     jz    tfx3
  423. ;
  424. ; ask user to mount output disk
  425. ;
  426. tfx9:    lda    pauseflg
  427.     ora    a
  428.     jz    tfx9a
  429.     xra    a
  430.     sta    pauseflg
  431.     mess    msga    ;print mount output disk, type cr
  432.     call    racc    ;read response
  433.     cpi    cr    ;loop if anything but cr
  434.     jnz    tfx9
  435.     call    crlf
  436.     jmp    tfx10
  437. ;
  438. tfx9a:    call    crlf
  439.     mess    msga1
  440.     call    crlf
  441. tfx10:    mvi    c,reset;reset disk system (make r/w)
  442.     call    entry
  443.     lda    opt$buf$flg   ;jump if opt$buf$flg not set
  444.     ora    a
  445.     jz    tfxa
  446.     lxi    h,output$fcb  ;copy output$fcb into tfcb
  447.     lxi    d,tfcb
  448.     mvi    b,33
  449.     call    move
  450.     lxi    d,tfcb
  451.     mvi    c,open    ;open previos file
  452.     call    entry
  453.     lhld    opt$fil$ntp   ;backup output fnt pointer 4 bytes
  454.     lxi    d,-4
  455.     dad    d
  456.     shld    opt$fil$ntp
  457.     lxi    h,tfcb+fn    ;print file name
  458.     call    wasc
  459.     mess    msg6    ;print -
  460.     jmp    tfxb    ;continue writing previous file
  461. ;
  462. pauseflg:
  463.     db    1    ;set true
  464. ;+++++++++++++++++++++++++++++++++++++++
  465. ;+ Write next file to destination disk +
  466. ;+++++++++++++++++++++++++++++++++++++++
  467. tfxa:    lhld    opt$fil$ntp
  468.     mov    a,m
  469.     ora    a
  470.     jz    tfxf
  471.     cpi    0ffh
  472.     jz    tfxf
  473.     inx    h
  474.     lxi    d,tfcb+fn
  475.     mvi    b,11
  476.     call    move
  477.     shld    opt$fil$ntp
  478.     lxi    h,tfcb+fn
  479.     call    wasc
  480.     mess    msg6
  481.     xra    a
  482.     sta    tfcb
  483.     sta    tfcb+ex
  484.     sta    tfcb+nr
  485.     lda    tfcb+9    ;fource to $r/w for 2.0
  486.     ani    7fh
  487.     sta    tfcb+9    ;fource to $dir for 2.0
  488.     lda    tfcb+10
  489.     ani    7fh
  490.     sta    tfcb+10
  491.     lxi    d,tfcb    ;try to create output file (5)
  492.     mvi    c,delt
  493.     call    entry
  494.     lxi    d,tfcb
  495.     mvi    c,make
  496.     call    entry
  497.     cpi    255    ;jump if o.k.
  498.     jnz    tfxb
  499.     mess    msgb    ;print unable to create'
  500.     jmp    tfxg
  501. ;
  502. tfxb:    lhld    opt$fil$ntp
  503.     mov    d,m    ;fetch fwa of file from fnt
  504.     inx    h
  505.     mov    e,m
  506.     inx    h
  507.     xchg
  508.     shld    mem$pt$buf   ;save it
  509.     xchg
  510.     mov    d,m    ;fetch size of file from pointer
  511.     inx    h
  512.     mov    e,m
  513.     inx    h
  514.     xchg
  515.     shld    file$size   ;save it
  516.     shld    prt$size   ;save for printout
  517.     xchg
  518.     shld    opt$fil$ntp
  519.     lhld    file$size   ;jump   if file$size = 0
  520.     mov    a,h
  521.     ora    l
  522.     jz    tfxda
  523. tfxc:    lhld    mem$pt$buf   ;set dma address to mbuff
  524.     xchg
  525.     mvi    c,setdma
  526.     call    entry
  527.     lxi    d,tfcb    ;write next sector (5)
  528.     mvi    c,write
  529.     call    entry
  530.     ora    a    ;jump if ok
  531.     jz    tfxd
  532.     mess    msgc    ;error writting file
  533.     jmp    tfxg
  534. ;
  535. tfxd:    lhld    mem$pt$buf   ;mem$pt$buf = mem$pt$buf + 128
  536.     lxi    d,128
  537.     dad    d
  538.     shld    mem$pt$buf
  539.     lhld    file$size   ;file$size = file$size - 1
  540.     dcx    h
  541.     shld    file$size
  542.     mov    a,h    ;loop until zero
  543.     ora    l
  544.     jnz    tfxc
  545. tfxda:    lxi    h,tfcb    ;copy tfcb into output$fcb
  546.     lxi    d,output$fcb
  547.     mvi    b,33
  548.     call    move
  549.     lxi    d,disk$buf  ;reset dma pointer
  550.     mvi    c,setdma
  551.     call    entry
  552.     mvi    c,close ;try to close file (5)
  553.     lxi    d,tfcb
  554.     call    entry
  555.     cpi    255    ;jump if ok
  556.     jnz    tfxe
  557.     mess    msgd    ;unable to close
  558. tfxe:    lhld    prt$size   ;print number of sectors written
  559.     call    wdwc
  560.     mess    msge    ;print sectors written
  561.     jmp    tfxa
  562. ;
  563. tfxf:    lda    inp$buf$flg   ;loop if inp$buf$flg set
  564.     ora    a
  565.     jnz    tfxh
  566. tfxg:    mess    msgf    ;exit to cp/m
  567.     call    racc    ;read response
  568.     cpi    cr    ;loop if anything but cr
  569.     jnz    tfxg
  570.     jmp    boot    ;reboot cp/m
  571. ;
  572. tfxh:    call    crlf
  573.     mess    msgg
  574.     jmp    tfx1a
  575. ;
  576. ;    subroutines
  577. ;
  578. move:    mov    a,m
  579.     inx    h
  580.     stax    d
  581.     inx    d
  582.     dcr    b
  583.     jnz    move
  584.     ret
  585. ;+++++++++++++++++++++++++++++++++++
  586. ;+    get file name subroutine       +
  587. ;+++++++++++++++++++++++++++++++++++
  588. getn:    mov    a,m
  589.     ora    a
  590.     rz
  591.     cpi    ' '
  592.     jnz    getno
  593.     inx    h
  594.     jmp    getn
  595. ;
  596. getno:    lxi    d,temp$fcb
  597.     xra    a
  598.     stax    d
  599.     inx    d
  600.     push    d
  601.     mvi    b,11
  602.     mvi    a,' '
  603. getn6:    stax    d
  604.     inx    d
  605.     dcr    b
  606.     jnz    getn6
  607.     pop    d
  608.     mvi    b,9
  609. getn1:    mov    a,m
  610.     ora    a
  611.     jz    getn4
  612.     inx    h
  613.     cpi    ' '
  614.     jz    getn4
  615.     cpi    '.'
  616.     jz    getn2
  617.     cpi    '*'
  618.     jz    getn7
  619.     stax    d
  620.     inx    d
  621.     dcr    b
  622.     jz    getn5
  623.     jmp    getn1
  624. ;
  625. getn7:    dcr    b
  626.     jz    getn9
  627.     mvi    a,'?'
  628.     stax    d
  629.     inx    d
  630.     jmp    getn7
  631. ;
  632. getn9:    mov    a,m
  633.     cpi    '.'
  634.     jnz    getn4
  635.     inx    h
  636. getn2:    lxi    d,temp$fcb+ft
  637.     mvi    b,4
  638. getn3:    mov    a,m
  639.     ora    a
  640.     jz    getn4
  641.     inx    h
  642.     cpi    ' '
  643.     jz    getn4
  644.     cpi    '*'
  645.     jz    getn8
  646.     stax    d
  647.     inx    d
  648.     dcr    b
  649.     jz    getn5
  650.     jmp    getn3
  651. ;
  652. getn8:    dcr    b
  653.     jz    getn4
  654.     mvi    a,'?'
  655.     stax    d
  656.     inx    d
  657.     jmp    getn8
  658. ;
  659. getn4:    xra    a
  660.     ret
  661. ;
  662. getn5:    stc
  663.     ret
  664. ;
  665. ;+++++++++++++++++++++++++++++++++++
  666. ;+    create file names table       +
  667. ;+++++++++++++++++++++++++++++++++++
  668. ;
  669. cfnt:    lxi    h,file$nt   ;reset inp$fil$ntp
  670.     shld    inp$fil$ntp
  671. cfnt1:    lhld    cmd$pt$buf   ;get cmd$pt$buf
  672.     mov    a,m
  673.     ora    a
  674.     rz
  675.     call    getn     ;get next afn
  676.     shld    cmd$pt$buf   ;save command buffer ptr
  677.     jnc    cfnt2
  678.     mess    msg5    ;print syntax error in filename
  679.     jmp    cfnt1
  680. ;
  681. cfnt2:    xra    a    ;clear temp$fcb extent field
  682.     sta    temp$fcb+ex
  683.     lxi    d,temp$fcb  ;search for first occurance
  684.     mvi    c,sfirst
  685.     call    bdos
  686.     cpi    255    ;jump found
  687.     jnz    cfnt3
  688.     lxi    h,temp$fcb+fn  ;print filename
  689.     call    wasc
  690.     mess    msg7    ;print not found
  691.     jmp    boot    ;exit to cp/m
  692. ;
  693. cfnt3:    ani    3    ;index into cbuf
  694.     mov    l,a
  695.     mvi    h,0
  696.     dad    h    ;*2
  697.     dad    h    ;*4
  698.     dad    h    ;*8
  699.     dad    h    ;*16
  700.     dad    h    ;*32
  701.     lxi    d,disk$buf
  702.     dad    d
  703.     xchg        ;copy filename into file$nt
  704.     lhld    inp$fil$ntp
  705.     xchg
  706.     mvi    b,12
  707.     call    move
  708.     lxi    h,nulls ;buffer rest of entry
  709.     mvi    b,4
  710.     call    move
  711.     xchg
  712.     shld    inp$fil$ntp   ;save input file$nt pointer
  713.     mvi    m,0ffh    ;insure ff byte at end
  714.     lxi    d,temp$fcb  ;search for next occurance
  715.     mvi    c,snext
  716.     call    bdos
  717.     cpi    255    ;jump if found
  718.     jnz    cfnt3
  719.     jmp    cfnt1    ;go get next afn
  720. ;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  721. ;+   print ascii string to console - terminated by '0'     +
  722. ;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  723. ;
  724. wasc:    mov    a,m
  725.     ora    a
  726.     rz
  727.     call    pchar     ;print it
  728.     inx    h
  729.     jmp    wasc
  730. ;++++++++++++++++++++++++++++++++++++
  731. ;+   print end of line to console   +
  732. ;++++++++++++++++++++++++++++++++++++
  733. crlf:    mess    msgx
  734.     ret
  735. ;++++++++++++++++++++++++++++++++++++
  736. ;+   print decimal word to console  +
  737. ;++++++++++++++++++++++++++++++++++++
  738. wdwc:    push    h
  739.     push    d
  740.     push    b
  741.     mvi    b,0    ;clear b
  742.     lxi    d,10000 ;print 1st digit
  743.     call    wndd
  744.     lxi    d,1000    ;print 2nd digit
  745.     call    wndd
  746.     lxi    d,100    ;print 3rd digit
  747.     call    wndd
  748.     lxi    d,10    ;print 4th digit
  749.     call    wndd
  750.     lxi    d,1    ;print 5th digit
  751.     mvi    b,1    ;force last digit to print
  752.     call    wndd
  753.     pop    b
  754.     pop    d
  755.     pop    h
  756.     ret
  757. ;
  758. wndd:    mvi    c,0    ;c = 0
  759. wndd1:    mov    a,l    ;hl = hl - de
  760.     sub    e
  761.     mov    l,a
  762.     mov    a,h
  763.     sbb    d
  764.     mov    h,a
  765.     jc    wndd2    ;jump if < 0
  766.     inr    c    ;c = c + 1
  767.     jmp    wndd1    ;loop
  768. ;
  769. wndd2:    dad    d    ;hl = hl + de
  770.     mov    a,c    ;jump if c non-zero
  771.     ora    c
  772.     jnz    wndd4
  773.     mov    a,b    ;jump if digit written
  774.     ora    b
  775.     jnz    wndd4
  776.     mvi    a,' '    ;print one space
  777.     jmp    pchar
  778. ;
  779. wndd4:    mvi    b,1    ;set 'digit written' flag
  780.     mov    a,c    ;encode c into decimal ascii
  781.     adi    '0'
  782.     jmp    pchar     ;go print it
  783. ;
  784. phex:    push    psw
  785.     rrc
  786.     rrc
  787.     rrc
  788.     rrc        ;shift right 4
  789.     call    pnib    ;print nibble
  790.     pop    psw
  791.     call    pnib
  792.     ret
  793. ;
  794. pnib:    ani    0fh
  795.     cpi    10
  796.     jnc    p10
  797. ;less than or equal to 9
  798.     adi    '0'
  799.     jmp    prn
  800. ;greater or equal to 10
  801. p10:    adi    'A'-10
  802. prn:    call    pchar
  803.     ret
  804. ;++++++++++++++++++++++++++++++++++++++++++++
  805. ;+ pchar - print ascii character to console +
  806. ;++++++++++++++++++++++++++++++++++++++++++++
  807. pchar:    push    h    ;no - this isn't over kill !
  808.     push    d
  809.     push    b
  810.     push    psw
  811.     mvi    c,write$con
  812.     mov    e,a    ;character to e
  813.     call    bdos
  814.     pop    psw
  815.     pop    b
  816.     pop    d
  817.     pop    h
  818.     ret
  819. ;
  820. ; racc - read ascii character from console
  821. ;
  822. racc:    mvi    c,read$con
  823.     jmp    bdos
  824. ;
  825. entry:    db    0cdh    ;call instruction
  826. xbdos:    ds    2    ;address to xbdos
  827.     ret        ;return to caller
  828. ;
  829. ;
  830. msg0:    db    ' >>   CP/M to CP/M file transfer utility   <<'
  831.     db    cr,lf
  832.     db    ' Version 1.2  as of 12/18 by: Brent J. Crable'
  833.     db    cr,lf,cr,lf,'$'
  834. msg1:    db    '   resident bdos entry = $'
  835. msg1a:    db    'co-resident bdos entry = $'
  836. msg2:    db    'buffer size =$'
  837. msg3:    db    ' (128) byte sectors',cr,lf,'$'
  838. msg4:    db    'Mount source disk in <A>, type CR',cr,lf,'$'
  839. msg5:    db    'syntax error in file name',cr,lf,'$'
  840. msg6:    db    ' - $'
  841. msg7:    db    ' not found',cr,lf,'$'
  842. msg8:    db    'read error - $'
  843. msg9:    db    ' sectors read',cr,lf,'$'
  844. msga:    db    cr,lf,'Mount destination disk in <A>, type CR',cr,lf,'$'
  845. msga1:    db    '+++ Writing to destination disk +++',cr,lf,'$'
  846. msgb:    db    'unable to create',cr,lf,'$'
  847. msgc:    db    'error writing file',cr,lf,'$'
  848. msgd:    db    'unable to close',cr,lf,'$'
  849. msge:    db    ' sectors written',cr,lf,'$'
  850. msgf:    db    cr,lf,'insert host cp/m disk, type CR$'
  851. msgg:    db    '+++ Reading from source disk +++',cr,lf,'$'
  852. msgx:    db    cr,lf,'$'
  853. msgz:    db    '+++ no file name specified +++$'
  854. ;
  855. ;
  856. nulls:    db    0,0,0,0
  857. ;
  858.     org    ($+15)/16*16
  859. ;
  860. file$nt:      ds      16*64+1 ;file name table
  861. stack:          ds      64      ;64 level stack
  862. aval$space:   ds      2       ;available space
  863. mem$size:     ds      2       ;memory size
  864. cmd$buf:      ds      80      ;command buffer
  865. cmd$pt$buf:   ds      2       ;command buffer pointer
  866. file$size:    ds      2       ;file size in sectors
  867. prt$size:     ds      2       ;file size for printout
  868. inp$fil$ntp:  ds      2       ;input fnt pointer
  869. opt$fil$ntp:  ds      2       ;output fnt pointer
  870. mem$pt$buf:   ds      2       ;memory buffer pointer
  871. input$fcb:    ds      33      ;input file control block
  872. output$fcb:   ds      33      ;output file control block
  873. temp$fcb:     ds      33      ;temporary file control block
  874. inp$buf$flg:  ds      1       ;input break flag
  875. opt$buf$flg:  ds      1       ;output break flag
  876. xentry:       ds      2       ;co-resident jmp table entry
  877. ;
  878. mbuf:    equ    $
  879.     end    tfx
  880.  
  881.