home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol006 / zx65r.zsm < prev    next >
Encoding:
Text File  |  1984-04-29  |  38.7 KB  |  1,777 lines
  1.     NAME    ZXMAIN
  2.     TITLE    ZX65  VER 2.1  8/80  RMK
  3. ;
  4. ; V 2.1 OF ZX65 IS MODIFIED TO BE LINKED AT ASSEMBLY
  5. ; TIME WITH ZXLD V 2.1.  THIS COMBINATION IS TOTALLY
  6. ; RELOCATABLE, AND WILL FUNCTION UNDER ANY CPM 1.4
  7. ; SYSTEM SIZE.  FORMAT IS FOR SD SYSTEMS ASSEMBLER
  8. ; V 3.3 AND LINKER V 3.0
  9. ;
  10. ; V 2.1 INCLUDES ALL PREVIOUS MODS PLUS CORRECTED
  11. ; JSR/JMP/RTS FUNCTIONS.
  12. ;
  13.     GLOBAL    RELBAS
  14. ;
  15. BASE    EQU    $
  16. HOST    EQU     BASE+0F00H    ; HOST SYSTEM CBIOS
  17. SYSTK    EQU    HOST        ; SYSTEM STACK
  18. CPWRM    EQU    HOST+3        ; CP/M COLD ST
  19. CONST    EQU    HOST+6        ; HOST SYSTEM INPUT TEST
  20. CONIN   EQU     HOST+9        ; HOST SYSTEM CONS IN
  21. CONOUT  EQU     HOST+0CH    ; HOST SYSTEM CONS OUT
  22. HOME    EQU    HOST+18H    ; DRIV HOME
  23. SETDRV    EQU    HOST+1BH    ; SELECT DRVE
  24. SETTRK    EQU    HOST+1EH    ; SELECT TRACK
  25. SETSEC    EQU    HOST+21H    ; SELECT SECTOR
  26. SETBUF    EQU    HOST+24H    ; SET XFER ADDRESS
  27. READ    EQU    HOST+27H    ; READ A SECTOR
  28. WRITE    EQU    HOST+2AH    ; WRITE A SECTOR
  29. ;
  30. RELBAS    LD    SP,SYSTK
  31.     LD    C,1
  32.     CALL    DRVS        ; ACTIVATE DRV B
  33.     CALL    HOMB        ; AND INIT IT
  34.     LD      IY,INTRO
  35.     CALL    PRTXT        ; PRINT HEADER
  36.     CALL    CRLF
  37. ;
  38. ; COMMAND LEVEL...RETURN HERE FROM ANY POINT IN PGM
  39. ;
  40. CMND    LD      HL,CMND
  41.     PUSH    HL        ; RET ADDR ON STACK
  42.     CALL    CRLF
  43.     CALL    PROM
  44.     CALL    GETCHR        ; GET COMMAND
  45.     CP    'E'
  46.     JP    Z,EXAM        ; EXAM MEMORY
  47.     CP    'M'
  48.     JP    Z,SUBM        ; SUB MEMORY
  49.     LD    IX,VREG        ; FOR SIMX
  50.     CP      'B'
  51.     JR      Z,BRKP-$    ; RUN TO BREAKPOINT
  52.     CP    'C'
  53.     JP    Z,RGSTR        ; DSPLY/MODIFY CPU REGS
  54.     CP      'G'
  55.     JP    Z,RUN        ; RUN FROM NPC
  56.     CP    'T'
  57.     JR    Z,MULTX-$    ; TRACE/DISPLAY N STEPS
  58.     CP      ' '
  59.     JR      Z,EXONE-$    ; EX ONE INSTR & STOP
  60.     LD    IX,BUFFR    ; FOR DOS
  61.     CP      'D'
  62.     JP      Z,PDIR        ; DOS DIR
  63.     CP      'I'
  64.     JP      Z,INIT        ; DOS INITIALIZE
  65.     CP      'K'
  66.     JP      Z,KILL        ; DOS ERASE
  67.     CP      'L'
  68.     JP      Z,LOAD        ; DOS LOADER
  69.     CP    'R'
  70.     JP    Z,LDGO        ; LOAD AND RUN PGM
  71.     CP      'S'
  72.     JP      Z,SAVE        ; DOS SAVER
  73.     LD    C,'?'
  74.     CALL    PRNC        ; INVALID COMMAND
  75.     JR    CMND-$
  76. ;
  77. ; EXECUTE N STEPS
  78. ;
  79. MULTX    LD    IY,MLTMSG
  80.     CALL    PRTXT
  81.     CALL    GETWRD        ; GET N
  82.     LD    A,E
  83.     JR      NZ,DOMULT-$
  84. EXONE   LD      A,1        ; EXECUTE 1 STEP
  85. ;
  86. ; EXECUTE # STEPS IN A
  87. ;
  88. DOMULT  LD      (NSTEPS),A      ; STORE N IN TEMP
  89.     CALL    STEP        ; EXEC & DSPLY INSTR
  90.     CALL    DSPLY
  91.     LD      A,(NSTEPS)
  92.     DEC     A
  93.     RET    Z
  94.     PUSH    AF
  95.     LD    BC,DLYCON    ; DELAY FOR VIEWING
  96. DOLP    DEC    BC
  97.     LD    A,B
  98.     OR    C
  99.     JR    NZ,DOLP-$
  100.     POP    AF
  101.     JR    DOMULT-$
  102. ;
  103. ; RUN WITHOUT DISPLAY TO BREAKPOINT
  104. ;
  105. BRKP    LD    IY,BKPMSG
  106.     CALL    PRTXT
  107.     CALL    GETWRD         ; GET IT
  108.     LD      (BREAK),DE      ; STORE IT IN TEMP
  109. BKLP    CALL    STEP        ; EXEC ONE INSTR
  110.     LD      DE,(BREAK)
  111.     LD      A,H        ; CHECK IF AT BKPT
  112.     CP      D
  113.     JR      NZ,INTST-$
  114.     LD      A,L
  115.     CP      E
  116.     JR    NZ,INTST-$
  117.     CALL    STEP        ; DO ONE MORE
  118.     JR    DSPLY-$
  119. INTST    CALL    KBST        ; TEST FOR KBD INP
  120.     JR    Z,BKLP-$    ; CONTINUE IF NONE
  121.     JR    QDSP-$
  122. ;
  123. ; RUN ONLY..NO DISPLAY OR BREAKPOINT
  124. ;
  125. RUN     CALL    STEP        ; DO A STEP
  126.     CALL    KBST        ; CHECK FOR KB INPUT
  127.     JR    Z,RUN-$        ; IF NONE JUST REPEAT
  128. ;
  129. ; STOP, DISPLAY, & RET TO CMND
  130. ;
  131. QDSP    CALL    KBIN        ; CLEAR UART
  132.     JR    DSPLY-$        ; DISP CPU & RET
  133. ; 
  134. ; DISPLAY & UPDATE CPU REGISTERS
  135. ;
  136. RGSTR   PUSH    IX
  137.     CALL    CRLF
  138.     LD      IY,HEADR+42
  139.     CALL    PRN6         ; PRINT RG NAME
  140.     LD      DE,(NPC)     ; NEXT PC TO DE
  141.     CALL    PRTWRD        ; PRINT IT
  142.     CALL    PROM         ; PROMPT FOR CHANGE
  143.     CALL    GETWRD
  144.     JR      Z,AREG-$     ; SPACE = NO CHANGE
  145.     LD    (NPC),DE    ; PUT IN NEW VALUE
  146. AREG    LD      IY,HEADR+12
  147.     LD      B,5
  148. NREG    CALL    CRLF         ; DO REST OF REGS
  149.     CALL    PRN6         ; PRINT NAME
  150.     LD      E,(IX+0)
  151.     CALL    PRTBYT        ; PRINT CONTENTS
  152.     CALL    PROM        ; PROMPT FOR CHANGE
  153.     CALL    GETWRD
  154.     JR      Z,NXTREG-$      ; SPACE = NO CHANGE
  155.     LD      (IX+0),E
  156. NXTREG  INC     IX        ; POINT TO NEXT REG
  157.     DJNZ    NREG-$         ; DO AGAIN IF MORE
  158.     POP     IX
  159.     RET
  160. ;
  161. ; DISPLAY PC, INSTRUCTION, AND ALL REGISTERS
  162. ;
  163. DSPLY    PUSH    IX        ; SAVE POINTER
  164.     PUSH    BC        ; SAVE MNEMONIC CODE
  165.     CALL    CRLF
  166.     LD    IY,HEADR
  167.     CALL    PRN6        ; 'CPC'
  168.     LD    DE,(CPC)
  169.     CALL    PRTWRD        ; VALUE
  170.     CALL    PRN6        ; 'INS'
  171.     POP    BC
  172.     PUSH    IY
  173.     PUSH    BC
  174.     LD    IY,MNMTBL    ; DET MNEM FROM BC
  175.     LD    A,0FCH
  176.     AND    C
  177.     SRL    A
  178.     LD    E,A
  179.     LD    D,0
  180.     ADD    IY,DE
  181.     LD    E,(IY+0)    ; GET PACKED MNEM
  182.     LD    D,(IY+1)
  183.     SLA    E        ; UNPACK IT
  184.     RL    D
  185.     LD    C,3        ; & PRINT THREE CHRS
  186. MNM2    XOR    A
  187.     LD    B,5
  188. MNM1    SLA    E
  189.     RL    D
  190.     RLA
  191.     DJNZ    MNM1-$
  192.     SET    6,A
  193.     PUSH    BC
  194.     CALL    PRNA
  195.     POP    BC
  196.     DEC    C
  197.     JR    NZ,MNM2-$
  198.     POP    BC        ; DECODE ADDR MODE
  199.     LD    A,B
  200.     SLA    A
  201.     SLA    A
  202.     SLA    A
  203.     LD    E,A
  204.     LD    D,0
  205.     LD    IY,AMDTBL
  206.     ADD    IY,DE
  207.     CALL    PRN8        ; PRINT ADDR MODE
  208.     POP    IY
  209.     LD    B,5
  210. DSP1    CALL    PRN6        ; PRINT ALL REGS
  211.     LD    E,(IX+0)
  212.     CALL    PRTBYT
  213.     INC    IX
  214.     DJNZ    DSP1-$
  215.     CALL    PRN6        ; PRINT NEXT PC
  216.     LD    DE,(NPC)
  217.     CALL    PRTWRD
  218.     POP    IX
  219.     RET
  220. ;
  221. PRN6    LD    E,6        ; PRINT 6 CHARS PER IY
  222.     JP    PRNLP
  223. PRN8    LD      E,8        ; PRINT 8 CHRS PER IY
  224.     JP      PRNLP
  225. ;
  226. ; CODE FOR DECODING AND EXECUTING ONE INSTRUCTION
  227. ; ENTER WITH HL POINTING TO INSTR TO BE DECODED. EXITS
  228. ; WITH HL POINTING TO NEXT INSTR, B HOLDING ADDRESSING
  229. ; MODE CODE, C HOLDING MNEMONIC CODE
  230. ;
  231. STEP    LD      HL,(NPC)     ; NEXT PC TO HL
  232.     LD      (CPC),HL     ; BECOMES CURRENT PC
  233.     LD      A,(HL)         ; OP CODE
  234.     OR      A         ; ZERO?
  235.     JP      Z,PBRK         ; IF SO, 'BRK'
  236.     BIT     0,A        ; TEST LSD FOR ODD/EVEN
  237.     JP      NZ,MLTMOD    ; ODD INSTRS MULTI MODE
  238.     AND     0FH
  239.     JR      NZ,FLGTST-$
  240.     LD      A,(HL)         ; RESTORE OP CODE
  241.     BIT     4,A        ; MSD ODD/EVEN
  242.     JP      NZ,PBRNCH    ; IF ODD, BRANCH
  243.     CP      20H
  244.     JP      Z,PJSR        ; PROCESS JSR
  245.     CP      40H
  246.     JP      Z,PRTI        ; PROCESS RTI
  247.     CP      60H
  248.     JP      Z,PRTS        ; PROCESS RTS
  249.     JP      MLTMOD        ; ELSE MULTI MODE
  250. FLGTST  CP      8
  251.     JR      NZ,IMP2-$
  252.     LD      A,(HL)        ; RESTORE
  253.     BIT     4,A        ; MSD ODD/EVEN
  254.     JP      Z,PIMPL        ; IF EVEN, MST BE IMPLD
  255.     CP      98H        ; MSD = 9?
  256.     JP      Z,PTYA        ; YES, PROC TYA SPECIAL
  257.     JP      PFLGS        ; ELSE PROCESS FLAG OPS
  258. IMP2    CP      0AH
  259.     JR      NZ,JMPTST-$     ; MUST BE JUMP
  260.     LD      A,(HL)        ; RESTORE
  261.     AND     0F0H        ; TESTS ON MSD
  262.     BIT     4,A        ; ODD/EVEN
  263.     JP      NZ,PTSS        ; PROSESS SP OPS SPECIAL
  264.     CP      70H
  265.     JP      C,MLTMOD     ; PROCESS ACCUM MODES
  266.     JP      PIMPL       ; ELSE MORE IMPLIEDS
  267. JMPTST  LD      A,(HL)        ; RESTORE OP CODE
  268.     CP      4CH
  269.         JP      Z,PJABS        ; PROCESS ABS JMP
  270.     CP      6CH
  271.         JP      Z,PJIND        ; PROCESS INDIRECT JMP
  272.     JP      MLTMOD
  273. ;
  274. ; INSTURCTION PROCESSORS BEGIN HERE.. ENTER WITH
  275. ; HL = PC, IX POINTING TO SIM CPU
  276. ;
  277. ; IF BRK VECTOR (IPOINT) = 0, RETURN TO CMND
  278. ;
  279. PBRK    SET     4,(IX+1)    ; SET BRK STATUS BIT
  280.     LD    HL,(IPOINT)    ; SEE IF RET TO CMND
  281.     LD    A,H
  282.     OR    L
  283.     JR    NZ,BRK1-$
  284.     POP    BC        ; ADJUST SP
  285.     LD    BC,429H        ; RET TO CMND
  286.     JP    DSPLY
  287. BRK1    INC    HL        ; NORMAL BREAK
  288.         CALL    TSPY          ; SP TO IY
  289.     LD      (IY+0),H    ; 'PUSH' PC
  290.         DEC     IY
  291.     LD      (IY+0),L
  292.         DEC     IY
  293.     LD      A,(IX+1)    ; 'PUSH' P
  294.         LD      (IY+0),A
  295.     DEC     IY
  296.         CALL    TYSP          ; IY TO SP
  297.     LD      HL,(IPOINT)    ; GET INTERRUPT VECTOR
  298.         LD      BC,429H        ; CODE FOR # BYTES & MNEM
  299.     JP      END1          ; AND FINISH
  300. ;
  301. ; PROCESS BRANCHES
  302. ;
  303. PBRNCH    LD      B,0            ; FORM INDEX INTO MSKTBL
  304.     LD      C,(HL)        ; INSTR TO C
  305.     LD    IY,MSKTBL
  306.         SRL     C        ; GET MSD
  307.     SRL     C
  308.         SRL     C
  309.     SRL     C
  310.         DEC     C
  311.     ADD     IY,BC
  312.         INC     HL             ; POINT TO OFFSET
  313.     BIT     1,C        ; MSD ODD/EVEN
  314.     LD    A,(IX+1)    ; P REG TO ACC
  315.         LD      C,(IY+0)    ; # CODE
  316.     LD      B,(IY+1)    ; FLAG MASK
  317.         JR      NZ,BRSET-$    ; ODD/EVEN DET SET/CLR
  318.     AND     B             ; ISOLATE BIT FOR TEST
  319.         JR      Z,TRUE-$
  320.     JR      FALSE-$
  321. BRSET   AND     B
  322.     JR      NZ,TRUE-$
  323.         JR      FALSE-$
  324. TRUE    LD      D,0           ; CONDITION MET; BRANCH
  325.     LD      E,(HL)        ; OFFSET TO E
  326.         BIT    7,E            ; CHECK SIGN OF OFFSET
  327.     JR      Z,TRU1-$
  328.         DEC     D              ; IF B7 IS SET, DO NEG
  329. TRU1    ADD     HL,DE         ; ADD OFFSET FOR NEW PC
  330. FALSE   LD      B,0        ; COND NOT MET; GO ON
  331.     JP      END
  332. ;
  333. ; PROCESS JUMPS AND JSR...JMP 0-4 AND JSR 0-4 GO INTO Z80
  334. ; ROUTINES PER JUMP TABLE AT USR0. CONTROL THEN RETURNS
  335. ; TO SIMULATOR UPON Z80 'RET' (C9).. ALL OTHERS PROCESSED
  336. ; NORMALLY.
  337. ;
  338. PJSR    LD    BC,273H        ; JSR
  339.     PUSH    BC
  340.     CALL    SPCTST        ; TEST FOR USER
  341.     JR    NZ,PJS2-$
  342.     CALL    INUSR        ; GO TO USER SR
  343.     POP    BC
  344.     JR    EE0-$
  345. PJS2    CALL    TSPY        ; NORMAL JSR
  346.     LD      (IY+0),H    ; PUSH CURRENT PC
  347.         DEC     IY
  348.     LD      (IY+0),L
  349.         DEC     IY
  350.     CALL    TYSP
  351.     JR    DOJ1-$
  352. PJABS    LD      BC,26FH        ; ABS JMP
  353.         JR      DOJP-$
  354. PJIND    LD    BC,0C6FH    ; INDIRECT JMP
  355.     CALL    SPCTST
  356.     EX    DE,HL
  357.     DEC    HL
  358. DOJP    PUSH    BC
  359.     CALL    SPCTST        ; TEST FOR SPECIALS
  360.     JR    NZ,DOJ1-$
  361.     CALL    INUSR        ; FOR SPECIALS
  362.     CALL    PRET        ; DO SR RETURN
  363.     POP    BC
  364.     JR    EE0-$        ; GO TO PC+1
  365. DOJ1    EX    DE,HL        ; NEW PC
  366.     POP    BC
  367.     JR    EE1-$
  368. ;
  369. ; PROCESS SR AND INTERRUPT RETURNS
  370. ;
  371. PRTS    CALL    PRET        ; RTS...RESTORE PC
  372.         LD      BC,4A9H
  373. EE0    JP      END        ; GO TO PC+1
  374. PRTI    CALL    TSPY        ; RTI
  375.     INC    IY
  376.     LD    A,(IY+0)    ; RESTORE FLAGS
  377.     LD    (IX+1),A
  378.     CALL    PRET1        ; RESTORE PC
  379.     LD      BC,4A5H
  380. EE1    JP      END1
  381. PRET    CALL    TSPY          ; SP TO IY
  382. PRET1    INC     IY            ; POINT TO LAST ENTRY
  383.         LD      L,(IY+0)    ; RESTORE PCL
  384.     INC     IY
  385.         LD      H,(IY+0)    ; RESTORE PCH
  386.     JP      TYSP          ; RESTORE NEW SP
  387. ;
  388. ; TEST FOR USER SUBROUTINE CALLS/JUMPS. IF TARGET
  389. ; ADDRESS < 0005 THEN RET WITH Z FLG SET, ELSE CLR
  390. ;
  391. SPCTST    INC    HL        ; TEST FOR USR SR
  392.     LD    E,(HL)        ; LO BYTE
  393.     INC    HL        ; TARGET TO DE
  394.     LD    D,(HL)        ; HI BYTE
  395.     LD    A,0        ; TARGET < 0005?
  396.     OR    D
  397.     RET    NZ
  398.     LD    A,4
  399.     CP    E
  400.     RET    C
  401.     XOR    A        ; SET Z FLAG
  402.     RET
  403. ;
  404. ; INDEX INTO USER SUBROUTINE TABLE
  405. ; PASS A, X, & Y TO/FROM USER ROUTINE AS A, B, & C.
  406. ;
  407. INUSR    LD    D,0
  408.     LD    A,E
  409.     ADD    A,E
  410.     ADD    A,E
  411.     LD    E,A
  412.     LD    IY,USR0
  413.     LD    BC,USRET    ; RETURN ON STACK
  414.     PUSH    BC
  415.     ADD    IY,DE
  416.     LD    A,(IX+0)    ; PASS A,X, & Y
  417.     LD    B,(IX+2)
  418.     LD    C,(IX+3)
  419.     JP    (IY)        ; AND GO
  420. USRET    LD    (IX+0),A    ; RETURN HERE
  421.     LD    (IX+2),B    ; RETURN PARAMETERS
  422.     LD    (IX+3),C
  423.     RET
  424.     NOP            ; PAD FOR PATCH
  425.     NOP
  426.     NOP
  427. ;
  428. ; PROCESS SP EXCHANGES
  429. ;
  430. PTSS    CP      90H           ; WHICH ONE IS IT?
  431.     JR      NZ,PTSX-$
  432. PTXS    LD      A,(IX+2)    ; MOVE DATA FROM X...
  433.     LD      (IX+4),A    ; TO SP
  434.         LD      BC,4D9H
  435.     JP      END
  436. PTSX    LD      A,(IX+4)    ; MOVE SP
  437.     LD      (IX+2),A    ; TO X REG
  438.         LD      C,0D1H
  439.     JP    COMPL        ; AND MODIFY FLAGS
  440. ;
  441. ; PROCESS ALL REMAINING IMPLIED INSTRUCTIONS
  442. ;
  443. PIMPL    LD    C,A        ; OP CODE
  444.     SRL     C             ; GET MSD
  445.         SRL     C
  446.     SRL     C
  447.         SRL     C
  448.     AND    0FH        ; CHECK LSD
  449.     CP    8
  450.         LD      IY,IMPTBL    ; INDEX INTO TABLE
  451.     JP    Z,JPIB
  452.     LD      IY,IMPTBL+8
  453.     JP    JPIB
  454. ;
  455. ; IMPLIED INSTR PROCESSORS
  456. ;
  457. PINX    INC     (IX+2)        ; INX
  458.     LD      C,65H
  459.         JR      IDEFLG-$
  460. PINY    INC     (IX+3)        ; INY
  461.     LD      C,69H
  462.         JR      IDEFLG-$
  463. PDEX    DEC     (IX+2)        ; DEX
  464.     LD      C,55H
  465.         JR      IDEFLG-$
  466. PDEY    DEC     (IX+3)        ; DEY
  467.     LD      C,59H
  468. IDEFLG    RES    1,(IX+1)    ; SET/RES Z FLG
  469.     JR      NZ,SINTST-$    ; PER Z80 FLAGS
  470.         SET     1,(IX+1)
  471. SINTST    RES    7,(IX+1)    ; ALSO SIGN FLG
  472.         JP      P,ENDIT
  473.     SET     7,(IX+1)
  474.         JP      ENDIT
  475. PNOP    LD    BC,485H        ; NOP
  476.     JP    END
  477. PPHA    CALL    TSPY          ; PHA
  478.     LD      A,(IX+0)    ; ACCUM
  479.         LD      C,8DH
  480.     JR      DOPUSH-$    ; PUSH IT
  481. PPHP    CALL    TSPY        ; PHP
  482.     LD      A,(IX+1)    ; P REG
  483.         LD      C,91H
  484. DOPUSH    PUSH    BC
  485.         LD      (IY+0),A    ; PLACE ON STACK
  486.     DEC     IY            ; BUMP SP DOWN
  487.         CALL    TYSP          ; & REPLACE IT
  488.     POP    BC
  489.         JP      ENDIT
  490. PPLA    CALL    DOPULL        ; PLA
  491.     LD      (IX+0),A    ; DATA TO ACC
  492.     CALL    SINS1         ; SET/RES S,Z FLGS
  493.     CALL    TYSP        ; RESTORE SP
  494.         LD      BC,495H
  495.     JP      END
  496. PPLP    CALL    DOPULL        ; PLP
  497.     LD      (IX+1),A    ; DATA TO P REG
  498.         CALL    TYSP          ; RESTORE SP
  499.     LD      BC,499H
  500.         JP      END
  501. DOPULL    CALL    TSPY        ; GET SP
  502.     INC     IY            ; BUMP SP
  503.         LD      A,(IY+0)    ; GET DATA
  504.     RET
  505. ;
  506. ; PROCESS ACC/INDEX TRANSFERS
  507. ;
  508. PTAX    LD      A,(IX+0)    ; TAX
  509.     LD      (IX+2),A
  510.         LD      C,0C9H
  511.     JR      COMPL-$
  512. PTAY    LD      A,(IX+0)    ; TAY
  513.     LD      (IX+3),A
  514.         LD      C,0CDH
  515.     JR      COMPL-$
  516. PTXA    LD      A,(IX+2)    ; TXA
  517.     LD      (IX+0),A
  518.         LD      C,0D5H
  519.     JR    COMPL-$
  520. PTYA    LD      A,(IX+3)    ; TYA
  521.     LD      (IX+0),A
  522.         LD      C,0DDH
  523. COMPL   CALL    SINS1        ; SET/RES S,Z FLGS
  524.     JR    ENDIT-$
  525. ;
  526. ; PROCESS FLAG SET/RES INSTRUCTIONS
  527. ;
  528. PFLGS    LD    IY,FLGTBL    ; TABLE START
  529.     LD    B,0
  530.     CP    0B8H        ; CLV SPECIAL
  531.     JR    NZ,PFL1-$
  532.     RES    5,A
  533. PFL1    RRA            ; CHECK MSD
  534.     RRA
  535.     RRA
  536.     RRA
  537.     AND    0EH        ; MASK MSD + 1
  538.     BIT    1,A        ; TEST FOR SET/RES
  539.     LD    C,A        ; FORM TABLE INDEX
  540.     ADD    IY,BC
  541.     LD    C,(IY+0)    ; GET MNEM CODE
  542.     LD    A,(IY+1)    ; GET MASK
  543.     JR    NZ,PFL2-$
  544.     CPL            ; DO CLEARS
  545.     AND    (IX+1)
  546.     JR    PFL3-$
  547. PFL2    OR    (IX+1)        ; DO SETS
  548. PFL3    LD    (IX+1),A    ; AND STUFF IT
  549. ENDIT    LD    B,4
  550.     JP    END
  551. ;
  552. ; PROCESS ALL INSTRUCTIONS HAVING MULTIPLE ADDRESSING
  553. ;
  554. MLTMOD  LD      BC,MLTEND    ; PUT RETURN ON STACK
  555.     PUSH    BC
  556.         LD      A,(HL)        ; GET INSTR TO A
  557.     LD      C,A           ; AND TO C
  558.         SRL     C             ; TEST EVEN/ODD
  559.     PUSH    AF
  560.         SRL     C             ; ROTATE MSD INTO LSD
  561.     SRL     C
  562.         SRL     C
  563.     RES     0,C           ; MASK LSB
  564.     POP    AF
  565.         LD      IY,EVNTBL    ; JUMP PER TABLES
  566.     JP    NC,JPIB
  567.     LD    IY,ODDTBL
  568.     JP    JPIB
  569. ;
  570. ; MULTI-MODE INSTRUCTION PROCESSORS
  571. ;
  572. PASL    CALL    MODBBB        ; GET MODE,ADDR,&DATA
  573.     SLA     A             ; ASL
  574.         CALL    SINSET        ; SET/RES S,Z,C FLGS
  575.     CALL    PUTDAT        ; RESTORE DATA
  576.         LD      A,8
  577.     RET
  578. PBTRL   BIT     1,A           ; BIT OR ROL?
  579.     JR      Z,PBIT-$
  580.         CALL    MODBBB        ; ROL
  581.     CALL    CARSET        ; SET UP C FLAG
  582. PROL1   RLA                   ; DO ROTATE
  583.     CALL    SINSET
  584.         CALL    PUTDAT
  585.     LD      A,9CH
  586.         RET
  587. PBIT    RES     6,(IX+1)    ; BIT
  588.     CALL    MODBBX
  589.         PUSH    BC
  590.     LD      B,A           ; SAVE IT IN B
  591.         LD      A,(IX+0)    ; GET SIM ACC
  592.     AND     B             ; AND IT
  593.         BIT     6,A           ; CHECK V BIT
  594.     JR      Z,PBIT1-$
  595.         SET     6,(IX+1)    ; SET V BIT IF REQD
  596. PBIT1   CALL    SINS1         ; SET/RES S,Z FLGS
  597.     POP     BC
  598.         LD      A,18H
  599.     RET
  600. PLSR    CALL    MODBBB        ; LSR
  601.     SRL     A
  602.         CALL    SINSET
  603.     CALL    PUTDAT
  604.         LD      A,80H
  605.     RET
  606. PROR    CALL    MODBBB        ; ROR
  607.     CALL    CARSET        ; SET UP C FLG
  608. PROR1   RRA                   ; DO ROTATE
  609.     CALL    SINSET
  610.         CALL    PUTDAT
  611.     LD      A,0A0H
  612.         RET
  613. PSTXY   BIT     1,A           ; WHICH ONE?
  614.     JR      Z,PSY-$
  615.         CALL    MODBBX        ; STX
  616.     LD      A,(IX+2)
  617.     CALL    PUTDAT
  618.         LD      A,0C0H
  619.     RET
  620. PSY     CALL    MODBBX        ; STY
  621.     LD      A,(IX+3)
  622.     CALL    PUTDAT
  623.         LD      A,0C4H
  624.     RET
  625. PLDXY   BIT     1,A           ; WHICH ONE?
  626.     JR      Z,PLY-$
  627.         CALL    MODDDD        ; LDX
  628.     LD      (IX+2),A
  629.     CALL    SINS1
  630.         LD      A,78H
  631.     RET
  632. PLY     CALL    MODDDD        ; LDY
  633.     LD      (IX+3),A
  634.     CALL    SINS1
  635.         LD      A,7CH
  636.     RET
  637. PDCY    BIT     1,A           ; WHICH ONE?
  638.     JR      Z,PCPY-$
  639.         CALL    MODBBX        ; DEC
  640.     DEC     A
  641.         CALL    SINS1
  642.     CALL    PUTDAT
  643.         LD      A,50H
  644.     RET
  645. PICX    BIT     1,A           ; WHICH ONE?
  646.     JR      Z,PCPX-$
  647.         CALL    MODBBX        ; INC
  648.     INC     A
  649.         CALL    SINS1
  650.     CALL    PUTDAT
  651.         LD      A,60H
  652.     RET
  653. PCPX    CALL    CXY           ; CPX
  654.     CALL    SINSET
  655.         LD      A,48H
  656.     RET
  657. PCPY    INC     IX
  658.     CALL    CXY           ; CPY
  659.         DEC     IX
  660.     CALL    SINSET
  661.         LD      A,4CH
  662.     RET
  663. CXY     CALL    MODCC
  664.     PUSH    BC
  665.         LD      B,A           ; MEM DAT INTO B
  666.     LD      A,(IX+2)    ; X (Y) INTO A
  667.         SUB     B
  668.     CCF                   ; BORROW = 6502 /C
  669.         POP     BC
  670.     RET
  671. PSBC    RES     6,(IX+1)    ; SBC...CLR V FLG
  672.     CALL    MODAAA
  673.         PUSH    BC
  674.     LD      B,A        ; DATA TO B
  675.         LD      A,(IX+0)    ; ACC TO A
  676.     CALL    CARSET        ; SET UP C FLAG
  677.     CCF            ; AND COMPLEMENT IT
  678. PSBC1   BIT     3,(IX+1)    ; CHECK FOR DEC MODE
  679.     JR      NZ,PSDEC-$
  680.         SBC     A,B
  681.     JR      PSBC2-$
  682. PSDEC   SBC     A,B           ; DECIMAL MODE
  683.     DAA
  684. PSBC2   LD      (IX+0),A    ; RESULT TO ACCUM
  685.     CCF            ; BORROW = 6502 /C
  686.     CALL    SINSET
  687.     AND    0C0H        ; TEST XOR OF B6 & B7
  688.     JR    Z,SBC3-$
  689.     CP    0C0H
  690.     JR    Z,SBC3-$
  691.     SET     6,(IX+1)    ; SET V FLAG IF XOR = 1
  692. SBC3    POP     BC
  693.         LD      A,0ACH
  694.     RET
  695. PORA    CALL    MODAAA        ; ORA
  696.     PUSH    BC
  697.         LD      B,A           ; DATA TO B
  698.     LD      A,(IX+0)    ; ACC TO A
  699.         OR      B
  700.     LD      (IX+0),A    ; RESULT TO ACC
  701.         CALL    SINS1
  702.     POP     BC
  703.         LD      A,88H
  704.     RET
  705. PAND    CALL    MODAAA        ; AND
  706.     PUSH    BC
  707.         LD      B,A           ; DATA TO B
  708.     LD      A,(IX+0)    ; ACC TO A
  709.         AND     B
  710.     LD      (IX+0),A    ; RESULT TO ACC
  711.         CALL    SINS1
  712.     POP     BC
  713.         LD      A,4
  714.     RET
  715. PEOR    CALL    MODAAA        ; EOR
  716.     PUSH    BC
  717.         LD      B,A        ; DATA TO B
  718.     LD      A,(IX+0)    ; ACC TO A
  719.         XOR     B
  720.     LD      (IX+0),A    ; RESULT TO ACC
  721.         CALL    SINS1
  722.     POP     BC
  723.         LD      A,5CH
  724.     RET
  725. PADC    RES     6,(IX+1)    ; ADC: CLEAR V FLAG
  726.     CALL    MODAAA
  727.         PUSH    BC
  728.     LD      B,A        ; DATA TO B
  729.         LD      A,(IX+0)    ; ACC TO A
  730.     CALL    CARSET        ; SET UP C FLG
  731. PADC1   BIT     3,(IX+1)    ; CHECK FOR DEC MODE
  732.     JR      NZ,PADEC-$
  733.         ADC     A,B           ; BINARY MODE
  734.     JR      PADC2-$
  735. PADEC   ADC     A,B           ; DECIMAL MODE
  736.     DAA
  737. PADC2   LD      (IX+0),A    ; RESULT TO ACC
  738.     CALL    SINSET
  739.     AND    0C0H        ; CHECK XOR OF B6 & B7
  740.     JR    Z,PADC3-$
  741.     CP    0C0H
  742.     JR    Z,PADC3-$
  743.     SET     6,(IX+1)    ; SET V FLG IF XOR = 1
  744. PADC3   POP     BC
  745.     LD      A,0
  746.         RET
  747. PSTA    CALL    MODAAA        ; STA
  748.     LD      A,(IX+0)    ; ACC TO MEM
  749.         CALL    PUTDAT
  750.     LD      A,0BCH
  751.         RET
  752. PLDA    CALL    MODAAA        ; LDA
  753.     LD      (IX+0),A    ; MEM TO ACC
  754.         CALL    SINS1
  755.     LD      A,74H
  756.         RET
  757. PCMP    CALL    MODAAA        ; CMP
  758.     PUSH    BC
  759.         LD      B,A           ; DATA TO B
  760.     LD      A,(IX+0)    ; ACC TO A
  761.         SUB     B
  762.     CCF                   ; BORROW = 6502 /C
  763.         CALL    SINSET
  764.     POP     BC
  765.         LD      A,44H
  766.     RET
  767. ;
  768. ; END OF ALL MULTI MODE PROCESSORS
  769. ;
  770. MLTEND  ADD     A,C        ; FORM MNEM CODE IN C
  771.     LD      C,A
  772. END     INC     HL        ; POINT TO NXT INSTR
  773. END1    LD      (NPC),HL
  774.     RET            ; BACK TO CMND
  775. ;
  776. ; VARIOUS SUBROUTINES FOR TRANSLATOR
  777. ;
  778. ; SET Z80 C FLAG TO MATCH 6502 C FLG
  779. ;
  780. CARSET    SCF
  781.     BIT    0,(IX+1)
  782.     RET    NZ
  783.     CCF
  784.     RET
  785. ;
  786. ; SET SIMULATOR S,Z,C FLAGS PER Z80 RESULTS
  787. ;
  788. SINSET  RES     0,(IX+1)    ; RESET C FLAG
  789.     JR      NC,SINS1-$
  790.         SET     0,(IX+1)    ; SET C PER Z80 C
  791. SINS1   RES     1,(IX+1)    ; CLEAR Z FLAG
  792.     OR      A             ; SEE IF ACC = 0
  793.         JR      NZ,SINS2-$
  794.     SET     1,(IX+1)    ; SET Z FLG
  795. SINS2   RES     7,(IX+1)    ; CLEAR SIGN FLAG
  796.     BIT     7,A           ; CHECK SIGN OF ACC
  797.         RET     Z
  798.     SET     7,(IX+1)    ; SET S IF NECESSARY
  799.         RET
  800. ;
  801. ; TRANSFER SIMULATOR SP TO/FROM IY
  802. ;
  803. TSPY    LD      B,1           ; XFER SP TO IY
  804.         LD      C,(IX+4)
  805.     PUSH    BC
  806.     POP    IY
  807.         RET
  808. TYSP    PUSH    IY        ; XFER IY TO SP
  809.     POP    BC
  810.     LD      (IX+4),C
  811.         RET
  812. ;
  813. ; ADDRESS MODE DECODERS...RETURN WITH DATA TO BE MODIFIED
  814. ; IN A, ADDRESS MODE CODE IN B, # BYTES IN C, ADDRESS OF
  815. ; DATA IN DE
  816. ;
  817. MODAAA  LD      IY,AAATBL    ; GROUP 1
  818.     JR      MOD1-$
  819. MODBBB  LD      IY,BBBTBL    ; GROUP 2
  820.     JR      MOD1-$
  821. MODDDD  LD      IY,DDDTBL    ; GROUP 3
  822.         CP      0B6H          ; LDX ZPG,Y SPECIAL
  823.     JR      NZ,DDD1-$
  824.         LD      A,10H
  825. DDD1    CP      0BEH          ; LDX ABS,Y SPECIAL
  826.     JR      NZ,MOD1-$
  827.         LD      A,18H
  828.     JR      MOD1-$
  829. MODBBX  LD      IY,BBXTBL    ; GROUP 4 & 6
  830.         CP      96H           ; STX ZPG,Y SPECIAL
  831.     JR      Z,BBX-$
  832.     RRA            ; EXTRA SHIFT
  833.     AND    0CH        ; EXTRA MASK
  834.     JR    MOD1-$
  835. BBX    LD    A,10H        ; SPECIAL
  836.     JR    MOD1-$
  837. MODCC   LD      IY,CCTBL    ; GROUP 5
  838. MOD1    RRA                   ; ROTATE MODE INTO LSD
  839.         AND     0EH           ; MASK THE REST
  840.         LD      B,0           ; FORM OFFSET IN BC
  841.     LD      C,A
  842.         ADD     IY,BC         ; ADD TO TABLE START
  843.     LD      C,(IY+0)    ; MODE OFFSET
  844.         LD      B,(IY+1)    ; # CODE
  845.     PUSH    BC            ; SAVE FOR LATER
  846. GETDAT  LD      IY,GETTBL    ; JUMP TABLE
  847.     JP    JPIB
  848. PABY    INC     HL            ; ABS,Y
  849.     LD      A,(HL)        ; 2ND BYTE INSTR
  850.         ADD     A,(IX+3)    ; PLUS Y INDEX
  851.     LD      E,A           ; TO E
  852.         INC     HL
  853.     LD      A,(HL)        ; 3RD BYTE INSTR
  854.         ADC     A,0           ; PLUS CARRY
  855.     LD      D,A           ; TO D
  856.         JR      EXIT-$
  857. PIMM    INC     HL            ; IMMEDIATE
  858.     LD      A,(HL)        ; DATA TO ACC
  859.         JR      EX1-$
  860. PACX    LD      A,(IX+0)    ; ACCUM
  861.     PUSH    IX
  862.         POP     DE
  863.     JR      EX1-$
  864. PZPG    INC     HL            ; ZPG
  865.     LD      E,(HL)        ; ADDRESS TO DE
  866.         LD      D,0
  867.     JR      EXIT-$
  868. PAB     INC     HL            ; ABSOLUTE
  869.     LD      E,(HL)        ; ADDRESS TO DE
  870.         INC     HL
  871.     LD      D,(HL)
  872.         JR      EXIT-$
  873. PZX     LD      A,(IX+2)    ; ZPG,X...GET X INDEX
  874.     JR      PZ1-$
  875. PZY     LD      A,(IX+3)    ; ZPG,Y...GET Y INDEX
  876. PZ1     INC     HL
  877.     ADD     A,(HL)        ; ADD BASE ADDRESS
  878.         LD      E,A           ; PUT IN E
  879.     LD      D,0           ; ZERO PAGE, NO WRAP
  880.         JR      EXIT-$
  881. PZIX    INC     HL            ; (ZPG,X)
  882.     LD      A,(HL)        ; 2ND BYTE INSTR
  883.         ADD     A,(IX+2)    ; ADD X INDEX
  884.     LD      E,A           ; TO FORM BASE ADDRESS...
  885.         LD      D,0           ; IN ZERO PG, NO WRAP
  886.     LD      IY,0
  887.         ADD     IY,DE         ; TRANSFER TO IY
  888.     LD      E,(IY+0)    ; EFF ADDR TO DE
  889.         LD      D,(IY+1)
  890.     JR      EXIT-$
  891. PZIY    INC     HL            ; (ZPG),Y
  892.     LD      E,(HL)        ; BASE ADDRESS
  893.         LD      D,0           ; IN ZERO PAGE
  894.     LD      IY,0
  895.         ADD     IY,DE         ; TRANSFER TO IY
  896.     LD      A,(IY+0)    ; EFF ADDRESS...
  897.         ADD     A,(IX+3)    ; PLUS Y INDEX...
  898.     LD      E,A           ; TO DE
  899.         LD      A,(IY+1)
  900.     ADC     A,0
  901.         LD      D,A
  902.     JR      EXIT-$
  903. PABX    INC     HL            ; ABS,X
  904.     LD      A,(HL)        ; 2ND BYTE INSTR
  905.         ADD     A,(IX+2)    ; PLUS X INDEX
  906.     LD      E,A           ; TO E
  907.         INC     HL            ; 3RD BYTE INSTR
  908.     LD      A,(HL)
  909.         ADC     A,0           ; PLUS CARRY
  910.     LD      D,A           ; TO E
  911. EXIT    LD      A,(DE)        ; DATA TO ACC
  912. EX1     POP     BC            ; RESTORE # CODE
  913.     PUSH    AF            ; SAVE DATA
  914.         LD      A,3
  915.     AND     B             ; # BYTES...
  916.         LD      C,A           ; TO C
  917.     SRL     B
  918.         SRL     B             ; B=ADDR MODE
  919.     POP     AF            ; RESTORE DATA
  920.         RET
  921. ;
  922. ; STORE DATA TO ADDRESS FROM GETDAT
  923. ;
  924. PUTDAT  LD      (DE),A
  925.     RET
  926. ;
  927. ; INDEX INTO JUMP TABLES...ENTER WITH TABLE START
  928. ; ADDRESS IN IY AND OFFSET IN C. CALCULATES TABLE
  929. ; POSITION AND JUMPS TO RESULT
  930. ;
  931. JPIB    LD    B,0        ; INDIRECT JUMP PER TABLE
  932.     ADD    IY,BC        ; TABLE ADDRESS TO IY
  933.     LD    C,(IY+0)    ; TABLE ENTRY TO BC
  934.     LD    B,(IY+1)
  935.     PUSH    BC
  936.     POP    IY        ; ENTRY TO IY
  937.     JP    (IY)        ; AND GO TO IT
  938. ;
  939. ; ELEMENTARY MONITOR FUNCTIONS TO EXAMINE A BLOCK OF
  940. ; MEMORY LOCATIONS (E) AND TO CHECK AND UPDATE
  941. ; INDIVIDUAL LOCATIONS (M)
  942. ;
  943. EXAM    LD    DE,GETADR    ; EXAM BLOCK OF MEM
  944.     CALL    PRTDE
  945.     CALL    GETWRD        ; GET START ADDR
  946.     PUSH    DE
  947.     CALL    LINF
  948.     LD    DE,GETN
  949.     CALL    PRTDE
  950.     CALL    GETWRD        ; GET # BYTES
  951.     PUSH    DE
  952.     POP    BC
  953.     LD    E,4        ; CHANGE TO # LINES (/16)
  954.     XOR    A
  955. BYTLN    SRL    B
  956.     RR    C
  957.     JR    NC,XXX-$
  958.     INC    A
  959. XXX    DEC    E
  960.     JR    NZ,BYTLN-$
  961.     OR    A        ; SEE IF PARTIAL LINE
  962.     JR    Z,YYY-$
  963.     INC    BC
  964. YYY    POP    HL        ; HL = START, BC = COUNT
  965.     DEC    BC        ; ONE LESS LINE
  966. EXLP    PUSH    BC        ; LOOP FOR ONE LINE
  967.     CALL    CRLF
  968.     CALL    LADR        ; PRINT ADDRESS AT START
  969.     CALL    TWO        ; INSERT TWO SPACES
  970.     PUSH    HL        ; SAVE ADDRESS FOR ALPHA
  971.     LD    E,16        ; 16 ENTRIES PER LINE
  972. LNLP    LD    A,(HL)        ; GET BYTE FROM MEMORY
  973.     CALL    PACC        ; PRINT IT HEX
  974.     CALL    ONE        ; SPACE
  975.     INC    HL        ; POINT TO NEXT BYTE
  976.     DEC    E        ; DONE WITH HEX?
  977.     JR    NZ,LNLP-$    ; NO, DO NEXT BYTE
  978.     CALL    TWO        ; YES, SET UP FOR ALPHA
  979.     POP    HL        ; SAME STARTING ADDRESS
  980.     LD    E,16
  981. ASCII    LD    A,(HL)        ; GET BYTE
  982.     CP    20H        ; IS IT PRINTABLE?
  983.     JR    C,DOT-$
  984.     CP    80H
  985.     JR    C,ASOK-$
  986. DOT    LD    A,'.'        ; NO, PRINT A DOT
  987. ASOK    CALL    PRNA
  988.     INC    HL        ; BUMP POINTER
  989.     DEC    E        ; DONE WITH LINE?
  990.     JR    NZ,ASCII-$
  991.     POP    BC
  992.     LD    A,B        ; SEE IF ALL DONE
  993.     OR    C
  994.     RET    Z        ; YES, RET TO CMND
  995.     DEC    BC
  996.     JR    EXLP-$        ; ELSE DO ANOTHER LINE
  997. ;
  998. ; SUBSTITUTE MEMORY...ENTER BY 'M'
  999. ;
  1000. SUBM    LD    DE,GETADR    ; ASK FOR ADDRESS
  1001.     CALL    PRTDE
  1002.     CALL    GETWRD        ; GET IT
  1003.     EX    DE,HL        ; MOVE IT TO HL
  1004. SULP    CALL    CRLF
  1005.     CALL    LADR        ; PRINT THE ADDRESS
  1006.     CALL    TWO
  1007.     LD    A,(HL)
  1008.     CALL    PACC        ; PRINT THE CONTENTS
  1009.     CALL    TWO
  1010. JLP    CALL    GETCHR        ; GET INPUT
  1011.     CP    2EH        ; EXIT ON "."
  1012.     RET    Z
  1013.     CP    20H
  1014.     JR    Z,FWD-$        ; SKIP AHEAD ON "SPACE"
  1015.     CALL    CONV        ; CONV HEX IF POSSIBLE
  1016.     JR    Z,JLP-$        ; NOT A HEX NUMBER
  1017.     PUSH    HL        ; SAVE ADDRESS AGAIN
  1018.     LD    HL,0        ; CLEAR FOR ROTATE
  1019. LLP    CALL    ROBYT        ; ROTATE NYBBLE INTO HL
  1020. KLP    CALL    GETCHR        ; GET ANOTHER CHARACTER
  1021.     CP    0DH
  1022.     JR    Z,PUTIN-$    ; IF "CR" STUFF IT
  1023.     CALL    CONV        ; CONV BINARY
  1024.     JR    Z,KLP-$        ; NOT A HEX NUMBER
  1025.     JR    LLP-$        ; CONTINUE
  1026. PUTIN    PUSH    HL        ; DATA TO BC
  1027.     POP    BC
  1028.          POP    HL        ; RETRIEVE ADDRESS
  1029.     LD    (HL),C        ; STUFF THE DATA
  1030. FWD    INC    HL        ; BUMP POINTER
  1031.     JR    SULP-$        ; ...AND CONTINUE
  1032. LADR    EX    DE,HL        ; PRINT WORD IN HL
  1033.     CALL    PRTWRD
  1034.     EX    DE,HL
  1035.     RET
  1036. PACC    PUSH    DE        ; PRINT BYTE IN A
  1037.     LD    E,A
  1038.     CALL    PRTBYT
  1039.     POP    DE
  1040.     RET
  1041. TWO    CALL    ONE        ; PRINT 2 SPACES
  1042. ONE    PUSH    BC        ; PRINT SPACE
  1043.     LD    C,' '
  1044.     CALL    PRNC
  1045.     POP    BC
  1046.     RET
  1047. ;
  1048. ; ELEMENTARY DOS BEGINS HERE. FILES ARE MAINTAINED ON
  1049. ; DRIVE B ONLY AND ARE NOT CP/M COMPATIBLE. FUNCTIONS
  1050. ; ARE DIRECTORY LIST (D), SAVE (S), LOAD (L), KILL (K)
  1051. ; AND INITIALIZE (I).
  1052. ; FILE NAMES CONSIST OF A PRIMARY FILE NAME OF UP TO
  1053. ; SIX CHARS AND AN OPTIONAL FILE TYPE OF UP TO THREE.
  1054. ;
  1055. ; LIST DIRECTORY
  1056. ;
  1057. PDIR    CALL    DIR1        ; SET UP FOR DIR SCH
  1058. PAGLP    CALL    NEWPG        ; NEXT DIR PG TO BUFF
  1059.     LD    B,8        ; 8 ENTRIES/PAGE
  1060. PRPAG    LD    A,(IX+0)    ; STATUS BYTE
  1061.     DEC    A
  1062.     RET    Z        ; QUIT IF DONE
  1063.     DEC    A
  1064.     JR    NZ,NEXT-$
  1065.     CALL    CRLF
  1066. PRLIN    PUSH    BC        ; PRINT NAME FROM DIR
  1067.     PUSH    IX
  1068.     LD    B,10
  1069. PLNLP    LD    C,(IX+1)
  1070.     CALL    PRNC
  1071.     INC    IX
  1072.     DJNZ    PLNLP-$
  1073.     POP    IX
  1074.     CALL    SPAC
  1075.     LD    E,(IX+11)    ; PRINT ADDRESS
  1076.     LD    D,(IX+12)
  1077.     CALL    PRTWRD
  1078.     CALL    SPAC
  1079.     LD    E,(IX+15)    ; PRINT # RECORDS
  1080.     CALL    PRTBYT
  1081.     POP    BC
  1082. NEXT    LD    DE,10H
  1083.     ADD    IX,DE        ; POINT TO NXT ENTRY
  1084.     DJNZ    PRPAG-$        ; AND REPEAT
  1085.     JR    PAGLP-$
  1086. ;
  1087. ; LOAD PGM FROM DRIVE B AND RUN FROM START ADDRESS
  1088. ;
  1089. LDGO    CALL    LOAD        ; GET PGM
  1090.     LD    IX,VREG        ; FOR SIMULATOR
  1091.     JP    RUN
  1092. ;
  1093. ; SEARCH FOR AND LOAD A FILE AT ADDR PER DIRECTORY
  1094. ;
  1095. LOAD    CALL    ANAME        ; LOAD A FILE
  1096.     CALL    NAMSCH        ; TRY TO MATCH NAME
  1097.     JP    Z,NTFND
  1098.     LD    L,(IY-5)    ; SAVE START ADDR
  1099.     LD    H,(IY-4)
  1100.     LD    (NPC),HL
  1101. LOADLP    CALL    SETDAT        ; SET UP FOR LOAD
  1102.     CALL    RDONE        ; AND READ N SECTORS
  1103.     CALL    INCDAT
  1104.     JR    NZ,LOADLP-$
  1105.     RET
  1106. ;
  1107. ; SAVE A FILE AND ADD IT TO DIRECTORY
  1108. ;
  1109. SAVE    CALL    ANAME        ; SAVE # SECTORS
  1110.     CALL    NAMSCH        ; SEE IF HAVE ALREADY
  1111.     JR    Z,SAV1-$
  1112.     CALL    LINF
  1113.     LD    DE,HAVMSG    ; IF SO, INFORM & QUIT
  1114.     CALL    PRTDE
  1115.     RET
  1116. SAV1    LD    IY,TEMPS
  1117.     LD    A,2        ; NEW ACTIVE FILE
  1118.     LD    (IY+0),A
  1119.     CALL    LINF
  1120.     LD    DE,GETADR    ; GET RUN ADDR
  1121.     CALL    PRTDE
  1122.     CALL    GETWRD
  1123.     LD    (IY+11),E
  1124.     LD    (IY+12),D
  1125.     CALL    LINF
  1126.     LD    DE,GETN        ; GET # BYTES
  1127.     CALL    PRTDE
  1128.     CALL    GETWRD
  1129.     XOR    A        ; CONVERT TO SECTORS
  1130.     LD    B,7        ; DIV BY 128
  1131. SAVX    SRL    D
  1132.     RR    E
  1133.     JR    NC,SAVY-$
  1134.     INC    A
  1135. SAVY    DJNZ    SAVX-$
  1136.     OR    A        ; FRACTIONAL SCTR?
  1137.     JR    Z,SAVZ-$
  1138.     INC    E        ; THEN ADD ONE
  1139. SAVZ    LD    (IY+15),E    ; SAVE IT
  1140.     CALL    DIR1        ; SET UP FOR DIR SCH
  1141. SAV2    CALL    NEWPG        ; SEARCH FOR NAME
  1142.     LD    B,8
  1143. SAV3    LD    A,(IX+0)    ; STAT BYTE
  1144.     DEC    A
  1145.     JR    Z,SAVNEW-$    ; NEW FILE
  1146.     SUB    2        ; DEAD FILE?
  1147.     JR    NZ,SAV4-$
  1148.     LD    A,(IY+15)    ; WILL IT FIT?
  1149.     DEC    A
  1150.     CP    (IX+15)
  1151.     JR    C,SAVOLD-$
  1152. SAV4    LD    DE,10H        ; CHECK NXT ONE
  1153.     ADD    IX,DE
  1154.     LD    D,(IX-3)    ; OLD TRACK
  1155.     LD    E,(IX-2)    ; OLD SECTOR
  1156.     LD    C,(IX-1)    ; OLD #
  1157.     DJNZ    SAV3-$
  1158.     JR    SAV2-$
  1159. SAVNEW    LD    A,26        ; NEW ENTRY
  1160.     INC    C
  1161. NEWLP    INC    E
  1162.     CP    E        ; >26?
  1163.     JR    NC,NEW1-$
  1164.     INC    D        ; IF SO, NXT TRK
  1165.     LD    E,1
  1166. NEW1    DEC    C
  1167.     JR    NZ,NEWLP-$
  1168.     JR    UPDIR-$
  1169. SAVOLD    LD    D,(IX+13)
  1170.     LD    E,(IX+14)
  1171. UPDIR    LD    (IY+13),D    ; PUT NEW TRK & SCTR
  1172.     LD    (IY+14),E
  1173.     CALL    PUTDIR        ; UPDATE DIR
  1174. SAVER    CALL    SETDAT        ; SET UP FOR SAVE
  1175.     CALL    WRONE        ; & WRITE # SECTORS
  1176.     CALL    INCDAT
  1177.     JR    NZ,SAVER-$
  1178.     RET
  1179. ;
  1180. ; KILL A FILE (SET INACTIVE STATUS IN DIRECTORY)
  1181. ;
  1182. KILL    CALL    ANAME        ; GET NAME
  1183.     CALL    NAMSCH        ; FIND IT
  1184.     JP    Z,NTFND
  1185.     LD    IY,TEMPS
  1186.     LD    A,3        ; MAKE STAT = 03
  1187.     LD    (IY+0),3
  1188.     JR    PUTDIR-$    ; AND UPDATE DIRECTORY
  1189. ;
  1190. ; INITIALIZE DISK (WRITES BLANK DIRECTORY)
  1191. ;
  1192. INIT    LD    DE,INIMSG    ; INITIALIZE DISK
  1193.     CALL    PRTDE
  1194.     CALL    GETCHR        ; ASK YES OR NO
  1195.     CP    'Y'
  1196.     RET    NZ
  1197.     CALL    HOMB
  1198.     LD    IX,BUFFR    ; FILL BUFF W/PATTERN
  1199.     LD    IY,INIMSK    ; STORED AT INIMSK
  1200.     PUSH    IX
  1201.     LD    C,8
  1202. INLP1    PUSH    IY
  1203.     LD    B,10H
  1204. INLP2    LD    A,(IY+0)
  1205.     LD    (IX+0),A
  1206.     INC    IX
  1207.     INC    IY
  1208.     DJNZ    INLP2-$
  1209.     POP    IY
  1210.     DEC    C
  1211.     JR    NZ,INLP1-$
  1212.     POP    IX
  1213.     LD    A,3        ; MAKE 1ST ONE DEAD
  1214.     LD    (IX+0),A
  1215.     LD    BC,BUFFR
  1216.     CALL    BUFS
  1217.     LD    C,0
  1218.     CALL    TRKS
  1219.     INC    C
  1220.     CALL    SECS
  1221.     CALL    WRONE        ; 1ST DIR PAGE
  1222.     LD    A,1        ; RESTORE PATTERN
  1223.     LD    (IX+0),A
  1224.     LD    BC,1902H
  1225. WRLP    PUSH    BC        ; WRITE REST OF TRK 0
  1226.     CALL    SECS
  1227.     CALL    WRONE
  1228.     POP    BC
  1229.     INC    C
  1230.     DJNZ    WRLP-$
  1231.     RET
  1232. ;
  1233. ; OVERWRITE CURRENT DIRECTORY PAGE
  1234. ;
  1235. PUTDIR    LD    B,10H        ; UPDATE DIR
  1236. UPLP    LD    A,(IY+0)
  1237.     LD    (IX+0),A
  1238.     INC    IX
  1239.     INC    IY
  1240.     DJNZ    UPLP-$
  1241.     CALL    WRONE        ; REWRITE DIR PAGE
  1242.     RET
  1243. ;
  1244. ; SEARCH FOR FILE NAME IN DIRECTORY.. RETURN WITH Z FLG
  1245. ; SET IF NOT FOUND, Z CLEAR AND BUFFER FILLED IF FOUND
  1246. ;
  1247. NAMSCH    CALL    DIR1        ; SET UP FOR DIR SCH
  1248. LDLP    CALL    NEWPG        ; READ PAGE OF NDX
  1249.     LD    B,8
  1250. LDLP1    LD    A,(IX+0)    ; CHECK STAT
  1251.     DEC    A
  1252.     JR    NZ,LDLP2-$
  1253.     RET
  1254. LDLP2    DEC    A
  1255.     PUSH    IX
  1256.     PUSH    IY
  1257.     JR    NZ,LDNXT-$    ; INACTIVE?
  1258.     LD    C,10        ; ELSE COMP NAME
  1259. CMPLP    LD    A,(IY+1)
  1260.     CP    (IX+1)
  1261.     JR    NZ,LDNXT-$
  1262.     INC    IX
  1263.     INC    IY
  1264.     DEC    C
  1265.     JR    NZ,CMPLP-$
  1266.     JR    CMPOK-$        ; SAME NAME
  1267. LDNXT    POP    IY        ; TRY NEXT ONE
  1268.     POP    IX
  1269.     LD    DE,10H
  1270.     ADD    IX,DE
  1271.     DJNZ    LDLP1-$
  1272.     JR    LDLP-$        ; NEXT PAGE
  1273. CMPOK    POP    IY        ; NAME MATCHES
  1274.     POP    IX
  1275.     LD    B,10H        ; XFER DIR NTRY TO BUFF
  1276. FILLP    LD    A,(IX+0)
  1277.     LD    (IY+0),A
  1278.     INC    IX
  1279.     INC    IY
  1280.     DJNZ    FILLP-$
  1281.     LD    DE,-10H
  1282.     ADD    IX,DE
  1283.     XOR    A
  1284.     INC    A        ; EXIT A = 1
  1285.     RET
  1286. NEWPG    EXX            ; GET NXT DIR PAGE
  1287.     LD    IX,BUFFR
  1288.     INC    (IY+14)        ; NXT SCTR
  1289.     LD    C,(IY+14)
  1290.     CALL    SECS
  1291.     CALL    RDONE        ; READ IT IN
  1292.     EXX
  1293.     RET
  1294. NTFND    CALL    LINF        ; NOT FOUND
  1295.     LD    DE,NFMSG
  1296.     CALL    PRTDE
  1297.     LD    SP,SYSTK-2    ; RET TO CMND
  1298.     RET
  1299. ;
  1300. ; FILL IN DISK DATA. USES SR CALLS IN CBIOS
  1301. ;
  1302. SETDAT    LD    IY,TEMPS    ; SET UP FOR DSK DATA
  1303.     LD    C,(IY+11)
  1304.     LD    B,(IY+12)
  1305.     CALL    BUFS        ; XFER ADDR
  1306.     LD    C,(IY+13)
  1307.     CALL    TRKS        ; TRACK
  1308.     LD    C,(IY+14)
  1309.     JP    SECS        ; SECTOR
  1310. ;
  1311. ; BUMP SECTOR/TRACK AND XFER ADDRESS FOR MULTI
  1312. ; SECTOR READ OR WRITE
  1313. ;
  1314. INCDAT    LD    A,(IY+11)    ; BUMP DSK DATA
  1315.     ADD    A,80H        ; BUMP XFER ADDR
  1316.     LD    (IY+11),A
  1317.     JR    NC,INC1-$
  1318.     INC    (IY+12)
  1319. INC1    LD    A,(IY+14)
  1320.     INC    A        ; BUMP SECTOR
  1321.     CP    27
  1322.     JR    C,INC2-$
  1323.     LD    A,1
  1324.     INC    (IY+13)        ; AND TRK IF NEEDED
  1325. INC2    LD    (IY+14),A
  1326.     LD    A,(IY+13)    ; CHECK FOR VALID TRACK
  1327.     CP    77
  1328.     JR    C,INC3-$
  1329.     LD    DE,DERMSG    ; ERROR
  1330.     CALL    PRTXT
  1331.     POP    BC        ; RET TO CMND
  1332.     RET
  1333. INC3    DEC    (IY+15)
  1334.     RET
  1335. ;
  1336. ; GET FILE NAME TO BUFFER
  1337. ;
  1338. ANAME    LD    IY,TEMPS
  1339.     PUSH    IY
  1340.     LD    B,10
  1341.     LD    A,' '
  1342. MPTY    LD    (IY+1),A    ; CLEAR INPUT BUFFER
  1343.     INC    IY
  1344.     DJNZ    MPTY-$
  1345.     LD    DE,NAMSG    ; PROMPT FOR NAME
  1346.     CALL    PRTDE
  1347.     POP    IY
  1348.     PUSH    IY
  1349. NAMLP    CALL    GETCHR
  1350.     CP    0DH        ; END?
  1351.     JR    Z,NAMIN-$
  1352.     CP    '.'        ; DELIMITER?
  1353.     JR    Z,FTYP-$
  1354.     LD    (IY+1),A    ; PUT IT IN BUFFER
  1355.     INC    IY
  1356.     JR    NAMLP-$
  1357. FTYP    POP    IY
  1358.     PUSH    IY
  1359.     LD    (IY+7),A
  1360.     INC    IY
  1361. TYPLP    CALL    GETCHR
  1362.     CP    0DH
  1363.     JR    Z,NAMIN-$
  1364.     LD    (IY+7),A
  1365.     INC    IY
  1366.     JR    TYPLP-$
  1367. NAMIN    POP    IY
  1368.     RET
  1369. ;
  1370. ; SET UP FOR DIRECTORY SEARCH
  1371. ;
  1372. DIR1    LD    IY,TEMPS    ; SET UP FOR DIR SCH
  1373.     LD    BC,BUFFR
  1374.     CALL    BUFS
  1375.     LD    C,0        ; TRACK 0
  1376.     LD    (IY+13),C
  1377.     LD    (IY+14),C
  1378.     JP    TRKS
  1379. ;
  1380. ; VARIOUS ROUTINES USED BY TRANSLATOR, MONITOR, AND DOS
  1381. ;
  1382. CRLF    LD      C,0DH        ; PRINT CRLF
  1383.     CALL    PRNC
  1384. LINF    LD      C,0AH
  1385.     JP      PRNC
  1386. PROM    LD      C,' '        ; PRINT ' >'
  1387.     CALL    PRNC
  1388.         LD      C,'>'
  1389.     JP      PRNC
  1390. ;
  1391. ; GET HEX DATA IN DE. ROTATE CONTINUOUSLY UNTIL A
  1392. ; 'CR' IS INPUT. LSB IN E. SET Z FLG AND RET ON 'SPACE'
  1393. ;
  1394. GETWRD  CALL    GETCHR        ; GET BINARY DATA
  1395.     CP      ' '           ; RET Z IF SACE
  1396.         RET     Z
  1397.     EX      DE,HL
  1398.         LD      HL,0          ; CLEAR HO DING REG
  1399.     CALL    CONV        ; CHANGE TO HEX
  1400.     JR    Z,GETWRD-$    ; INVALID CHAR
  1401.     CALL    ROBYT        ; ROTATE INTO HL
  1402. WRDLP   CALL    GETCHR        ; GET NEXT CHAR
  1403.     CP      0DH           ; TERMINATOR
  1404.     JR    Z,WRDON-$
  1405.     CALL    CONV
  1406.     JR    Z,WRDLP-$
  1407.     CALL    ROBYT
  1408.     JR    WRDLP-$
  1409. WRDON    OR      A             ; CLEAR Z FLAG
  1410.         EX      DE,HL         ; DATA INTO DE
  1411.     RET
  1412. ;
  1413. ; CONVERT ASCII DATA IN A TO HEX. SET Z FLG IF INVALID
  1414. ;
  1415. CONV    CP      '0'           ; CONVERT TO BINARY
  1416.     JR      C,BAD-$
  1417.         CP      3AH
  1418.     JR      C,GOOD-$
  1419.         CP      41H
  1420.     JR      C,BAD-$
  1421.         CP      47H
  1422.     JR      C,GOOD-$
  1423. BAD     LD      C,'?'
  1424.     CALL    PRNC        ; NOTIFY BAD INPUT
  1425.     XOR    A        ; SET Z FLAG
  1426.     RET
  1427. GOOD    SUB     30H
  1428.     CP      10
  1429.     JR      C,GOOD1-$
  1430.     SUB     7
  1431. GOOD1    CP    0FFH        ; CLEAR Z FLAG
  1432.     RET
  1433. ;
  1434. ; ROTATE BYTE IN A INTO HL VIA L
  1435. ;
  1436. ROBYT    ADD    HL,HL        ; ROTATE A INTO HL
  1437.     ADD     HL,HL        ; ROTATE HL 4 BITS LEFT
  1438.     ADD     HL,HL
  1439.     ADD     HL,HL
  1440.     OR      L             ; PUT NEW DIGIT INTO L
  1441.     LD      L,A
  1442.     RET
  1443. ;
  1444. ; PRINT FOUR DIGIT VALUE IN DE
  1445. ;
  1446. PRTWRD  LD      A,D
  1447.     CALL    PRBIN
  1448. PRTBYT  LD      A,E           ; PRINT VALUE IN E
  1449. PRBIN   PUSH    AF
  1450.     RRC     A
  1451.     RRC     A
  1452.     RRC     A
  1453.     RRC     A
  1454.     CALL    PRB1
  1455.     POP     AF
  1456. PRB1    AND     0FH
  1457.     ADD     A,90H
  1458.     DAA
  1459.     ADC     A,40H
  1460.     DAA
  1461.     JR      PRNA-$
  1462. ;
  1463. ; PRINT STRING POINTED TO BY DE. USES PRTXT
  1464. ;
  1465. PRTDE    PUSH    IY        ; PRNT PER DE
  1466.     PUSH    DE
  1467.     POP    IY
  1468.     CALL    PRTXT
  1469.     POP    IY
  1470.     RET
  1471. ;
  1472. ; PRINT ASCII STRING POINTED TO BY IY. CHECK FOR
  1473. ; SPECIALS: '1' PRINTS AS BYTE POINTED TO BY HL, '2'
  1474. ; PRINTS (HL+1), '!' DOES NOT PRINT, '^' TERMINATES.
  1475. ;
  1476. PRTXT   LD      E,0           ; PRNT UP TO 255 CHRSY
  1477. PRNLP   LD      A,(IY+0)
  1478.     CP      '^'        ; TERMINATOR?
  1479.     RET     Z
  1480.     CP      '!'        ; NO PRINT?
  1481.     JR      Z,DONXT+1-$
  1482.     PUSH    DE
  1483.     LD      HL,(CPC)
  1484.     INC     HL
  1485.     CP      '2'        ; PRINT (HL+1)?
  1486.     JR      NZ,PRN1-$
  1487.     INC     HL
  1488.     LD      E,(HL)
  1489.     CALL    PRTBYT
  1490.     JR      DONXT-$
  1491. PRN1    CP      '1'        ; PRINT (HL)?
  1492.     JR      NZ,DOALPH-$
  1493.     LD      E,(HL)
  1494.     CALL    PRTBYT
  1495.     JR      DONXT-$
  1496. DOALPH  LD      C,A        ; ALL OTHER CHARACTERS
  1497.     CALL    PRNC
  1498. DONXT   POP     DE
  1499.     INC     IY
  1500.     DEC     E
  1501.     JR      NZ,PRNLP-$
  1502.     RET
  1503. ;
  1504. SPAC    PUSH    BC            ; PRINT 6 SPACES
  1505.     LD      B,6
  1506.     LD      C,' '
  1507. SPLP    CALL    PRNC
  1508.     DJNZ    SPLP-$
  1509.     POP     BC
  1510.     RET
  1511. ;
  1512. ; CONSOLE I/O
  1513. ;
  1514. GETCHR  CALL    KBIN         ; GET CHAR & TEST
  1515.     CP    3        ; ^C....
  1516.     JP    Z,CPWRM        ; CPM WARM START
  1517.     CP    18H        ; ^X (CAN)...
  1518.     JR    NZ,PRNA-$
  1519.     LD    SP,SYSTK-2    ; FOR RET TO CMND
  1520.     LD    A,'#'
  1521. PRNA    LD      C,A        ; PRINT CHAR IN A
  1522.     PUSH    AF
  1523.     CALL    PRNC
  1524.     POP    AF
  1525.     RET
  1526. ;
  1527. ; JUMPS TO EXTERNAL I/O...MODIFY AS NEEDED
  1528. ;
  1529. KBIN    JP    CONIN        ; GET SINGLE CHAR IN A
  1530. KBST    JP    CONST        ; TEST INPUT STATUS
  1531. PRNC    JP      CONOUT        ; PRINT CHAR IN C
  1532. HOMB    JP    HOME        ; DRIVE HOME
  1533. DRVS    JP    SETDRV        ; SET DRIVE #
  1534. SECS    JP    SETSEC        ; SET SECTOR #
  1535. TRKS    JP    SETTRK        ; SET TRK #
  1536. BUFS    JP    SETBUF        ; SET XFER ADDRESS
  1537. RDONE    JP    READ        ; READ A SECTOR
  1538. WRONE    JP    WRITE        ; WRITE A SECTOR
  1539. ;
  1540. ; JUMP TABLE FOR LINKS TO Z80 ROUTINES...FILL IN AS REQD
  1541. ; FIRST TWO INITIALIZED TO CONSOLE I/O VIA ACC
  1542. ;
  1543. USR0    JP    KBIN        ; 6502 USER ROUTINES
  1544. USR1    JP    PRNA
  1545. USR2    DEFB    0C9H,0,0
  1546. USR3    DEFB    0C9H,0,0
  1547. USR4    DEFB    0C9H,0,0
  1548. ;
  1549. ; 6502 BREAK VECTOR...INIT TO GO TO COMMAND LEVEL
  1550. ;
  1551. IPOINT    DEFW    0
  1552. ;
  1553. ; TEMPORARIES FOR TRANSLATOR
  1554. ;
  1555. NSTEPS  DEFB    1             ; # STEPS TO EXECUTE
  1556. NBYTES  DEFB    0             ; # BYTES IN INSTR
  1557. DLYCON    DEFW    0A00H        ; TIME DELAY FOR # STEP
  1558. BREAK   DEFW    0             ; BREAKPOINT ADDRESS
  1559. ;
  1560. ; SIMULATED 6502 CPU REGISTERS...INIT TO THESE VALUES
  1561. ;
  1562. VREG    DEFB    0             ; ACCUMULATOR
  1563.     DEFB    0             ; STATUS (P) REG
  1564.     DEFB    0             ; X INDEX REG
  1565.     DEFB    0             ; Y INDEX REG
  1566.     DEFB    0FFH          ; STACK POINTER
  1567. CPC     DEFW    200H         ; PROGRAM COUNTER
  1568. NPC     DEFW    200H           ; LOCATION OF NXT INSTR
  1569. ;
  1570. ; VARIOUS MESSAGES FOR SYSTEM
  1571. ;
  1572. INTRO   DEFM    '***** XENTRIX ZX/65 *****^'
  1573. HEADR   DEFM    ' CPC.. INS.. A.... P....'
  1574.     DEFM    ' X.... Y.... SP... NPC..'
  1575. NFMSG    DEFM    'FILE NOT FOUND^'
  1576. HAVMSG    DEFM    'FILE EXISTS^'
  1577. DERMSG    DEFM    'BAD TRACK/SECTOR #^'
  1578. GETADR    DEFM    '  ENTER START ADDRESS: ^'
  1579. GETN    DEFM    '  ENTER NO. BYTES: ^'
  1580. NAMSG    DEFM    '  ENTER FILNAM.TYP: ^'
  1581. MLTMSG    DEFM    '  ENTER # STEPS: ^'
  1582. BKPMSG    DEFM    '  ENTER BRKP ADDR: ^'
  1583. INIMSG    DEFM    '  INITIALIZE? (Y/N) ^'
  1584. ;
  1585. ; DOS BUFFERS AND DATA
  1586. ;
  1587. TEMPS    DEFS    10H        ; DISK ENTRY BUFFER
  1588. BUFFR    DEFS    80H        ; DIRECTORY PAGE BUFFER
  1589. INIMSK    DEFB    1,20H,20H,20H,20H,20H,20H,20H
  1590.     DEFB    20H,20H,20H,20H,20H,1,0,0
  1591. ;
  1592. ; DATA TABLES FOR TRANSLATOR BEGIN HERE
  1593. ;
  1594. ; ADDRESSING MODE TABLES
  1595. ;
  1596. AAATBL  DEFW    1A0CH         ; (ZPG,X)
  1597.     DEFW    0E04H         ; ZPG
  1598.     DEFW    0600H         ; IMM
  1599.     DEFW    0B06H         ; ABS
  1600.     DEFW    1E0EH         ; (ZPG),Y
  1601.     DEFW    2208H         ; ZPG,X
  1602.     DEFW    2F12H         ; ABS,Y
  1603.     DEFW    2B10H         ; ABS,X
  1604. BBBTBL  DEFW    0             ; INVALID
  1605.     DEFW    0E04H         ; ZPG
  1606.     DEFW    1502H         ; ACC
  1607.     DEFW    0B06H         ; ABS
  1608.     DEFW    260AH         ; ZPG,Y
  1609.     DEFW    2208H         ; ZPG,X
  1610.     DEFW    2F12H         ; ABS,Y
  1611.     DEFW    2B10H         ; ABS,X
  1612. DDDTBL  DEFW    0600H         ; IMM
  1613.     DEFW    0E04H         ; ZPG
  1614.     DEFW    0             ; INVALID
  1615.     DEFW    0B06H         ; ABS
  1616.     DEFW    260AH         ; ZPG,Y
  1617.     DEFW    2208H         ; ZPG,X
  1618.     DEFW    2F12H         ; ABS,Y
  1619.     DEFW    2B10H         ; ABS,X
  1620. BBXTBL  DEFW    0E04H         ; ZPG
  1621.     DEFW    0B06H         ; ABS
  1622.     DEFW    2208H         ; ZPG,X
  1623.     DEFW    2B10H         ; ABS,X
  1624.     DEFW    260AH        ; ZPG,Y
  1625. CCTBL   DEFW    0600H         ; IMM
  1626.     DEFW    0E04H         ; ZPG
  1627.     DEFW    0             ; INVALID
  1628.     DEFW    0B06H         ; ABS
  1629. ;
  1630. ; BRANCH MASK TABLE
  1631. ;
  1632. MSKTBL  DEFW    8026H         ; BPL
  1633.     DEFW    801EH         ; BMI
  1634.     DEFW    402EH         ; BVC
  1635.     DEFW    4032H         ; BVS
  1636.     DEFW    010EH         ; BCC
  1637.     DEFW    0112H         ; BCS
  1638.     DEFW    0222H         ; BNE
  1639.     DEFW    0216H         ; BEQ
  1640. ;
  1641. ; FLAG SET/RESET CODES
  1642. ;
  1643. FLGTBL  DEFW    0135H          ; CLC
  1644.     DEFW    01B1H        ; SEC
  1645.     DEFW    043DH        ; CLI
  1646.     DEFW    04B9H        ; SEI
  1647.     DEFW    4041H        ; CLV
  1648.     DEFW    0000        ; INVALID
  1649.     DEFW    0839H        ; CLD
  1650.     DEFW    08B5H        ; SED
  1651. ;
  1652. ; JUMP TABLES TO IMPLIED INSTRUCTIONS
  1653. ;
  1654. IMPTBL  DEFW    PPHP          ; IMPLIED INSTR TABLE
  1655.     DEFW    PPLP
  1656.     DEFW    PPHA
  1657.     DEFW    PPLA
  1658.     DEFW    PDEY
  1659.     DEFW    PTAY
  1660.     DEFW    PINY
  1661.     DEFW    PINX
  1662.     DEFW    PTXA
  1663.     DEFW    PTAX
  1664.     DEFW    PDEX
  1665.     DEFW    PNOP
  1666. ;
  1667. ; JUMP TABLE TO ADDR MODE PROCESSORS
  1668. ;
  1669. GETTBL  DEFW    PIMM          ; INSTR MODE TABLE
  1670.     DEFW    PACX
  1671.     DEFW    PZPG
  1672.     DEFW    PAB
  1673.     DEFW    PZX
  1674.     DEFW    PZY
  1675.     DEFW    PZIX
  1676.     DEFW    PZIY
  1677.     DEFW    PABX
  1678.     DEFW    PABY
  1679. ;
  1680. ; JUMP TABLES TO MULTI-MODE PROCESSORS
  1681. ;
  1682. EVNTBL  DEFW    PASL          ; JUMPS TO PROCESSORS
  1683.     DEFW    PBTRL
  1684.     DEFW    PLSR
  1685.     DEFW    PROR
  1686.     DEFW    PSTXY
  1687.     DEFW    PLDXY
  1688.     DEFW    PDCY
  1689.     DEFW    PICX
  1690. ODDTBL  DEFW    PORA
  1691.     DEFW    PAND
  1692.     DEFW    PEOR
  1693.     DEFW    PADC
  1694.     DEFW    PSTA
  1695.     DEFW    PLDA
  1696.     DEFW    PCMP
  1697.     DEFW    PSBC
  1698. ;
  1699. ; MNEMONIC ASCII CODES (PACKED INTO 2 BYTES)
  1700. ;
  1701. MNMTBL  DEFW    0483H          ; MNEMONIC TABLE
  1702.     DEFW    05C4H
  1703.     DEFW    066CH
  1704.     DEFW    0863H         ; BCC
  1705.     DEFW    0873H
  1706.     DEFW    08B1H
  1707.     DEFW    0934H
  1708.     DEFW    09A9H
  1709.     DEFW    09C5H
  1710.     DEFW    0A0CH
  1711.     DEFW    0A4BH
  1712.     DEFW    0AC3H
  1713.     DEFW    0AD3H
  1714.     DEFW    0D83H         ; CLC
  1715.     DEFW    0D84H
  1716.     DEFW    0D89H
  1717.     DEFW    0D96H
  1718.     DEFW    0DB0H
  1719.     DEFW    0E18H
  1720.     DEFW    0E19H
  1721.     DEFW    10A3H        ; DEC
  1722.     DEFW    10B8H
  1723.     DEFW    10B9H
  1724.     DEFW    15F2H        ; EOR
  1725.     DEFW    25C3H        ; INC
  1726.     DEFW    25D8H
  1727.     DEFW    25D9H
  1728.     DEFW    29B0H        ; JMP
  1729.     DEFW    2A72H
  1730.     DEFW    3081H        ; LDA
  1731.     DEFW    3098H
  1732.     DEFW    3099H
  1733.     DEFW    3272H
  1734.     DEFW    39F0H        ; NOP
  1735.     DEFW    3E41H        ; ORA
  1736.     DEFW    4101H        ; PHA
  1737.     DEFW    4110H
  1738.     DEFW    4181H
  1739.     DEFW    4190H
  1740.     DEFW    49ECH        ; ROL
  1741.     DEFW    49F2H
  1742.     DEFW    4A89H
  1743.     DEFW    4A93H
  1744.     DEFW    4C43H        ; SBC
  1745.     DEFW    4CA3H
  1746.     DEFW    4CA4H
  1747.     DEFW    4CA9H
  1748.     DEFW    4E81H
  1749.     DEFW    4E98H
  1750.     DEFW    4E99H
  1751.     DEFW    5038H        ; TAX
  1752.     DEFW    5039H
  1753.     DEFW    5278H
  1754.     DEFW    5301H
  1755.     DEFW    5313H
  1756.     DEFW    5321H
  1757. ;
  1758. ; ADDRESS MODE PRINT TABLE
  1759. ;
  1760. AMDTBL  DEFM    ' $1    !'     ; ADDR MODE TABLE...REL
  1761.     DEFM    ' #$1   !'     ; IMMEDIATE
  1762.     DEFM    ' $21  !!'     ; ABS
  1763.     DEFM    ' $1    !'     ; ZPG
  1764.     DEFM    '        '     ; IMPLIED
  1765.     DEFM    ' A      '     ; ACCUM
  1766.     DEFM    ' ($1,X)!'     ; (ZPG,X)
  1767.     DEFM    ' ($1),Y!'     ; (ZPG),Y
  1768.     DEFM    ' $1,X  !'     ; ZPG,X
  1769.     DEFM    ' $1,Y  !'     ; ZPG,Y
  1770.     DEFM    ' $21,X!!'     ; ABS,X
  1771.     DEFM    ' $21,Y!!'     ; ABS,Y
  1772.     DEFM    ' ($21)!!'     ; INDIRECT
  1773. ;
  1774. ; THAT'S ALL!
  1775. ;
  1776.     END
  1777.