home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / cpmug / cpmug041.ark / TTYX.ASM < prev    next >
Encoding:
Assembly Source File  |  1984-04-29  |  4.1 KB  |  166 lines
  1. ; 
  2. ;        ASCXMT(4) REV. 2
  3. ;    BY KEITH PETERSEN, W8SDZ.  10/29/78.
  4. ; 
  5. ; THIS PROGRAM IS FOR TRANSMITTING ASCII
  6. ; THROUGH A BAUDOT MEDIUM USE A SPECIAL
  7. ; FORMAT OF FIGURES BLANK (X) - WHERE (X)
  8. ; IS A SPECIAL BAUDOT CHARACTER USED TO
  9. ; CONVEY THE ASCII EQUIVALENT CHARACTER TO THE
  10. ; RECEIVING END WHERE IT IS THEN CONVERTED BACK
  11. ; TO ASCII AGAIN.  LOWER CASE ALPHA CHARACTERS
  12. ; ARE TRANSMITTED VIA A 4TH CASE, LTRS BLANK (X).
  13. ;
  14. ; EQUATES
  15. ; 
  16. LTRS:    EQU    1FH
  17. FIGS:    EQU    1BH
  18. CR:    EQU    48H
  19. LF:    EQU    42H
  20. STATUS:    EQU    0AH    ;BAUDOT UART STATUS PORT
  21. TBE:    EQU    80H    ;UART TRANS. BUF. EMPTY FLAG
  22. BTTY:    EQU    0BH    ;BAUDOT UART DATA PORT
  23. ALTMOD:    EQU    7DH    ;ALTERNATE MODE KEY
  24. BEGIN:    EQU    0FA00H    ;MY ADDRESS FOR THIS PROGRAM
  25. ; 
  26. ;          PROGRAM STARTS HERE.
  27. ; CALL WITH ASCII CHARACTER IN ACCUMULATOR.
  28. ; 
  29.     ORG    BEGIN    ;PUT STARTING ADDRESS HERE
  30. ; 
  31. START:    PUSH    PSW    ;SAVE REGISTERS USED
  32.     PUSH    B
  33.     PUSH    H
  34. ; 
  35. BAUDOT:    MVI    C,0    ;SET UP COUNTER
  36.     ANI    7FH    ;STRIP PARITY BIT
  37.     CPI    ALTMOD    ;ALTERNATE MODE KEY?
  38.     JNZ    BAUD2    ;NO, IGNORE NEXT ROUTINE
  39.     MVI    A,09H    ;BAUDOT '$'
  40.     JMP    BAUD3
  41. ; 
  42. BAUD2:    CPI    7BH    ;ABOVE L.C. 'Z' ?
  43.     JNC    TTY0    ;IF SO, IGNORE IT
  44.     LXI    H,BTABLE ;POINT TO TABLE START
  45.     ADD    L    ;ADD CHARACTER VALUE
  46.     MOV    L,A    ;L POINTS TO BAUDOT CHAR.
  47.     MOV    A,H    ;GET H FOR CORRECTION
  48.     ACI    0    ;CORRECT IF NECESSARY
  49.     MOV    H,A    ;H IS NOW CORRECT
  50.     MOV    A,M    ;GET BAUDOT CHARACTER
  51.     ORA    A    ;IS IT A NON-PRINTING CHAR?
  52.     JZ    TTY0    ;IF SO IGNORE IT
  53.     CPI    CR    ;IS IT A CARRIAGE RETURN?
  54.     JZ    TTYOUT-1 ;YES, HANDLE WITHOUT CASE TEST
  55.     CPI    LF    ;IS IT A LINE FEED?
  56.     JNZ    BAUD3    ;NO, IGNORE NEXT ROUTINE
  57.     MVI    A,LTRS    
  58.     PUSH    PSW    ;SAVE IT ON STACK
  59.     MVI    A,LF
  60.     LXI    H,SCASE    ;POINT TO PRESENT CASE REG.
  61.     MVI    M,40H    ;SET IT TO LOWER CASE
  62.     JMP    TTYOUT-2 ;SEND LF AND LTRS
  63. ; 
  64. BAUD3:    PUSH    PSW    ;SAVE CHARACTER
  65.     ANI    0C0H    ;STRIP ALL BUT CASE BITS
  66.     LXI    H,SCASE    ;POINT TO PRESENT CASE REG.
  67.     CMP    M    ;SAME CASE AS PREVIOUS CHARACTER?
  68.     JZ    TTYOUT    ;YES NO CHANGE NECESSARY
  69.     MOV    M,A    ;UPDATE CASE REGISTER
  70.     ORA    A
  71.     JZ    TCASE
  72.     CPI    80H
  73.     JZ    UCASE
  74.     CPI    0C0H
  75.     JNZ    LCASE
  76. ; 
  77. FCASE:    XRA    A    ;GET A BAUDOT 'BLANK'
  78.     PUSH    PSW    ;SAVE IT ON THE STACK
  79.     INR    C    ;INCREMENT CHARACTER COUNT
  80. ; 
  81. LCASE:    MVI    A,LTRS
  82.     JMP    TTYOUT-2
  83. ; 
  84. TCASE:    XRA    A    ;GET A BAUDOT 'BLANK'
  85.     PUSH    PSW    ;SAVE IT ON THE STACK
  86.     INR    C    ;INCREMENT CHARACTER COUNT
  87. ; 
  88. UCASE:    MVI    A,FIGS
  89.     INR    C    ;INCREMENT CHARACTER COUNT
  90.     PUSH    PSW    ;SAVE IT ON THE STACK
  91. ; 
  92. TTYOUT:    IN    STATUS    ;BAUDOT UART STATUS
  93.     ANI    TBE    ;TRANS. BUFFER EMPTY?
  94.     JZ    TTYOUT    ;IF NOT, LOOP AND WAIT
  95.     POP    PSW    ;GET CHARACTER
  96. ; 
  97. ; OMIT NEXT THREE LINES IF NO LIGHTS.
  98. ; 
  99.     CMA        ;INVERT FOR LIGHTS
  100.     OUT    0FFH    ;PUT ON FRONT PANEL LIGHTS
  101.     CMA        ;INVERT BACK TO NORMAL
  102. ;
  103. ; OMIT ABOVE THREE LINES IF NO LIGHTS.
  104. ; 
  105.     ORI    0E0H    ;MAKE UPPER 3 BITS MARKING
  106.     OUT    BTTY    ;SEND TO BAUDOT UART PORT
  107.     DCR    C    ;MORE TO SEND?
  108.     JP    TTYOUT    ;YES, CONTINUE SENDING
  109. ; 
  110. TTY0:    POP    H    ;RESTORE REGISTERS
  111.     POP    B
  112.     POP    PSW
  113.     RET        ;RETURN TO CALLING PROGRAM
  114. ; 
  115. BTABLE:    DB    5FH,17H,13H    ;NUL SOH STX
  116.     DB    1,0,0AH        ;ETX EOT ENQ
  117.     DB    0,85H,10H    ;ACK BEL BS
  118.     DB    15H,42H,0C2H    ;HT  LF  VT
  119.     DB    2,48H,0        ;FF  CR  SO
  120.     DB    7,0,0        ;SI  DLE DC1
  121.     DB    0,0,0        ;DC2 DC3 DC4
  122.     DB    0,6,0        ;NAK SYN ETB
  123.     DB    18H,0,16H    ;CAN EM  SUB
  124.     DB    0EH,0,0        ;ESC FS  GS
  125.     DB    0,0,44H        ;RS  US  SPACE
  126.     DB    8DH,91H,94H    ;!   "   #
  127.     DB    89H,0BH,9AH    ;$   PCT &
  128.     DB    8BH,8FH,92H    ;'   (   )
  129.     DB    14H,1AH,8CH    ;AS  PL  ,
  130.     DB    83H,9CH,9DH    ;-   .   /
  131.     DB    96H,97H,93H    ;0   1   2
  132.     DB    81H,8AH,90H    ;3   4   5
  133.     DB    95H,87H,86H    ;6   7   8
  134.     DB    98H,8EH,9EH    ;9   :   ;
  135.     DB    0FH,0DH,12H    ;LT  EQ  GT
  136.     DB    99H,5,43H    ;?   AT  A
  137.     DB    59H,4EH,49H    ;B   C   D
  138.     DB    41H,4DH,5AH    ;E   F   G
  139.     DB    54H,46H,4BH    ;H   I   J
  140.     DB    4FH,52H,5CH    ;K   L   M
  141.     DB    4CH,58H,56H    ;N   O   P
  142.     DB    57H,4AH,45H    ;Q   R   S
  143.     DB    50H,47H,5EH    ;T   U   V
  144.     DB    53H,5DH,55H    ;W   X   Y
  145.     DB    51H,11H,1DH    ;Z   LB  LS
  146.     DB    1CH,19H,3    ;RB  UA  LA
  147. ; 
  148. ; THESE ARE THE LOWER CASE ALPHA CHARACTERS
  149. ; 
  150.     DB    0,0C3H,0D9H    ;'   A   B
  151.     DB    0CEH,0C9H,0C1H    ;C   D   E
  152.     DB    0CDH,0DAH,0D4H    ;F   G   H
  153.     DB    0C6H,0CBH,0CFH    ;I   J   K
  154.     DB    0D2H,0DCH,0CCH    ;L   M   N
  155.     DB    0D8H,0D6H,0D7H    ;O   P   Q
  156.     DB    0CAH,0C5H,0D0H    ;R   S   T
  157.     DB    0C7H,0DEH,0D3H    ;U   V   W
  158.     DB    0DDH,0D5H,0D1H    ;X   Y   Z
  159. ; 
  160. ; TEMPORARY STORAGE AREA
  161. ; 
  162. SCASE:    DB    40H    ;PRESENT CASE REGISTER
  163. ; 
  164.     END
  165.   
  166.