home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / cpmug / cpmug017.ark / DISPLAY.ASM < prev    next >
Encoding:
Assembly Source File  |  1984-04-29  |  5.3 KB  |  327 lines
  1. ; 
  2. ; DISPLAY PROCESSOR MODULE
  3. ; 
  4. ; INITIALIZATION
  5. ; 
  6. STACK    EQU    0FFH        ;STACK ADDR
  7. CINTC    EQU    0FFFBH        ;RTC CONTROL ADDR
  8. GSTRT    EQU    100H        ;START ADDR
  9. KINTC    EQU    0FFC0H        ;KBRD INT CONTROL ADDR
  10. TIME    EQU    3FH        ;SYSTEM TIME
  11. TOP    EQU    40H        ;DISPLAY FILE START ADDR
  12. XYOUT    EQU    0FFFCH        ;CRT OUTPUT ADDR
  13. ; 
  14.     ORG    GSTRT
  15. INIT:    LXI    D,0        ;ZERO XY (IN DE ALWAYS)
  16.     LXI    H,TABLE
  17.     SHLD    INCPT        ;INIT INCR PTR
  18.     LXI    SP,STACK        ;INIT STACK PTR
  19.     MVI    A,10H
  20.     STA    KINTC        ;TURN ON KB INT
  21.     MVI    A,80H    
  22.     STA    CINTC        ;TURN ON RTC INT
  23.     EI
  24.     LHLD    TOP
  25.     SHLD    PNTR        ;INIT INSTRUCTION PTR
  26. ; 
  27. ; OPCODE DECODING
  28. ; 
  29. MLOOP:    LHLD    PNTR        ;ADDR OF OPCODE
  30.     MOV    C,M
  31.     MVI    B,0        ;OPCODE IN BC
  32.     LXI    H,JMTAB        ;BASE OF JUMP TABLE
  33.     DAD    B        ;ADD OPCODE
  34.     MOV    C,M    
  35.     INX    H
  36.     MOV    H,M
  37.     MOV    L,C        ;ADDR OF ROUTINE IN HL
  38.     PCHL            ;JUMP TO IT
  39. ; 
  40. ; JUMP TABLE FOR OPCODE PROCESSING
  41. ; 
  42. JMTAB:    DW    MBEAM        ;0
  43.     DW    MDISP        ;2
  44.     DW    LVEC        ;4
  45.     DW    SVEC        ;6
  46.     DW    PARAM        ;8
  47.     DW    JUMP        ;A
  48.     DW    JUMPS        ;C
  49.     DW    RETS        ;E
  50.     DW    EXEC        ;10H
  51.     DW    SYNC        ;12H
  52. ; 
  53. ; MOVE BEAM - DON'T DIPLAY POINT
  54. ; 
  55. MBEAM:    LHLD    PNTR
  56.     INX    H
  57.     MOV    D,M        ;GET X COORD
  58.     INX    H
  59.     MOV    E,M        ;GET Y COORD
  60.     INX    H
  61.     SHLD    PNTR        ;RESTORE PTR
  62.     JMP    MLOOP        ;GET ANOTHER INSTRUCTION
  63. ; 
  64. ; MOVE BEAM AND DISPLAY POINT
  65. ; 
  66. MDISP:    LHLD    PNTR
  67.     INX    H
  68.     MOV    D,M
  69.     INX    H
  70.     MOV    E,M
  71.     INX    H
  72.     SHLD    PNTR
  73.     XCHG            ;XY TO HL
  74.     SHLD    XYOUT        ;WRITE TO CRT
  75.     XCHG            ;XY TO DE
  76.     JMP    MLOOP
  77. ; 
  78. ; SET ORIENTATION AND SCALE
  79. ; 
  80. PARAM:    LHLD    PNTR
  81.     INX    H
  82.     MOV    C,M
  83.     INX    H
  84.     SHLD    PNTR
  85.     MOV    L,C        ;NEW ORIENT & SCALE IN HL
  86.     MVI    H,0
  87.     LXI    B,TABLE        ;ADDR OF INCR TABLE
  88.     DAD    B        ;ADD ORIENT & SCALE
  89.     SHLD    INCPT        ;STORE IN INCR PTR
  90.     JMP    MLOOP        ;GET ANOTHER INSTRUCTION
  91. ; 
  92. ; JUMP TO A NEW LOCATION IN DISPLAY FILE
  93. ; 
  94. JUMP:    LHLD    PNTR
  95.     INX    H
  96.     MOV    A,M        ;LSB OF ADDR
  97.     INX    H
  98.     MOV    H,M        ;MSB OF ADDR
  99.     MOV    L,A
  100.     SHLD    PNTR        ;STORE IN INSTRUCTION PTR
  101.     JMP    MLOOP
  102. ; 
  103. ; JUMP TO SUBROUTINE
  104. ; 
  105. JUMPS:    LHLD    PNTR
  106.     INX    H
  107.     MOV    C,M    
  108.     INX    H
  109.     MOV    B,M        ;NEW ADDR IN BC
  110.     INX    H
  111.     PUSH    H        ;STORE OLD PTR ON STACK
  112.     MOV    H,B
  113.     MOV    L,C
  114.     SHLD    PNTR        ;ADDR IN INSTRUCTION PTR
  115.     JMP    MLOOP
  116. ; 
  117. ; RETURN FROM SUBROUTINE
  118. ; 
  119. RETS:    POP    H        ;RESTORE PTR FROM STACK
  120.     SHLD    PNTR
  121.     JMP    MLOOP
  122. ; 
  123. ; SHORT VECTOR MODE
  124. ; 
  125. SVEC:    LHLD    PNTR        ;CURRENT INSTR INDEX
  126.     INX    H
  127. NEXT:    MOV    B,M        ;SHORT VECTOR INSTRUCTION
  128.     INX    H
  129.     SHLD    PNTR        ;RESTORE PTR
  130.     MOV    A,B
  131.     ANI    7H        ;MASK DIRECTION BITS
  132.     MOV    C,A        ;OFFSET IN C
  133.     MOV    A,B        ;ORIG INSTR IN A
  134.     MVI    B,0        ;ZERO IN B
  135.     LHLD    INCPT        ;INCR PTR
  136.     DAD    B        ;ADD DIRECTION OFFSET
  137.     MOV    B,M        ;X INCREMENT
  138.     INX    H
  139.     INX    H
  140.     MOV    C,M        ;Y INCREMENT
  141.     XCHG            ;XY IN HL
  142.     MOV    E,A        ;ORIGINAL INSTR
  143.     ANI    70H        ;LENGTH BITS
  144.     RRC
  145.     RRC
  146.     RRC
  147.     RRC            ;SHIFT RIGHT 4
  148.     MOV    D,A        ;IN D
  149.     MOV    A,E        ;ORIGINAL INSTR
  150.     ANI    8H        ;ON/OFF BIT
  151.     JNZ    FLOOP        ;JUMP IF "OFF"
  152.     SHLD    XYOUT        ;INITIAL DOT TO CRT
  153. NLOOP:    MOV    A,B        ;X INCREMENT
  154.     ADD    H
  155.     MOV    H,A
  156.     MOV    A,C
  157.     ADD    L
  158.     MOV    L,A        ;NEW XY IN HL
  159.     SHLD    XYOUT        ;WRITE TO CRT
  160.     DCR    D
  161.     JNZ    NLOOP        ;LOOP IF NOT DONE
  162.     JMP    CKESC        ;CHECK "ESCAPE"
  163. FLOOP:    MOV    A,B        ;X INCREMENT
  164.     ADD    H        ;ADD TO X
  165.     MOV    H,A
  166.     MOV    A,C        ;Y INCREMENT
  167.     ADD    L
  168.     MOV    L,A        ;NEW XY IN HL
  169.     DCR    D
  170.     JNZ    FLOOP        ;LOOP IF NOT DONE
  171. CKESC:    MOV    A,E        ;ORIGINAL INSTR
  172.     XCHG            ;XY TO DE
  173.     RLC            ;SET CARRY IF "ESCAPE"
  174.     JC    MLOOP        ;MAIN LOOP IF SO
  175.     LHLD    PNTR
  176.     JMP    NEXT        ;GET MORE DATA IF NOT
  177. ; 
  178. ; LONG VECTOR MODE
  179. ; 
  180. LVEC:    LHLD    PNTR
  181.     INX    H
  182.     MOV    B,M        ;NEW X POS
  183.     INX    H
  184.     MOV    A,M        ;NEW Y POS
  185.     INX    H
  186.     SHLD    PNTR    
  187. ; 
  188.     MVI    C,0F8H        ;SPECIAL MASK FOR -
  189.     SUB    E        ;DEL Y IN A 
  190.     JC    PLUSY        ;TEST SIGN OF DEL
  191.     MVI    C,0        ;SPECIAL MASK FOR +
  192. PLUSY:    RLC
  193.     RLC
  194.     RLC            ;DIVIDE BY 32
  195.     MOV    H,A        ;SAVE IN H
  196.     ANI    0F8H        ;SAVE 1ST 5 BITS
  197.     MOV    L,A        ;L.O. Y INC
  198.     MOV    A,H        ;RESTORE
  199.     ANI    7        ;SAVE LAST 3 BITS
  200.     XRA    C        ;XOR SPECIAL MASK
  201.     MOV    H,A        ;H.O. Y INC
  202.     SHLD    YINC        ;STORE
  203. ; 
  204.     MOV    A,B        ;X POS
  205.     MVI    C,0F8H
  206.     SUB    D        ;DEL X IN A
  207.     JC    PLUSX
  208.     MVI    C,0
  209. PLUSX:    RLC
  210.     RLC
  211.     RLC
  212.     MOV    H,A
  213.     ANI    0F8H
  214.     MOV    L,A        ;L.O. X INCR
  215.     MOV    A,H
  216.     ANI    7
  217.     XRA    C
  218.     MOV    H,A        ;H.O. X INCR
  219.     SHLD    XINC
  220. ; 
  221.     MOV    B,D        ;X IN BC (H.O.)
  222.     MVI    C,0
  223.     MOV    D,E        ;Y IN DE (H.O.)
  224.     MVI    E,0
  225.     MVI    A,20H        ;32 POINTS IN VECT
  226. ; 
  227. LLOOP:    LHLD    YINC
  228.     DAD    D
  229.     XCHG            ;NEW Y IN DE
  230.     LHLD    XINC
  231.     DAD    B
  232.     MOV    B,H        ;NEW X IN BC
  233.     MOV    C,L
  234.     MOV    L,D        ;XY IN HL (H.O.)
  235.     SHLD    XYOUT        ;WRITE TO CRT
  236.     DCR    A
  237.     JNZ    LLOOP
  238. ; 
  239.     XCHG            ;RESTORE XY TO DE
  240.     JMP    MLOOP
  241. ; 
  242. ; TRANSFER CONTROL TO EXECUTIVE
  243. ; 
  244. EXEC:    LHLD    PNTR        ;BUMP PTR
  245.     INX    H
  246.     SHLD    PNTR
  247.     MVI    H,80H        ;BEAM TO SCREEN CENTER
  248.     MVI    L,80H
  249.     SHLD    XYOUT
  250.     RST    3        ;XFER TO LOC 18H
  251.     JMP    MLOOP        ;NEXT INSTRUCTION
  252. ; 
  253. ; SYNCHRONIZE WITH REAL-TIME CLOCK
  254. ; 
  255. SYNC:    LHLD    PNTR        ;BUMP PTR
  256.     INX    H
  257.     SHLD    PNTR
  258.     MVI    H,80H        ;BEAM TO SCREEN CENTER
  259.     MVI    L,80H
  260.     SHLD    XYOUT
  261.     LXI    H,TIME
  262.     MOV    A,M        ;OLD TIME IN A
  263. SLOOP:    CMP    M        ;OLD=NEW?
  264.     JZ    SLOOP        ;YES - KEEP TRYING
  265.     JMP    MLOOP        ;NO - NEXT INSTR
  266. ; 
  267. ; TABLE FOR VECTOR ORIENTATION AND SCALING
  268. ; 
  269. TABLE:    DB    0
  270.     DB    2
  271.     DB    2
  272.     DB    2
  273.     DB    0
  274.     DB    -2
  275.     DB    -2
  276.     DB    -2
  277.     DB    0
  278.     DB    2
  279.     DB    2
  280.     DB    2
  281.     DB    0
  282.     DB    -2
  283.     DB    -2
  284.     DB    -2
  285.     DB    0
  286.     DB    3
  287.     DB    3
  288.     DB    3
  289.     DB    0
  290.     DB    -3
  291.     DB    -3
  292.     DB    -3
  293.     DB    0
  294.     DB    3
  295.     DB    3
  296.     DB    3
  297.     DB    0
  298.     DB    -3
  299.     DB    -3
  300.     DB    -3
  301.     DB    0
  302.     DB    4
  303.     DB    4
  304.     DB    4
  305.     DB    0
  306.     DB    -4
  307.     DB    -4
  308.     DB    -4
  309.     DB    0
  310.     DB    4
  311.     DB    4
  312.     DB    4
  313.     DB    0
  314.     DB    -4
  315.     DB    -4
  316.     DB    -4
  317.     DB    0
  318. ; 
  319. ; THE FOLLOWING ARE STORAGE CELLS NOT TO BE IN PROM
  320. ; WORKING STORAGE
  321. ; 
  322. PNTR:    DW    0        ;PTR TO NEXT INSTR
  323. XINC:    DW    0        ;LVEC ONLY
  324. YINC:    DW    0        ;LVEC ONLY
  325. INCPT:    DW    0        ;PTR TO INCREMENT IN TABLE
  326.     END
  327.