home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / cpmug / cpmug013.ark / BAGELS.BAS < prev    next >
Encoding:
BASIC Source File  |  1984-04-29  |  2.1 KB  |  89 lines
  1. 1000 FOR I = 1 TO 20:PRINT:NEXT I
  2. 1010 PRINT TAB(20);"******* BAGELS *******"
  3. 1020 FOR I = 1 TO 10:PRINT:NEXT I
  4. 1030 DIM A(3),B(3)
  5. 1040 N$="0123456789"
  6. 1060 RANDOMIZE
  7. 1050 Y=0
  8. 1070 INPUT"INSTRUCTIONS ";I$
  9. 1080 IF LEFT$(I$,2)="NO" THEN 1150
  10. 1090 IF LEFT$(I$,2)="YE" THEN 1100
  11. 1095 PRINT"YES OR NO ";:GOTO 1070
  12. 1100 PRINT"I AM THINKING OF A THREE DIGIT NUMBER.  YOU CAN GUESS WHAT"
  13. 1110 PRINT"NUMBER I HAVE IN MIND AND I WILL TELL YOU:"
  14. 1120 PRINT"  PICO     - ONE DIGIT IS IN THE WRONG PLACE"
  15. 1130 PRINT"  FERMI    - ONE DIGIT IS IN THE RIGHT PLACE"
  16. 1140 PRINT"  BAGELS   - NO DIGIT CORRECT"
  17. 1150 A(1)=INT(10*RND)
  18. 1160 A(2)=INT(10*RND)
  19. 1170 IF A(2)=A(1) THEN 1160
  20. 1180 A(3)=INT(10*RND)
  21. 1190 IF A(3)=A(1) OR A(3)=A(2) THEN 1180
  22. 1210 PRINT"OKAY, I HAVE A NUMBER IN MIND."
  23. 1220 FOR I=1 TO 20
  24. 1230 PRINT:PRINT"GUESS #";I;":";
  25. 1240 INPUT A$
  26. 1250 IF LEN(A$) <> 3 THEN 1630
  27. 1260 FOR J=1 TO 3
  28. 1265 K=0
  29. 1270 FOR C=1 TO 10
  30. 1280 IF MID$(A$,J,1)=MID$(N$,C,1) THEN K=1:B(J)=C-1
  31. 1290 NEXT C
  32. 1295 IF K<>1 THEN PRINT"WHAT": GOTO 1230
  33. 1300 NEXT J
  34. 1310 PRINT B(1);B(2);B(3);
  35. 1340 IF B(1)=B(2) OR B(2)=B(3) OR B(3)=B(1) THEN 1650
  36. 1350 C=0:D=0
  37. 1360 FOR J=1 TO 2
  38. 1370 IF A(J)<>B(J+1) THEN 1390
  39. 1380 C=C+1
  40. 1390 IF A(J+1)<>B(J) THEN 1410
  41. 1400 C=C+1
  42. 1410 NEXT J
  43. 1420 IF A(1)<>B(3) THEN 1440
  44. 1430 C=C+1
  45. 1440 IF A(3)<>B(1) THEN 1460
  46. 1450 C=C+1
  47. 1460 FOR J=1 TO 3
  48. 1470 IF A(J)<>B(J) THEN 1490
  49. 1480 D=D+1
  50. 1490 NEXT J
  51. 1500 IF D=3 THEN 1680
  52. 1510 PRINT TAB(10);
  53. 1515 IF C=0 THEN 1545
  54. 1520 FOR J=1 TO C
  55. 1530 PRINT"PICO ";
  56. 1540 NEXT J
  57. 1545 IF D=0 THEN 1580
  58. 1550 FOR J=1 TO D
  59. 1560 PRINT"FERMI ";
  60. 1570 NEXT J
  61. 1580 IF C+D THEN 1600
  62. 1590 PRINT"BAGELS";
  63. 1600 NEXT I
  64. 1610 PRINT"OH WELL!"
  65. 1620 GOTO 1700
  66. 1630 PRINT"TRY GUESSING A THREE DIGIT NUMBER"
  67. 1640 GOTO 1230
  68. 1650 PRINT"OH. I FORGOT TO TELL YOU THAT THE NUMBER I HAVE IN MIND"
  69. 1660 PRINT"HAS NO TWO DIGITS THE SAME."
  70. 1670 GOTO 1230
  71. 1680 PRINT:PRINT"YOU GOT IT!"
  72. 1690 Y=Y+1
  73. 1700 PRINT"AGAIN ";
  74. 1710 INPUT I$
  75. 1720 IF LEFT$(I$,1)="Y" THEN 1150
  76. 1730 IF Y=0 THEN 1750
  77. 1740 PRINT "A";Y;" POINT BAGELS BUFF"
  78. 1750 END
  79.  
  80.  
  81.  
  82.  
  83.  
  84.  
  85.  
  86.  
  87.  
  88.  
  89.