home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / enterprs / cpm / utils / a / bios-5.arc / CXIO.ASM < prev    next >
Encoding:
Assembly Source File  |  1989-05-08  |  24.1 KB  |  1,293 lines
  1. ; code in this module was modified to set the screen up for 80 col 
  2. ; automaticly, all 40 column code has been deleted.  the label NULL40 is
  3. ; still maintained in the device table as removing it would change
  4. ; the subsequent device numbers, affecting the use of RS-232 (it would
  5. ; require rewrites of all modem programs)
  6. ; code at the label ?rlccp has been added to reset the feel and repeat
  7. ; rate at every warm start, this corrects problems that arise after 
  8. ; terminating a modem program. 
  9. ;
  10. ; Code has been added to allow setting the cursor flash rate and shape,
  11. ; set the temporary drive, and the drive search chain.
  12. ; 
  13. ; Code has been added to require a password to be entered before the
  14. ; system finishes initialization, 3 trys are allowed, the system locks
  15. ; up if you fail all three.
  16. ;
  17. ; A label has been added to allow the 6551 init code to install baud
  18. ; rates based on the value in DEVTBL.
  19. ;
  20. ; User assumes _ALL_ liability for the use of this module. Original 
  21. ; Copyright is still maintained by Commodore
  22. ;
  23. ; Code to set cursor and drive chain; Copyright April 26, 1987 by
  24. ;    James W. Waltrip IV
  25. ;------------------------------------------------------------------------
  26. ; *ADDITIONS BY Randy Winchester, 5/6/89
  27. ;
  28. ; Default printer is device 4.
  29. ;
  30. ; Set up for non-flashing block cursor
  31. ;
  32. ; Search chain/temp drive:  M:,*,F: [TEMP=M:]
  33. ; Drive F: is reserved for the Quick Brown Box battery powered RAM cartridge.
  34. ; The QBB is initialized with QD.COM from Herne Data Systems, Ltd.
  35. ;
  36. ; No password protection for booting the system.
  37. ;
  38. ; Colors set in sign-on message.  Background=lt. gray, character=blue
  39. ;
  40. ; Default system baud rate set for 75 baud.  This speeds up normal operation
  41. ; considerably.
  42. ;
  43. ; Printer names set to PRT-D4 and PRT-D5 (devices 4 and 5)
  44. ;-------------------------------------------------------------------------
  45. ;
  46.     title    'C128 BIOS, main I/O and sys functions     6 May   89'
  47.  
  48. ;
  49. ;    This module contains CXIO,CXINIT,CXMOVE and CXTIME.
  50. ;
  51.     maclib    cpm3
  52.  
  53.     maclib    z80
  54.  
  55.     maclib    cxequ
  56.  
  57.     maclib    modebaud
  58.  
  59. ;**********************************************************
  60.  
  61.     extrn    repeat            ; repeat rate
  62.  
  63. repeat$amt    equ    2
  64.  
  65.     extrn    delay            ; delay before repeat
  66.  
  67. delay$amt    equ    16
  68.  
  69.  
  70. printnum    equ    010h        ; printer device to init
  71.                     ; Device 4 = 010h (16 decimal)
  72.                     ; Device 5 = 08
  73.  
  74. pass        equ    false        ; set to 'false' if password
  75.                      ;protection not wanted
  76.  
  77. pass$word    macro
  78.  
  79.     db    'PASS'                ; password is defined here
  80. ;                                       ; if using lower case letters
  81. ;                    ; use the HEX values rather than
  82. ;                    ; the characters themselves
  83. ;                    ; ie.-> 061h  instead of 'a'
  84.         endm
  85.  
  86. ;*************************************************************
  87.     public    ?init,?ldccp,?rlccp
  88.  
  89.     public    ?user,?di$int
  90.  
  91.     extrn    ?sysint
  92.  
  93. bdos    equ    5    
  94.     
  95.     extrn    @civec,@covec,@aivec,@aovec,@lovec
  96.     extrn     ?bnksl
  97.  
  98.     public    ?cinit,?ci,?co,?cist,?cost
  99.     public    @ctbl
  100.     extrn    ?kyscn
  101.  
  102. ; Utility routines in standard BIOS
  103.     extrn    ?wboot        ; warm boot vector
  104.     extrn    ?pmsg        ; print message @<HL> up to 00
  105.                 ; saves <BC> & <DE>
  106.     extrn    ?pdec        ; print binary number in <A> from 0 to 99.
  107.     extrn    ?pderr        ; print BIOS disk error header
  108.     extrn    ?conin,?cono    ; con in and out
  109.     extrn    ?const        ; get console status
  110.  
  111.     extrn    @hour,@min,@sec,@date,?bnksl
  112.     public    ?time
  113.  
  114.     page
  115. ;
  116. ;    keyboard scanning routine 
  117. ;
  118.     extrn    ?get$key,?int$cia
  119.     extrn    Fx$V$tbl
  120. ;
  121. ;    links to 80 column display
  122. ;
  123.     extrn    ?out80,?int80
  124.  
  125.     extrn    ?pt$i$1101,?pt$o$1,?pt$o$2
  126.  
  127. ;
  128. ;    bios8502 function routines
  129. ;
  130.     public    ?fun65
  131.  
  132. ;
  133. ;
  134. ;
  135.     public    X6551$baud
  136.     extrn    ?int65,?in65,?ins65,?out65
  137.     extrn    @drcha,@drchb,@drchc,@drchd,@tpdrv
  138.  
  139.  
  140.     DSEG
  141. ?fun65:
  142.     sta    vic$cmd            ; save the command passed in A
  143.  
  144. fun$di$wait:
  145.     lda    RS232$status
  146.     ani    01000010b        ; transmitting or receiving ?
  147.     jrnz    fun$di$wait        ; yes, wait for int to clean up
  148.     di
  149.     lda    force$map        ; get current MMU configuration
  150.     push    psw            ; save it
  151.     sta    io$0            ; make I/O 0 current
  152.     
  153.     lxi    d,1            ; D=0,  E=1
  154.     lxi    b,page$1$h
  155.     outp    d
  156.     dcr    c
  157.     outp    e            ; page 1, 0-1
  158.     dcr    c
  159.     outp    d
  160.     dcr    c
  161.     outp    d            ; page 0, 0-0
  162.     call    enable$6502+6        ; go run the 8502
  163.     mvi    c,low(page$1$h)
  164.     outp    e
  165.     dcr    c
  166.     outp    e            ; page 1, 1-1
  167.     dcr    c
  168.     outp    e
  169.     dcr    c
  170.     outp    d            ; page 0, 1-0
  171.  
  172.     pop    psw            ; recover the MMU config.
  173.     sta    force$map        ; restore it
  174.     ei                ; turn interrupts back on
  175.     lda    vic$data        ; get command results
  176.     ora    a            ; set the zero flag if A=0
  177.     ret
  178.  
  179. ?di$int:
  180.     push    psw
  181. di$int$1:
  182.     lda    RS232$status
  183.     ani    01000010b        ; transmitting or receiving ?
  184.     jrnz    di$int$1        ; yes, wait for int to clean up
  185.     pop    psw
  186.     di
  187.     ret
  188.  
  189.     page
  190. ;
  191. ;    set up the MMU for CP/M Plus
  192. ;
  193.     DSEG            ; init done from banked memory
  194. ?init:
  195.     mvi    a,3eh            ; force MMU into I/O space
  196.     sta    force$map        ;
  197.     lxi    h,mmu$table+11-1    ; table of 11 values
  198.     lxi    b,mmu$start+11-1    ; to to MMU registers
  199.     mvi    d,11            ; move all 11 bytes to the MMU
  200.  
  201. init$mmu$loop:
  202.     mov    a,m
  203.     outp    a
  204.     dcx    h
  205.     dcx    b
  206.     dcr    d
  207.     jrnz    init$mmu$loop
  208.  
  209.     mvi    a,1            ; enable track and sector status
  210.     sta    stat$enable        ; on the status line
  211.  
  212. ;    mvi    a,1h            ; no parity, 8 bits, 1 stop bit    
  213.     sta    XxD$config
  214.  
  215.     lxi    h,Fx$V$tbl
  216.     shld    key$FX$function
  217. ;*********************************************************
  218. ;
  219. ; install I/O assignments
  220. ;
  221.     lxi    h,4000h            ; 80 and 40 column drivers
  222.     shld    @covec
  223.     mvi    h,80h
  224.     shld    @civec            ; assign console input to keys
  225.     mvi    h,printnum        ; device # 4
  226.     shld    @lovec            ; assign printer to LPT:
  227.     mvi    h,00h
  228.     shld    @aivec
  229.     shld    @aovec            ; assign rdr/pun port
  230.  
  231. ;
  232. ; init SCB
  233. ;
  234.     mvi    a,0dh            ; The following instr. set up the
  235.     sta    @drcha            ; Drive Search Chain, and the Temp. 
  236.     sta    @tpdrv            ; Drive.  This replaces the SETDEF
  237.     mvi    a,0            ; method of setting this up.
  238.     sta    @drchb            ; M:,*,F: [TEMP=M:]
  239.     mvi    a,6
  240.     sta    @drchc
  241.     mvi    a,0ffh            ; 0ffh = filler byte
  242.     sta    @drchd
  243. ;
  244. ; Where are the bytes for COM/SUB execution?
  245. ;
  246. ; 80 Col. screen cursor attributes
  247. ;
  248.     lxi    b,0D600h    ; 80 col cmd reg
  249.     mvi    a,010        ; reg 10 of 8563 (cursor type, start scan line)
  250.     outp    a        ; tell 8563 you want reg 10
  251. lx1:                
  252.     inp    a        ; get status
  253.     jp    lx1        ; loop until status good
  254.     lxi    b,0D601h    ; 80 col data reg
  255.     mvi    a,00000000b    ; slow cursor, scan line 4 lines from top
  256.     outp    a
  257. ;
  258.     lxi    b,0D600h
  259.     mvi    a,011        ; reg 11 of 8563 (cursor end scan line)
  260.     outp    a
  261. lx2:
  262.     inp    a
  263.     jp    lx2
  264.     lxi    b,0D601h
  265.     mvi    a,00000111b    ; Scan line 5 lines from top
  266.     outp    a
  267.     lxi    b,0D011h    ; Vic controll reg 1
  268.     mvi    a,00001000b    ; turn off Vic
  269.     outp    a
  270. ;
  271.     page
  272. ;
  273. ; print sign on message
  274. ;
  275.     call    prt$msg            ; print signon message
  276.     db    'Z'-'@'            ; home and clear screen (to BG color)
  277.     db    esc,esc,esc,26h,esc,esc,esc,3fh    ; black back, white char
  278.     db    esc,'=',32+2,32+37,'CP/M 3.0'
  279.     db    esc,'=',32+3,32+31,'On the Commodore 128 '
  280.     db    esc,'=',32+4,32+22,'6 Dec 85 System -*- Modified  6 May 89'
  281.     db    cr,lf,lf,lf,lf,0
  282. ;;*********************************************************
  283.     page
  284.  
  285. ;
  286. ;
  287.     mvi    a,-1            ; set block move to NORMAL mode
  288.     sta    source$bnk
  289. ;
  290. ;    install mode 2 page vectors
  291. ;
  292.     mvi    a,JMP
  293.     sta    INT$vector        ; install a JMP at vector location
  294.     lxi    h,?sysint
  295.     shld    INT$vector+1        ; install int$handler adr
  296. ;
  297. ; A software fix is  required for the lack of hardware to force the
  298. ; LSB of the INT vector to 0. If the bus floats INT VECT could be
  299. ; read as 0FFh; thus ADRh=I (I=0FCh) ADRl=FF for first read, and
  300. ; ADRh=I+1 ADRl=00 for second, to ensure that control is retained
  301. ; 0FD00h will also have FDh in it.
  302. ;
  303.     lxi    h,int$block        ; FC00h
  304.     lxi    d,int$block+1        ; FC01h
  305.     lxi    b,256-1+1        ; interrupt pointer block
  306.     mvi    m,INT$vector/256    ; high and low are equal (FD)
  307.     ldir
  308.     mvi    a,INT$block/256
  309.     stai                ; set interrupt page pointer
  310.     im2                ; enable mode 2 interrupts
  311.  
  312.     page
  313. ;
  314. ;
  315.     mvi    a,vicinit        ; null command just to setup BIOS8502
  316.     call    ?fun65
  317. ;
  318. ;
  319. ;
  320.     lda    sys$freq        ; 0=60Hz 0FFh=50Hz
  321.     ani    80h            ; 0=60Hz 080h=50Hz
  322.     mov    l,a            ; save in L
  323.     lxi    b,cia$1+0eh        ; point to CRA
  324.     inp    a            ; get old config
  325.     ani    7fh            ; clear freq bit
  326.     ora    l            ; add in new freq bit
  327.     outp    a            ; set new config
  328.  
  329.     mvi    c,8            ; start RTC
  330.     outp    a
  331.  
  332.     lxi    h,date$hex
  333.     shld    @date            ; set date to system data
  334.  
  335. ;
  336. ;    setup the sound variables
  337. ;
  338.     lhld    key$tbl
  339.     lxi    d,58*4
  340.     dad    d
  341.     mov    e,m
  342.     inx    h
  343.     mov    d,m
  344.     inx    h
  345.     xchg
  346.     shld    sound1            ; H=SID reg 24, L=SID reg 5
  347.     xchg
  348.     mov    e,m
  349.     inx    h
  350.     mov    d,m
  351.     xchg
  352.     shld    sound2            ; H=SID reg 6, L=SID reg 1
  353.     lxi    h,9
  354.     dad    d
  355.     mov    e,m
  356.     inx    h
  357.     mov    d,m
  358.     xchg
  359.     shld    sound3            ; H=SID reg 4 then L=SID reg 4 
  360. ;
  361. ;    set-up key click sound registers
  362. ;
  363.     lxi    b,sid+7
  364.     lxi    h,0040h
  365.     outp    l            ; (sid+7)=40h
  366.     inr    c
  367.     outp    l            ; (sid+8)=40h
  368.     mvi    c,low(sid+12)
  369.     outp    h            ; (sid+12)=0  Attack=2ms, Decay=6ms
  370.     inr    c
  371.     outp    h            ; (sid+13)=0  Sustain=0,  Release=6ms
  372.     mvi    a,6
  373.     sta    tick$vol        ; set keyclick volumn level
  374.  
  375. ;**********************************************
  376. ;  Password protection routine
  377. ;**********************************************
  378. ;
  379. if    pass
  380. ;
  381.     mvi    a,0
  382.     sta    count
  383. loop1:
  384.     lda    count
  385.     inr    a
  386.     sta    count
  387.     cpi    4
  388.     jnz    over
  389.     call    prt$msg
  390.     db    cr,lf,lf,esc,'G2','Password Error,  System Aborting....',0
  391. there:
  392.     jmp    there
  393. over:
  394.     lxi    h,cmp$string
  395.     push    h
  396.     call    prt$msg
  397.     db    cr,lf,'Password: ',0
  398. lz1:
  399.     call    key$board$in
  400.     pop    h
  401.     cmp    m
  402.     jnz    loop1
  403.     inx    h
  404.     push    h
  405.     mov    a,m
  406.     cpi    0
  407.     jnz    lz1
  408.     call    prt$msg
  409.     db    cr,lf,lf,0
  410. ;
  411. endif
  412. ;
  413.     ret
  414. ;
  415. if    pass
  416. ;
  417. cmp$string:
  418.     pass$word        ;password macro
  419.     db    0
  420. count:
  421.     ds    1
  422. ;
  423. endif
  424. ;
  425. ;***************************************************
  426. ;
  427.  
  428. mmu$table:
  429.     mmu$tbl$M
  430.  
  431.     page
  432. ;
  433. ;
  434. ;
  435.     CSEG
  436. prt$msg:
  437.     xthl
  438.     call    ?pmsg
  439.     xthl
  440.     ret
  441.  
  442.  
  443. ;
  444. ;    placed in common memory to keep IO from stepping on this code
  445. ;        always called from bank 0
  446. ;
  447.     CSEG
  448. read$d505:
  449.     sta    io$0            ; enable MMU (not RAM)
  450.     lxi    b,0d505h
  451.     inp    a            ; read 40/80 column screen
  452.     sta    bank$0            ; re-enable RAM
  453.     ret
  454.  
  455.     page
  456. ;
  457. ;
  458. ;
  459.     DSEG
  460. init$RS232:
  461.     di
  462.  
  463.     xra    a
  464.     sta    RS232$status
  465.     lxi    h,RxD$buf$count        ; clear the count
  466.     mvi    m,0
  467.     inr    l            ; point to RxD$buf$put
  468.     mvi    m,low(RxD$buffer)
  469.     inr    l            ; point to RxD$buf$get
  470.     mvi    m,low(RxD$buffer)
  471.     lxi    h,NTSC$baud$table
  472.  
  473. ;***************************************
  474. ; code to check for NTSC or PAL removed here, system now assumes 
  475. ; that you are using a north american 128 at 60 hz.
  476. ; ***************************************
  477.  
  478. use$NTSC:
  479.     lda    RS232$baud
  480.     cpi    baud$1200        ; baud rate less then 1200 baud
  481.     jrc    baud$ok            ; yes, go set it
  482.     mvi    a,baud$1200        ; no, 1200 baud is the max
  483.     sta    RS232$baud        ; (change to 1200 baud)
  484.  
  485. baud$ok:
  486.     mov    e,a
  487.     mvi    d,0
  488.     dad    d            ; +1X
  489.     dad    d            ; +1X
  490.     dad    d            ; +1X = +3X
  491.     mov    e,m
  492.     inx    h
  493.     mov    d,m
  494.     inx    h            ;
  495.     mov    a,m            ; get rate #
  496.     sta    int$rate        ;
  497.  
  498.     lxi    b,CIA1+timer$b$low    ;
  499.     outp    e            ;
  500.     inr    c            ; point to timer$b$high
  501.     outp    d            ;
  502.  
  503.     mvi    a,11h            ;
  504.     mvi    c,CIA$ctrl$b        ; turn on timer B
  505.     outp    a            ;
  506.  
  507.     lxi    b,CIA2+data$b        ; setup user port for RS232
  508.     inp    a            ; get old data
  509.     ori    6            ; set CTS and DTR
  510.     outp    a            ; update it
  511.     ei
  512.     ret
  513.  
  514.     page
  515. ;
  516. ;    NTSC rates (1.02273 MHz)
  517. ;
  518. NTSC$baud$table:
  519.     dw    6818            ; no baud rate     (6666.47)
  520.     db    1
  521.     dw    6818            ; 50    6666.7us (6666.47)
  522.     db    1
  523.     dw    4545            ; 75    4444.4us (4443.99)
  524.     db    1
  525.     dw    3099            ; 110    3030.3us (3030.13)
  526.     db    1
  527.     dw    2544            ; 134    2487.6us (2487.46)
  528.     db    1
  529.     dw    2273            ; 150    2222.2us (2222.48)
  530.     db    2
  531.     dw    1136            ; 300    1111.1us (1110.75)
  532.     db    3
  533.     dw    568            ; 600     555.6us ( 555.38)
  534.     db    6
  535.     dw    284            ; 1200     277.8us ( 277.69)
  536.     db    12
  537.  
  538. ;****************************************************
  539. ; PAL baud table removed from here (redundant, as it is not checked for
  540. ; or used)
  541. ;******************************************************
  542.  
  543.     page
  544. ;
  545. ;
  546. ;
  547. out$RS232:
  548.     lda    RS232$status
  549.     ani    80h
  550.     jrnz    out$RS232
  551.     mov    a,c
  552.     sta    xmit$data        ; get character to send in A
  553.     lxi    h,RS232$status
  554.     setb    7,m            ; set Xmit request bit
  555.     ret
  556.  
  557. ;
  558. ;
  559. ;
  560. out$st$RS232:
  561.     lda    RS232$status
  562.     ani    80h            ; bit 8 set if busy
  563.     xri    80h            ; A cleared if busy (=80h if not)
  564.     rz
  565.     ori    0ffh            ; A=ff if ready (not busy)
  566.     ret
  567.  
  568. ;
  569. ;
  570. ;
  571. in$RS232:
  572.     lda    RS232$status
  573.     ani    1
  574.     jrz    in$RS232
  575.     lda    recv$data
  576.     lxi    h,RS232$status
  577.     res    0,m
  578.     ret
  579.  
  580. ;
  581. ;
  582. ;
  583. in$st$RS232:
  584.     lda    RS232$status
  585.     ani    1
  586.     rz
  587.     ori    0ffh            ; set data ready (-1)
  588.     ret
  589.  
  590.     page
  591. ;
  592. ;    this routine is used to provide the user with a method
  593. ;    of interfacing with low level system functions
  594. ;
  595.     CSEG
  596. ;
  597. ;    input:
  598. ;        all registers except HL and A are passed to function
  599. ;
  600. ;    output:
  601. ;        all resisters from function are preserved
  602. ;
  603. ?user:
  604.     shld    user$hl$temp
  605.     xchg
  606.     shld    de$temp            ; save DE for called function
  607.  
  608.     mov    e,a            ; place function number in E
  609.     mvi    a,num$user$fun-1    ; last legal function number
  610.  
  611.     call    vector            ; function
  612. usr$tb:    dw    read$mem$0        ; 0
  613.     dw    write$mem$0        ; 1
  614.     dw    ?kyscn            ; 2
  615.     dw    do$rom$fun        ; 3  (L=function #)     
  616.     dw    do$6502$fun        ; 4  (L=function #)
  617.     dw    read$d505        ; 5  returns MMU reg in A
  618.     dw    code$error        ; not 0 to 5 ret version number in HL
  619.  
  620. num$user$fun    equ    ($-usr$tb)/2
  621.  
  622.     page
  623. ;
  624. ;    address in DE is read and returned in C
  625. ;    A=0 if no error
  626. ;
  627.     DSEG
  628. read$mem$0:
  629.     ldax    d            ; read location addressed by DE
  630.     mov    c,a            ; value returned in C
  631.     xra    a            ; clear error flag
  632.     ret
  633.  
  634. ;
  635. ;    address in DE is written to with value in C
  636. ;    A=0 if no errors
  637. ;
  638. write$mem$0:
  639.     mvi    a,-1            ; get error flag and 0ffh value
  640.     cmp    d            ; do not allow write from FF00 to FFFF
  641.                     ;   this is 8502 space, MMU direct reg.
  642.     rz
  643.     mov    a,d
  644.     cpi    10h            ; do not allow write from 0000 to 0FFF
  645.                     ;   this is ROM space
  646.     mvi    a,-1            ; get error flag
  647.     rc                ; return if 00h to 0fh
  648.     mov    a,c
  649.     stax    d
  650.     xra    a            ; clear error flag 
  651.     ret
  652.  
  653.     page
  654. ;
  655. ;    This is the function code entry point for direct execution
  656. ;    of driver functions. If the MSB of the function number is
  657. ;    set, the 40 column driver is used; else the 80 column drive 
  658. ;    is used.
  659. ;
  660. do$rom$fun:
  661.     lhld    user$hl$temp        ; get HL (L=fun #)
  662.  
  663.     mvi    a,7eh            ; only allow even functions
  664.     ana    l
  665.     cpi    79h
  666.     jrc    no$hl$req
  667.     lhld    @dma            ; HL will be passed in @dma by
  668.     push    h            ; ..the user
  669. no$hl$req:
  670.     mov    l,a
  671.     rst    5            ; call rom functon (RCALL) L=fun #    
  672.     ret
  673.  
  674. ;    mvi    a,7eh            ; only allow even functions
  675. ;    ana    l
  676. ;    sta    no$hl$req+1
  677. ;    cpi    79h
  678. ;    jrc    no$hl$req
  679. ;    lhld    @dma            ; HL will be passed in @dma by
  680. ;    push    h            ; ..the user
  681. ;no$hl$req:
  682. ;    will be changed to RCALL xx   RET for next release (ROM FN 7A, 7C
  683. ;        and 7E will not function with current code, they expect
  684. ;        a return address on the stack
  685. ;
  686. ;    RJMP    5Eh            ; unused function, real fun# installed
  687.                     ; ..above
  688.  
  689. do$6502$fun:
  690.     lhld    user$hl$temp
  691.     mov    a,l
  692.     jmp    ?fun65
  693. ;
  694. ;
  695. ;
  696. code$error:
  697.     lxi    h,date$hex
  698.     mvi    a,-1
  699.     ret
  700.  
  701.     page
  702. ;
  703. ;
  704. ;
  705.     CSEG
  706. ?rlccp:
  707. ;
  708. ;******************************************************************
  709.     mvi    a,01            ; sets feel, put here to set it
  710.     sta    0fd52h            ; on every warm start
  711.     mvi    a,repeat$amt        ; set at 3
  712.     sta    repeat
  713.     mvi    a,delay$amt        ; set at 24
  714.     sta    delay
  715. ;******************************************************************
  716.     lxi    h,ccp$buffer
  717.     lxi    b,0c80h
  718.  
  719. load$ccp:
  720.     sta    bank$0
  721.     mov    a,m
  722.     sta    bank$1
  723.     lxi    d,-ccp$buffer+100h
  724.     dad    d
  725.     mov    m,a
  726.     lxi    d,ccp$buffer-100h+1
  727.     dad    d
  728.     dcx    b
  729.     mov    a,b
  730.     ora    c
  731.     jrnz    load$ccp
  732.     ret
  733.  
  734.     page
  735. ;
  736. ;
  737. ;
  738.     CSEG
  739. ?ldccp:
  740.     xra    a
  741.     sta    ccp$fcb+15    ; zero extent
  742.     lxi    h,0
  743.     shld    fcb$nr        ; start at beginning of file
  744.     lxi    d,ccp$fcb
  745.     call    open        ; open file containing CCP
  746.     inr    a
  747.     jrz    no$CCP        ; error if no file...
  748.     lxi    d,0100h
  749.     call    setdma        ; start of TPA
  750.     lxi    d,128
  751.     call    setmulti    ; allow up to 16K bytes
  752.     lxi    d,ccp$fcb
  753.     call    read
  754.  
  755.     lxi    h,0100h
  756.     lxi    b,0c80h
  757.     lda    force$map
  758.     push    psw
  759.  
  760. ;
  761. ;
  762. save$ccp:
  763.     sta    bank$1
  764.     mov    a,m
  765.     sta    bank$0
  766.     lxi    d,ccp$buffer-100h
  767.     dad    d
  768.     mov    m,a
  769.     lxi    d,-ccp$buffer+100h+1
  770.     dad    d
  771.     dcx    b
  772.     mov    a,b
  773.     ora    c
  774.     jrnz    save$ccp
  775.  
  776.     pop    psw
  777.     sta    force$map
  778.     ret
  779.  
  780.  
  781.  
  782.     page 
  783. ;
  784. ;
  785. ;
  786. no$CCP:                ; here if we couldn't find the file
  787.     call    prtmsg        ; report this...
  788.     db    cr,lf,'BIOS Err on A: No CCP.COM file',0
  789.     call    ?conin        ; get a response
  790.     jr    ?ldccp        ; and try again
  791.  
  792.  
  793. ;
  794. ; CP/M BDOS Function Interfaces
  795. ;
  796.     CSEG
  797. open:
  798.     mvi    c,15        ; open file control block
  799.  
  800.     db    21h        ; lxi h,(mvi c,26)
  801. setdma:
  802.     mvi    c,26        ; set data transfer address
  803.  
  804.     db    21h        ; lxi h,(mvi c,44)    
  805. setmulti:
  806.     mvi    c,44        ; set record count
  807.  
  808.     db    21h        ; lxi h,(mvi c,20)
  809. read:
  810.     mvi    c,20        ; read records
  811.     jmp    bdos
  812.  
  813. ;               12345678901
  814. ccp$fcb        db    1,'CCP     COM',0,0,0
  815. fcb$rc        db    0
  816.         ds    16
  817. fcb$nr        db    0,0,0
  818.  
  819.  
  820.     page
  821. ;
  822. ;    CXIO.ASM and CXEM.ASM
  823. ;
  824. ;==========================================================
  825. ;        ROUITINE TO VECTOR TO HANDLER
  826. ;==========================================================
  827. ;    CP/M IO routines    b=device : c=output char : a=input char
  828. ;
  829.     CSEG
  830. ;*********************************************************************
  831. ; code in the following vector tables has been altered to null the 40
  832. ; column screen
  833. ;--------------------------------------------------
  834.  
  835. ?cinit:                ; initialize usarts
  836.     mov    b,c
  837.     call    vector$io    ; jump with table adr on stack
  838. number$drivers:
  839.     dw    ?int$cia    ; keys
  840.     dw    ?int80        ; 80col
  841.     dw    rret          ; 40col
  842.     dw    ?pt$i$1101    ; prt1
  843.     dw    ?pt$i$1101    ; prt2
  844.     dw    ?int65        ; 6551
  845.     dw    init$RS232    ; software RS232
  846.     dw    rret        ;
  847. max$devices    equ    (($-number$drivers)/2)-1
  848.  
  849. ;
  850. ;
  851. ;
  852. ?ci:                ; character input
  853.     call    vector$io    ; jump with table adr on stack
  854.     dw    key$board$in    ; keys
  855.     dw    rret        ; 80col
  856.     dw    rret        ; 40col
  857.     dw    rret        ; ptr1
  858.     dw    rret        ; prt2
  859.     dw    ?in65        ; 6551
  860.     dw    in$RS232    ; software RS232
  861.     dw    null$input
  862.  
  863. ;
  864. ;
  865. ;
  866. ?cist:                ; character input status
  867.     call    vector$io    ; jump with table adr on stack
  868.     dw    key$board$stat    ; keys
  869.     dw    rret        ; 80col
  870.     dw    rret        ; 40col
  871.     dw    rret        ; prt1
  872.     dw    rret        ; prt2
  873.     dw    ?ins65        ; 6551
  874.     dw    in$st$RS232    ; software RS232
  875.     dw    rret
  876.  
  877. ;
  878. ;
  879. ;
  880. ?co:                ; character output
  881.     call    vector$io    ; jump with table adr on stack
  882.     dw    rret        ; keys
  883.     dw    ?out80        ; 80col
  884.     dw    rret        ; 40col
  885.     dw    ?pt$o$1        ; prt1
  886.     dw    ?pt$o$2        ; prt2
  887.     dw    ?out65        ; 6551
  888.     dw    out$RS232    ; software RS232
  889.     dw    rret
  890.  
  891. ;
  892. ;
  893. ;
  894. ?cost:                ; character output status
  895.     call    vector$io    ; jump with table adr on stack
  896.     dw    ret$true    ; keys
  897.     dw    ret$true    ; 80col
  898.     dw    ret$true    ; 40col
  899.     dw    ret$true    ; prt1    ?pt$s$1101
  900.     dw    ret$true    ; prt2
  901.     dw    ret$true    ; 6551
  902.     dw    out$st$RS232    ; software RS232
  903.     dw    ret$true
  904.  
  905. ;************************************************************
  906.  
  907.     page
  908. ;
  909. ;    This entry does not care about values of DE
  910. ;
  911. vector$io:
  912.     mvi    a,max$devices    ; check for device # to high
  913.     mov    e,b        ; get devive # in E
  914. ;
  915. ;
  916. ;    INPUT:
  917. ;        Vector # in E, Max device in A
  918. ;        passes value in DE$TEMP in DE
  919. ;        HL has routine's address in it on entering routine
  920. ;
  921. ;    OUTPUT:
  922. ;        ALL registers of returning routine are passed
  923. ;
  924. vector:
  925.     pop    h        ; get address vector list
  926.     mvi    d,0        ; zero out the MSB
  927.     cmp    e        ; is it too high?
  928.     jrnc    exist        ; no, go get the handler address
  929.  
  930.     mov    e,a        ; yes, set to max$dev$handler(last one) 
  931. exist:
  932.     dad    d        ; 
  933.     dad    d        ; point into table
  934.  
  935.      mov    a,m
  936.     inx    h
  937.     mov    h,m
  938.     mov    l,a        ; get routine adr in HL
  939.  
  940.     shld    hl$temp        ; save exec adr
  941.     lxi    h,0
  942.     dad    sp
  943.     lxi    sp,bios$stack
  944.     push    h        ; save old stack
  945.  
  946.     lhld    de$temp
  947.     xchg
  948.     lhld    hl$temp        ; recover exec adr
  949.  
  950.     lda    force$map    ; get current bank
  951.     push    psw        
  952.     sta    bank$0        ; set bank 0 as current
  953.  
  954.     call    ipchl
  955.  
  956.     sta    a$temp        ; save value to return
  957.     pop    psw
  958.     sta    force$map    ; set old bank back
  959.     lda    a$temp        ; recover value to return
  960.  
  961.     shld    hl$temp
  962.     pop    h        ; recover old stack
  963.     sphl            ; set new stack
  964.     lhld    hl$temp
  965.     ret
  966.  
  967. ipchl:
  968.     pchl            ; jmp to handler
  969.  
  970.     ds    30h
  971. bios$stack:
  972.  
  973.  
  974.     page
  975. ;==========================================================
  976. ;        CHARACTER INPUT ROUTINES
  977. ;==========================================================
  978.  
  979.     DSEG
  980. ;
  981. ;
  982. ;
  983. key$board$in:
  984.     call    key$board$stat    ; test if key is available
  985.     jrz    key$board$in    
  986.  
  987.     lda    key$buf
  988.     push    psw        ; save on stack
  989.     xra    a        ; clear key 
  990.     sta    key$buf
  991.     pop    psw        ; recover current key
  992. rret:
  993.     ret
  994.  
  995. ;
  996. ;
  997. ;
  998. null$input:        ; return a ctl-Z for no device
  999.     mvi    a,1Ah
  1000.     ret
  1001.  
  1002.  
  1003.     page
  1004.  
  1005. ;==========================================================
  1006. ;    CHARACTER DEVICE INPUT STATUS
  1007. ;==========================================================
  1008.  
  1009.     DSEG
  1010. ;
  1011. ;
  1012. ;
  1013. key$board$stat:
  1014.     lda    key$buf
  1015.     ora    a
  1016.     jrnz    ret$true
  1017.  
  1018.     call    ?get$key
  1019.     ora    a        ; =0 if none
  1020.     rz            ; return character not advailable
  1021.  
  1022.     sta    key$buf        ; was one, save in key buffer
  1023.  
  1024. ret$true:
  1025.     ori    0ffh        ; and return true
  1026.     ret
  1027.  
  1028.     page
  1029.  
  1030.     cseg
  1031. @ctbl
  1032.     db    'KEYBRD'    ; device 0, internal keyboard
  1033.     db    mb$input
  1034.     db    baud$none
  1035.  
  1036.     db    '80-COL'    ; device 1, 80 column display
  1037.     db    mb$output
  1038.     db    baud$none
  1039.  
  1040.     db    'NULL40'    ; device 2, 40 column display
  1041.     db    mb$output
  1042.     db    baud$none
  1043.  
  1044.     db    'PRT-D4'    ; device 3, serial bus printer (device 4)
  1045.     db    mb$output
  1046.     db    baud$none
  1047.  
  1048.     db    'PRT-D5'    ; device 4, serial bus printer (device 5)
  1049.     db    mb$output
  1050.     db    baud$none
  1051.  
  1052.     db    '6551  '    ; device 5, EXT CRT
  1053.     db    mb$in$out+mb$serial+mb$softbaud+mb$xonxoff
  1054. X6551$baud:
  1055.     db    baud$9600
  1056.  
  1057.     db    'RS-232'    ; device 6, software RS232 device
  1058.     db    mb$in$out+mb$serial+mb$xonxoff+mb$softbaud
  1059. RS232$baud:
  1060.     db    baud$75
  1061.  
  1062.     db    0        ; mark end of table
  1063.  
  1064.     page
  1065. ;
  1066. ;    TIME.ASM
  1067. ;
  1068.     cseg
  1069. ;
  1070. ;    HL and DE must be presevered
  1071. ;
  1072. ?time:
  1073.     inr    c
  1074.     lxi    b,cia$hours
  1075.     jrz    set$time
  1076. ;
  1077. ;    update SCB time  (READ THE TIME)
  1078. ;
  1079.     inp    a            ; read HR (sets sign flag)
  1080.     jp    is$am            ; jmp if AM (positive)
  1081.     ani    7fh
  1082.     adi    12h            ; noon=24(PM), midnight=12(AM)
  1083.     daa
  1084.     cpi    24h            ; check for noon (12+12 PM)
  1085.     jrnz    set$hr
  1086.     mvi    a,12h
  1087.     jr    set$hr
  1088.  
  1089. is$am:
  1090.     cpi    12h            ; check for midnight (AM)
  1091.     jrnz    set$hr
  1092.     xra    a            ; becomes 00:00
  1093. set$hr:
  1094.     sta    @hour
  1095.     mov    b,a
  1096.     lda    old$hr
  1097.     mov    c,a
  1098.     mov    a,b
  1099.     sta    old$hr
  1100.     cmp    c            ; if @hour<old$hr
  1101.     jrnc    same$day
  1102.  
  1103.     push    h
  1104.     lhld    @date
  1105.     inx    h
  1106.     shld    @date
  1107.     pop    h
  1108.  
  1109. same$day:
  1110.     lxi    b,cia$hours-1
  1111.     inp    a            ; read MIN
  1112.     sta    @min
  1113.  
  1114.     dcr    c
  1115.     inp    a            ; read SEC
  1116.     sta    @sec
  1117.  
  1118.     dcr    c
  1119.     inp    a            ; read 1/10 of SEC (a must to free
  1120.     ret                ; the holding register)
  1121.  
  1122. old$hr:
  1123.     ds    1
  1124.     page
  1125. ;
  1126. ;
  1127. ;
  1128. set$time
  1129.     lda    @hour
  1130.     cpi    12h            ; test for noon
  1131.     jrz    set$as$is
  1132.     ana    a            ; test for 00:xx
  1133.     jrnz    not$zero$hundred
  1134.     mvi    a,80h+12h            ; set to midnight
  1135.     jr    set$as$is
  1136.  
  1137. not$zero$hundred:
  1138.      cpi    11h+1            ; test for 1 to 11 AM
  1139.     jrc    set$as$is
  1140.     sui    12h
  1141.     daa                ; decimal adjust
  1142. set$msb:
  1143.     ori    80h            ; set PM
  1144.  
  1145. set$as$is:
  1146.     outp    a
  1147.     dcr    c
  1148.     lda    @min
  1149.     outp    a
  1150.     dcr    c
  1151.     lda    @sec
  1152.     outp    a
  1153.     dcr    c
  1154.     xra    a
  1155.     outp    a
  1156.     ret
  1157.  
  1158.     page
  1159.  
  1160. ;
  1161.     page
  1162. ;
  1163. ; CXMOVE.ASM
  1164. ;
  1165.     public ?move,?xmove,?bank
  1166.  
  1167. ;
  1168. ;    Move a block of data from DE to HL
  1169. ;    count is in BC (within current bank)
  1170. ;
  1171. ;
  1172.     cseg            ; place code in common
  1173. ?move:
  1174.     xchg            ;*
  1175.     lda    source$bnk    ; =FFh if normal block move 
  1176.     inr    a        ; 
  1177.     jrnz    inter$bank$move
  1178.  
  1179.     LDIR            ;* do block move    
  1180.     xchg            ;*
  1181.     ret
  1182.  
  1183.  
  1184. ;
  1185. ;
  1186. ;
  1187. ?xmove:                ; can be in bank 0    
  1188.     mov    a,c
  1189.     sta    source$bnk
  1190.     mov    a,b
  1191.     sta    dest$bnk
  1192.     ret            ;*
  1193.  
  1194.     page
  1195. ;
  1196. ;
  1197. ;
  1198. inter$bank$move:
  1199.     shld    @buffer        ; save HL TEMP
  1200.     lxi    h,0
  1201.     dad    sp
  1202.     lxi    sp,bios$stack
  1203.     push    h        ; save old stack  ;**1
  1204.     lhld    @buffer
  1205.  
  1206.     mov    a,b        ; get msb of count
  1207.     ora    a
  1208.     jrz    count$less$than$256
  1209.  
  1210.     push    b        ; save the count  ;**2
  1211.     push    d        ; save the dest   ;**3
  1212.     lxi    d,@buffer    ; make buffer the dest
  1213.     lxi    b,256        ; move 256 bytes
  1214.     lda    source$bnk
  1215.     call    ?bank
  1216.     ldir            ; move source to buffer
  1217.  
  1218.     pop    d        ; recover dest    ;**2
  1219.     push    h        ; save updated source ;**3
  1220.     lxi    h,@buffer    ; make the buffer the source
  1221.     lxi    b,256        ; move 256 bytes
  1222.     lda    dest$bnk
  1223.     call    ?bank
  1224.     ldir            ; move buffer to dest
  1225.  
  1226.     pop    h        ; recover updated source ;**2
  1227.     pop    b        ; recover count          ;**1
  1228.     dcr    b        ; subtract 256 from count
  1229.     jr    inter$bank$move
  1230.  
  1231.     page
  1232. ;
  1233. ;
  1234. ;
  1235. count$less$than$256:
  1236.     ora    c        ; BC=0  [A (0) or'ed with C]
  1237.      jrz    exit$move
  1238.  
  1239.     push    d        ; save count for 2nd half  ;**2
  1240.     push    b        ; save dest adr            ;**3
  1241.     lxi    d,@buffer
  1242.     lda    source$bnk
  1243.     call    ?bank
  1244.     ldir            ; move source to buffer
  1245.  
  1246.     pop    b        ; recover count          ;**2
  1247.     pop    d        ; recover dest          ;**1
  1248.     push    h        ; save updated dest      ;**2
  1249.     lxi    h,@buffer
  1250.     lda    dest$bnk
  1251.     call    ?bank
  1252.     ldir            ; move buffer to dest
  1253.     pop    h                        ;**1
  1254.  
  1255. ;
  1256. ;
  1257. ;
  1258. exit$move:
  1259.     xchg
  1260.     mvi    a,-1
  1261.     sta    source$bnk    ; set MOVE back to normal
  1262.     lda    @cbnk
  1263.  
  1264.     shld    @buffer
  1265.     pop    h        ; recover old stack    ;**0
  1266.     sphl
  1267.     lhld    @buffer
  1268.  
  1269. ; call    ?bank        ; set current bank
  1270. ; ret
  1271.  
  1272.     page
  1273. ;
  1274. ;    switch bank to bank number in A
  1275. ;
  1276.     cseg            ; (must be in common)
  1277. ?bank:                
  1278.     ora    a        ; bank 0 ?
  1279.     jrnz    not$bank$0    ; go check for bank 1
  1280.  
  1281.     sta    bank$0        ; set bank 0
  1282.     ret
  1283.  
  1284. ;
  1285. ;
  1286. not$bank$0:
  1287.     dcr    a        ; bank 1 ?
  1288.     rnz            ; if not a valid bank just return
  1289.     sta    bank$1        ; set bank 1
  1290.     ret
  1291.  
  1292.     end
  1293.