home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / enterprs / cpm / utils / a / bios-5.arc / CXDISK.ASM < prev    next >
Encoding:
Assembly Source File  |  1989-05-08  |  33.0 KB  |  1,712 lines
  1. ; Date:  05/07/89           
  2. ;
  3. ; changes made to this module were to remove test for 
  4. ; disk status line (it is displayed all of the time now), and
  5. ; to remove unecessary disk definitions ( only A, B, and C now)
  6. ; The virtual drive E: has been removed,  and the 40 column disk status
  7. ; display has been removed (previously it was always running no matter
  8. ; what.
  9. ;
  10. ; compare with an original copy of CXDISK.ASM if you want to
  11. ; find what the changes were
  12. ;
  13. ;  User assumes _ALL_ liability for use of this module.  Original
  14. ;  copyright is still maintained by Commodore
  15. ;
  16. ;-------------------------------------------------------------------------
  17. ; ADDITIONS by Randy Winchester, 6 May 89
  18. ;
  19. ; Drive D: has been put back.
  20. ;
  21. ; A Drive E: has been added.  This is not to be confused with the Drive E:
  22. ; virtual disk of earlier CP/M releases.  The purpose of the Drive E: entry
  23. ; is to make room for a driver for the Quick Brown Box.  The QBB is
  24. ; installed with QD.COM from Herne Data Systems, Ltd, as Drive F: so as not
  25. ; to conflict with any software that might expect Drive E: to behave the
  26. ; way it used to.
  27. ;
  28. ; Added MFM definitions for Gene Pizzetta's 1581 796K format.  Disks can be
  29. ; formatted using Gene's public domain FORMAT81.COM.
  30. ;
  31. ; Added MFM definitions for Miklos Garamszeghy's MAXI 1571 format.  This
  32. ; allows 398K per disk.  Disks can be formatted using Herne Data System's
  33. ; Jugg'ler, FORMAT22, which is a free demo of Jugg'ler, or the following 128
  34. ; direct mode command:  print#15,"u0"+chr$(102)+chr$(128)+chr$(0)+chr$(3)+
  35. ;                       chr$(39)+chr$(5)+chr$(0)+chr$(0)+chr$(229)
  36. ; This was taken from the April 1988 issue of "The Transactor."
  37. ;-------------------------------------------------------------------------
  38. ;
  39. ;
  40. ;
  41. ;    *****************************************
  42. ;    *                    *
  43. ;    *    Commodore Disk    Controller    *
  44. ;    *    Module for CP/M 3.0 BIOS    *
  45. ;    *                    *
  46. ;    *****************************************
  47. ;
  48. ;
  49. ;
  50.     title 'CXDISK   Commodore C-128 Disk Controller     6 May   89'
  51.  
  52.  
  53.  
  54.  
  55. ; CP/M 3 Disk definition macros
  56.  
  57.     maclib    cpm3
  58.  
  59.     maclib    z80
  60.  
  61. ; C-128 system equates
  62.  
  63.     maclib    cxequ
  64.  
  65.     page
  66.  
  67. ; Disk drive dispatching tables for linked BIOS
  68.  
  69.     public    cmdsk0,cmdsk1,cmdsk2,cmdsk3,cmdsk4
  70.  
  71. ; System Control Block variables
  72.     extrn    @ermde        ; BDOS error mode
  73.  
  74. ; Utility routines in standard BIOS
  75.     extrn    ?wboot        ; warm boot vector
  76.     extrn    ?pmsg        ; print message @<HL> up to 00
  77.                 ; saves <BC> & <DE>
  78.     extrn    ?pdec        ; print binary number in <HL> from 0 to 65535
  79.     extrn    ?pderr        ; print BIOS disk error header
  80.     extrn    ?conin,?cono    ; con in and out
  81.     extrn    ?const        ; get console status
  82.     extrn    ?sctrn        ; sector translation routine
  83.     extrn    @covec
  84.  
  85. ;    status line calls
  86.  
  87.     extrn    ?save,?recov,?stat
  88.  
  89. ; System function call
  90.     extrn    ?kyscn
  91.     extrn    ?fun65
  92.     extrn    ?bank
  93.     extrn    ?di$int
  94.  
  95.     public    ?dskst
  96.     public    ?dkmov
  97.     extrn    ?stat
  98.  
  99.     page
  100. ;
  101. ; Initialization entry point.
  102. ; called for first time initialization.
  103. ;
  104.     DSEG
  105. init$154X:
  106.     xra    a
  107.     sta    fast
  108.     lxi    h,MFM$table
  109.     shld    MFM$tbl$ptr
  110.     ret
  111.  
  112.  
  113.     page
  114. ;
  115. ; This entry is called when a logical drive is about to
  116. ;  be logged into for the purpose of density and type determination.
  117. ;  It may adjust the parameters contained in the disk
  118. ;  parameter header pointed to by <DE>
  119. ;
  120.     DSEG
  121. ;
  122. ;    if disk type GCR or drive type 1541
  123. ;       if 1st sector has 'CBM' (1st 3 bytes)
  124. ;          if last byte = -1 (0FFh)
  125. ;             set C128 double sided
  126. ;          else
  127. ;             set C128 single sided
  128. ;          endif
  129. ;       else
  130. ;          set C64 type
  131. ;       endif
  132. ;    else (must be MFM)
  133. ;       TEST MFM
  134. ;    endif
  135. ;
  136. login$154X:
  137.     call    get$drv$info    ; set the drive to check (DPH$pointer set)
  138.  
  139.     mvi    a,vic$test
  140.     call    ?fun65
  141.     mov    b,a
  142.     ani    0ch
  143.     cpi    0ch
  144.     jrz    GCR$type    ; jump if not a 1571
  145.  
  146.     mov    a,b
  147.     rlc
  148.     jrc    MFM$type
  149.  
  150.     page
  151. ;
  152. ;
  153. ;
  154. GCR$type:
  155.     lhld    DPH$pointer
  156.     dcx    h
  157.     mvi    m,dsk$c64
  158.     lxi    d,dpb$c64$cpm    ; set DPB to C64
  159.     call    set$dpb$only
  160.  
  161.     xra    a
  162.     sta    vic$sect    ; set track 1 sector 0 (1st sector
  163.     inr    a        ; on the disk)
  164.     sta    vic$trk
  165.  
  166.     lxi    h,@buffer
  167.     shld    local$DMA    ; move DMA pointer to disk buffer
  168.     call    login$rd
  169.     ana    a        ; read error ?
  170.     rnz            ; yes, just return
  171.  
  172.     RCALL    FR$check$CBM
  173.     rnz            ; return if not 'CBM'
  174.                 ; A=0FFh if double sided
  175.     inr    a
  176.  
  177.     lhld    DPH$pointer
  178.     dcx    h        ; does not affect flags
  179.     mvi    m,dsk$c128
  180.  
  181.     lxi    d,dpb$c128$SS
  182.     jrnz    set$dpb$only
  183.  
  184.     lxi    d,dpb$c128$DS
  185.  
  186.     page
  187. ;
  188. ;
  189. ;
  190. set$dpb$only:
  191.     lxi    b,0        ; set sector translation to zero
  192. set$format:
  193.     lhld    DPH$pointer
  194.     mov    m,c
  195.     inx    h
  196.     mov    m,b        ; install sector translation
  197.     lxi    b,25-1        ; ofset to DPB
  198.     dad    b        ; HL points to DPB now
  199.     lxi    b,17        ; dpb size
  200.     xchg            ; move to DPB location
  201.     ldir
  202.     ret
  203.  
  204.  
  205.     page
  206. ;
  207. ;    TEST MFM()
  208. ;    save number bytes/sector
  209. ;       if double sided
  210. ;          mark two sided
  211. ;       endif
  212. ;       find start and end sector numbers
  213. ;       scan table of disk for match (if more then 1 match ask user) 
  214. ;
  215. MFM$type:
  216.     mvi    c,01100000b
  217.     ana    c            ; A = status(trk1) shifted left 1 
  218.     push    psw            ; save in case bad query
  219.     push    b            ; save BC
  220.  
  221.     call    get$max$num$B        ; used to set the pointer only
  222.     mov    b,m            ; get size, and disk lock flag
  223.     inx    h
  224.     mov    a,m
  225.     inx    h
  226.     mov    h,m            ; get last MFM$mactch$ptr
  227.     mov    l,a
  228.     mov    a,b            ; get lock flag in A
  229.     ani    80h            ; lock bit set ?
  230.     sta    lock$flag        ;   (save old lock status)
  231.     shld    last$match        ; save last match pointer
  232.     jrz    not$$locked$entry    ; yes, then set same disk type
  233. ; set$locked$entry
  234.     xra    a
  235.     sta    lock$flag
  236.     mvi    c,0B0h
  237.     lda    vic$data        ; get sector size info
  238.     ana    c
  239.     mov    b,a            ; save disk sector size info
  240.     xchg                ; save HL
  241.     lhld    DPH$pointer
  242.     dcx    h
  243.     mov    a,c
  244.     ana    m            ; get old disk sector size
  245.     cmp    b            ; are they the same?
  246.     jrnz    not$locked$entry    ; no, then unlock disk anyway
  247.  
  248.     xchg                ; get last match pointer (in DE)
  249.     pop    psw            ; yes, remove two data elements 
  250.     pop    psw            ; ..save on stack
  251.     jr    set$this$entry
  252.  
  253. not$locked$entry:
  254.     lxi    h,MFM$match$tbl        ; clear Match table
  255.     shld    MFM$cur$ptr
  256.     lxi    d,MFM$match$tbl+1
  257.     mvi    m,0
  258.     lxi    b,(MFM$tbl$entries*2)-1+1+1    ; table, offset and count
  259.     ldir
  260.     mvi    a,4
  261.     sta    vic$trk            ; do query on track 4
  262.     mvi    a,vic$query
  263.     call    ?fun65
  264.     pop    b            ; recover BC
  265.     ani    0eh            ; query error ?
  266.     jrnz    query$error        ; yes, use only bits 5 and 6 
  267.     lda    @buffer            ; get trk 4 status
  268.     mov    b,a            ; save in B
  269.     ani    0eh            ; trk 4 status error ?
  270.     jrnz    query$error        ; yes, use only bits 5 and 6
  271.     mov    a,b            ; recover B (trk 4 status)
  272.     add    a            ; shift left
  273.     ana    c            ; mask sector size bits
  274.     mov    b,a
  275.     pop    psw            ; get trk 1 sector size bits
  276.     cmp    b            ; same as trk 4 sector size?
  277.     mvi    c,01111111b
  278.     jrz    trk$1$trk$4        ; yes, (then test for mult format)
  279.     mvi    a,80h            ; set MSB to mean mult format
  280.     add    b            ; ..(track 0 different sector size
  281.                     ; ..then track 4) 
  282.     mov    b,a            ; save in B
  283.     mvi    c,11111111b
  284. trk$1$trk$4:
  285.     lda    @buffer+1        ; get number of sectors/track
  286.     sui    4            ; remove 4 to extend the range
  287.     add    a            ; shift    left
  288.     add    b            ; combine with rest of mask
  289.     mov    b,a            ; save in B for now
  290.  
  291.     lda    @buffer+3        ; minimum sector number
  292.     add    b            ; add in start sector #
  293.     push    psw            ; save on stack for a moment
  294.  
  295. query$error:
  296.     pop    psw            ; get value to match 
  297.     ana    c            ; test only those bits in the mask
  298.  
  299.     lhld    MFM$tbl$ptr
  300.     mvi    b,MFM$tbl$entries
  301. check$next:
  302.     push    b            ; save BC for a moment
  303.     mov    b,a            ; move compare value to 
  304.     mov    a,m            ; get type info
  305.     ana    c            ; test only the good info
  306.     cmp    b            ; match the current type byte
  307.     mov    a,b            ;   (recover A)
  308.     pop    b            ;   (recover BC)
  309.     jrnz    not$found        ; no, do not queue data
  310.                     ; yes queue table entry address
  311.  
  312.     xchg                ; save adr in DE
  313.     lhld    MFM$cur$ptr
  314.     mov    m,e
  315.     inx    h
  316.     mov    m,d
  317.     inx    h
  318.     shld    MFM$cur$ptr
  319.     lxi    h,MFM$count
  320.     inr    m            ; add one to counter
  321.     xchg
  322.  
  323.     page
  324. ;
  325. ;
  326. not$found:
  327.     lxi    d,32            ; table entry size
  328.     dad    d
  329.     djnz    check$next
  330.  
  331.     lda    MFM$count        ; number of matches in table 
  332.     ana    a            ; test for zero
  333.     jz    tell$user$no$entry    ; none, tell the user 
  334.  
  335.     dcr    a            ; only one ?
  336.     jrnz    user$select        ; no, go check with user (which one)
  337.     lhld    MFM$match$tbl        ; yes, use the only one found
  338.  
  339. ;
  340. ;    install data form pointer in HL
  341. ;
  342. set$this$entry:
  343.     push    h        ; save table pointer
  344.     inx    h
  345.     mov    a,m        ; get type info. 
  346.     xchg            ; save table address in DE
  347.     lhld    DPH$pointer
  348.     dcx    h
  349.     mov    m,a        ; save type code
  350.     xchg            ; get table adr to HL
  351.     inx    h        ; HL points to sector translation table 
  352.     mov    c,m        ; ..zero if none
  353.     inx    h
  354.     mov    b,m
  355.     inx    h        ; HL points to DPB
  356.     xchg            ; DE points to DPB (HL trash)
  357.     call    set$format
  358.     mov    b,m        ; get the number of sect/trk from MFM table
  359.     lda    lock$flag    ; get the current lock flag value
  360.     ora    b        ; combine with sect/trk
  361.     xchg            ; HL=to adr,  DE=from adr
  362.     mov    m,a        ; install sect/trk and lock flag
  363.     pop    d        ; recover table pointer
  364.     inx    h
  365.     mov    m,e
  366.     inx    h
  367.     mov    m,d        ; save MFM table pointer at end of DPH
  368.     ret
  369.  
  370.     page
  371. ;
  372. ;    let the user select the Disk type s/he wants
  373. ;
  374. user$select:
  375.     inr    a            ; number of entries to try to match
  376.     mov    b,a            ; set in B as loop count
  377.     lhld    last$match        ; get value to match with
  378.     mov    d,h
  379.     mov    e,l            ; last match pointer is in DE
  380.  
  381.     lxi    h,MFM$match$tbl
  382.     shld    MFM$cur$ptr
  383.     mvi    c,0            ; start offset at zero
  384.  
  385. try$next$format:
  386.     mov    a,e
  387.     cmp    m
  388.     inx    h
  389.     jrnz    not$last$match
  390.     mov    a,d
  391.     cmp    m
  392.     jrnz    not$last$match
  393. ;
  394. ; match, set pointer
  395. ;
  396.     mov    a,c            ; get offset in A
  397.     push    psw
  398.     call    save$dsk$window
  399.     pop    psw
  400.     jr    set$offset
  401.  
  402. not$last$match:
  403.     inx    h            ; each pointer uses two bytes 
  404.     inr    c            ; advance the index
  405.     djnz    try$next$format        ; test for more, loop if so
  406.  
  407.     call    save$dsk$window
  408.  
  409.     lhld    MFM$cur$ptr
  410. user$loop:
  411.     mov    e,m            ; HL=(MFM$cur$ptr)
  412.     inx    h
  413.     mov    d,m
  414.     lxi    h,22            ; offset to NAME field
  415.     dad    d            ; point to Disk name
  416.     call    dsk$window$old
  417.  
  418. dsk$user$sel$wait:
  419.     call    ?kyscn
  420.     inr    b            ; test for key pressed
  421.     jrz    dsk$user$sel$wait
  422.     dcr    b            ; adjust back
  423.     mov    a,b            ; move matrix position to A
  424.     cpi    SF$exit
  425.     jrnz    CK$dsk$user$rt
  426.  
  427.     mov    a,c
  428.     ani    4            ; control key down ?
  429.     jrz    no$cntr$key        ; no, don't lock this selection
  430.     mvi    a,80h            ; yes, lock disk type to this drive
  431. no$cntr$key:
  432.     sta    lock$flag        ;
  433.     call    dsk$window$remove
  434.     lhld    MFM$cur$ptr
  435.     mov    e,m
  436.     inx    h
  437.     mov    d,m
  438.     xchg
  439.     jr    set$this$entry
  440.  
  441.     page
  442. ;
  443. ;
  444. ;
  445. CK$dsk$user$rt:
  446.     cpi    SF$right        ;
  447.     jrnz    CK$dsk$user$lf
  448.  
  449. ; move window down
  450.     lda    MFM$count        ; get number of items in list
  451.     mov    b,a            ; save in B
  452.     lda    MFM$offset        ; get current position
  453.     inr    a            ; advance position
  454.     cmp    b            ; at last position ? (n-1+1 =count)
  455.     jrnz    set$offset        ; no, then use A as new position
  456.     xra    a            ; yes, move back to start
  457.     jr    set$offset
  458.     
  459. CK$dsk$user$lf:
  460.     cpi    SF$left            ;
  461.     jrnz    dsk$user$sel$wait
  462.  
  463. ; move window up
  464.     lda    MFM$offset
  465.     dcr    a            ; back up offset (under flow?)
  466.     jp    set$offset        ; result positive, jump
  467.     lda    MFM$count        ; get last item number
  468.     dcr    a            ; pointer is 0 to n-1 (not 1 to n)
  469. set$offset:
  470.     sta    MFM$offset        ; set new list offset
  471.     inr    a            ; add one to adjust for DCR below
  472.     lxi    h,MFM$match$tbl        ; set to the beginning
  473.  
  474. adjust$dsk$loop:
  475.     shld    MFM$cur$ptr        ; set pointer here !
  476.     dcr    a            ; at offset yet?
  477.     jrz    user$loop        ; yes, go display name
  478.     inx    h
  479.     inx    h
  480.     jr    adjust$dsk$loop
  481.  
  482.     page
  483. ;
  484. ;
  485. ;
  486. tell$user$no$entry:
  487.     lda    vic$data        ; get disk test status
  488.     ani    0b0h            ; save only sector size and MFM flag
  489.     lhld    DPH$pointer
  490.     dcx    h
  491.     mov    m,a            ; set disk size and Type0 (MFM)
  492.  
  493.     lxi    h,dsk$window*256+buff$pos
  494.     lxi    d,no$dsk$msg
  495. disp$msg$DE$HL:
  496.     call    dsk$window$new
  497. dsk$no$entry$wait:
  498.     call    ?kyscn
  499.     inr    b
  500.     jrz    dsk$no$entry$wait
  501.     dcr    b
  502.     mov    a,b
  503.     cpi    SF$exit
  504.     jrnz    dsk$no$entry$wait
  505. ;    jr    dsk$window$remove
  506.  
  507.     page
  508. ;
  509. ;
  510. ;
  511. dsk$window$remove:
  512.     lhld    window$info
  513.     mov    b,h
  514.     mov    c,l
  515.     jmp    ?recov
  516. ;
  517. ;
  518. ;
  519. save$dsk$window:
  520.     lxi    h,dsk$window*256+buff$pos    ; H=size l=pos
  521.     shld    window$info
  522.     mov    b,h
  523.     mov    c,l
  524.     jmp    ?save
  525. ;
  526. ;
  527. ;
  528. dsk$window$new:
  529.     shld    window$info
  530.     xchg
  531.     mov    b,d
  532.     mov    c,e
  533.     push    h
  534.     call    ?save
  535.     pop    h
  536.  
  537. dsk$window$old:
  538.     lda    window$info        ; get start index
  539.     inr    a
  540.     mov    c,a            ; place in C
  541.  
  542. dsk$out$next:
  543.     push    h
  544.     lhld    window$info
  545.     mov    a,h
  546.     add    l            ; compute max index (start+size)
  547.     dcr    a            ; ..less 1
  548.     pop    h
  549.     cmp    c
  550.     rz    
  551.     mov    b,m
  552.     call    dsk$B$out
  553.     inx    h
  554.     jr    dsk$out$next
  555.  
  556. ;
  557. ;
  558. ;
  559. dsk$B$out:
  560.     mvi    a,01000000b            ; set reverse video attr
  561.     push    b
  562.     push    h
  563.     call    ?stat                ; display space
  564.     pop    h
  565.     pop    b                ; recover count
  566.     inr    c
  567.     ret
  568.  
  569.     page
  570. ;
  571. ; disk READ and WRITE entry points.
  572. ; These entries are called with the following arguments:
  573. ;    relative drive number in @rdrv (8 bits)
  574. ;    absolute drive number in @adrv (8 bits)
  575. ;    disk transfer address in @dma (16 bits)
  576. ;    disk transfer bank    in @dbnk (8 bits)
  577. ;    disk track address    in @trk (16 bits)
  578. ;    disk sector address    in @sect (16 bits)
  579. ;    pointer to XDPH in <DE>
  580. ;
  581. ;   return with an error code in <A>
  582. ;     A=0    no errors
  583. ;     A=1    non-recoverable error
  584. ;    A=2    disk write protected
  585. ;    A=FF    media change detected
  586. ;
  587.     DSEG
  588. read$154X:
  589.     call    get$drv$info
  590.     jm    mfm$rd
  591.     call    set$up$GCR        ; compute effective track and sector
  592. login$rd:
  593.     lda    vic$drv
  594.     mov    b,a
  595.     lda    fast            ; get fast flags
  596.     ana    b            ; isolate fast bit for this drive
  597.     jrnz    rd$fast            ; go handle fast drive
  598. rd$slow:
  599.     mvi    a,vicrd            ; read a sector of data (A=1)
  600.     call    dsk$fun            ; a=0 if no errors
  601.     jnz    test$error        ; check for disk error or media change
  602. ;
  603. ;
  604. ;
  605. buf$move:
  606.     xra    a            ; set direction to read
  607.     call    ?dkmov            ; go move buffer to DMA
  608.     lda    sect$cnt
  609.     ana    a
  610.     rz                ; a=0 means not read errors
  611.     call    set$up$next
  612.     jr    rd$slow
  613.  
  614.     page
  615. ;
  616. ;    A=drive type info
  617. ;
  618. mfm$rd:
  619.     call    set$up$MFM
  620.  
  621. rd$fast:
  622.     mvi    a,vic$rd$f
  623.     call    dsk$fun            ; go read the disk
  624.  
  625.     ani    0eh            ; mask off error bits
  626.     jrnz    test$error
  627.  
  628.     call    get$sector$size
  629.     inr    d
  630.     inr    e            ; adjust count for pre-decrement
  631.  
  632.     call    ?di$int
  633.     lxi    b,0DD00h        ; D2PRA
  634.     inp    a            ; get current clock polarity 
  635.     xri    10h            ; toggle clk$bit
  636.     outp    a            ; to have status sent (extra clock
  637.                     ; supplied by rd$1571$data for multi
  638.                     ; sector transfers)
  639.     lda    vic$count
  640. rd$multi$sect:
  641.     push    psw
  642.     push    d        ; save the sector size
  643.     call    rd$1571$data    ; read disk data to DMA address
  644.     pop    d
  645.  
  646.     lda    vic$data
  647.     ani    0eh
  648.     jrnz    test$error$pop    ; A=0 if no errors
  649.     pop    psw
  650.     dcr    a
  651.     jrnz    rd$multi$sect
  652.     ei
  653.     lda    sect$cnt
  654.     ana    a        ; any sectors left to read
  655.     jrz    done$rd$1571
  656.  
  657.     call    set$up$next
  658.     jr    rd$fast
  659.  
  660. done$rd$1571:
  661.     lxi    b,0DD00h        ;   D2PRA
  662.     inp    a
  663.     ani    not(10h)        ; set clk$bit hi
  664.     outp    a
  665.     xra    a            ; A=0 for no errors
  666.     ret
  667.  
  668.  
  669.     page
  670. ;
  671. ;
  672. ;
  673. write$154X:
  674.     call    get$drv$info
  675.     jm    mfm$wr
  676.     call    set$up$GCR
  677.     lda    vic$drv
  678.     mov    b,a
  679.     lda    fast            ; get fast flags
  680.     ana    b            ; isolate fast bit for this drive
  681.     jrnz    wr$fast$drive        ; go handle fast drive
  682. wr$slow:
  683.     mvi    a,-1            ; set direction to write
  684.     call    ?dkmov            ; go move DMA to buffer
  685.  
  686.     mvi    a,vicwr            ; write a sector of data
  687.     call    dsk$fun            ; a=0 if no errors
  688.     ani    0eh
  689.     jrnz    test$error
  690.     lda    sect$cnt
  691.     ana    a
  692.     rz
  693.     call    set$up$next
  694.     jr    wr$slow
  695.  
  696. test$error$pop:
  697.     pop    psw
  698. test$error:
  699.     ei
  700.     lda    vic$data
  701.     ani    0fh            ; check for disk error or media change
  702.     cpi    0bh            ; disk change ?
  703.     jrz    change$error
  704.     cpi    08h            ; test for write protect error
  705.     jrz    write$prot$error
  706.  
  707.     mvi    a,1            ;  get general error flag
  708.     ret
  709.  
  710. ;
  711. ;
  712. write$prot$error:
  713.     mvi    a,2
  714.     ret
  715.  
  716. ;
  717. ;
  718. change$error:
  719.     mvi    a,-1
  720.     ret
  721.  
  722.     page
  723. ;
  724. ;
  725. ;
  726. mfm$wr:
  727.     call    set$up$MFM
  728. wr$fast$drive:
  729.     mvi    a,vic$wr$f
  730.     call    dsk$fun            ; go send the write command
  731.  
  732.     call    get$sector$size        ; setup DMA adr and transfer count
  733.     lda    vic$count
  734. wr$multi$sect:
  735.     push    psw
  736.     push    d            ; save sector size
  737.     call    wr$1571$data        ; write data to disk from DMA address
  738.     pop    d
  739.     ani    0eh
  740.     jrnz    test$error$pop
  741.     pop    psw
  742.     dcr    a
  743.     jrnz    wr$multi$sect
  744.  
  745.     ei
  746.     lda    sect$cnt
  747.     ana    a
  748.     rz                ; return if no errors (A=0)
  749.     call    set$up$next
  750.     jr    wr$fast$drive
  751.  
  752.     page
  753. ;
  754. ;
  755. ;
  756. get$drv$info:
  757.     lhld    @dma
  758.     shld    local$dma
  759.     xchg
  760.     shld    DPH$pointer
  761.  
  762.     lda    @adrv            ; get drive number (0 to F)
  763.     dcx    h            ; point at drive mask
  764.     dcx    h
  765.     mov    a,m            ; get drive mask
  766.     mov    b,a            ; save in B
  767.     sta    vic$drv            ; save vic drive # (values 1,2,4,8)
  768.  
  769.     inx    h            ; point at disk type
  770.     xra    a
  771.     sta    sect$cnt        ; clear the count
  772.     inr    a
  773.     sta    vic$count
  774.     mov    a,m            ; get disk type
  775.     ana    a
  776.     ret
  777.  
  778. ;
  779. ;    
  780. ;
  781. ;
  782. get$max$num$b:
  783.     lhld    DPH$pointer
  784.     lxi    b,42            ; offset to number of sectors on track
  785.     dad    b
  786.     mov    a,m            ; get number sectors/track/side
  787.     ani    1fh
  788.     mov    b,a
  789.     ret
  790. ;
  791. ;
  792. ;
  793. get$sector$size:
  794.     lhld    DPH$pointer
  795.     dcx    h
  796.     mov    a,m            ; disk type in B (bit 5,4 size info)
  797.     rrc                ; ..00 = 080h byte sectors
  798.     rrc                ; ..01 = 100h byte sectors
  799.     rrc                ; ..10 = 200h byte sectors
  800.     rrc                ; ..11 = 400h byte sectors
  801.     ani    3
  802.     jrz    set$128
  803.     jpo    not$3            ; jump if (A=) 01b or 10b
  804.     inr    a            ; make A = 4
  805. not$3:
  806.     mvi    e,0            ; set E to zero
  807.     mov    d,a            ; set sector size (1,2 or 4)
  808. get$DMA:
  809.     lhld    local$DMA        ; get the current DMA pointer
  810.     ret
  811.  
  812. set$128:
  813.     lxi    d,128
  814.     jr    get$DMA 
  815.  
  816.     page
  817. ;
  818. ;
  819. ;
  820.     DSEG
  821. set$up$GCR:
  822.     cpi    dsk$c128
  823.     jnz    tst$c64
  824.  
  825.     mvi    a,4
  826.     sta    sect$cnt
  827.     lxi    h,sect$buffer
  828.     shld    sect$buf$ptr
  829.  
  830.     lhld    @trk            ; 1 K sector pointer 
  831.     dad    h
  832.     dad    h            ; make 256 byte pointer
  833. ;
  834. ;    build a list of tracks and sectors
  835. ;
  836. next$sect:
  837.     shld    @trk
  838.     RCALL    FR$trk$sect
  839.     lhld    vic$trk            ; get trk(L) and sector(H) to HL
  840.     xchg
  841.     lhld    sect$buf$ptr
  842.     mov    m,e
  843.     inx    h
  844.     mov    m,d
  845.     inx    h
  846.     shld    sect$buf$ptr
  847.     lhld    @trk
  848.     inr    l            ; update saved above at next$sect
  849.     mov    a,l
  850.     ani    3
  851.     jrnz    next$sect
  852. ;
  853. ;    check list of trk-sectors for number of sectors on this trk
  854. ; 
  855.     lxi    h,sect$buffer
  856.     shld    sect$buf$ptr
  857.     lda    vic$drv
  858.     mov    b,a
  859.     lda    fast
  860.     ana    b            ; drive type 1571
  861.     jrz    handle$1541        ; no, handle as 1541
  862.  
  863.     lda    sect$cnt        ; number of sectors to rd/wr
  864.     mov    b,a
  865.     inx    h
  866.     mov    a,m            ; get 1st sector #
  867.     sta    vic$sect
  868.     dcx    h
  869.     mov    a,m            ; get 1st track #
  870.     sta    vic$trk
  871.  
  872. try$next:
  873.     cmp    m            ; test for same trk #
  874.     jrnz    exit$no$match
  875.     inx    h
  876.     inx    h            ; advance to next trk
  877.     shld    sect$buf$ptr
  878.     djnz    try$next    
  879.  
  880. exit$no$match:
  881.     lda    sect$cnt        ; number of sectors to rd/wr
  882.     sub    b            ; remove number left
  883.                     ; (leaving number matched)
  884.     sta    vic$count        ; save number to read
  885.     mov    a,b            ; get remaining count
  886.     sta    sect$cnt        ; save remaining count
  887.     ret
  888.  
  889.  
  890. set$up$next:
  891.     lda    vic$count        ; get number of sectors read
  892.     lhld    local$DMA        ; get current DMA pointer
  893.     add    h            ; advance pointer by number of
  894.     mov    h,a            ; sectors read
  895.     shld    local$DMA
  896. handle$1541:
  897.     lhld    sect$buf$ptr
  898.     mov    a,m
  899.     sta    vic$trk
  900.     inx    h
  901.     mov    a,m
  902.     sta    vic$sect
  903.     inx    h
  904.     shld    sect$buf$ptr
  905.     lda    vic$drv
  906.     mov    b,a
  907.     lda    fast
  908.     ana    b
  909.     jrz    set$up$next$slow
  910.     lda    sect$cnt
  911.     sta    vic$count
  912.     xra    a            ; two reads max with fast drive
  913.     jr    set$up$next$exit
  914.  
  915. set$up$next$slow:
  916.     lda    sect$cnt
  917.     dcr    a
  918. set$up$next$exit:
  919.     sta    sect$cnt
  920.     ret
  921.  
  922. tst$c64:
  923.     cpi    dsk$c64    
  924.     jrnz    tst$none    ; compute adjusted track number
  925. ;
  926. ;    this routine will adjust the track number if necessary.
  927. ;    The C64 CP/M disk has the C64 directory in the center
  928. ;    of the disk. This routine checks and adds one to the track
  929. ;    number if we have reached or passed the directory track. 
  930. ;    An additional offset of is added to make the track number
  931. ;    range from 1 to N+1 instead of 0 to N.
  932. ;
  933. set$up$c64:
  934.     lda    @trk
  935.     inr    a
  936.     cpi    dir$track    ; carry=1 if A < dir$track
  937.     cmc            ; add one if dir$track or more (carry not set)
  938.     aci    0        ; add the carry bit in
  939.  
  940. set$up$cont:
  941.     sta    vic$trk
  942.     lda    @sect
  943.     sta    vic$sect
  944.     ret
  945. ;
  946. ;    This format is for direct track and sector addressing 
  947. ;
  948. tst$none:
  949. ;    cpi    dsk$none    ; don't test extras for now....??
  950. ;    rnz
  951. do$type$7:
  952.     lda    @trk
  953.     jr    set$up$cont
  954.  
  955.     page
  956. ;
  957. ;    A=dsk$info on entry
  958. ;
  959. set$up$MFM:
  960.     mvi    d,0        ; D=side # (0)
  961.     mov    e,a        ; save dsk$info in E
  962.     ani    TypeX        ; look at Type0 to Type7
  963.     jrz    do$type$0    ;
  964.     cpi    Type2
  965.     lda    @trk        ; used by Type1, Type2 and Type3
  966.     jrz    do$type$2
  967.     jrc    do$type$1
  968.  
  969. ;    cpi    Type6
  970. ;    jrz    do$type$6
  971. ;    jnc    do$type$7    ; MSB of sector(byte) set for 2nd side of disk
  972.  
  973.     cpi    Type7
  974.     jz    do$type$7    ; MSB of sector(byte) set for 2nd side of disk
  975. ;
  976. ;    only types 0 to 2 and 7 are currenty defined
  977. ;        Type3 to Type6 will do Type2
  978. ;do$type$3:
  979. ;do$type$6:
  980.  
  981. do$type$2:
  982.     mov    b,a        ; save a copy in B
  983.     sui    40
  984.     jrc    do$type$0    ; jump if still on side 0
  985.     mvi    a,79        ; on back side count 39,38,37,...,0
  986.     sub    b
  987. set$trk:
  988.     mvi    d,80h        ; D=side # (1)
  989.     sta    @trk
  990.     jr    do$type$0
  991.  
  992.     page
  993. ;
  994. ;    divide the track number by two and if Head=1
  995. ;        add #sect/side to @sect
  996. ;
  997. do$type$1:
  998.     cmc            ; carry was set clear it
  999.     rar            ; divide track by 2 (carry gets LSB)
  1000.     sta    @trk
  1001.     jrnc    do$type$0
  1002.     call    get$max$num$b    ; HL and C changed
  1003.     lda    @sect
  1004.     add    b
  1005.     sta    @sect
  1006.  
  1007. do$type$0:
  1008.     lda    @trk
  1009.     sta    vic$trk
  1010.     call    get$max$num$b    ; B=number of sectors per track per side
  1011.     lda    @sect        ; ..HL and C changed
  1012.     cmp    b
  1013.     jrc    is$side$0
  1014.     mvi    d,80h        ; D=side # (1)
  1015.     bit    C1$bit,e    ; dsk$info in E
  1016.                 ; sector numbering continues on side 1 ?
  1017.     jrnz    is$side$0    ; yes, do not remove side one bias
  1018.     sub    b        ; no, remove side one bias
  1019. is$side$0:
  1020.     mov    c,a        ; hold @sect in C    
  1021.     mov    a,e        ; get dsk$info to A
  1022.     ani    S1        ; A=Starting  sector number (0 or 1)
  1023.     add    c        ; add back @sect
  1024.     ora    d        ; add in the side bit
  1025.     sta    vic$sect
  1026.     ret
  1027.  
  1028.     page
  1029. ;
  1030. ;    input:
  1031. ;        DE = number bytes to read
  1032. ;        HL = DMA address
  1033. ;
  1034.     CSEG
  1035. rd$1571$data:
  1036.     lda    @dbnk            ; get the disk DMA bank
  1037.     call    ?bank            ; set it
  1038.  
  1039.     lxi    b,0DC0Dh        ; D1ICR
  1040. rd$1571$stat$wait:
  1041.     inp    a
  1042.     ani    8            ; data ready bit set?
  1043.     jrz    rd$1571$stat$wait    ; no, loop
  1044.  
  1045.     mvi    c,0ch            ; D1SDR
  1046.     inp    a            ; read the status byte
  1047.     sta    vic$data        ; save it
  1048.     ani    0eh            ; any errors ?
  1049.     jrnz    rd$1571$exit        ; yes, exit
  1050.  
  1051.     lxi    b,0DD00h
  1052.     inp    a            ; get current clock polarity
  1053.  
  1054. rd$1571$next:
  1055.     lxi    b,0DD00h        ; D2PRA
  1056.     xri    10h            ; toggle clk$bit
  1057.     outp    a            ; clock the 1571 for a byte
  1058.  
  1059.     dcr    e            ; DE=count
  1060.     jnz    rd$1571$more        ; leave as normal jump to keep
  1061.     dcr    d            ; the transfer speed at it's max
  1062.     jrz    rd$1571$exit        ; ...
  1063.  
  1064. ;
  1065. rd$1571$more:
  1066.     dcr    b
  1067. rd$1571$wait:
  1068.     mvi    c,0dh            ; D1ICR (DC0Dh)
  1069.     inp    c
  1070.     bit    3,c
  1071.     jz    rd$1571$wait
  1072.     mvi    c,0ch            ; D1SDR
  1073.     ini                ; (hl) <- (bc) ; hl <- hl+1 ; b <- b-1
  1074.     jmp    rd$1571$next
  1075.  
  1076.  
  1077. rd$1571$exit:
  1078.     sta    bank$0            ; restore current mem config
  1079.     ret
  1080.  
  1081.     page
  1082.  
  1083. clk$in    equ    40h
  1084. ;
  1085. ;    input:
  1086. ;        DE = number of bytes to write
  1087. ;        HL = DMA address
  1088. ;
  1089. wr$1571$data:
  1090.     call    ?di$int
  1091. ; do spout inline
  1092.     lxi    b,mode$reg
  1093.     mvi    a,fast$wr$en
  1094.     sta    io$0
  1095.     outp    a            ; set data direction to output
  1096.     sta    bank$0
  1097.  
  1098.     lxi    b,0dc05h        ; low (D1T1h)
  1099.     xra    a
  1100.     outp    a
  1101.     dcr    c            ; low(D1T1l)
  1102.     mvi    a,3            ; clk = osc/3
  1103.     outp    a            ;
  1104.  
  1105.     mvi    c,0eh            ; D1CRA
  1106.     inp    a
  1107.     ani    80h
  1108.     ori    55h
  1109.     outp    a
  1110.     dcr    c            ; D1ICR
  1111.     inp    a
  1112.  
  1113.     lda    @dbnk            ; get the disk DMA bank
  1114.     call    ?bank            ; set it
  1115.  
  1116.     mvi    a,clk$in
  1117.     sta    cur$clk
  1118.  
  1119.     page
  1120. ;
  1121. ;
  1122. clk$wait:
  1123.     lxi    b,0dd00h        ; D2PRA
  1124.     inp    a
  1125.     inp    c            ; debounce
  1126.     cmp    c
  1127.     jrnz    clk$wait
  1128.  
  1129.     lda    cur$clk            ; get old clk value
  1130.     xra    c            ; check if changed 
  1131.     ani    clk$in            ; (only clock in bit)
  1132.     jrz    clk$wait        ; loop if not
  1133.  
  1134.     mov    a,c            ; 
  1135.     sta    cur$clk            ; make this the current clk value
  1136.     lxi    b,0dc0ch        ; D1SDR
  1137.     mov    a,m
  1138.     outp    a            ; send character to drive
  1139.     inx    h            ; advance pointer
  1140.     dcx    d            ; dec the char count
  1141.  
  1142.     inr    c            ; D1ICR
  1143. send$wait:
  1144.     inp    a
  1145.     ani    8
  1146.     jz    send$wait
  1147.  
  1148.     mov    a,d
  1149.     ora    e
  1150.     jnz    clk$wait        ; go send the next byte
  1151.  
  1152. ; do spin
  1153.     lxi    b,0DC0Eh        ; D1CRA
  1154.     inp    a
  1155.     ani    80h
  1156.     ori    8
  1157.     outp    a
  1158.     lxi    b,mode$reg
  1159.     mvi    a,fast$rd$en
  1160.     sta    io$0            ; enable the MMU
  1161.     outp    a            ; set data direction to input
  1162.     sta    bank$0            ; disable MMU
  1163. ; spin done
  1164.  
  1165.     page
  1166.  
  1167.     lxi    b,0DC0Dh        ; D1ICR
  1168.     inp    a            ; clear data pending flag
  1169.  
  1170.     lxi    b,0DD00h        ; D2PRA
  1171.     inp    a
  1172.     ori    10h            ; set clk$bit low (hardware inverted)
  1173.     outp    a            ; 
  1174.  
  1175.     lxi    b,0DC0Dh        ; D1ICR
  1176. wait$status:
  1177.     inp    a
  1178.     ani    8
  1179.     jrz    wait$status
  1180.  
  1181.     lxi    b,0DC0Ch        ; D1SDR
  1182.     inp    d
  1183.  
  1184.     lxi    b,0DD00h        ; D2PRA
  1185.     inp    a
  1186.     ani    not(10h)        ; set clk$bit hi (hardware inverted)
  1187.     outp    a            ; 
  1188.  
  1189.     mov    a,d            ; recover the status byte
  1190.     sta    vic$data
  1191.  
  1192.     ei
  1193.     ret
  1194.  
  1195.     page
  1196. ;
  1197. ;    This routine is used to move a sector of data
  1198. ;     to/from the sector buffer and the DMA pointer.
  1199. ;         A=0 for buffer to DMA  (disk read)
  1200. ;         A<>0 for DMA to buffer (disk write)
  1201. ;
  1202.     CSEG
  1203. ?dkmov:
  1204.     lhld    local$DMA    ; current DMA adr
  1205.     lxi    d,@buffer    ; location of disk read/write buffer
  1206.     lxi    b,256        ; sector size
  1207. ;
  1208. ;
  1209. dk$cont:
  1210.     ora    a
  1211.     jrnz    dsk$read    ; swap pointer for read
  1212.     xchg
  1213. ;
  1214. ;
  1215. dsk$read:
  1216.     lda    @dbnk        ; get the disk bank
  1217.     call    ?bank
  1218.     ldir            ; do the data move
  1219.     sta    bank$0        ; current bank will ALWAYS be 0
  1220.     ret
  1221.  
  1222. ;
  1223. ;
  1224. ;
  1225.     DSEG
  1226. dsk$fun:
  1227.     sta    vic$cmd
  1228.     call    disp$dsk$info        ; yes, go display disk info
  1229.     jmp    ?fun65+3        ; go do the function
  1230.  
  1231.     page
  1232. ;
  1233. ;*****************************************************************
  1234. ;
  1235.     DSEG
  1236. ?dskst:
  1237. disp$dsk$info:
  1238.     mvi    a,72            ; r/w in col 72 (col 0-79)
  1239.     sta    offset
  1240.     lda    vic$cmd
  1241.     mvi    b,'R'
  1242.     dcr    a            ; ?1 normal$rd
  1243.     jrz    out$cmd$rd
  1244.     dcr    a            ; ?2 normal$wr
  1245.     jrz    out$cmd$wr
  1246.     dcr    a            ; ?3 fast$rd
  1247.     jrz    out$cmd$rd
  1248.     dcr    a            ; ?4 fast$wr
  1249.     rnz
  1250. out$cmd$wr:
  1251.     mvi    b,'W'
  1252. out$cmd$rd:
  1253.     call    disp$B
  1254.     call    disp$space
  1255.     mvi    b,'A'-1
  1256.     lda    vic$drv
  1257. next$drv:
  1258.     inr    b
  1259.     rrc
  1260.     jrnc    next$drv
  1261.  
  1262.     call    disp$B
  1263.     lda    vic$trk
  1264.     call    disp$dec
  1265.     lda    vic$sect
  1266.     ani    80h
  1267.     cz    disp$space
  1268.     mvi    b,'-'
  1269.     cnz    disp$B
  1270.     lda    vic$sect    
  1271.     ani    7fh
  1272.  
  1273.     page
  1274. ;
  1275. ;
  1276. ;
  1277. disp$dec:
  1278.     mvi    b,'0'-1
  1279.  
  1280. conv$loop:
  1281.     inr    b
  1282.     sui    10
  1283.     jrnc    conv$loop
  1284.  
  1285.     adi    '0'+10
  1286.     push    psw
  1287.     call    disp$B
  1288.     pop    psw
  1289. disp$A:
  1290.     mov    b,a
  1291. disp$B:
  1292.     lda    offset
  1293.     mov    c,a            ; col # in C
  1294.     inr    a
  1295.     sta    offset            ; advance cursor position
  1296.     xra    a            ; no attribute to write
  1297.     call    ?stat
  1298.  
  1299.     xra    a
  1300.     ret
  1301.  
  1302. disp$space:
  1303.     mvi    b,' '
  1304.     jr    disp$B
  1305.  
  1306.     page
  1307.  
  1308. ;*****************************************************************
  1309. ;
  1310. ; Extended Disk Parameter Headers (XDPHs)
  1311. ;
  1312.     CSEG            ; place tables in common
  1313. ;
  1314. ;    1st disk drive on the system
  1315. ;
  1316.     dw    write$154X
  1317.     dw    read$154X
  1318.     dw    login$154X
  1319.     dw    init$154X
  1320.     db    1        ; bit 0 set (drive 0)
  1321.     db    dsk$c128    ; format type byte
  1322. cmdsk0:    
  1323.     dph    0,dpb$0
  1324.  
  1325. dpb$0:
  1326.     dpb    1024,1,1360,2048,128,0
  1327.     db    0        ; max sector number and lock flag
  1328.     dw    0        ; MFM table pointer
  1329.  
  1330.     page
  1331. ;
  1332. ;    2nd disk Drive on the system
  1333. ;
  1334.     dw    write$154X
  1335.     dw    read$154X
  1336.     dw    login$154X
  1337.     dw    init$154X
  1338.     db    2        ; bit 1 set (drive 1)
  1339.     db    dsk$c128    ; format type byte 
  1340. cmdsk1:
  1341.     dph    0,dpb$1
  1342.  
  1343. dpb$1:
  1344.     dpb    1024,1,1360,2048,128,0
  1345.     db    0        ; max sector number and lock flag
  1346.     dw    0        ; MFM table pointer
  1347.  
  1348.     page
  1349. ;
  1350. ;    3rd disk drive on the system
  1351. ;
  1352.     dw    write$154X
  1353.     dw    read$154X
  1354.     dw    login$154X
  1355.     dw    init$154X
  1356.     db    4        ; bit 2 set (drive 2)
  1357.     db    dsk$c128    ; format type byte
  1358. cmdsk2:    
  1359.     dph    0,dpb$2
  1360.  
  1361. dpb$2:
  1362.     dpb    1024,1,1360,2048,128,0
  1363.     db    0        ; max sector number and lock flag
  1364.     dw    0        ; MFM table pointer
  1365.  
  1366.     page
  1367. ;
  1368. ;    4th disk drive on the system
  1369. ;    (Drive D: returned to active duty. -RW)
  1370. ;
  1371.     dw    write$154X
  1372.     dw    read$154X
  1373.     dw    login$154X
  1374.     dw    init$154X
  1375.     db    8        ; bit 3 set (drive 3) (-RW)
  1376.     db    dsk$c128    ; format type byte
  1377. cmdsk3:
  1378.     dph    0,dpb$3
  1379.  
  1380. dpb$3:
  1381.     dpb    1024,1,1360,2048,128,0
  1382.     db    0        ; max sector number and lock flag
  1383.     dw    0        ; MFM table pointer
  1384.  
  1385.     page
  1386. ;
  1387. ;    5th disk drive on the system
  1388. ;    (Drive E: will be used as Drive F: by the Quick Brown Box -RW)
  1389. ;
  1390.     dw    write$154X
  1391.     dw    read$154X
  1392.     dw    login$154X
  1393.     dw    init$154X
  1394.     db    16        ; bit 4 set (drive 4) (-RW)
  1395.     db    dsk$c128    ; format type byte
  1396. cmdsk4:
  1397.     dph    0,dpb$4
  1398.  
  1399. dpb$4:
  1400.     dpb    1024,1,1360,2048,128,0
  1401.     db    0        ; max sector number and lock flag
  1402.     dw    0        ; MFM table pointer
  1403.  
  1404.     page
  1405. ;
  1406. ;    NOTE: The blocking factor for all of these formats is
  1407. ;        1K (2K for double sided), thus the fractional
  1408. ;        parts are unusable by CP/M.  They can be accessed
  1409. ;        by absolute sector addressing.
  1410. ;
  1411. ;    NOTE: 1571 and 1541 disk drives use track numbers
  1412. ;        of 1 to 35 and sector numbers of 0 to nn
  1413.  
  1414. ;
  1415. ;        The method used to access the full disk
  1416. ;        is to tell the system that there is 1 sector
  1417. ;        per track and then to use the track # as an
  1418. ;        absolute sector address and do conversion in BIOS.
  1419. ;
  1420. ; 
  1421. ; DPB FOR C128 CP/M 3.0 disk        ( 170K, 34K larger then C64 CP/M)
  1422. ;    256 byte sectors        ( 170.75K )
  1423. ;    1 sectors/track
  1424. ;        up to 21 physical sectors (0 to 16,17,18 or 20)
  1425. ;    680 tracks/disk (usable, 683 real)
  1426. ;        35 physical tracks (0 to 34)
  1427. ;    1K allocation blocks
  1428. ;    64 directory entries
  1429. ;    track offset of 2 (2 sectors) (handled by set$up$c128)
  1430. ;
  1431.     DSEG        ; these tables are moved to common when used
  1432. dpb$c128$SS:
  1433.     dpb    1024,1,170,1024,64,0
  1434.  
  1435.     page
  1436. ;
  1437. ; DPB FOR C128 CP/M 3.0 double sided disk    ( 340K )
  1438. ;    256 byte sectors            ( 341.5K )    
  1439. ;    1 sectors/track
  1440. ;        up to 21 physical sectors (0 to 16,17,18 or 20)
  1441. ;    1360 tracks/disk (usable, 1366 real)
  1442. ;        70 physical tracks (0 to 34 side 0, 35 to 69 side 1)
  1443. ;    2K allocation units
  1444. ;    128 directory entrys
  1445. ;    track offset of 1 (1 sectors) taken care of in set$up$c128
  1446. ;
  1447. dpb$c128$DS:
  1448.     dpb    1024,1,340,2048,128,0
  1449.  
  1450.     page
  1451. ;
  1452. ; DPB FOR C64 CP/M 2.2 disk --             ( 136K )
  1453. ;    256 byte sectors
  1454. ;    17 sectors / tracks    (sector numbering 0-16)
  1455. ;        sector 18 to n on the outer tracks are unused
  1456. ;    34 tracks / disk
  1457. ;        tracks track 2 to 16    (track numbering 0-34)
  1458. ;        track 17 is the C128 directory track (not counted)
  1459. ;        track 19 to 34
  1460. ;    1K allocation blocks
  1461. ;    64 directory entrys
  1462. ;    track offset of 2 (1st two tracks used for CP/M 2.2 boot)
  1463. ;
  1464. dpb$c64$cpm:
  1465.     dpb    256,17,34,1024,64,2
  1466.                 
  1467.     page
  1468. ;
  1469.     DSEG
  1470. MFM$table:
  1471.     db    S256*2+(16*2-8)+1    ; 256 byte sect, 16 sect/trk
  1472.     db    MFM+S256+Type0+C0+S1    ;     DSDD
  1473.     dw    0            ; start on track 4 sect 1 (2 alc)
  1474.     dpb    256,32,40,2048,128,2    ; sect# 1 to 16
  1475.     db    16            ; (top and bottom numbered the same)
  1476.     db    'Epson QX10'        ;1 Epson QX10
  1477.  
  1478.  
  1479.  
  1480.  
  1481.  
  1482.     db    80h+S512*2+(10*2-8)+1    ; 512 byte sect, 10 sect/trk
  1483. ;    db    S256*2            ; track 0 is 256 bytes/sector
  1484.     db    MFM+S512+Type0+C0+S1    ;    DSDD
  1485.     dw    0            ; start on track 2 sect 1 (2 alc)
  1486.     dpb    512,20,40,2048,128,2    ; sect# 1 to 10
  1487.     db    10            ; (top and bottom numbered the same)
  1488.     db    'Epson QX10'        ;2
  1489.  
  1490.     page
  1491.  
  1492.     db    S512*2+(8*2-8)+1    ; 512 byte sect 8 sect/trk
  1493.     db    MFM+S512+Type2+C0+S1    ;     SSDD
  1494.     dw    0            ; start on track 1 sector 1 (2 alc)
  1495.     dpb    512,8,40,1024,64,1    ; sect# 1 to 8
  1496.     db    8            ;
  1497.     db    ' IBM-8 SS '        ;3
  1498.  
  1499.  
  1500.  
  1501.  
  1502.  
  1503.     db    S512*2+(8*2-8)+1    ; 512 byte sect 8 sect/trk
  1504.     db    MFM+S512+Type2+C0+S1    ;     DSDD
  1505.     dw    0            ; start on track 1 sector 1 (1 alc)
  1506.     dpb    512,8,80,2048,64,1    ; sect# 1 to 8
  1507.     db    8            ; (top and bottom numbered the same)
  1508.     db    ' IBM-8 DS '        ;4
  1509.  
  1510.     page
  1511.  
  1512.     db    S512*2+(10*2-8)+0    ; 512 byte sector, 10 sect/trk
  1513.     db    MFM+S512+Type1+C1+S0    ;    DSDD
  1514.     dw    0            ; start on track 0 sector 10 (2 alc)
  1515.     dpb    512,10,80,2048,128,1    ; sect# 0 to 9 on top (even tracks)
  1516.     db    10            ; sect# 10 to 19 on bottom (odd tracks)
  1517.     db    'KayPro IV '        ;5
  1518.  
  1519.  
  1520.  
  1521.  
  1522.  
  1523.     db    S512*2+(10*2-8)+0    ; 512 byte sect, 10 sect/trk
  1524.     db    MFM+S512+Type0+C1+S0    ;     SSDD
  1525.     dw    0            ; start on track 1 sector 0 (4 alc)
  1526.     dpb    512,10,40,1024,64,1    ; sect# 0 to 9 
  1527.     db    10            ;
  1528.     db    'KayPro II '        ;6
  1529.  
  1530.     page
  1531.  
  1532.     db    S1024*2+(5*2-8)+1    ; 1024 byte sect, 5 sect/trk
  1533.     db    MFM+S1024+Type0+C0+S1    ;     SSDD
  1534.     dw    0            ; start on track 3 sector 1 (2 alc)
  1535.     dpb    1024,5,40,1024,64,3    ; sect# 1 to 5
  1536.     db    5            ;
  1537.     db    'Osborne DD'        ;7
  1538.  
  1539.  
  1540.  
  1541.  
  1542.     db    S512*2+(9*2-8)+1    ; 512 byte sect 9 sect/track (uses 8)
  1543.     db    MFM+S512+Type1+C0+S1    ;     DSDD
  1544.     dw    0            ; start on trk 0, sect 1, hd 1 (1 alc)
  1545.     dpb    512,8,80,2048,64,1    ; sect# 1 to 9
  1546.     db    8            ; (top and bottom numbered the same)
  1547.     db    '  Slicer  '        ;8
  1548.  
  1549.     page
  1550.  
  1551.     db    S256*2+(16*2-8)+1    ; 256 byte sect, 16 sect/trk
  1552.     db    MFM+S256+Type0+C0+S1    ;     DSDD
  1553.     dw    0            ; start on track 4 sect 1 (2 alc)
  1554.     dpb    256,32,40,2048,128,4    ; sect# 1 to 16
  1555.     db    16            ; (top and bottom numbered the same)
  1556.     db    'Epson Euro'        ;9 Epson European (MFCP/M ?)
  1557.  
  1558.  
  1559.  
  1560.  
  1561.  
  1562.     db    -1
  1563.     db    MFM            ; 
  1564.     dw    0            ; 
  1565.     dpb    512,20,40,2048,128,2    ; 
  1566.     db    8            ;
  1567.     db    '   None   '        ;10
  1568.  
  1569.     page
  1570.  
  1571.  
  1572.     db    80h+S512*2+(10*2-8)+1    ; 256 byte sector, 16 sectors/track
  1573.     db    MFM+S512+Type0+C0+S1    ; DSDD
  1574.     dw    0            ; start on track 2 sect 1 (2 alc)
  1575.     dpb    512,20,80,2048,128,0    ; sect# 1 to 10
  1576.     db    10            ; (top and bottom numbered the same)
  1577.     db    ' 1581 GP  '        ;11 - Gene Pizzetta's 1581 format
  1578.  
  1579.  
  1580.  
  1581.     db    62h
  1582.     db    0b0h
  1583.     db    0
  1584.     db    0
  1585.     db    50h
  1586.     db    0
  1587.     db    04
  1588.     db    0fh
  1589.     db    01
  1590.     db    0c8h
  1591.     db    0
  1592.     db    7fh
  1593.     db    0
  1594.     db    0c0h
  1595.     db    0
  1596.     db    20h
  1597.     db    0
  1598.     db    0
  1599.     db    0
  1600.     db    03
  1601.     db    07
  1602.     db    05
  1603.         db      'Maxi 1571 '        ;12 -  M. Garamszeghy's 398K format
  1604.  
  1605.     page
  1606.  
  1607.     db    -1
  1608.     db    MFM            ; 
  1609.     dw    0            ; 
  1610.     dpb    512,20,40,2048,128,2    ; 
  1611.     db    8            ;
  1612.     db    '   None   '        ;13
  1613.  
  1614.     db    -1
  1615.     db    MFM            ; 
  1616.     dw    0            ; 
  1617.     dpb    512,20,40,2048,128,2    ; 
  1618.     db    8            ;
  1619.     db    '   None   '        ;14
  1620.  
  1621.     page
  1622.  
  1623.     db    -1
  1624.     db    MFM            ; 
  1625.     dw    0            ; 
  1626.     dpb    512,20,40,2048,128,2    ; 
  1627.     db    8            ;
  1628.     db    '   None   '        ;15
  1629.  
  1630.     db    -1
  1631.     db    MFM            ; 
  1632.     dw    0            ; 
  1633.     dpb    512,20,40,2048,128,2    ; 
  1634.     db    8            ;
  1635.     db    '   None   '        ;16
  1636.  
  1637.  
  1638.     page
  1639. ;
  1640. ;    not functional yet
  1641. ;
  1642.  
  1643. ;    db    S1024*2+(5*2-8)+1    ; 1024 byte sect 5 sect/track
  1644. ;    db    MFM+S1024+Type0+C0+S1    ;     SSDD
  1645. ;    dw    0            ; start on trk 2, sect 1 (2 alc)
  1646. ;    dpb    1024,5,40,2048,128,2    ; sect# 1 to 5
  1647. ;    db    5            ;
  1648. ;    db    'Morrow MD2'        ; 
  1649.  
  1650.  
  1651.  
  1652.  
  1653.  
  1654. ;    db    S1024*2+(5*2-8)+1    ; 1024 byte sect  5 sect/trk
  1655. ;    db    MFM+S1024+Type0+C0+S1    ;     DSDD
  1656. ;    dw    0            ; start on trk 1, sect 1, hd 0 (3 alc)
  1657. ;    dpb    1024,10,40,2048,192,1    ; sect# 1 to 5
  1658. ;    db    5            ;
  1659. ;    db    'Morrow MD3'        ; 
  1660.  
  1661.  
  1662. MFM$tbl$entries    equ    ($-MFM$table)/32
  1663.  
  1664.     db    -1
  1665.     db    -1
  1666.  
  1667.     page
  1668.  
  1669.     cseg
  1670. cur$clk:    ds    1
  1671.  
  1672.     dseg
  1673. lock$flag    ds    1
  1674. last$match    ds    2
  1675. window$info:    ds    2
  1676.  
  1677. dsk$window    equ    12
  1678.  
  1679. no$dsk$msg:
  1680.         ;1234567890
  1681.     db    ' Missing  ' 
  1682.  
  1683.  
  1684. MFM$match$tbl:
  1685.     ds    2*MFM$tbl$entries    ; MFM$count MUST follow this parm
  1686. MFM$count:
  1687.     ds    1            ; MFM$offset MUST follow this parm
  1688. MFM$offset:
  1689.     ds    1
  1690.  
  1691. MFM$cur$ptr:
  1692.     ds    2
  1693.  
  1694. DPH$pointer:
  1695.     ds    2
  1696.  
  1697. sect$cnt:
  1698.     ds    1
  1699. sect$buf$ptr:
  1700.     ds    2
  1701. sect$buffer:
  1702.     ds    4*2
  1703.  
  1704. local$DMA:
  1705.     ds    2
  1706.  
  1707. status$atr    equ    0
  1708. offset:        db    0
  1709.  
  1710.     end
  1711.  
  1712.