home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / utils / dirutl / xren.lbr / XREN.AZM / XREN.ASM
Encoding:
Assembly Source File  |  1987-01-15  |  9.0 KB  |  334 lines
  1.  
  2.  
  3. ;**********************************************
  4. ;              XREN.ASM     2/18/84   7:45 P.M.
  5. ;
  6. ;     File renaming with wild cards *,?
  7. ;     allowed in both the old and new file names
  8. ;
  9. ;    USAGE:  XREN (d:)fileOld fileNew
  10. ;
  11. ;    Program: By Miguel Vasquez based on
  12. ;             program by George M Gallen
  13. ;
  14. ;        needs 8080   and CP/M
  15. ;***********************************************
  16. ;
  17. ;--------------------EQUATES--------------------
  18. ;
  19. BDOS    EQU    5    ;Entry point to CP/M functions
  20. PRINTS    EQU    9    ;Func. # to Print String 
  21. OPEN    EQU    15    ;Func. # to Open existing File 
  22. CLOSE    EQU    16    ;Func. # to Close File 
  23. REN    EQU    23    ;Func. # to Rename File 
  24. FCB0    EQU    5CH    ;CP/M's FCB
  25. NOFIND    EQU    0FFH    ;Error code for file not found
  26. ;------------------------------------------------
  27. ;*************** MAIN PROGRAM START **************
  28.     ORG    0100H        ;Start of TPA
  29. MAIN:    CALL    INIT        ;Initialize our Stack.
  30.     LDA    FCB0+1        ;Check if source file is
  31.     CPI    ' '        ;blank. If so give BAD
  32.     JZ    BF        ;FORMAT messg. and exit.
  33.     LDA    FCB0+17        ;Check second file
  34.     CPI    ' '        ;also.
  35.     JZ    BF        ;
  36. ;
  37.     LXI    H,FCB0+1    ;Move original file name
  38.     LXI    D,FCB1+1    ;to its place in
  39.     LXI    B,11        ;FCB1 and FCB3.
  40.     CALL    LDIR        ;
  41.     LXI    H,FCB0+1    ;
  42.     LXI    D,FCB3+1
  43.     LXI    B,11        ;
  44.     CALL    LDIR        ;
  45. ;
  46.     LXI    H,FCB0+17    ;Move new file name
  47.     LXI    D,FCB5+1    ;to FCB5.
  48.     LXI    B,11        ;
  49.     CALL    LDIR        ;
  50. ;
  51.     CALL    DRIVE        ;Save Drive specs
  52. ;
  53. RNLOOP:    LXI    H,FCB3        ;Try to open source file.
  54.     CALL    FOPEN        ; 
  55.     CPI    NOFIND        ;If unsuccessful, then no more
  56.     JZ    ENDIT        ;files, so end it.
  57. ;
  58.     LXI    H,FCB0+1    ;Put full file name (now without ??)
  59.     LXI    D,FCB1+1    ;(with the extensions) to
  60.     LXI    B,11        ;the appropriate spots in
  61.     CALL    LDIR        ;FCB1.
  62.     CALL    NEWNAM        ;Make new full file name in FCB2.
  63. ;
  64.     MVI    C,CLOSE        ;Close the original file
  65.     LXI    D,FCB0        ;
  66.     CALL    BDOS        ;
  67. ;
  68.     LXI    H,FCB2+1    ;Set up new full file name
  69.     LXI    D,FCB4+1    ;(with extension)
  70.     LXI    B,11        ;in FCB4.
  71.     CALL    LDIR        ;
  72. ; 
  73.     LXI    H,FCB4        ;Try to open the new file
  74.     CALL    FOPEN        ;
  75.     CPI    NOFIND        ;Could open it?  Horrors!!
  76.     JNZ    CANNT        ;Exit without renaming.
  77. ;
  78.     MVI    C,REN        ;Rename the old file
  79.     LXI    D,FCB1        ;to the new name.
  80.     CALL    BDOS        ;
  81. ;
  82.     CALL    INFORM        ;Inform of files renamed
  83.     JMP    RNLOOP        ;Process next one.
  84. ;
  85. CANNT:    MVI    C,CLOSE        ;Found a file with that name!!
  86.     CALL    BDOS        ;close it !
  87. ;
  88.     LXI    H,FCB2+1    ;Move the Bad file 
  89.     LXI    D,MSG7        ;name and extension
  90.     LXI    B,8        ;into Message #7
  91.     CALL    LDIR        ;
  92.     INX    D        ;
  93.     LXI    B,3        ;
  94.     CALL    LDIR        ;
  95.     LXI    D,MSG8        ;display message and
  96.     JMP    STROUT        ;exit.
  97.  
  98. ENDIT:    LXI    D,MSG5        ;We're done, prepare message
  99.     JMP    STROUT        ;Print it and return to CP/M
  100. ;
  101. BF:    LXI    D,MSG6        ;Prepare BAD FORMAT message
  102.     JMP    STROUT        ;go printit and exit
  103. ;
  104. ;=============== SUBROUTINES ======================
  105. ;
  106. ;********************************************************
  107. ;                INFORM
  108. ;
  109. ;      to print message with files being renamed
  110. ;********************************************************
  111. INFORM:    LXI    H,FCB1+1    ;Move old file name
  112.     LXI    D,MSG3        ;and extension into
  113.     LXI    B,8        ;MSG3.
  114.     CALL    LDIR        ;
  115.     INX    D        ;
  116.     LXI    B,3        ;
  117.     CALL    LDIR        ;
  118.     LXI    H,FCB2+1    ;Move new file name
  119.     LXI    D,MSG4        ;and extension into
  120.     LXI    B,8        ;MSG4.
  121.     CALL    LDIR        ;
  122.     INX    D        ;Then display message
  123.     LXI    B,3        ;with the two names
  124.     CALL    LDIR        ;to let us know what's
  125.     LXI    D,MSG1        ;going on. (Drop down
  126. ;    JMP    STROUT        ;into STROUT to do it)
  127. ;********************************************************
  128. ;                STROUT  to send a string to the console
  129. ;
  130. ;   Arguments : DE has the addr. of the string to be sent
  131. ;*******************************************************
  132. STROUT:    MVI    C,PRINTS    ;Set function code
  133.     JMP    BDOS        ;go doit
  134. ;        
  135. ;*******************************************************
  136. ;                 DRIVE   to save drives
  137. ;
  138. ;    Arguments:  The first byte of FCB0 contains
  139. ;                the source drive:
  140. ;                0  for the logged drive
  141. ;         1  for drive A
  142. ;                2  for drive B, etc.
  143. ;*******************************************************
  144. DRIVE:    LDA    FCB0        ;Get the drive # and store
  145.     STA    FCB1        ;it in its place in FCB1,
  146.     STA    FCB3        ;FCB3, and FCB4.
  147.     STA    FCB4        ;
  148.     ORA    A        ;Is it the Logged drive?
  149.     RZ            ;Yes, leave drive blank.
  150.     ADI    64        ;No, convert to letter,
  151.     STA    DRV1        ;Save it and 
  152.     STA    DRV2        ;add a colon.
  153.     MVI    A,':'        ;
  154.     STA    DRV1+1        ;
  155.     STA    DRV2+1        ;
  156.     RET
  157. ;
  158. ;********************************************************
  159. ;                NEWNAM  to make new name
  160. ;
  161. ;     Arguments:    FCB0 has a regular full filename 
  162. ;              FCB5 hs a file name with wild cards (?)
  163. ;              On exit FCB2 will have FCB5 but
  164. ;                     with ?'s replaced with the corresponding
  165. ;                     character from FCB0.
  166. ;********************************************************
  167. NEWNAM:    MVI    B,11        ;Counter (bytes in file name).
  168.     LXI    D,FCB2+1    ;Destination addr. in DE.
  169.     LXI    H,FCB0+1    ;Use Stack as an extra
  170.     PUSH    H        ;index register for FBC0.(Source)
  171.     LXI    H,FCB5+1    ;Mask addr. in HL
  172. LBA:    MOV    A,M        ;Move mask byte to A.
  173.     CPI    '?'        ;MasK='?' ?
  174.     JNZ    LBB        ;no, output A.
  175.     XTHL            ;yes, Get FCB0 index into HL.
  176.     MOV    A,M        ;Get source byte. 
  177.     XTHL            ;Put FCB0 index back in stack.
  178.     CPI    ' '        ;Is source a blank?
  179.     JNZ    LBB        ;No, then output it.
  180.     MVI    C,1        ;Yes, set C to number of
  181.     MOV    A,B        ;bytes neccessary to
  182.     CPI    4        ;fill the rest of
  183.     JM    LBC        ;the name or extension
  184.     MVI    C,4        ;with blanks. That is:
  185. LBC:    MOV    A,B        ;if B<4 then C=1 else C=4
  186.     SUB    C        ;C=B-C
  187.     MOV    C,A        ;
  188. LBD:    MOV    A,C        ;If C=0 then we are
  189.     ORA    A        ;at the last blank byte,
  190.     MVI    A,' '        ;Go and output it.
  191.     JZ    LBB        ;
  192.     STAX    D        ;Put blank in FCB5.
  193.     INX    H        ;Increment the three
  194.     INX    D        ;indexes.
  195.     XTHL            ;
  196.     INX    H        ;
  197.     XTHL            ;
  198.     DCR    B        ;Decrement the two
  199.     DCR    C        ;counters.
  200.     JMP    LBD        ;
  201. LBB:    STAX    D        ;Put char. in FCB5.
  202.     INX    H        ;Increment the three
  203.     INX    D        ;indexes.
  204.     XTHL            ;
  205.     INX    H        ;
  206.     XTHL            ;
  207.     DCR    B        ;Process next byte if
  208.     JNZ    LBA        ;not thru yet.
  209.     POP    H        ;If thru, restore stack
  210.     RET            ;and return
  211. ;    
  212. ;********************************************************
  213. ;             FOPEN  to try to open an existing file
  214. ;
  215. ;      Arguments:  HL has addr. of FCB with file to be opened
  216. ;********************************************************
  217. FOPEN:    LXI    D,FCB0        ;Move FCB to CP/M's
  218.     LXI    B,35        ;FCB.
  219.     CALL    LDIR        ;
  220.     MVI    C,OPEN        ;Try to open the file.
  221.     LXI    D,FCB0        ;
  222.     CALL    BDOS        ;
  223.         RET
  224. ;
  225. ;********************************************************
  226. ;              LDIR     to simulate Z-80's LDIR
  227. ;
  228. ;  used to move a string from a location to another
  229. ;  
  230. ;  Arguments:   HL  addr. of source
  231. ;               DE  addr. of destination
  232. ;               BC  Number of bytes to be moved
  233. ;
  234. ; All the registers are modified
  235. ;
  236. ; Any Z-80 based computer (such as Osborne 1's)
  237. ; can replace all the CALL LDIR's
  238. ; with:     DB    0EDH,0B0H 
  239. ; or replace this subroutine with
  240. ; LDIR:    DB    0EDH,0B0H
  241. ;     RET
  242. ;*************************************************** 
  243. LDIR:    MOV    A,M        ;Move next byte
  244.     STAX    D        ;to its destination.
  245.     INX    H        ;Increment the pointers
  246.     INX    D        ;to source and destination.
  247.     DCX    B        ;Decrement byte count.
  248.     MOV    A,B        ;Test if BC
  249.     ORA    C        ;is zero.
  250.     RZ                 ; Yes, then return.
  251.     JMP    LDIR        ; No, process another byte
  252. ;
  253. ;********************************************************
  254. ;        INIT to initialize the stack
  255. ;        and save CP/M's stack
  256. ;********************************************************
  257. INIT:    POP    B        ;get return addr.
  258.     LXI    H,0        ;load HL with
  259.     DAD    SP        ;the stack pointer.
  260.     SHLD    CPMSTK        ;save it in CPMSTK.
  261.     LXI    H,MYSTAK    ;Change to my stack.
  262.     SPHL            ;
  263.     LXI    D,FINISH    ;Put finish routine
  264.     PUSH    D        ;in stack.
  265.     PUSH    B        ;put return addr.in stack.
  266.     RET            ;return 
  267. FINISH    LHLD    CPMSTK        ;reinstall CP/M's stack
  268.     SPHL            ;
  269.     RET            ;and return to CP/M.
  270. ;
  271. ;========================= DATA AREAS ==================
  272. FCB1:    DB    0        ;Drive for the Original FCB, 
  273.     DB    '????????'    ;Name
  274.     DB    '???'        ;Extension
  275.     DB    0,0,0,0        ;Filler
  276. ;
  277. FCB2:    DB    0        ;New FCB, (drive)
  278.     DB    '????????'    ;Name
  279.     DB    '???'        ;Extension
  280.     DB    0,0,0,0        ;Filler
  281. ;
  282. FCB3:    DB    0        ;Full original FCB 
  283.     DB    '????????'
  284.     DB    '???'
  285.     DB    0,0,0,0,0
  286.     DB    0,0,0,0,0
  287.     DB    0,0,0,0,0
  288.     DB    0,0,0,0,0
  289.     DB    0,0,0
  290. ;
  291. FCB4:    DB    0        ;Full new FCB
  292.     DB    '????????'
  293.     DB    '???'
  294.     DB    0,0,0,0,0
  295.     DB    0,0,0,0,0
  296.     DB    0,0,0,0,0
  297.     DB    0,0,0,0,0
  298.     DB    0,0,0
  299. ;
  300. FCB5:    DB    0        ;Mask for New FCB
  301.     DB    '????????'    ;Name
  302.     DB    '???'        ;Extension
  303. ;
  304. ; misc messages to let you know what's going on
  305. ;
  306. MSG1:    DB    'RENAMING '
  307. DRV1:    DB    '  '        ;2 spaces
  308. MSG3:    DB    '        '     ;8 spaces
  309.     DB    '.'
  310.     DB    '   '        ;3 spaces
  311.     DB    ' TO '
  312. MSG4:    DB    '        '     ;8 spaces
  313.     DB    '.'
  314.     DB    '   '        ;3 spaces
  315.     DB    13,10,'$'
  316. MSG5:    DB    10,'No more matches',13,10
  317.     DB    'I AM DONE......',13,10,'$'
  318. MSG6:    DB    '* INVALID FORMAT *',13,10,10
  319.     DB    'It should be :  '
  320.     DB    'XREN [d:]fileOld fileNew',13,10,10,7,'$'
  321. MSG8:    DB    10,'THE FILE '
  322. DRV2:    DB    '  '        ;2 spaces
  323. MSG7:    DB    '        '     ;8 spaces
  324.     DB    '.'
  325.     DB    '   '        ;3 spaces
  326.     DB    ' ALREADY EXISTS. ',13,10
  327.         DB    'PROCESSING HALTED. CANNOT RENAME ALL FILES'
  328.         DB    13,10,10,7,'$'
  329. ;
  330. CPMSTK    DS    2        ;CP/M's stack pointer
  331.     DS    40        ;
  332. MYSTAK    EQU    $        ;My stack.
  333.     END
  334.