home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / utils / asmutl / hd64180a.lbr / IO.AZM / IO.ASM
Encoding:
Assembly Source File  |  1991-08-04  |  10.6 KB  |  465 lines
  1.     title    'I/O Drivers for Core Board'
  2. ;----------------------------------------------------------------
  3. ;            Core Board I/O Drivers 
  4. ;
  5. ;        Written     By Richard Holmes    12-05-86
  6. ;        Last Update By Richard Holmes    23-01-87
  7. ;
  8. ; Changed Dart setup for DTR set on                   08-06-86
  9. ; Modified clock routine to save year in 58167 ram    08-06-86
  10. ; Modified clock routine to use DE as buffer address  30-06-86
  11. ; Use WDT$FLG in the clrwdt routine                   23-11-86
  12. ; Added LED drivers                                   18-01-87
  13. ; Removed AUX drivers                                 19-01-87
  14. ;----------------------------------------------------------------
  15. ;
  16.     maclib    z80
  17.     maclib    core
  18. ;
  19.     public    cie,coe,cst
  20.     public    con$inp,con$out,con$ist
  21.     public    clkrd,clkwr,schrd
  22.     public    init,clrwdt
  23. ; Led Drivers
  24.     public    ini$led,tog$led        ; Initialize led drivers
  25.     public    clr$led,set$led        ; Led number on/off
  26.     public    ori$led,ani$led        ; OR and AND led bit mask
  27.     public    xri$led            ; XOR led image
  28. ; Bell driver
  29.     public    set$bel,clr$bel        ; Set/Clear bell
  30.     public    tog$bel            ; Toggle bell bit on/off
  31. ;
  32. ;================================================================
  33. ;        LED Drivers
  34. ;
  35. ;================================================================
  36. ; Initialize the LED drivers by clearing the data byte and hence 
  37. ; the led port
  38. ;----------------------------------------------------------------
  39. ;
  40. ini$led:
  41.     mvi    a,wr$en        ; Memory enable only
  42.     sta    led$byt        ; Save for masks later
  43.     out    @ledd        ; Send to driver
  44.     ret
  45. ;
  46. ;----------------------------------------------------------------
  47. ; Set the specified bit in A LED on. Leave others alone.
  48. ;
  49. ; On Entry
  50. ;    A = 1..6 for the led number
  51. ; On Exit
  52. ;     Led number turned on. Others preserved.
  53. ;----------------------------------------------------------------
  54. ;
  55. set$led:
  56.     ora    a
  57.     rz                ; Exit if = 0
  58.     cpi    7
  59.     rnc                ; NC and > 6 hence in error
  60.     push    b
  61.     call    led$msk
  62.     lda    led$byt            ; Load old data
  63.     ora    c            ; OR in the new bit mask
  64. led$com:
  65.     sta    led$byt
  66.     out    @ledd            ; Write out again
  67.     pop    b
  68.     ret
  69. ;
  70. ;----------------------------------------------------------------
  71. ; Clear the specified bit in A. Leave others alone.
  72. ;
  73. ; On Entry
  74. ;    A = 1..6 for the led number
  75. ; On Exit
  76. ;     Led number cleared. Others preserved.
  77. ;----------------------------------------------------------------
  78. ;
  79. clr$led:
  80.     ora    a
  81.     rz                ; Exit if = 0
  82.     cpi    7
  83.     rnc                ; NC and > 6 hence in error
  84.     push    b
  85.     call    led$msk
  86.     cma    
  87.     mov    c,a            ; Invert and save led mask
  88.     lda    led$byt            ; Load old data
  89.     ana    c            ; And OFF the selected bit
  90.     ori    wr$en            ; Mask in the memory enable bit
  91.     jr    led$com
  92. ;
  93. ;----------------------------------------------------------------
  94. ; Or the specified bit mask in A into the LED Outputs.
  95. ;
  96. ; On Entry
  97. ;    A = led mask
  98. ;
  99. ; On Exit
  100. ;     Set bit leds turned on. Others preserved.
  101. ;----------------------------------------------------------------
  102. ;
  103. ori$led:
  104.     push    b
  105.     ani    0011$1111b        ; Mask off any top bits
  106.     mov    c,a            ; Save
  107.     lda    led$byt            ; Load old data
  108.     ora    c            ; OR in the bit mask
  109. ; Maskin ram enable
  110.     ori    1100$0000b        ; Turns ram on.
  111.     jr    led$com
  112. ;
  113. ;----------------------------------------------------------------
  114. ; AND the specified bit mask in A into the LED Outputs.
  115. ;
  116. ; On Entry
  117. ;    A = led mask
  118. ;
  119. ; On Exit
  120. ;     Set bit leds turned on. Others turned off.
  121. ;----------------------------------------------------------------
  122. ;
  123. ani$led:
  124.     push    b
  125.     mov    c,a            ; Save
  126.     lda    led$byt            ; Load old data
  127.     ana    c            ; AND the bit image of previous leds
  128.     ori    wr$en            ; OR in memory enable
  129.     jr    led$com
  130. ;
  131. ;----------------------------------------------------------------
  132. ; Exclusive OR the bit in A with the current LED port mask.
  133. ;
  134. ; On Entry
  135. ;    A = bit mask to XOR into led image
  136. ;
  137. ; On Exit
  138. ;    LED image updated
  139. ;----------------------------------------------------------------
  140. ;
  141. xri$led:
  142.     push    b
  143.     mov    c,a
  144.     lda    led$byt
  145.     xra    c
  146.     jr    led$com
  147. ;
  148. ;----------------------------------------------------------------
  149. ; Toggle the passed in LED
  150. ;
  151. ;----------------------------------------------------------------
  152. ;
  153. tog$led:
  154.     ora    a
  155.     rz
  156.     cpi    8
  157.     rnc
  158. ;
  159.     push    b
  160.     call    led$msk
  161.     lda    led$byt
  162.     xra    c
  163.     ori    wr$en
  164.     jmp    led$com
  165. ;
  166. ; ---------------------------------------------
  167. ; -- Convert a bit number into an actual Bit --
  168. ; ---------------------------------------------
  169. ;
  170. led$msk:
  171.     mov    b,a            ; load counter
  172.     mvi    a,080h            ; Seed. Must rotate at least once.
  173. led$rot:
  174.     rlc                ; Shift left
  175.     djnz    led$rot
  176.     mov    c,a            ; Save data into C for later
  177.     ret
  178. ;
  179. ;----------------------------------------------------------------
  180. ;           Turn on the system bell
  181. ;----------------------------------------------------------------
  182. ;
  183. set$bel:
  184.     push    psw
  185.     mvi    a,1
  186.     sta    bel$byt
  187.     out    @buz            ; To bell / buzzer
  188.     pop    psw
  189.     ret
  190. ;
  191. ;----------------------------------------------------------------
  192. ;           Turn off the system bell
  193. ;----------------------------------------------------------------
  194. ;
  195. clr$bel:
  196.     push    psw
  197.     xra    a            ; Send a 0
  198.     sta    bel$byt
  199.     out    @buz            ; To bell / buzzer
  200.     pop    psw
  201.     ret
  202. ;
  203. ;----------------------------------------------------------------
  204. ;     Toggle the system bell bit ON/OFF
  205. ;----------------------------------------------------------------
  206. ;
  207. tog$bel:
  208.     push    psw
  209.     lda    bel$byt
  210.     xri    1
  211.     sta    bel$byt
  212.     out    @buz            ; To bell / buzzer
  213.     pop    psw
  214.     ret
  215. ;
  216. ;----------------------------------------------------------------
  217. ; Clear the watchdog timer by writing a 1 then 0 to toggle
  218. ; the port.
  219. ;----------------------------------------------------------------
  220. ;
  221. clrwdt:
  222.     push    psw
  223.     lda    wdt$flg
  224.     out    @wdt
  225.     xri    1            ; Toggle bit 1
  226.     sta    wdt$flg
  227.     pop    psw
  228.     ret
  229. ;
  230. ;----------------------------------------------------------------
  231. ; Read the dip switch into A for the user
  232. ;----------------------------------------------------------------
  233. ;
  234. schrd:
  235.     in    @sch
  236.     ret
  237. ;
  238. ;----------------------------------------------------------------
  239. ;    Read real time clock to ram at DE
  240. ;
  241. ; Memory is laid out in the following format:
  242. ; 
  243. ; seconds
  244. ; minutes
  245. ; hours
  246. ; day of week
  247. ; day of month
  248. ; month
  249. ; Year. Saved in ram in the clock chip at port 01fh
  250. ;
  251. ; Note the bit of code that stops the clock from being read
  252. ; constantly if the chip is faulty. This is the count value
  253. ; in B.
  254. ;----------------------------------------------------------------
  255. ;
  256. clkrd:
  257.     push    h
  258.     push    b                ; Save
  259.     sded    ?time
  260.     mvi    b,5                ; 5 times maximum read count
  261. ;
  262. ;
  263. ;
  264. read$clock:                ; Repeat here if a rollover
  265.     lhld    ?time
  266.     in    @clk + 2            ; Seconds
  267.     mov    m,a
  268.     inx    h
  269. ;
  270.     in    @clk + 3            ; Minutes
  271.     mov    m,a
  272.     inx    h
  273. ;
  274.     in    @clk + 4            ; hours
  275.     mov    m,a
  276.     inx    h
  277. ;
  278.     in    @clk + 5            ; Day of week
  279.     mov    m,a
  280.     inx    h
  281. ;
  282.     in    @clk + 6            ; Day of month
  283.     mov    m,a
  284.     inx    h
  285. ;
  286.     in    @clk + 7            ; Month
  287.     mov    m,a
  288.     inx    h            ; -> year register in system ram
  289.     in    @clk + 0fh        ; Year ram in clock
  290.     mov    m,a
  291. ;
  292. ; Check rollover status port. Bitset = an internal ripple, re-read required.
  293. ;
  294.     in    @clk+20            ; Status port
  295.     ani    1            ; Status bit is in D0
  296.     jz    read$kend        ; if 00, a good read
  297.     djnz    read$clock        ; Read till a 0 bit.
  298. ;
  299. ; Else the time is valid
  300. ;
  301. read$kend:
  302.     pop    b            ; Restore all
  303.     pop    h
  304.     ret
  305. ;
  306. ;----------------------------------------------------------------
  307. ;
  308. ; Write the real time clock from a ram store. This is expected
  309. ; to be in the same format as that for clock read.
  310. ;
  311. ; On entry
  312. ;  DE -> time buffer
  313. ;----------------------------------------------------------------
  314. ;
  315. clkwr:
  316.     push    h
  317. ; Reset clock counters
  318.     mvi    a,0ffh            ; All 1's for a reset counter command
  319.     out    @clk + 18        ; Resets all the counters
  320. ;
  321.     ldax    d
  322.     mov    a,m
  323.     out    @clk + 2
  324.     inx    d
  325. ;
  326.     ldax    d
  327.     out    @clk + 3            ; Minutes
  328.     inx    d
  329. ;
  330.     ldax    d
  331.     out    @clk + 4            ; hours
  332.     inx    d
  333. ;
  334.     ldax    d
  335.     out    @clk + 5            ; Day of week
  336.     inx    d
  337. ;
  338.     ldax    d
  339.     out    @clk + 6            ; Day of month
  340.     inx    d
  341. ;
  342.     ldax    d
  343.     out    @clk + 7            ; Month
  344.     inx    d
  345. ;
  346.     ldax    d                ; Write year to clock ram
  347.     out    @clk + 0fh            ; Write to year register ram
  348. ;
  349.     pop    h
  350.     ret
  351. ;
  352. ;----------------------------------------------------------------
  353. ;     Initialize the hardware on the board
  354. ;
  355. ; Initialize the SIO for channel A and channel B 8 bit, 1 stop
  356. ; no parity and 9600 baud each.
  357. ; CTC channels 0 and 1 are for SIO baud rates
  358. ; CTC channel 2 for external interrupts......... (see monitor)
  359. ; CTC channel 3 for real time clock interrupts.. (see monitor)
  360. ;----------------------------------------------------------------
  361. ;
  362. init:
  363.     lxi    h,initbl
  364. initlp:    mov    b,m            ; get counter
  365.     inx    h
  366.     mov    c,m            ; get port    
  367.     mov    a,b
  368.     ora    a            ; check for zero
  369.     jz    inictc            ; exit if count=0
  370.     inx    h
  371.     outir                ; send all out
  372.     jr    initlp
  373. ;
  374. inictc:
  375.     mvi    a,02h            ; Reset channel
  376.     out    @ctc0
  377. ;
  378.     nop
  379.     nop
  380. ;
  381. ;
  382.     mvi    a,045h            ; Time constant follows
  383.     out    @ctc0
  384.     mvi    a,13
  385.     out    @ctc0
  386. ;
  387. ; Initialize the watchdog timer clear routine that toggles the
  388. ; low order bit each time called.
  389. ;
  390.     xra    a
  391.     sta    wdt$flg
  392.     sta    bel$byt
  393. ;
  394.     ret
  395. ;
  396. ;----------------------------------------------------------------
  397. ;         Console output
  398. ;----------------------------------------------------------------
  399. ;
  400. con$out:
  401. coe:
  402.     push    psw
  403. coe$wait:
  404.     in    @stat0
  405.     ani    txmsk            ; See if transmitter empty.
  406.     jrz    coe$wait
  407. ; Ok, send the data out.
  408.     pop    psw
  409.     out    @data0
  410.     ret
  411. ;
  412. ;----------------------------------------------------------------
  413. ;         Console input
  414. ;----------------------------------------------------------------
  415. ;
  416. con$inp:
  417. cie:
  418.     call    clrwdt
  419.     in    @stat0
  420.     ani    rxmsk
  421.     jz    cie
  422.     in    @data0
  423.     ret                ; Done
  424. ;
  425. ;----------------------------------------------------------------
  426. ;         Console status
  427. ;----------------------------------------------------------------
  428. ;
  429. con$ist:
  430. cst:
  431.     call    clrwdt            ; Clear the dog
  432.     in    @stat0
  433.     ani    rxmsk
  434.     rz
  435.     mvi    a,0ffh
  436.     ret
  437. ;
  438. ;----------------------------------------------------------------
  439. ;         Hardware setups for the system chips.
  440. ;----------------------------------------------------------------
  441. ;
  442. initbl:
  443. ; Setup the dart A channel
  444.     db    01,@stat0,018h        ; Channel reset
  445.     db    02,@stat0,04,044h    ; X1 clock, 1 stop bit, parity OFF
  446.     db    02,@stat0,01,000h    ; Clear internal status
  447.     db    02,@stat0,03,0c1h    ; Rx 8 bit. Rx enable, auto enables OFF
  448.     db    02,@stat0,05,0eah    ; DTR, Tx 8 bit, Tx enable, RTS, DTR of
  449.     db    00
  450. ; 
  451. ; NOTE that the B channel is initialized in the AUX driver module used
  452. ; by the system. This makes sense as different system software may
  453. ; need different AUX drivers.
  454. ;
  455.     dseg
  456. ;
  457. bel$byt    db    00            ; Last bell port write
  458. led$byt    db    00            ; Last LED output byte
  459. wdt$flg    db    00            ; Dog flag bit 0
  460. ?time:    ds    8            ; Time buffer address
  461.     end
  462.  
  463.     
  464.  
  465. ;