home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / utils / asmutl / buffers.lbr / TEST3.MZC / TEST3.MAC
Encoding:
Text File  |  1987-01-14  |  3.3 KB  |  128 lines
  1. ; test buffers module. Copy file 1 to file 2
  2. ; This illustrates use of the .BFSWAP routine for single
  3. ; buffering, and fast file to file copying.
  4. ;
  5. ;   d>TEST3 [d[u]:]filename.typ [d[u]:]outname.typ
  6. ;        copies filename.typ to outname.typ
  7. ;        (with full du addressing, across users, drives)
  8. ; 
  9. ; SEE BUFFERS.DOC for linking instructions
  10. ;
  11. boot    equ    0
  12. tfcb    equ    boot+05ch
  13. defdma    equ    boot+080h
  14. ;
  15.     extrn    .dos, b.wflg
  16.     extrn    .bload, .bdump, .bfswap
  17.     extrn    .bfropen, .fopnw, .bfclose
  18.     extrn    .pfnmdu, .xltusr, .initfcb
  19. ;
  20. begin:    lhld    6;        set stack at top of memory
  21.     mvi    l,0
  22.     sphl
  23. ;    "    "
  24. ; apportion memory to two file buffers
  25.     lxi    d,-buffer-128;    128 byte stack/b.ohead allowance
  26.     dad    d;        form size of memory available
  27.     mov b,h    ! mov c,l;    will be rounded down to 128 byte unit
  28.     push    b;        save buffer size
  29. ;    "    "
  30. ; initialize fcbs
  31.     lxi    h,fcbin
  32.     call    .initfcb
  33.     lxi    h,fcbout
  34.     call    .initfcb
  35. ;    "    "
  36. ; mark end of command line, just in case.
  37. ; Done by most CCPs, but undocumented.  CCPLUS is documented
  38.     lxi    h,defdma
  39.     mov    a,m;        line length
  40.     inx    h
  41.     add    l
  42.     mov    l,a
  43.     adc    h
  44.     sub    l
  45.     mov    h,a
  46.     mvi    m,0;        mark eol
  47. ;    "    "
  48. ; parse the file names
  49.     lxi    d,defdma+1;    set command scanning pointer
  50.     lxi    h,fcbin
  51.     call    .pfnmdu;    will parse an empty line into
  52.     lda    fcbin+1;    a blank FCB.
  53.     cpi    ' ';        could use the open error instead, but
  54.     jz    nofile;          CPM can create a blank named file
  55.     mov    a,b;        designated user
  56.     call    .xltusr;    convert 0 into current, etc
  57.     sta    inuser
  58.     mov    a,b;        but bfropen needs original form
  59.     pop    b;        get buffer size back
  60.     push    d;        save input scan pointer
  61.     lxi    d,fcbin
  62.     lxi    h,buffer
  63.     call    .bfropen;    open buffered file for read
  64.     jc    error;        can't find it, abort
  65.     pop    d;        restore input scan pointer
  66.     lxi    h,fcbout
  67.     call    .pfnmdu
  68.     lda    fcbout+1
  69.     cpi    ' '
  70.     jz    noutfile
  71.     mov    a,b;        designated user
  72.     call    .xltusr;    convert to standard form
  73.     ori    b.wflg;        essential to flag correctly ** <<< **
  74.     sta    outuser;    save for future
  75.     lxi    d,fcbout
  76.     call    .fopnw;        open file for write
  77.     jc    createrr;    can't create file
  78. ;    "    "
  79. ; All files open, and buffers assigned.
  80. ; Copy fcbin to fcbout in largest possible blocks
  81. copy:    lxi    h,buffer
  82.     call    .bload;        fill the buffer
  83.     push    psw;        save carry for eof
  84.     lda    outuser
  85.     lxi    d,fcbout
  86.     call    .bfswap;    change to write
  87.     sta    inuser
  88.     call    .bdump;        write the buffer out
  89.     jc    outerr;        error occured
  90.     pop    psw;        saved eof above
  91.     jc    done
  92.     lda    inuser;        saved above
  93.     lxi    d,fcbin
  94.     call    .bfswap;    return to loading
  95.     sta    outuser;    save for next switch
  96.     jmp    copy;        not complete
  97. ;
  98. ; done, close output file. No need to fill, using full recds.
  99. done:    call    .bfclose
  100.     jnc    boot;        no close error
  101. ;    "    "
  102. ; all the errors simplified to one message
  103. outerr:
  104. createrr:
  105. error
  106. noutfile:
  107. nofile:    lxi    d,errmsg
  108.     mvi    a,9
  109.     call    .dos
  110.     jmp    boot
  111. ;
  112. errmsg:    db    'Some sort of error occured$'
  113. ;
  114. ;    ---------    Data Segment    --------
  115. ;    Link this AFTER all the code segments
  116. ;
  117.     dseg
  118. inuser:        ds    1;    user # for input file
  119. fcbin:        ds    36;    input file fcb
  120. outuser:    ds    1;    user # for output file
  121. fcbout:        ds    36;    output file fcb
  122. ;
  123. ; This must be the last program storage, see linking above.
  124. ; An alternative is to use a separate dseg file.
  125. buffer:        ds    0;    actually rest of memory
  126. ;
  127.     end
  128. √