home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / utils / asmutl / asmlib.lbr / TOKEN.AZM / TOKEN.ASM
Encoding:
Assembly Source File  |  1991-06-25  |  6.1 KB  |  201 lines
  1. ;----------------------------------------------------------------
  2. ;         This is a module in the ASMLIB library.
  3. ;
  4. ; This is the token processing module. It is responsible for
  5. ; all the token processing and contains the following code
  6. ;
  7. ; 1) DEFDEL    Define Token delimeters
  8. ; 2) GETTOK    Get a token from a string
  9. ; 3) TABSRC    Search a table for a token
  10. ;
  11. ;            Written        R.C.H.        22/10/83
  12. ;            Last Update    R.C.H.        01/11/83
  13. ;----------------------------------------------------------------
  14. ;
  15.     name    'token'
  16.     extrn    cmpstr,delstr
  17.     public    gettok,defdel,tabsrc
  18.     maclib    z80
  19. ;
  20. ;
  21. defdel:
  22.     sded    delims            ; Save the address of the delimeters
  23.     push    b
  24.     ldax    d            ; get size of the string
  25.     ora    a            ; return a zero if size = 0
  26.     pop    b
  27.     ret
  28. ;
  29. ; This is a major routine which must use the delimeter string to define
  30. ; where a token will end. If no delimeter then the token ends on a string
  31. ; boundary. If no delimeters then return a carry set to indicate an error.
  32. ; On entry DE -> string to extract a token from
  33. ;          HL -> Destination for the token
  34. ;           B -> maximum allowable length for a token.
  35. ;
  36. ; On exit carry set means error.
  37. ;   if destination count too small then carry returned
  38. ;   When a token is returned the delimeter that caused the return is
  39. ;    appended to the end of the string. This is always done.
  40. ;
  41. ; This module has been written with the aid of a pseudo code sketch.
  42. ;
  43. ;  start:
  44. ;       get size of input string
  45. ;        if zero then return
  46. ;       get length of delimeter string
  47. ;           if zero then return
  48. ;  main loop:
  49. ;    get a character 
  50. ;    load into destination string
  51. ;       check if a delimeter
  52. ;           if so thgen return no zer or carry
  53. ;       check if destination full
  54. ;           if so then return a carry
  55. ;       check if source empty.
  56. ;           if so then return a zero
  57. ;        goto main loop.
  58. ;
  59. ;
  60. gettok:
  61.     ldax    d
  62.     ora    a            ; is source string zero length ?
  63.     rz                ; exit with zero for end of job
  64.     shld    dst$adr            ; save destination string address
  65.     sded    src$adr            ; save source string address
  66.     mov    c,a            ; save the original length
  67.     sbcd    siz$str            ; save original size setups
  68. ;
  69. main1:    ; main loop. DE -> source, HL -> dest, B = dest size, C = source size
  70.     inx    d            ; point ot a character in the source
  71.     inx    h            ; point to next character in the dest
  72.     ldax    d            ; get a character
  73.     mov    m,a            ; save it
  74.     dcr    c            ; decrement the source size
  75.     dcr    b            ; decrement the dest size
  76. ; Check if the character was a delimeter.
  77.     call    chk$delim        ; check. return zero true if so
  78.     jrz    delim$end        ; delimetered end return
  79. ; Check if the source is empty. This is a valid return
  80.     mov    a,c
  81.     ora    a
  82.     jrz    delim$end        ; this is a delimetered end, cr did it
  83. ; check if the dest is full
  84.     mov    a,b
  85.     ora    a
  86.     jrz    end$dest        ; set carry to indicate the error
  87. ; All else means that we get another character
  88.     jmp    main1            ; keep on going
  89. ;
  90. ; Here and the destination went full prematurely so we signal the error
  91. ; and exit without saving any string lengths etc.
  92. ;
  93. end$dest:    ; end of destination buffer, signal an error
  94.     stc                ; set the carry flag
  95.     lhld    dst$adr
  96.     lded    src$adr
  97.     ret
  98. ;
  99. ; Here and the string was properly delimetered by either the source string end
  100. ; or there was a match with a token delimeter character. When this happens we 
  101. ; must change the string sizes in both the source and dest strings
  102. ;
  103. delim$end:
  104.     lded    siz$str            ; get original sizes into DE
  105.     mov    a,e            ; get original source string size
  106.     sub    c            ; take decremented size
  107.     lhld    dst$adr            ; get start address of dest string
  108.     mov    m,a            ; save size of the destination string
  109. ; 
  110.     mov    b,a            ; save a copy for the delete
  111.     mvi    c,1             ; start at character 1
  112.      lded    src$adr            ; start of source string
  113.     call    delstr            ; delete the substring
  114.     ret
  115. ;
  116. ; This routine returns a zero if the character in A matches a delimeter
  117. ; character in the delimeter string.
  118. ;
  119. chk$delim:
  120.     push    h            ; save
  121.     push    b            ; save maximum string length bytes
  122.     lhld    delims            ; get delimeter string address
  123.     mov    b,m            ; get string size
  124. chk$loop:                ; loop here checking bytes
  125.     inx    h            ; point to next delimeter
  126.     cmp    m
  127.     jrz    chk$match        ; matches a delimeter 
  128.     djnz    chk$loop        ; loop on
  129.     mvi    a,0ffh            ; ensure zero flag off
  130. ;
  131. ; If the following is jumped then the zero flag is not turned off
  132. ; and we return saying that there was a match therefore
  133. ;
  134.     ora    a
  135. chk$match:                ; jump here if a match, zero maintained
  136.     pop    b
  137.     pop    h            ; restore all
  138.     ret
  139. ;
  140. ;----------------------------------------------------------------
  141. ;     This routine must search a table of strings for a match with the
  142. ; input string. If it matches then a return is done with the carry
  143. ; off , zero off and A= index into the table where the match happened.
  144. ;     If there was no match then return with a zero in a and a zero flag.
  145. ;
  146. ; No entry DE -> string
  147. ;          HL -> table end of table has a string size of 00.
  148. ;
  149. ; Note that the routine assumes the table is in alpha order.
  150. ; This routine uses the external referenced compare routine
  151. ; 
  152. ;----------------------------------------------------------------
  153. ;
  154. tabsrc:
  155.     ldax    d            ; get source string length
  156.     ora    a
  157.     rz                ; return if a zero 
  158.     mvi    c,01            ; count strings checked.
  159.     shld    dst$adr            ; save table address
  160.     sded    src$adr            ; save string address
  161. ; Now we can check the strings.
  162. ; DE -> the source string
  163. ; HL -> table string
  164. tab$loop:
  165.     push    b
  166.     call    cmpstr            ; compare them
  167.     pop    b
  168.      mov    a,c
  169.     rz                ; exit with a = number checked if =
  170. ; If no carry then the table string > source string so error exit
  171.     jrc    err$exit
  172. ; Else we must index to the next string in the table
  173.     lhld    dst$adr            ; get start of the string
  174.     mov    e,m
  175.     mvi    d,00            ; make an index
  176.     dad    d            ; point to next string
  177.     inx    h            ; make up for counter byte
  178.     mov    a,m            ; is table length = 0
  179.     ora    a
  180.     rz    
  181.     shld    dst$adr            ; save it
  182.     lded    src$adr            ; get address of string again
  183.     inr    c
  184.     jr    tab$loop
  185. ;
  186. ;
  187. err$exit:
  188.     xra    a            ; indicate a not found string
  189.     stc
  190.     ret
  191. ;
  192.     dseg
  193. delims:    db    00,00        ; initialize to zero for checking
  194. src$adr    db    00,00        ; source string address
  195. dst$adr    db    00,00        ; destination string address
  196. siz$str    db    00,00        ; original string setup sizes
  197.     end
  198.  
  199.  
  200.  
  201.