home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / utils / asmutl / asmlib.lbr / SMEPLI.AZM / SMEPLI.ASM
Encoding:
Assembly Source File  |  1991-06-25  |  9.3 KB  |  337 lines
  1. ;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  2. ; This is a library of routines for interfacing to PL/I-80
  3. ; which supports some added features due to SME Systems hardware 
  4. ; and some other nifty things.
  5. ;
  6. ; This version contains....
  7. ;
  8. ; INITRND    Initialize a random number seed
  9. ; RAND16    Return a random number +-32k in size
  10. ; RANDP16    Return a positive random number 0..32k
  11. ; RAND8        Return an 8 bit number +-127
  12. ; CLKRD        Read the real time clock on SBC-800 into ram
  13. ; CONIN        Return a character from the console
  14. ; CONST        Return the console status
  15. ;
  16. ;    Extended and patchable screen functions.
  17. ;
  18. ; CLEAR        Erase the screen
  19. ; CLEOL        Clear to end of line
  20. ; CLEOP        Clear to end of page
  21. ; SETXY        Position cursor to X, Y co-ords
  22. ; SETREV    Initialize reverse video
  23. ; SETUND    Initialize underlined characters
  24. ; SETHLF    Initialize half intensity characters
  25. ; SETBLK    Initialize blinking characters
  26. ; CLRATT    Clear the current attribute
  27. ; CURON        Enale the cursor
  28. ; CUROFF    Disable the cursor
  29. ;
  30. ;
  31. ; For full documentation on this lot, see SMEPLI DOCUMENTATION which
  32. ; contains examples etc. (if you are lucky)
  33. ;
  34. ;            Written        R.C.H.         26/10/83
  35. ;                      Last Update    R.C.H.           28/11/83
  36. ;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  37. ;
  38.     name    'SMEPLI'
  39.     maclib    z80
  40.     public    conin,const,initrnd,randp16,rand16
  41.     public    rand8,clkrd
  42. ;
  43. ;
  44. bdos    equ    5
  45. ;
  46. ;----------------------------------------------------------------
  47. ;           CONIN - Get a character from the console
  48. ; 
  49. ; This function returns the first character typed on the keyboard.
  50. ; The character is returned as char(1) to PL/I.
  51. ;
  52. ; This function uses the bdos function 10 to return the character 
  53. ; which is not echoed as it is received. This is l;eft to the user.
  54. ;----------------------------------------------------------------
  55. ;
  56. conin:
  57.     call    cst
  58.     jrz    conin            ; wait for a character
  59. ; Now do a direct bdos call for the character
  60. conin1:
  61.     mvi    e,0ffh            ; get character routine
  62.     mvi    c,06            ; direct console i/o
  63.     call    bdos            ; character is in A now
  64.     ora    a
  65.     jrz    conin1            ; if no character, wait for it
  66. ; Now load the character onto PL/I's stack
  67.     pop    h            ; drop off return address
  68.     push    psw            ; put the character onto it
  69.     inx    sp            ; bump stack
  70.     mvi    a,1            ; characters on stack = 1
  71.     pchl                ; trick return
  72. ;
  73. ;----------------------------------------------------------------
  74. ;             CONST - Get the console status. 
  75. ;
  76. ; If a character is ready then the return is a true flag else
  77. ; a false flag is returned. This function uses the bdos function 
  78. ; 10 to detect if the character is there.
  79. ;----------------------------------------------------------------
  80. ;
  81. const:
  82.     call    cst            ; get the status 
  83.     ora    a            ; zero ?
  84.     rz                ; return if so
  85.     mvi    a,0ffh            ; clean true value
  86.     ret                ; if not then make it positively so
  87. ;
  88. ; The following code merely uses bdos function 11 to return the console
  89. ; status.
  90. ;
  91. cst:    
  92.     push    h
  93.     push    b
  94.     push    d
  95.     mvi    c,11            ; get console status fumction
  96.     call    bdos
  97.     pop    d
  98.     pop    b
  99.     pop    h
  100.     ora    a            ; Set the flag 00 = not ready
  101.     ret
  102. ;
  103. ;----------------------------------------------------------------
  104. ;         CLKRD - Read the real time clock
  105. ;
  106. ; This function uses the SBC-800 real time clock to return the 
  107. ; time into a piece of memory that may be either bit(8) or bin(7)
  108. ; or whatever. I like using a structure laid out with
  109. ; fileds called year,month,day,dow,hour,minute,second declared as
  110. ; bit(8) or bin(7) where appropriate.
  111. ;
  112. ; The following equates specify the port addresses of the real time clock
  113. ; chip and interface. The clock chip is an OKI 5832 and the interface 
  114. ; is an intel 8255.
  115. ;
  116. ; HACKERS - The following is a particularly nasty piece of code
  117. ;            which holds the OKI 5832 clock chip and reads all the 
  118. ;            internal registers. If running at 6Mhz then the timing loops
  119. ;            for the hold times may need expanding out to suit.
  120. ;
  121. ;----------------------------------------------------------------
  122. ;
  123. ;Clock and centronics ports on the sbc-800
  124. ;
  125. pp0a    equ    84h            ; Port a 0
  126. pp0b    equ    pp0a+1            ; Port b 0
  127. pp0c    equ    pp0a+2            ; Port c 0
  128. pp0d    equ    pp0a+3            ; Control port 0
  129. ;
  130. ;    I/O lines and part of clock strobe
  131. ;
  132. pp1a    equ    80h            ; Port a 1
  133. pp1b    equ    pp1a+1            ; Port b 1
  134. pp1c    equ    pp1a+2            ; Port c 1
  135. pp1d    equ    pp1a+3            ; Control port 1
  136. ;
  137. ;****************************************************************
  138. ;*        Read Real Time Clock to memory            *
  139. ;*        pointed by DE, and stored as follows        *
  140. ;*                                *
  141. ;*    hl+0 =>    years    1 byte 2 digit bcd            *
  142. ;*      +1 => months  1 byte 2 digit bcd            *
  143. ;*      +2 => days    1 byte 2 digit bcd            *
  144. ;*      +3 => dweek    1 byte 1 digit bcd ** low nibble only ***
  145. ;*      +4 => hours   1 byte 2 digit bcd            *
  146. ;*      +5 => minutes 1 byte 2 digit bcd            *
  147. ;*      +6 => seconds 1 byte 2 digit bcd            *
  148. ;*                                *
  149. ;****************************************************************
  150. ;
  151. ; Note that the user passes a POINTER to this function which then
  152. ; writes the bytes to the address for 7 bytes. Use carefully, it is
  153. ; a good routine to corrupt memory if poorly used.
  154. ;
  155. clkrd:    ; Read clock into memory at DE 
  156.     call    getp2             ; return the address in de
  157.     xchg                ; put into hl
  158. ;
  159. ; Here try to hold the clock chip for 150 us. 
  160.     mvi    a,00001101b        ; Hld bit
  161.     out    pp0d            ; Set bit
  162. ; Now load a counter for a 150 us delay.
  163.     mvi    b,120            ; 7 T
  164. ;
  165. hld$wait:
  166.     djnz    hld$wait        ; 8/10 T
  167. ;
  168.     out    pp1d            ; this is the read bit load
  169. ; Loop to read all registers in one go
  170.     mvi    b,12            ; register count
  171. rclk1:
  172.     call    get$reg
  173.     mov    a,b
  174.     cpi    6            ; Was it day of week
  175.     jrz    rclk2            ; Skip second register if so
  176.     dcr    b            ; Next register
  177.     call    get$reg            ; read the register
  178. rclk2:    ; Jump here after reading day of week
  179.     inx    h            ; next byte in ram to rotate into
  180.     dcr    b            ; register number
  181.     xra    a
  182.     ora    b            ; set the minus flag
  183.     jp    rclk1
  184. ; restore the port bits
  185.            mvi    a,00001100b        ; Reset bit 6
  186.     out    pp0d
  187.     out    pp1d               ; Clear hold+read
  188.     ret
  189. ;
  190. get$reg:    ; Read register in B into memory with an RLD
  191.     mov    a,b
  192.     out    pp0b
  193.     mvi    a,8
  194. rdreg1:    ; This loop is needed for a 6 us delay for reading the register
  195.     dcr    a
  196.     jrnz    rdreg1            ; another wait of 15 us or better
  197.     in    pp0a
  198.     ani    15            ; Get data
  199.     rld                ; Saved in memory
  200.     ret
  201. ;
  202. ;----------------------------------------------------------------
  203. ;         RANDOM NUMBER ROUTINES
  204. ;
  205. ; These routines intialize/return random numbers. The user must
  206. ; feed these routines a string of bytes (5 minimum) which are used as
  207. ; a seed. The initialization uses the Z-80 refresh register as a
  208. ; jumble function of these bytes.
  209. ;
  210. ;         This is a module in the ASMLIB Library.
  211. ;
  212. ; This module generates PSEUDO RANDOM NUMBERS by using a seed array
  213. ; and doing adds and shifts on the bytes in the array. 
  214. ;
  215. ;----------------------------------------------------------------
  216. ;
  217. initrnd:    ; initialize the random number seed string pointed to
  218.     call    getp2        ; get the pointer to the string
  219.     ldax    d        ; get the string size
  220.     cpi    5
  221.     rc            ; Error if less than 5 elements in the array
  222.     push    d
  223.     push    b
  224.     mov    b,a        ; Load counter
  225.     xchg
  226.     inx    h        ; Now HL -> first seed byte
  227.     ldar            ; Get refresh register value
  228.     dcr    b        ; Do one less than the required
  229. initloop:
  230.     add    m
  231.     rrc
  232.     mov    m,a
  233.     inr    m
  234.     mov    a,m
  235.     inx    h
  236.     djnz    initloop
  237. ; Restore and exit gracefully
  238.     xchg            ; Restore HL
  239.     pop    b
  240.     pop    d        ; Restore other registers
  241.     ret
  242. ;
  243. ; Return an 8 bit random number in A
  244. ;
  245. rand8:    
  246.     call    getp2        ; get the strings address
  247. rand81:
  248.     ldax    d        ; A = number of seeds
  249.     cpi    5        ; Check if less than 5 seed values
  250.     rc            ; Return with a carry to indicate an error
  251. ; Here we load the number of cells into B then decrtement so as to skip
  252. ; these which are operated on later.
  253.     push    b
  254.     push    d        ; Saver address of seed array
  255.     mov    b,a
  256.     dcr    b
  257.     dcr    b
  258.     inx    d        ; DE -> first seed in the array
  259.     xchg            ; Put memory pointer into HL
  260. ;
  261. ;Loop for N-2 times.
  262. loop:    inr    m        ;INCREMENT SEED VALUE.
  263.     mov    a,m
  264.     inx    h        ;HL POINTS TO NEXT SEED VALUE IN ARRAY.
  265.     add    m
  266.     rrc            ;ROTATE RIGHT CIRCULAR ACCUMULATOR.
  267.     mov    m,a
  268.     djnz    loop
  269. ;
  270. ; Last iteration to compute random byte in register a.
  271.     inx    h         ; HL -> last byte in the array
  272.     add    m
  273.     cma            ; complement the accumulator
  274.     rrc            ; rotate it right
  275.     mov    m,a
  276.     xra    a        ; Clear carry
  277.     mov    a,m        ; Re-load value, carry not set.
  278. ;
  279. ; Restore the registers and return with the value in A
  280. error:    
  281.     xchg            ; Restore HL
  282.     pop    d
  283.     pop    b
  284.     ret
  285. ;
  286. ; Return a 16 bit random number in HL.
  287. ;
  288. rand16:
  289.     call    getp2        ; get string address
  290.     push    d
  291.     call    rand81
  292.     mov    h,a        ; msb byte
  293.     pop    d        ; restore string address
  294.     call    rand81
  295.     mov    l,a        ; lsb byte
  296.     ret
  297. ;
  298. ; Return a positive 16 bit random number
  299. ;
  300. randp16:
  301.     call    rand16        ; get the number
  302.     mov    a,h
  303.     ani    07fh        ; Mask off top bit
  304.     mov    h,a        ; restore
  305.     mov    a,l        ; echo lsb in a
  306.     ret
  307. ;
  308. getp1:
  309.     mov    e,m
  310.     inx    h
  311.     mov    d,m
  312.     xchg
  313.     mov    e,m
  314.     ret
  315. ;
  316. ;
  317. getp2:
  318.     call    getp1
  319.     inx    h
  320.     mov    d,m
  321.     ret
  322. ;
  323. ;----------------------------------------------------------------
  324. ;         Screen Based Functions.....
  325. ;
  326. ; These are taken from the ASMLIB source code modules and as such are
  327. ; patchable to suit a termial in use by using the SETUP.COM program
  328. ; to write the correct terminal driver into the code patch area.
  329. ;----------------------------------------------------------------
  330.  
  331.  
  332.  
  333.     end
  334.  
  335.  
  336.  
  337.