home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / utils / asmutl / asmlib.lbr / RANDOM.AZM / RANDOM.ASM
Encoding:
Assembly Source File  |  1991-06-25  |  2.4 KB  |  114 lines
  1. ;----------------------------------------------------------------
  2. ;         This is a module in the ASMLIB Library.
  3. ;
  4. ; This module generates PSEUDO RANDOM NUMBERS by using a seed array
  5. ; and doing adds and shifts on the bytes in the array. The returned
  6. ; value from the function is in the accumulator.
  7. ;
  8. ; The entry points are as follows.
  9. ;
  10. ; 
  11. ;
  12. ; randinit
  13. ; rand8
  14. ; rand16
  15. ; randp16
  16. ;
  17. ;            Written        R.C.H.         12/10/83
  18. ;            Last Update     R.C.H.         13/10/83
  19. ;----------------------------------------------------------------
  20. ;
  21.     name    'random'
  22.     public    rand8,rand16,randp16,randinit
  23.     maclib    z80
  24. ;
  25. randinit:
  26.     ldax    d
  27.     cpi    5
  28.     rc            ; Error if less than 5 elements in the array
  29.     push    d
  30.     push    b
  31.     mov    b,a        ; Load counter
  32.     xchg
  33.     inx    h        ; Now HL -> first seed byte
  34.     ldar            ; Get refresh register value
  35.     dcr    b        ; Do one less than the required
  36. initloop:
  37.     add    m
  38.     rrc
  39.     mov    m,a
  40.     inr    m
  41.     mov    a,m
  42.     inx    h
  43.     djnz    initloop
  44. ; Restore and exit gracefully
  45.     xchg            ; Restore HL
  46.     pop    b
  47.     pop    d        ; Restore other registers
  48.     ret
  49. ;
  50. ; Return an 8 bit random number in A
  51. ;
  52. rand8:    
  53.     ldax    d        ; A = number of seeds
  54.     cpi    5        ; Check if less than 5 seed values
  55.     rc            ; Return with a carry to indicate an error
  56. ; Here we load the number of cells into B then decrtement so as to skip
  57. ; these which are operated on later.
  58.     push    b
  59.     push    d        ; Saver address of seed array
  60.     mov    b,a
  61.     dcr    b
  62.     dcr    b
  63.     inx    d        ; DE -> first seed in the array
  64.     xchg            ; Put memory pointer into HL
  65. ;
  66. ;Loop for N-2 times.
  67. loop:    inr    m        ;INCREMENT SEED VALUE.
  68.     mov    a,m
  69.     inx    h        ;HL POINTS TO NEXT SEED VALUE IN ARRAY.
  70.     add    m
  71.     rrc            ;ROTATE RIGHT CIRCULAR ACCUMULATOR.
  72.     mov    m,a
  73.     djnz    loop
  74. ;
  75. ; Last iteration to compute random byte in register a.
  76.     inx    h         ; HL -> last byte in the array
  77.     add    m
  78.     cma            ; complement the accumulator
  79.     rrc            ; rotate it right
  80.     mov    m,a
  81.     xra    a        ; Clear carry
  82.     mov    a,m        ; Re-load value, carry not set.
  83. ;
  84. ; Restore the registers and return with the value in A
  85. ERROR:    
  86.     xchg            ; Restore HL
  87.     pop    d
  88.     pop    b
  89.     ret
  90. ;
  91. ; Return a 16 bit random number in HL.
  92. ;
  93. rand16:
  94.     call    rand8
  95.     mov    h,a        ; msb byte
  96.     call    rand8
  97.     mov    l,a        ; lsb byte
  98.     ret
  99. ;
  100. ; Return a positive 16 bit random number
  101. ;
  102. randp16:
  103.     call    rand16
  104.     mov    a,h
  105.     ani    07fh        ; Mask off top bit
  106.     mov    h,a        ; restore
  107.     mov    a,l        ; echo lsb in a
  108.     ret
  109. ;
  110.     end
  111.  
  112.  
  113.  
  114.