home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / rcpm / message.asm < prev    next >
Encoding:
Assembly Source File  |  1994-07-13  |  2.8 KB  |  88 lines
  1. ;
  2. ; MESSAGE.ASM - ASCII message typing program for CP/M.
  3. ;
  4. ; Written 7/24/84 by Al Jewer and released in the public domain.
  5. ;
  6. ; Copyright (c) 1984 Al Jewer.
  7. ;
  8. ; THIS PROGRAM MUST NOT BE SOLD !!!!!!!!!!
  9. ;
  10. ; This file is intended to be used on CP/M systems to generate
  11. ; messages in response to typed commands. That is, suppose you
  12. ; run an RCPM system, and would like people to know that they
  13. ; can use TYPE instead of TYPESQ. This file can be edited to 
  14. ; contain a message such as: 
  15. ;      TYPESQ no longer needed.... use TYPE instead.
  16. ;
  17. ; The unique thing about this file is that it contains ONLY ASCII
  18. ; characters... that is, the assembled .COM file can be copied
  19. ; with, say, WORDSTAR in non-document mode, and the new message
  20. ; inserted starting on the second line, and terminated with a 
  21. ; dollar-sign character. The resultant file can then be run 
  22. ; directly, WITHOUT assembly or loading! 
  23. ; You only need a text editor to create a message file!
  24. ; 
  25. ; This is probably the wildest code I've ever written - if you
  26. ; can't follow it, don't worry! 
  27. ; Trust me, it works.
  28. ;
  29. ; Keep in mind that you really don't need the source code, just 
  30. ; the .COM file in order to create MESSAGE files.
  31. ;
  32.     ORG    100H        ; CP/M STARTING ADDRESS
  33. ;
  34. START:    DAD H            ;GET 0 IN THE L REGISTER
  35.     DAD H
  36.     DAD H
  37.     DAD H
  38.     DAD H    
  39.     DAD H
  40.     DAD H
  41.     DAD H
  42.     MOV H,L            ;ZERO THE HI BYTE OF HL PAIR
  43.     MOV D,L            ;ZERO HI BYTE OF DE PAIR
  44.     INR L            ;GET A 1
  45.     DAD H            ;SHIFT LEFT 2
  46.     DAD H
  47.     INR L            ;SHIFT IN ANOTHER 1
  48.     DAD H
  49.     INR L            ;AND ANOTHER
  50.     DAD H            ;FINAL SHIFT GIVES US 16H IN L
  51.     MOV A,L            ;GET VALUE TO A
  52.     CMA            ;THIS GIVES US 0E9H IN A REGISTER 
  53.                 ; (THIS IS A PCHL INSTRUCTION)
  54.     MOV L,H            ;RE-ZERO THE HL PAIR
  55.     INR L            ;GET A 1
  56.     MOV B,L            ;SAVE THE 1 IN THE B REGISTER
  57.     DAD H            ;GET A 5
  58.     DAD H
  59.     INR L
  60.     MOV E,L            ;SAVE THE 5 IN THE E REGISTER
  61.     DCR L            ;GET A 9
  62.     DAD H
  63.     INR L
  64.     MOV C,L            ;GET FUNCTION CODE (9) TO C REGISTER
  65.     MOV H,B            ;GET HI BYTE OF MESSAGE ADDRESS TO H
  66.     MVI L,(ADDRESS AND 0FFH) ;POINT TO OUR PCHL ADDRESS (THIS WILL
  67.                 ;BE AN OFFSET LARGER THAN 20H AND SMALLER
  68.                 ;THAN 7FH, THEREFORE AN ASCII CODE
  69.     MOV M,A            ;MOVE PCHL INSTRUCTION TO RAM
  70.     INR L            ;POINT PAST PCHL TO START OF MESSAGE
  71.     INR L            ;ALSO PAST INITIAL CRLF
  72.     INR L
  73.     MOV A,L            ;SWAP HL & DE (DE MUST POINT TO MESSAGE,
  74.                 ;HL MUST POINT TO LOCATION 5)
  75.     MOV B,H
  76.     MOV L,E
  77.     MOV H,D
  78.     MOV D,B    
  79.     MOV E,A
  80. ADDRESS: DB 'X'            ;THIS WILL BE CHANGED TO A PCHL
  81.     DB 0DH, 0AH        ;INITIAL CRLF
  82.     DB 'This is where the message goes', 0DH, 0AH
  83.     DB 'Make sure you end the message with a dollar-sign!', 0DH, 0AH
  84.     DB '$'            ;MESSAGE TERMINATOR
  85.     DB 'Z'-40H        ;ASCII END OF FILE
  86. ;
  87.     END    START
  88.