home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / modems / xmodem / xm82oscp.asm < prev    next >
Encoding:
Assembly Source File  |  1994-07-13  |  7.4 KB  |  254 lines
  1. ;XM82OSCP.ASM - XMODEMxx PATCH FILE FOR Osborne MODEM  01/16/84
  2. ;
  3. ; This is adapted from Irv Hoff's XMEX-1.ASM dated 11/17/83
  4. ;
  5. ;        by John Riehl 1-713-644-7070 days
  6. ;                  1-713-488-1257 evenings    
  7. ;
  8. ; This file adapts XMODEMxx to the Osborne 01 with the
  9. ; Osborne COMM-PAC modem. To use, first edit any options desired into
  10. ; XMODEMxx.ASM, then assemble (can use ASM.COM) and load which supplies
  11. ; XMODEMxx.COM.  Then edit this file as needed (check the CONOUT routine
  12. ; if you want to locally see file transfer time and the record count
  13. ; while programs are being sent).  Then assemble (can use ASM.COM) and
  14. ; merge via DDT or SID:
  15. ;
  16. ;    B>DDT XMODEMxx.COM
  17. ;    DDT VERS 2.2
  18. ;    NEXT  PC
  19. ;    1180 0100
  20. ;    -IXM82OSCP.HEX        (note the 'I' command)
  21. ;    -R            ('R' loads in the .HEX file)
  22. ;    NEXT  PC
  23. ;    1180 0000
  24. ;    -G0            (return to CP/M)
  25. ;    B>SAVE 17 XMODEMxx.COM  (now have a modified .COM file)
  26. ;
  27. ; NOTE: Save 22 (rather than 17) if LOGCAL is YES
  28. ;
  29. ;=======================================================================
  30. ;
  31. ; 01/16/84 - Original version adapted from XMEX-1.ASM by Irv Hoff
  32. ;                    John Riehl    
  33. ;
  34. ;=======================================================================
  35. ; 
  36. YES:    EQU    0FFH
  37. NO:    EQU    0
  38. ;
  39. ;=======================================================================
  40. ;
  41. ; The following options must be set as shown in XMODEM82:
  42. ;
  43. ; LARGEIO:    EQU    YES
  44. ; LARSIZE:    EQU    0B0H
  45. ;
  46. ; USECON:    EQU    NO    ;if you are using this XMODEM with BYE3
  47. ;
  48. ; Only one of the following can be yes and the others no
  49. ;
  50. BIOS13:    EQU    NO    ;yes = Osborne uses BIOS 1.3
  51. BIOS14: EQU    YES    ;yes = Osborne uses BIOS 1.4 or 1.41
  52. BIOS144:EQU    NO    ;yes = Osborne uses BIOS 1.44+ 
  53.             ;      (Nuevos Electronics 80 column mod.)
  54. ;
  55. ; If you have none of the above you have to use DDT to find out
  56. ; where the 5th JMP instruction in your BIOS jumps to and use it
  57. ; for the JMP at 103H. Set all three equates above to NO
  58. ;
  59. ;=======================================================================
  60. ;
  61. MODDATP: EQU    2A01H        ;data in port
  62. MODDATO: EQU    MODDATP        ;data out port
  63. MODCTLP: EQU    MODDATP-1    ;control/status port
  64. MODSNDB: EQU    2        ;bit to test for send
  65. MODSNDR: EQU    2        ;value when ready
  66. MODRCVB: EQU    1        ;bit to test for receive
  67. MODRCVR: EQU    1        ;value when ready
  68. MODDCDB: EQU    4        ;carrier detect bit
  69. MODDCDA: EQU    4        ;value when active
  70. MODPARE: EQU    40H        ;value for parity error
  71. MODOVRE: EQU    10H        ;value for overrun error
  72. MODFRME: EQU    20H        ;value for framing error
  73. ;
  74.  
  75. LSPEED:    EQU    YES        ;yes if using 'BYE' with speed selection
  76.                 ;no if using 'SPEED' manual selection
  77. MSPEED:    EQU    3CH        ;location of baud rate factor (set by
  78.                 ;'BYE')  set location in 'BYE' to agree.
  79.                 ;3dh and 3eh often used by newer ver-
  80.                 ;sions of 'ZCPR'.
  81. XSPEED:    EQU    1        ;speed for file time transfer without
  82.                 ;auto-set.  use one of the following:
  83.                 ;0=110 1=300 2=450 3=600 4=710 5=1200
  84. BASE:    EQU    100H        ;start of cp/m normal program area
  85. ;
  86. ;-------------------------------------------------------------------
  87. ;
  88. ; Jump table: The jump table must be in exactly the same sequence as the
  89. ; one in XMODEM.  Note the ORG of 103H - This jump table has no jump to
  90. ; 'BEGIN'.
  91. ;
  92. ;
  93.      ORG    BASE+3        ;start after 'JMP BEGIN'
  94. ;
  95. CONOUT:      IF    BIOS13
  96.      JMP    0E915H        ;BIOS 1.3 console output routine
  97.       ENDIF            ;BIOS13
  98. ;
  99.       IF    BIOS14
  100.      JMP    0E738CH        ;BIOS 1.4 console output routine
  101.       ENDIF            ;BIOS14
  102. ;
  103.       IF    BIOS144        ;BIOS 1.44+ console output routine
  104.      JMP    0E749H
  105.       ENDIF            ;BIOS144
  106. ;
  107.       IF (NOT BIOS13) AND (NOT BIOS14) AND (NOT BIOS144)
  108.      JMP    0000H        ;put your BIOS console out jump address here
  109.       ENDIF        ;(NOT BIOS13) AND (NOT BIOS14) AND (NOT BIOS144)
  110. ;
  111. ;
  112. PMINIT:     JMP    MINIT        ;initialization routine (if needed)
  113. PUNINIT: RET ! NOP ! NOP    ;not required
  114. PSENDR:     JMP    SENDR        ;send character (via pop psw)
  115. PCAROK:     JMP    CAROK        ;test for carrier
  116. PMDIN:     JMP    MDIN        ;receive data byte
  117. PGETCHR: JMP    GETCHR        ;get character from modem
  118. PRCVRDY: JMP    RCVRDY        ;check receive ready
  119. PSNDRDY: JMP    SNDRDY        ;check send ready
  120. PSPEED:     JMP    SPEED        ;get speed value for file transfer time
  121. POSTAT:  JMP    OSTAT        ;get I/O status
  122. PEXTRA1: RET ! NOP ! NOP    ;extra for custom routine
  123. PEXTRA2: RET ! NOP ! NOP    ;extra for custom routine
  124. ;
  125. ;=======================================================================
  126. ;
  127. ; ---> CAROK - check for presence of carrier.  RET with Z = carrier on
  128. ;
  129. CAROK:    CALL    POSTAT        ;get status
  130.     ANI    MODDCDB        ;get carrier detect bit
  131.     PUSH    PSW
  132.     CNZ    MDIN
  133.     POP    PSW
  134.     RET
  135. ;
  136. ;=======================================================================
  137. ;
  138. ; ---> GETCHR - - initialize if not already done, then get character
  139. ; ---> MDIN - - get a character
  140. ;
  141. GETCHR:    CALL    MINIT
  142. MDIN:    JMP    OSIN        ;get character from data in port
  143. ;
  144. ;=======================================================================
  145. ;
  146. ; This is the Osborne initialization routine which is required
  147. ; to relocate the memory mapped above 4000H.
  148. ;
  149. INITFLG:  DB    0        ;initialization flag
  150. ;    
  151. MINIT:      LDA    INITFLG        ;have we been here before?
  152.       ORA    A
  153.       RNZ            ;if yes, exit
  154.       INR    A
  155.       STA    INITFLG
  156.       PUSH    B
  157.       PUSH    D
  158.       PUSH    H
  159.       LXI    H,OSIN        ;get address of first byte to move
  160.       LXI    D,0A000H    ;get place to put first byte
  161.       LXI    B,RCVRDY-OSIN    ;get length of code to move
  162.       DB    0EDH,0B0H    ;Z80 LDIR
  163. ;
  164.       LXI    H,0A000H    ;get new address of OSIN
  165.       SHLD    MDIN+1        ;PATCH CALL FOR "GET CHAR." ROUTINE
  166.       LXI    H,0A000H+OSOUT-OSIN
  167.       SHLD    SENDR+2        ;PATCH CALL FOR "SEND CHAR." ROUTINE
  168.       LXI    H,0A000H+OSTAT-OSIN
  169.       SHLD    POSTAT+1    ;PATCH CALL FOR "GET STATUS" ROUTINE
  170.       POP    H
  171.       POP    D
  172.       POP    B
  173.       RET
  174. ;
  175. ;
  176. ; --- Routines that get placed just under 'BYE' ---
  177. ;
  178. OSIN:    DI            ;DISABLE INTERRUPTS
  179.     OUT    0        ;SWITCH TO ALTERNATE PAGE
  180.     LDA    MODDATP        ;GET DATA BYTE
  181.     OUT    1        ;SWITCH PAGES BACK
  182.     EI            ;RE-ENABLE INTERRUPTS
  183.     RET
  184. ;.....
  185. ;
  186. ;
  187. OSOUT:    DI            ;DISABLE INTERRUPTS
  188.     OUT    0        ;SWITDH TO ALTERNATE PAGE
  189.     STA    MODDATO        ;SEND DATA BYTE
  190.     OUT    1        ;SWITCH PAGES BACK
  191.     EI            ;RE-ENABLE INTERRUPTS
  192.     RET
  193. ;.....
  194. ;
  195. ;
  196. OSTAT:    DI            ;DISABLE INTERRUPTS
  197.     OUT    0        ;SWITCH TO ALTERNATE PAGE
  198.     LDA    MODCTLP        ;GET STATUS BYTE
  199.     OUT    1        ;SWITCH PAGES BACK
  200.     EI            ;RE-ENABLE INTERRUPTS
  201.     RET
  202. ;
  203. ;
  204. ;=======================================================================
  205. ;
  206. ; ---> RCVRDY - check receive ready.  RET with Z = character available.
  207. ;            Return with error code in A-reg.
  208. ;
  209. RCVRDY:    CALL    POSTAT        ;get modem status
  210.     PUSH    B        ;save scratch register
  211.     PUSH    PSW        ;check error status
  212.     ANI    MODFRME+MODOVRE
  213.     MOV    B,A        ;save it for a moment
  214.     POP    PSW
  215.     ANI    MODRCVB        ;isolate ready bit
  216.     CPI    MODRCVR        ;test it
  217.     MOV    A,B        ;get the error code char. back
  218.     POP    B
  219.     RET
  220. ;
  221. ;=======================================================================
  222. ;
  223. ; ---> SENDR - send character
  224. ;
  225. SENDR:    POP    PSW        ;get the character back
  226.     JMP    OSOUT        ;send it to the modem output
  227. ;
  228. ;=======================================================================
  229. ;
  230. ; ---> SNDRDY - check if ready to send.
  231. ;
  232. SNDRDY:    CALL    POSTAT        ;get status byte
  233.     ANI    MODSNDB        ;isolate ready bit
  234.     CPI    MODSNDR        ;ready to send?
  235.     RET
  236. ;
  237. ;=======================================================================
  238. ;
  239. ; ---> SPEED - sets the time shown for program transfer.
  240. ;
  241. SPEED:     IF    LSPEED
  242.     LDA    MSPEED        ;get index for baud rate from 'BYE'
  243.      ENDIF
  244. ;
  245.      IF     NOT LSPEED
  246.     MVI    A,XSPEED    ;get index for baud rate from 'XSPEED'
  247.      ENDIF
  248. ;
  249.     RET
  250. ;
  251. ;=======================================================================
  252. ;
  253.     END
  254.