home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / database / dims103.ark / DGET.ASC < prev    next >
Encoding:
Text File  |  1986-12-07  |  4.5 KB  |  174 lines
  1. 10 PRINT"This program must be entered via DIMS
  2. 20 STOP
  3. 1000 GOSUB 1890 'cs
  4. 1010 PRINT:PRINT TAB(29);"DGET 1.03 - October 30, 1983
  5. 1020 ' by Dan Dugan -- public domain
  6. 1030 PRINT
  7. 1040 DEFINT A-Z
  8. 1050 COMMON I,J,K,X,Y,T$,R$,S$,T1$,SKIPPARSE,FT,SEARCH,
  9.  
  10.     C,N,NC,P6,P7,P8,P9,PI,S,T,T1,T2,C(),B$(),N$(),
  11.  
  12.     SEARCHWORD$(),SEARCHFIELD(),SKIPWORD$(),LOOKFIELD(),DD$(),F$,FT$
  13. 1060 DIM DEST(30),USED(30),B1$(30):INREC=0
  14. 1070 '
  15.  
  16.  
  17.                 OPEN SOURCE FILE
  18.  
  19.  
  20. 1080 PRINT:INPUT"Name of source file";X$
  21. 1085 IF X$="" THEN 1820
  22. 1090 GOSUB 1920:F2$=Y$        'ucv
  23. 1100 IF MID$(F2$,2,1)=":" THEN 1120
  24. 1110 F2$=DD$(5)+F2$
  25. 1120 '
  26.  
  27.  
  28.         TEST FOR EXISTENCE
  29.  
  30.  
  31. 1130 ON ERROR GOTO 1160
  32. 1140    OPEN"I",3,F2$
  33. 1150    ON ERROR GOTO 0:GOTO 1200    'ok
  34. 1160 CLOSE 3
  35. 1170 IF ERR=53 THEN CLOSE 3:PRINT"File not found":RESUME 1070
  36. 1180 IF ERR=64 THEN PRINT"Bad file name, try again.":RESUME 1070
  37. 1190 ON ERROR GOTO 0
  38. 1200 '
  39.  
  40.  
  41.                 ENTER SEQUENCE OF FIELDS
  42.  
  43.  
  44. 1210 PRINT:PRINT"Here's the first line of "F2$".
  45. 1220 LINE INPUT#3,T$
  46. 1230 PRINT:PRINT T$
  47. 1240 CLOSE 3:OPEN"I",3,F2$
  48. 1250 PRINT:PRINT"Would you like to re-assign or skip fields? (n/y) ";:A$=INPUT$(1)
  49. 1252 IF A$="y" OR A$="Y" THEN 1260 ELSE FOR I=1 TO NC:DEST(I)=I:NEXT:NF=NC:PRINT:GOTO 1370
  50. 1260 PRINT:FOR I=1 TO NC:USED(I)=0:NEXT
  51. 1265 PRINT:INPUT"Number of fields in source file";NF:PRINT
  52. 1270 FOR I=1 TO NF
  53. 1280    PRINT"Destination field of field"I"(enter 0 to ignore)";:INPUT DEST(I)
  54. 1290    IF DEST(I)>NC THEN PRINT "This file only has"NC"fields.":GOTO 1280
  55. 1300    IF DEST(I)=0 THEN 1330
  56. 1310    IF USED(DEST(I)) THEN PRINT"Won't accept putting two fields into one.":GOTO 1280
  57. 1320    USED(DEST(I))=1
  58. 1330 NEXT
  59. 1340 PRINT:PRINT"Is this ok (y/n)? ";
  60. 1350 A$=INPUT$(1):PRINT A$
  61. 1360 IF A$<>"y" THEN GOTO 1200
  62. 1370 C=1:PRINT
  63. 1380 '
  64.  
  65.  
  66.                 READ FILE
  67.  
  68.  
  69. 1390 GOSUB 1840            'exit
  70. 1400 IF EOF(3) THEN 1790
  71. 1410 FOR I=1 TO NC:B$(I)="":NEXT:NR=NR+1
  72. 1420 LINE INPUT #3,T$
  73. 1430 INREC=INREC+1:GOSUB 2010         'parse into B1$ array j=fields found
  74. 1440 IF J<>NF THEN 1450 ELSE 1470
  75. 1450 IF P9 THEN PRINT CHR$(7);:LPRINT"Input file line"INREC"defective."
  76. 1460 PRINT"Input file line"INREC"defective."CHR$(7)
  77. 1470 FOR I=1 TO J 
  78. 1480    IF DEST(I) THEN 1490 ELSE 1520
  79. 1490    QUOTE=INSTR(T$,CHR$(126))
  80. 1500    IF QUOTE THEN MID$(T$,QUOTE,1)=CHR$(34):GOTO 1490
  81. 1510    B$(DEST(I))=B1$(I)
  82. 1520 NEXT
  83. 1530 '
  84.  
  85.  
  86.                 ADD RECORD TO DIMS FILE
  87.  
  88.  
  89. 1540 T$=""
  90. 1550 FOR J=1 TO NC
  91. 1560    IF LEN(T$)+LEN(B$(J))+1>FT*128
  92.  
  93.     THEN 1570 ELSE 1590
  94. 1570    IF P9 THEN LPRINT "Input line"INREC"too long."
  95. 1580    PRINT"Input line"INREC"too long."CHR$(7)
  96. 1590    T$=T$+B$(J)+CHR$(126)
  97. 1600 NEXT
  98. 1610 N=N+1:PRINT N;T$;
  99. 1620 GOSUB 1650:PRINT"*";:GOSUB 1720:PRINT"!":C=1
  100. 1630 '
  101.  
  102.  
  103.                 LOOP
  104.  
  105.  
  106. 1640 GOTO 1380
  107. 1650 '
  108.  
  109.  
  110.         (SUB) WRITE T$ AS RECORD # N
  111.  
  112.  
  113. 1660 ON FT GOTO 1690,1670
  114. 1670 LSET R$=MID$(T$,129)    'latter half
  115. 1680 PUT #1,FT*N+2
  116. 1690 LSET R$=LEFT$(T$,128)    'first half
  117. 1700 PUT #1,FT*N+1
  118. 1710 RETURN
  119. 1720 '
  120.  
  121.  
  122.         (SUB) WRITE T$ AS DUPE REC N
  123.  
  124.  
  125. 1730 ON FT GOTO 1760,1740
  126. 1740 LSET S$=MID$(T$,129)
  127. 1750 PUT #2,FT*N+2
  128. 1760 LSET S$=LEFT$(T$,128)
  129. 1770 PUT #2,FT*N+1
  130. 1780 RETURN
  131. 1790 '
  132.  
  133.  
  134.                 FINISH
  135.  
  136.  
  137. 1800 CLOSE 3
  138. 1810 PRINT:PRINT NR"records added.
  139. 1820 PRINT:PRINT TAB(32)"Re-loading DEDIT.
  140. 1830 CHAIN DD$(1)+"DEDIT",1000
  141. 1840 '
  142.  
  143.  
  144.  
  145.                 EXIT TEST (TERM DEP)
  146.  
  147.  
  148. 1850 X$=INKEY$:X=0
  149. 1860 IF X$<>"" THEN X=ASC(X$)
  150. 1870 IF X=27 THEN CLOSE 3:GOTO 1790    'use ESC to escape listing
  151. 1880 RETURN
  152. 1890 '
  153.  
  154.  
  155.  
  156.                 CLEAR SCREEN (TERM DEP)
  157.  
  158.  
  159. 1900 PRINT CHR$(12);
  160. 1910 RETURN
  161. 1920 '
  162.  
  163.  
  164.                 (SUB) UCV
  165.  
  166.  
  167. 1930 Y$=""
  168. 1940 FOR K=1 TO LEN(X$)
  169. 1950    Y$=Y$+CHR$(32)
  170. 1960    X=ASC(MID$(X$,K,1))
  171. 1970    IF 96<X AND X<123 THEN MID$(Y$,K,1)=CHR$(X-32):GOTO 1990
  172. 1980    MID$(Y$,K,1)=MID$(X$,K,1)
  173. 1990 NEXT
  174. 2000 RETURN
  175. 2010 '
  176.  
  177.  
  178.                 (SUB) PARSE ,-DELIM. RECORD T$ > B1$ ARRAY
  179.  
  180.  
  181. 2020 '                returns J = number of fields found
  182. 2030 FOR J=1 TO NF:B1$(J)="":NEXT
  183. 2040 J=0
  184. 2050 ' process loop
  185. 2060    J=J+1:IF J=NF THEN 2170
  186. 2070    X=INSTR(T$,CHR$(44)) 'comma
  187. 2080    IF X=0 THEN 2170    'must be last field
  188. 2090    Y=INSTR(T$,CHR$(34))     'quote
  189. 2100    IF Y=0 OR ( Y<>0 AND X<Y ) THEN 2140 ELSE 2120 'comma before quote
  190. 2120    Z=INSTR(Y+1,T$,CHR$(34))
  191. 2130    X=INSTR(Z+1,T$,CHR$(44))'loc of next comma after close quote
  192. 2140    B1$(J)=MID$(T$,1,X-1):GOSUB 2200
  193. 2150 '        TRIM OFF USED PART
  194. 2160    T$=MID$(T$,X+1):GOTO 2050
  195. 2170 '        LAST FIELD
  196. 2180    B1$(J)=T$:GOSUB 2200
  197. 2190 RETURN
  198. 2200 '                (SUB) TRIM QUOTES OFF STRING
  199. 2210 IF LEFT$(B1$(J),1)=CHR$(34) THEN B1$(J)=RIGHT$(B1$(J),LEN(B1$(J))-1)
  200. 2220 IF RIGHT$(B1$(J),1)=CHR$(34) THEN B1$(J)=LEFT$(B1$(J),LEN(B1$(J))-1)
  201. 2230 RETURN
  202. N B1$(J)=RIGHT$(B1$(J),LEN(B1$(J))-1)
  203. 2220 IF RIGH