home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / bye5 / b5-clock.lbr / B5C-SS1.IQS / B5C-SS1.INS
Encoding:
Text File  |  1986-03-08  |  2.8 KB  |  126 lines
  1. ; B5C-SS1.INS - Clock routine for the System Support 1
  2. ; 07/15/85  Renamed to B5C-SS1.INS  <wm>
  3. ; 
  4. ; 6/28/85 - Added hold support and also pokes RTCBUF with time.
  5. ;                        -- Paul Traina
  6. ;
  7. ;----------------------------------------------------------------
  8. ;
  9. ;    Note- This is an insert--not an overlay
  10. ;
  11.      IF    TIMEON OR RSPEED
  12. SS1BASE    EQU    050H        ; Base port for SS1
  13. CLKCMD    EQU    SS1BASE+10    ; Clock command port
  14. CLKDATA    EQU    SS1BASE+11    ; Clock data port
  15. CLKREAD    EQU    16        ; Read command bit
  16. CLKHOLD    EQU    64        ; Hold command bit
  17. ;
  18. TIME:    LXI    H,RTCBUF    ; Point to RTC buffer
  19.     MVI    C,5        ; Set counter for hour tens
  20.     CALL    RDIGIT        ; Get hour tens
  21.     CALL    SHFT4        ; Save in buffer
  22.     CALL    MULT10        ; Multiply by 10
  23.     MOV    B,A        ; Save in B reg
  24.     CALL    RDIGIT        ; Get hour units in A reg
  25.     CALL    ADDLOW        ; Set BCD digit
  26.     ADD    B        ; Add tens digit from B
  27.     STA    CCHOUR        ; Store for later use
  28. ;
  29. ;    Minutes
  30. ;
  31.     CALL    RDIGIT        ; Get minute tens in A reg
  32.     CALL    SHFT4        ; Save in buffer
  33.     CALL    MULT10        ; Multiply by 10
  34.     MOV    B,A        ; Save in B reg
  35.     CALL    RDIGIT        ; Get minute units in A reg
  36.     CALL    ADDLOW        ; Set BCD digit
  37.     ADD    B        ; Add in minutes tens from B
  38.     STA    CCMIN        ; Store for later use
  39. ;
  40. ;    Seconds
  41. ;
  42.     CALL    RDIGIT        ; Second tens
  43.     CALL    SHFT4
  44.     CALL    RDIGIT        ; Second units
  45.     CALL    ADDLOW
  46. ;
  47. ;    Year
  48. ;
  49.     INX    H        ; Skip over "19"
  50.     MVI    C,12        ; Start with years tens
  51.     CALL    RDIGIT
  52.     CALL    SHFT4
  53.     CALL    RDIGIT        ; Years units
  54.     CALL    ADDLOW
  55. ;
  56.     CALL    RDIGIT        ; Month tens
  57.     CALL    SHFT4
  58.     CALL    RDIGIT        ; Month units
  59.     CALL    ADDLOW
  60. ;
  61.     CALL    RDIGIT        ; Day tens
  62.     CALL    SHFT4
  63.     CALL    RDIGIT        ; Day units
  64.     CALL    ADDLOW
  65. ;
  66.     XRA    A
  67.     OUT    CLKCMD        ; Turn off hold bit
  68.     RET
  69. ;
  70. ;    Read a digit
  71. ;        Command in C
  72. ;        Digit returned in A
  73. ;        C is decremented
  74. ;        Hold bit is set
  75. ;
  76. RDIGIT:    MOV    A,C        ; Get command byte
  77.     DCR    C        ; Bump it for next operation
  78.     ORI    CLKREAD+CLKHOLD    ; Add in read & hold bits
  79.     OUT    CLKCMD        ; Output it
  80.     ANI    15        ; Strip off any commands
  81.     CPI    5        ; Was it hour tens digit?
  82.     IN    CLKDATA        ; Get data
  83.     RNZ            ; No, return
  84.     ANI    3        ; Yes, so kill 24 hour bit
  85.     RET
  86. ;
  87. ;    Multiply register A by 10
  88. ;    Destroys 'D'
  89. ;
  90. MULT10:    ADD    A        ; 2x
  91.     MOV    D,A
  92.     ADD    A        ; 4x
  93.     ADD    A        ; 8x
  94.     ADD    D        ; 10x
  95.     RET
  96. ;
  97. ;    Shift A to high nibble
  98. ;        Stores shifted value in 'M'
  99. ;        Destroys 'E'
  100. ;        A is left unchanged
  101. ;
  102. SHFT4:    MOV    E,A
  103.     ANI    15        ; Only handle lower 4 bits
  104.     RLC            ; Shift A over 4 bits
  105.     RLC
  106.     RLC
  107.     RLC            
  108.     MOV    M,A        ; Save it while we're at it
  109.     MOV    A,E
  110.     RET
  111. ;
  112. ;    Add in low BCD nibble
  113. ;        Gets high nibble from M
  114. ;        Stores new BCD byte in M
  115. ;        Increments HL
  116. ;        Destroyes 'E'
  117. ;
  118. ADDLOW:    MOV    E,A
  119.     ANI    15        ; Deal with low nibble only
  120.     ORA    M        ; Add in high nibble from tens digit
  121.     MOV    M,A        ; Save new BCD byte in buffer
  122.     INX    H        ; Move on to next location
  123.     MOV    A,E
  124.     RET
  125.      ENDIF            ; TIMEON OR RSPEED
  126.