home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / bye3 / b3c-dd.ins < prev    next >
Encoding:
Text File  |  1994-07-13  |  4.1 KB  |  189 lines
  1. ;
  2. ; B3C-DD.INS - Clock routine for the Digital Dynamics card 08/22/85
  3. ;                        -- by pst
  4. ; 
  5. ;    This insert should read the clock from a Digital Dynamics
  6. ;    SpeedPro5 clock card.  The SpeedPro5 uses a 5832 chip.
  7. ;
  8. ;    This clock routine needs:
  9. ;        BCD2BIN    - no
  10. ;        BIN2BCD - no
  11. ;
  12. ;    This routine NEEDS a Z80 processor to function properly.
  13. ;    It will NOT work with an 8080 or 8085.
  14. ;
  15. ;----------------------------------------------------------------
  16. ;
  17. ;    Note- This is an insert--not an overlay
  18. ;
  19.      IF    RTC
  20. DDBASE    EQU    156        ; Base port of PIO
  21. ADATA    EQU    DDBASE        ; Data port A
  22. ACTRL    EQU    DDBASE+1    ; Control port A
  23. BDATA    EQU    DDBASE+2    ; Data port B
  24. BCTRL    EQU    DDBASE+3    ; Control port B
  25. ;
  26. NCS    EQU    00000001B    ; Not chip select
  27. CLKRD    EQU    00000010B    ; Clock read
  28. CLKWR    EQU    00000100B    ; Clock write
  29. ADWWR    EQU    00001000B    ; Address write
  30. CLKHD    EQU    00010000B    ; Clock hold
  31. ;
  32. TIME:    LXI    B,ACTRL        ; Output mode - port A (reg B=0, C=port)
  33.     CALL    SETMODE
  34. ;
  35.     LXI    B,BCTRL        ; Output mode - port B (reg B=0, C=port)
  36.     CALL    SETMODE
  37. ;
  38.     XRA    A
  39.     OUT    ADATA        ; Zero address/data lines
  40.     MVI    A,NCS+CLKHD
  41.     OUT    BDATA        ; Deselect chip
  42. ;
  43.     LXI    H,RTCBUF    ; Point to RTC buffer
  44.     MVI    D,5        ; Set counter for hour tens
  45.     CALL    RDIGIT        ; Get hour tens
  46.     CALL    SHFT4        ; Save in buffer
  47.     CALL    MULT10        ; Multiply by 10
  48.     STA    CCHOUR        ; Save temporarily
  49.     CALL    RDIGIT        ; Get hour units in A reg
  50.     CALL    ADDLOW        ; Set BCD digit
  51.     MOV    B,A
  52.     LDA    CCHOUR
  53.     ADD    B        ; Add ones digit from B
  54.     STA    CCHOUR        ; Store for later use
  55. ;
  56. ;    Minutes
  57. ;
  58.     CALL    RDIGIT        ; Get minute tens in A reg
  59.     CALL    SHFT4        ; Save in buffer
  60.     CALL    MULT10        ; Multiply by 10
  61.     STA    CCMIN        ; Save in CCMIN
  62.     CALL    RDIGIT        ; Get minute units in A reg
  63.     CALL    ADDLOW        ; Set BCD digit
  64.     MOV    B,A
  65.     LDA    CCMIN
  66.     ADD    B        ; Add in minutes ones from B
  67.     STA    CCMIN        ; Store for later use
  68. ;
  69. ;    Seconds
  70. ;
  71.     CALL    RDIGIT        ; Second tens
  72.     CALL    SHFT4
  73.     CALL    RDIGIT        ; Second units
  74.     CALL    ADDLOW
  75. ;
  76. ;    Year
  77. ;
  78.     INX    H        ; Skip over "19"
  79.     MVI    D,12        ; Start with years tens
  80.     CALL    RDIGIT
  81.     CALL    SHFT4
  82.     CALL    RDIGIT        ; Years units
  83.     CALL    ADDLOW
  84. ;
  85.     CALL    RDIGIT        ; Month tens
  86.     CALL    SHFT4
  87.     CALL    RDIGIT        ; Month units
  88.     CALL    ADDLOW
  89. ;
  90.     CALL    RDIGIT        ; Day tens
  91.     CALL    SHFT4
  92.     CALL    RDIGIT        ; Day units
  93.     CALL    ADDLOW
  94. ;
  95.     MVI    A,0        ; Turn off hold
  96.     OUT    BDATA
  97.     MVI    A,NCS        ; Deselect chip
  98.     OUT    BDATA
  99.     RET
  100. ;
  101. ;    Read a digit
  102. ;        Command in D
  103. ;        Digit returned in A
  104. ;        D is decremented
  105. ;        Hold bit is set
  106. ;        Destroys: 'BCE'
  107. ;
  108. RDIGIT:    LXI    B,ACTRL        ; Output mode - port A (b=0, c=port)
  109.     CALL    SETMODE
  110. ;
  111.     MOV    A,D        ; Get command byte
  112.     OUT    ADATA        ; Set address on lines
  113.     MVI    A,CLKHD+ADWWR    ; Hold & Write
  114.     OUT    BDATA
  115.     MVI    A,CLKHD        ; Hold
  116.     OUT    BDATA
  117. ;
  118.     LXI    B,0FF00H+ACTRL    ; Input mode - port A (b=255, c=port)
  119.     CALL    SETMODE
  120. ;
  121.     MVI    A,CLKHD+CLKRD    ; Hold & Read
  122.     OUT    BDATA
  123. ;
  124.     MOV    A,D        ; Check for hour tens digit
  125.     DCR    D
  126.     CPI    5        ; Was it hour tens digit?
  127. ;
  128.     IN    ADATA        ; Read the digit
  129.     PUSH    PSW
  130.     MVI    A,CLKHD        ; Set hold mode
  131.     OUT    BDATA
  132.     POP    PSW
  133.     RNZ            ; No, return
  134.     ANI    3        ; Yes, so kill 24 hour bit
  135.     RET
  136. ;
  137. ;    Set for input or output mode of port A
  138. ;    Entry: mode in B -- 255=output, 0=input
  139. ;           port to send to in C
  140. ;
  141. SETMODE:MVI    A,207        ; Mode 3, bit I/O
  142.     DB    0EDh,079h    ; Z80 instruction = OUT (C),A
  143.     DB    0EDh,041h    ; Z80 instruction = OUT (C),B
  144.     MVI    A,7        ; Interrupt control
  145.     DB    0EDh,079h    ; Z80 instruction = OUT (C),A
  146.     MVI    A,3
  147.     DB    0EDh,079h    ; Z80 instruction = OUT (C),A
  148.     RET
  149. ;
  150. ;    Multiply register A by 10
  151. ;    Destroys 'E'
  152. ;
  153. MULT10:    ADD    A        ; 2x
  154.     MOV    E,A
  155.     ADD    A        ; 4x
  156.     ADD    A        ; 8x
  157.     ADD    D        ; 10x
  158.     RET
  159. ;
  160. ;    Shift A to high nibble
  161. ;        Stores shifted value in 'M'
  162. ;        Destroys 'E'
  163. ;        A is left unchanged
  164. ;
  165. SHFT4:    MOV    E,A
  166.     ANI    15        ; Only handle lower 4 bits
  167.     RLC            ; Shift A over 4 bits
  168.     RLC
  169.     RLC
  170.     RLC            
  171.     MOV    M,A        ; Save it while we're at it
  172.     MOV    A,E
  173.     RET
  174. ;
  175. ;    Add in low BCD nibble
  176. ;        Gets high nibble from M
  177. ;        Stores new BCD byte in M
  178. ;        Increments HL
  179. ;        Destroyes 'E'
  180. ;
  181. ADDLOW:    MOV    E,A
  182.     ANI    15        ; Deal with low nibble only
  183.     ORA    M        ; Add in high nibble from tens digit
  184.     MOV    M,A        ; Save new BCD byte in buffer
  185.     INX    H        ; Move on to next location
  186.     MOV    A,E
  187.     RET
  188.      ENDIF            ; RTC
  189.