home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / bdos / dosplsor.ark / SYSGEN.MAC < prev    next >
Encoding:
Text File  |  1987-05-08  |  5.9 KB  |  337 lines
  1. ; This creates a SYSGEN for the Kaypro 2/4 floppy disks.
  2. ; If no SYSGEN is supplied with your system try modifying this.
  3. ; Be sure to change the identification sign-on at the end.
  4. ;
  5. ; If modifying for hard disks, note 1 byte used for trk/sector sets.
  6. ;
  7. ; 87/05/02 slaved bad drive message to maxdv. cbf
  8. ;
  9. boot    equ    0
  10. @bios    equ    boot+1
  11. @cin    equ    1
  12. @cout    equ    2
  13. cpm    equ    5
  14. lf    equ    0Ah
  15. cr    equ    0Dh
  16. yes    equ    -1
  17. no    equ    not yes
  18.  
  19. @fopn    equ    15
  20. @rdsq    equ    20
  21. @stdma    equ    26
  22.  
  23. tfcb    equ    5Ch
  24. tfcbn    equ    5Dh
  25. tfcbr    equ    7Ch
  26. defdma    equ    080h
  27. ;
  28. ;    -------
  29. ; Modify the following equates for other systems.
  30. ;
  31. bootsz    equ    1;        number of boot loader sectors
  32. ;                (0 for Osborne I ? )
  33. image    equ    0980h - 128 * bootsz;    start of memory image
  34. ;
  35. ; Applies to all except last system track used.
  36. tk0bgn    equ    0;        1st sector to use on trk 0
  37. spertk    equ    40;        sectors / physical trk, use on trk 0
  38. ;
  39. ; Kaypro special.  Puts rest of system in allocated, unused
  40. ;  bk 1 (dsdd), or bks 2,3 (ssdd).  Most others use tk0bgn/spertk here
  41. ; NOTE not for hard disks, floppies only!!.  
  42. ltkbgn    equ    16;        1st sector to use on last trk
  43. ltksiz    equ    16;        # sectors to use on last trk
  44.  
  45. systks    equ    2;        Kaypro uses 0 and part of 1
  46. maxdv    equ    3;        allowed for put/get system 1=A etc.
  47. ;    -------
  48.  
  49. begin:    lxi    sp,stktop
  50.     lxi    h,signon
  51.     call    tstr
  52.     lda    tfcbn
  53.     cpi    ' '
  54.     jz    getsor;        no file specified
  55.     lxi    d,tfcb
  56.     call    fopen
  57.     inr    a
  58.     lxi    h,nosorf
  59.     jz    exitm;        not found
  60. ;    "    "
  61. fload:    xra    a;        Load from a file
  62.     sta    tfcbr;        start at record 0
  63.     mvi    b,(image - 100h) / 128;    skip 1st 2k
  64. fload1:    push    b
  65.     lxi    d,tfcb
  66.     lxi    h,defdma
  67.     call    frdseq;        into default dma & discard
  68.     pop    b
  69.     ora    a
  70.     lxi    h,short
  71.     jnz    exitm;        can't skip
  72.     dcr    b
  73.     jnz    fload1
  74.     lxi    h,image-128;    file pos'nd
  75. fload2:    ora    h;        a was zero
  76.     jm    putsys;        big input, over 32k!! Truncate
  77.     lxi    d,128
  78.     dad    d
  79.     lxi    d,tfcb
  80.     call    frdseq
  81.     ora    a
  82.     jz    fload2;        not eof
  83.     mov    a,h
  84.     lxi    h,short
  85.     cpi    (image + 1700h) shr 8
  86.     jc    exitm;        must have at least 128 bytes of bios
  87.     jmp    putsys
  88.  
  89. notsor:    call    badrv;        message and try again
  90. ;    "    "
  91. getsor:    lxi    h,sormsg;    Optionally get sys tracks
  92.     call    tstrc
  93.     call    cinup
  94.     cpi    cr
  95.     jz    putsys;        cr skips get
  96.     sta    sordrv
  97.     sui    'A'
  98.     cpi    maxdv
  99.     jnc    notsor;        invalid drive
  100.     call    bsetdv
  101.     call    crlf
  102.     lxi    h,sormnt
  103.     call    tstr
  104.     call    cinup
  105.     cpi    cr
  106.     jnz    abort;        non-cr aborts everything
  107.     xra    a
  108. ;    "    "
  109. ; read if a = 0, else write
  110. rwsys:    sta    wrtflg
  111.     call    crlf
  112.     call    sysio
  113.     lxi    h,dunmsg
  114.     call    tstr
  115.     jmp    putsys
  116.  
  117. notdst:    call    badrv;        message and try again
  118. ;    "    "
  119. putsys:    lxi    h,dstmsg;    Optionally put sys tracks
  120.     call    tstrc
  121.     call    cinup
  122.     cpi    cr
  123.     jz    exit;        cr aborts, leaves any image
  124.     sta    dstdrv
  125.     sui    'A'
  126.     cpi    maxdv
  127.     jnc    notdst;        invalid drive
  128.     call    bsetdv
  129.     lxi    h,dstmnt
  130.     call    tstrc
  131.     call    cinup
  132.     cpi    cr
  133.     jnz    abort;        non-cr aborts everything
  134.     mvi    a,1
  135.     jmp    rwsys
  136.  
  137. abort:    lxi    h,abortm
  138. ;    "    "
  139. exitm:    call    tstrc
  140. ;    "    "
  141. exit:    mvi    a,0
  142.     call    bsetdv;        select drive a on bios
  143.     jmp    boot
  144.  
  145. ; Subroutines
  146.  
  147. ; console in and upshift
  148. ; a,f
  149. cinup:    mvi    a,@cin
  150.     call    dos
  151.     cpi    'a'
  152.     rc;            not lower case
  153.     cpi    'z'+1
  154.     rnc;            not lower case
  155.     ani    5fh;        upshift
  156.     ret
  157.  
  158. ; cr/lf to console
  159. ; a,f,e
  160. crlf:    mvi    a,cr
  161.     call    couta
  162.     mvi    a,lf
  163. ;    "    "
  164. ; (a) a to console
  165. ; a,f,e
  166. couta:    mov    e,a
  167.     mvi    a,@cout
  168.     jmp    dos
  169.  
  170. badrv:    lxi    h,baddrv;    message
  171. ;    "    "
  172. ; crlf then string hl^
  173. ; a,f,e,h,l
  174. tstrc:    call    crlf
  175. ;    "    "
  176. ; string hl^ to console
  177. ; a,f,e,h,l
  178. tstr:    mov    a,m;        0 terminated message
  179.     ora    a
  180.     rz
  181.     call    couta
  182.     inx    h
  183.     jmp    tstr
  184.  
  185. ; Bios calls.  All regs modified
  186. ; 
  187. ; set drive a
  188. bsetdv:    mov    c,a
  189.     mvi    e,18h
  190. ;    "    "
  191. xbios:    mvi    d,0;        call entry #e/3
  192.     lhld    @bios
  193.     dad    d
  194.     pchl
  195.  
  196. bsetrk:    mvi    e,1bh
  197.     jmp    xbios
  198.  
  199. bstsec:    mvi    e,1eh
  200.     jmp    xbios
  201.  
  202. bstdma:    mvi    e,21h
  203.     jmp    xbios
  204.  
  205. bread:    mvi    e,24h
  206.     jmp    xbios
  207.  
  208. bwrite:    mvi    e,27h
  209.     jmp    xbios
  210.  
  211. ; CPM DOS calls
  212. ;
  213. ; read next record file de^ into hl^
  214. ; a,f
  215. frdseq:    xchg
  216.     mvi    a,@stdma
  217.     call    dos
  218.     xchg
  219.     mvi    a,@rdsq
  220. ;    "    "
  221. ; dos call (a), saving regs
  222. ; a,f
  223. dos:    push    h
  224.     push    d
  225.     push    b
  226.     mov    c,a
  227.     call    cpm
  228.     pop    b
  229.     pop    d
  230.     pop    h
  231.     ret
  232.  
  233. ; open file de^
  234. ; a,f
  235. fopen:    mvi    a,@fopn
  236.     jmp    dos
  237.  
  238. ; The actual work - get/put system
  239. ; a,f,b,c,d,e,h,l
  240. sysio:    lxi    h,image
  241.     shld    xfradr
  242.     mvi    a,0;        1st system track always 0
  243.     sta    track
  244. ;    "    "
  245. ; Repeat this code for each full track except the last.
  246.     rept    systks - 1
  247.      mvi    a,tk0bgn
  248.      sta    sector
  249.      mvi    a,spertk
  250.      sta    nsects
  251.      call    trkio;        do first track
  252.     endm
  253. ;    "    "
  254. ; following used for LAST system track.
  255.     if    systks GT 1
  256.      mvi    a,systks-1
  257.      sta    track
  258.      mvi    a,ltkbgn;    Magic for Kaypro
  259.      sta    sector;        setup for last track
  260.      mvi    a,ltksiz;    "    "
  261.      sta    nsects;        now do last track
  262.      call    trkio
  263.     endif
  264.     ret
  265. ;
  266. trkio:    lda    track;        rd/write 1 track area
  267.     mov    c,a
  268.     inr    a
  269.     sta    track;        advance for next time
  270.     call    bsetrk
  271. trkio1:    lda    sector
  272.     mov    c,a
  273.     inr    a
  274.     sta    sector
  275.     call    bstsec
  276.     lhld    xfradr
  277.     push    h
  278.     lxi    d,128
  279.     dad    d
  280.     shld    xfradr
  281.     pop    b
  282.     call    bstdma;        input value
  283.     xra    a
  284.     sta    errors
  285. trkio2:    lda    errors
  286.     cpi    1
  287.     jc    trkio3
  288.     lxi    h,ioerr
  289.     call    tstr
  290.     call    cinup
  291.     cpi    cr
  292.     jnz    exit
  293.     call    crlf
  294.     jmp    trkio6
  295.  
  296. trkio3:    inr    a
  297.     sta    errors
  298.     lda    wrtflg
  299.     ora    a
  300.     jz    trkio4
  301.     call    bwrite
  302.     jmp    trkio5
  303.  
  304. trkio4:    call    bread
  305. trkio5:    ora    a
  306.     jnz    trkio2
  307. trkio6:    lxi    h,nsects
  308.     dcr    m
  309.     jnz    trkio1
  310.     ret
  311.  
  312. signon:    db    'SYSGEN [fn.ft]  (for Kaypro only)',0
  313. sormsg:    db    'Source drive ( <ret> to skip) :',0
  314. sormnt:    db    'Source on '
  315. sordrv:    db    0,', then type return ',0
  316. dstmsg:    db    'Destination drive ( <ret> reboots) :',0
  317. dstmnt:    db    'Destination on '
  318. dstdrv:    db    0,', then type return ',0
  319. ioerr:    db    'PERMANENT ERROR, <ret> to ignore',0
  320. dunmsg:    db    'Function complete',0
  321. baddrv:    db    'Invalid drive (A thru '
  322.     db    maxdv+'@'
  323.     db    ')',0
  324. nosorf:    db    'Source file not found',0
  325. short:    db    'Source file too short',0
  326. abortm:    db    'Aborted',0
  327.  
  328. track:    ds    1
  329. sector:    ds    1
  330. nsects:    ds    1;    To read
  331. wrtflg:    ds    1;    zero to read, else write
  332. xfradr:    ds    2
  333. errors:    ds    1
  334.     ds    64
  335. stktop:    
  336.     end
  337. ┌8