home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / basic / worldbld.bas < prev    next >
Encoding:
BASIC Source File  |  1994-07-13  |  13.5 KB  |  283 lines
  1. 10 DIM SC$(8),M(8),C$(8),S$(36),LS(36),SS$(36),SM(36),MP(15),R(15)
  2. 20 FOR I=1 TO 8:READ SC$(I),M(I),C$(I):NEXT
  3. 30 FOR I=1 TO 17:READ S$(I),SS$(I),SM(I):LS(I)=SM(I)^3.5:NEXT
  4. 40 FOR I=18 TO 36:READ S$(I),SS$(I),LS(I):SM(I)=LS(I)^.285714:NEXT
  5. 50 DATA O,100,BLUE,B,17,PALE BLUE,A,3.2,WHITE,F,1.54,PALE YELLOW
  6. 60 DATA G,1.02,YELLOW,K,.75,ORANGE,M,.38,RED,D,0.,RED
  7. 70 DATA SOL,G2,1.0,ALPHA CENTAURI A,G4,1.08,ALPHA CENTAURI B,K1,.88
  8. 80 DATA EPSILON ERIDANI,K2,.8,TAU CETI,G8,.82
  9. 90 DATA 70 OPHIUCHI A,K1,.9,70 OPHIUCHI B,K5,.65
  10. 100 DATA ETA CASSIOPEIAE A,F9,.94,ETA CASSIOPEIAE B,K6,.58
  11. 110 DATA SIGMA DRACONIS,G9,.82,36 OPHIUCHI A,K2,.77
  12. 120 DATA 36 OPHIUCHI B,K1,.76,HR 7703,K2,.76
  13. 130 DATA DELTA PAVONIS,G7,.98,82 ERIDANI,G5,.91
  14. 140 DATA BETA HYDRI,G1,1.23,HR 8832,K3,.74
  15. 150 DATA SIRIUS,A1,23,CANOPUS,F0,130,VEGA,A0,52,ARCTURUS,K2,100
  16. 160 DATA RIGEL,B8,52000,CAPELLA,G8,145,PROCYON,F5,7.6
  17. 170 DATA ACHERNAR,B5,1000,ALTAIR,A7,10,BETELGEUSE,M2,8300
  18. 180 DATA ALDEBARAN,K5,160,SPICA,B1,760,ANTARES,M1,830
  19. 190 DATA POLLUX,K0,33,FOMALHAUT,A3,13,BETA CRUCIS,B0,8300
  20. 200 DATA DENEB,A2,52000,REGULUS,B7,160,BARNARD'S STAR,M5,.00044
  21. 210 PRINT CHR$(&H1A);"WORLD BUILDER"
  22. 220 PRINT"ENTER THE NUMBER FOR THE OPTION YOU WANT"
  23. 230 PRINT:PRINT"1. USE A KNOWN STAR"
  24. 240 PRINT"2. USE A STAR NOT ON LIST"
  25. 250 PRINT"3. LIST KNOWN STARS"
  26. 260 PRINT"4. QUIT"
  27. 270 INPUT"YOUR CHOICE? ",A
  28. 280 IF(A<1 OR A>4)THEN 210
  29. 290 ON(A)GOTO 360,500,320,300
  30. 300 INPUT"ARE YOU SURE YOU WANT TO QUIT? ",A$
  31. 310 IF(ASC(A$)=89 OR ASC(A$)=121)THEN END ELSE 210
  32. 320 PRINT CHR$(&H1A);"I KNOW THE FOLLOWING STARS:":PRINT
  33. 330 FOR I=1 TO 12
  34. 340 PRINT S$(I);TAB(20);S$(I+12);TAB(40);S$(I+24)
  35. 350 NEXT
  36. 360 PRINT:INPUT"WHICH STAR SHOULD I USE? ",S$
  37. 370 IF(S$="NONE" OR S$="")THEN 210
  38. 380 FOR I=1 TO 36
  39. 390 IF(S$=S$(I))THEN SK=I:GOTO 420
  40. 400 NEXT I
  41. 410 PRINT"I DON'T KNOW THAT STAR.":GOTO 220
  42. 420 SC = VAL(RIGHT$(SS$(SK),1))/10
  43. 430 S1$=LEFT$(SS$(SK),1)
  44. 440 FOR I=1 TO 7:IF(S1$=SC$(I))THEN J=I:GOTO 460
  45. 450 NEXT
  46. 460 MS=SM(SK):L=LS(SK):AS=(MS^-2.5)*10
  47. 470 P=(1.25-MS/(L^.285714))/.005
  48. 480 IF(P/100*AS>10)THEN P=1000/AS
  49. 490 GOTO 690
  50. 500 INPUT"WHAT IS THE STAR'S NAME? ",S$
  51. 510 INPUT"WHAT IS THE STAR'S SPECTRAL CLASS? ",S1$
  52. 520 IF(S1$<>"")THEN 590
  53. 530 INPUT"WHAT IS THE ABSOLUTE MAGNITUDE (SUN=4.85)? ",M
  54. 540 L=EXP(1.94-.4*M):MS=L^.285714
  55. 550 FOR I=1 TO 7:IF(M(I)<MS)THEN J=I-1:GOTO 570
  56. 560 NEXT
  57. 570 S1$=SC$(I-1):SC=INT((MS-M(J))/(M(I)-M(J)))/10
  58. 580 GOTO 630
  59. 590 SC=VAL(RIGHT$(S1$,1))/10:S1$=LEFT$(S1$,1)
  60. 600 FOR I=1 TO 7:IF(S1$=SC$(I))THEN J=I:GOTO 620
  61. 610 NEXT:PRINT"I DON'T KNOW THAT CLASS.":GOTO 510
  62. 620 MS=M(J)-SC*(M(J)-M(J+1))
  63. 630 AS=(MS^-2.5)*10
  64. 640 PRINT S$;" HAS AN EXPECTED LIFE OF";AS;" BILLION YEARS."
  65. 650 INPUT"WHAT PERCENT (1..100) HAS ALREADY PASSED? ",P
  66. 660 IF(P/100*AS>12)THEN PRINT"THE BIG BANG OCCURRED 12 BILLION YEARS AGO.":INPUT"IS THIS WHAT YOU WANT? ",A$:IF(ASC(A$)<>89)THEN 640
  67. 670 MS=MS*(1.25-.005*P)
  68. 680 L=MS^3.5
  69. 690 TS=6000*MS^.35
  70. 700 DS=MS^.3333
  71. 710 PRINT CHR$(&H1A);"STELLAR DATA:":PRINT
  72. 720 PRINT"THE SELECTED STAR, ";S$;", IS A CLASS '";S1$;SC*10;"' STAR."
  73. 730 IF(SC>.75)THEN PRINT"IT IS ";C$(J+1);:GOTO 760
  74. 740 IF(SC<.25)THEN PRINT"IT IS ";C$(J);:GOTO 760
  75. 750 PRINT"IT IS BETWEEN ";C$(J);" AND ";C$(J+1);
  76. 760 PRINT" IN COLOR.":PRINT"IT HAS A MASS OF";MS;"SOLAR MASSES,"
  77. 770 PRINT"AND IT IS";L;"TIMES AS BRIGHT AS THE SUN."
  78. 780 PRINT S$;" HAS AN EXPECTED LIFESPAN OF";AS;"BILLION YEARS."
  79. 790 PRINT"IT IS";P;"PERCENT (ABOUT";AS*P/100;"BILLION YEARS) INTO ITS LIFESPAN."
  80. 800 IF(P>95)THEN PRINT"IT IS IN ITS DEATH THROES."
  81. 810 IF(P<5)THEN PRINT"IT IS JUST A BABY STAR."
  82. 820 PRINT"IT HAS A MEAN SURFACE TEMPERATURE OF";TS;"DEGREES KELVIN,"
  83. 830 IF(J+SC<2.5 OR J+SC>7)THEN PRINT"AND IT IS NOT BELIEVED TO HAVE PLANETS.":GOTO 850
  84. 840 PRINT"AND IT MAY HAVE PLANETS."
  85. 850 PRINT S$;" WILL DIE AS A ";
  86. 860 IF(MS<1.5)THEN PRINT"WHITE DWARF.":GOTO 900
  87. 870 IF(MS<4)THEN PRINT"NEUTRON STAR.":GOTO 900
  88. 880 IF(MS<10)THEN PRINT"NEUTRON STAR AFTER GOING NOVA.":GOTO 900
  89. 890 PRINT"BLACK HOLE AFTER GOING SUPERNOVA."
  90. 900 INPUT"ANOTHER STAR? ",A$
  91. 910 IF(ASC(A$)=89)THEN 210
  92. 920 P=P/100
  93. 930 PRINT CHR$(&H1A);"INFORMATION WILL NOW BE GATHERED ABOUT THE MAIN PLANET OF INTEREST."
  94. 940 PRINT:PRINT"THE EARTH HAS AN AVERAGE SURFACE TEMPERATURE OF 60 DEGREES F."
  95. 950 INPUT"WHAT SURFACE TEMPERATURE WOULD YOU LIKE? ",TP:TP=TP+460
  96. 960 INPUT"DESIRED SURFACE GRAVITY (EARTH = 1)? ",G
  97. 970 IF(G<=0)THEN PRINT"COME ON, THE PLANET MUST HAVE SOME GRAVITY!":GOTO 960
  98. 980 RP=SQR(L/(TP/520)^4)
  99. 990 IF(RP<MS/5)THEN PRINT"THIS PLANET IS TOO CLOSE TO BE STABLE.":GOTO 940
  100. 1000 PP=SQR(RP^3/MS)
  101. 1010 IS=L/(RP*RP)
  102. 1020 RM=.00012*TS
  103. 1030 RX=.06452*EXP(.0005*TS)
  104. 1040 SA=DS/RP
  105. 1050 INPUT"HOW BIG SHOULD THE PLANET BE RELATIVE TO EARTH (EARTH = 1)? ",D
  106. 1060 M=G*D*D
  107. 1070 IF(M<.055)THEN PRINT"THIS PLANET WON'T RETAIN AN OXYGEN ATMOSPHERE."
  108. 1080 IF(M>17.6)THEN PRINT"THIS PLANET WON'T LOSE ITS HYDROGEN ATMOSPHERE."
  109. 1090 PRINT"EARTH'S ORBIT HAS AN ECCENTRICITY OF .01672"
  110. 1100 INPUT"WHAT IS THE ORBITAL ECCENTRICITY (LESS THAN 1)? ",EC
  111. 1110 IF(EC=>1)THEN 1100
  112. 1120 CA=(1-EC)*RP:FA=(1+EC)*RP
  113. 1130 INPUT"HOW DOES THE AXIS TILT (EARTH=23.5 DEGREES)? ",TI
  114. 1140 IF(TI<0 OR TI>90)THEN 1130
  115. 1150 INPUT"HOW MANY MOONS DOES THE PLANET HAVE? ",MN
  116. 1160 IF(MN>10)THEN PRINT"FOR CONVENIENCE WE'LL CALL IT 10.":MN=10
  117. 1170 MM=1000:H=0:R=56*G
  118. 1180 IF(MN<=0)THEN 1280
  119. 1190 FOR I=1 TO MN
  120. 1200 PRINT"MASS OF MOON #";I;"(OUR MOON = 1)";:INPUT"? ",MN(I)
  121. 1210 INPUT"ORBIT (OUR MOON = 30)? ",MR(I)
  122. 1220 IF(MR(I)<3*G)THEN PRINT"THE MOON IS TOO CLOSE AND WILL BREAK UP.":GOTO 1210
  123. 1230 IF(MR(I)>56*G)THEN PRINT"THE MOON IS TOO FAR AWAY AND WILL DRIFT OFF.":GOTO 1210
  124. 1240 MP(I)=SQR(MR(I)^3/M)*4
  125. 1250 IF(MR(I)<R)THEN MM=MP(I):R=MR(I)
  126. 1260 H=MN(I)*.01235/(MR(I)^3)+H
  127. 1270 NEXT
  128. 1280 H2=.85*D^4/M*(MS*333500!/(11759*RP)^3+H)
  129. 1290 DA=1.75926E+06*H2*14+10
  130. 1300 IF(DA>MM)THEN DA=MM
  131. 1310 PRINT CHR$(&H1A);"PLANETARY INFORMATION:":PRINT:PRINT"THE PLANET'S DAY SHOULD BE ABOUT";DA;"HOURS LONG."
  132. 1320 PRINT"THAT MAKES ITS YEAR";8766/DA*PP;"DAYS LONG.  WITH A TILT OF";TI;","
  133. 1330 HI=(1+.025*DA/24)*TP-460:LO=(1-.025*DA/24)*TP-460
  134. 1340 IF(LO<-460)THEN LO=-460
  135. 1350 IF(HI<-460)THEN HI=-460
  136. 1360 PRINT"TODAY'S HIGH TEMPERATURE SHOULD BE";HI;"DEGREES F,"
  137. 1370 PRINT"AND TONIGHT'S EXPECTED LOW SHOULD BE AROUND";LO;"."
  138. 1380 SH=HI+1.9*TI*(1+EC)^2:LL=LO-1.9*TI/(1+EC)^2
  139. 1390 IF(LL<-460)THEN LL=-460
  140. 1400 IF(SH<-460)THEN SH=-460
  141. 1410 PRINT"THIS SUMMER WE EXPECT IT TO GET UP TO";SH;", AND"
  142. 1420 PRINT"THIS WINTER WE EXPECT IT TO GET DOWN TO";LL;"DEGREES F."
  143. 1430 IF(SH<32 OR LL>175)THEN PRINT"THERE ARE TIMES WHEN NO LIQUID WATER EXISTS."
  144. 1440 PRINT"HIT ANY KEY TO CONTINUE.":A$=INPUT$(1)
  145. 1450 IF(MN<=0)THEN 1590
  146. 1460 IF(MN=1)THEN 1560
  147. 1470 FOR I=1 TO MN:FOR K=1 TO (MN-I)
  148. 1480 IF(MR(K+1)=>MR(K))THEN 1530
  149. 1490 T=MR(K):MR(K)=MR(K+1):MR(K+1)=T
  150. 1500 T=MN(K):MN(K)=MN(K+1):MN(K+1)=T
  151. 1510 T=MP(K):MP(K)=MP(K+1):MP(K+1)=T
  152. 1520 F=1
  153. 1530 NEXT K
  154. 1540 IF(F=0)THEN 1560
  155. 1550 NEXT I
  156. 1560 PRINT CHR$(&H1A);"YOUR SELECTED SYSTEM OF MOONS:":PRINT
  157. 1570 PRINT"ORBIT","MASS","PERIOD"
  158. 1580 FOR I=1 TO MN:PRINT MR(I),MN(I),MP(I);"HRS",MP(I)/DA;"DAYS":NEXT
  159. 1590 INPUT"DO YOU WANT A DIFFERENT SET OF MOONS? ",A$
  160. 1600 IF(ASC(A$)=89)THEN 1150
  161. 1610 PRINT CHR$(&H1A);"PLANETARY DATA:":PRINT
  162. 1620 PRINT"OUR PRINCIPAL PLANET OF INTEREST HAS AN AVERAGE SURFACE"
  163. 1630 PRINT"TEMPERATURE OF";TP-460;"DEGREES F.  THIS REQUIRES AN ORBIT"
  164. 1640 PRINT"OF";RP;"ASTRONOMICAL UNITS, OR";RP*93;"MILLION MILES."
  165. 1650 PRINT"THE CLOSEST APPROACH TO ";S$;" IS";CA;"A.U.,"
  166. 1660 PRINT"AND THE GREATEST DISTANCE FROM ";S$;" IS";FA;"A.U."
  167. 1670 PRINT"THIS ALSO MEANS THAT IT HAS A YEAR THAT IS";PP;" YEARS LONG."
  168. 1680 PRINT:PRINT S$;" APPEARS TO BE";
  169. 1690 IF(SA>1.5 OR SA<.75)THEN PRINT" MUCH";
  170. 1700 IF(SA=1)THEN PRINT" THE SAME SIZE AS";ELSE IF(SA>1)THEN PRINT" LARGER THAN";ELSE PRINT" SMALLER THAN";
  171. 1710 PRINT" OUR SUN APPEARS."
  172. 1720 IF(G>.95 AND G<1.05)THEN PRINT"GRAVITY IS ESSENTIALLY THE SAME AS EARTH'S.":GOTO 1840
  173. 1730 PRINT"SINCE THE PLANET HAS A GRAVITY";:IF(G<1)THEN 1790
  174. 1740 PRINT" GREATER THAN EARTH'S, WE EXPECT"
  175. 1750 PRINT"A THICKER ATMOSPHERE.  THERE IS GREATER TECTONIC ACTION AND GREATER"
  176. 1760 PRINT"RESISTING FORCES; THUS, WE ANTICIPATE MORE CONTINENTS AND SHORTER"
  177. 1770 PRINT"MOUNTAINS.  EARTHQUAKES SHOULD BE MORE FREQUENT AND MORE SEVERE."
  178. 1780 GOTO 1840
  179. 1790 PRINT" LESS THAN EARTH'S, WE EXPECT"
  180. 1800 PRINT"A THINNER ATMOSPHERE.  THERE IS LESS TECTONIC ACTION AND LOWER"
  181. 1810 PRINT"RESISTING FORCES; THUS, THERE WILL BE FEWER CONTINENTS AND FEWER"
  182. 1820 PRINT"MOUNTAINS, ALTHOUGH THEY MAY BE QUITE TALL.  EARTHQUAKES, IF ANY,"
  183. 1830 PRINT"WILL NOT BE AS SEVERE AS ON EARTH."
  184. 1840 PRINT"A GRAVITY OF";G;"MEANS THAT IF YOU WEIGH 220 POUNDS,"
  185. 1850 PRINT"YOU WOULD WEIGH";G*220;"POUNDS ON THE PLANET."
  186. 1860 INPUT"WOULD YOU LIKE A NEW GRAVITY? ",A$
  187. 1870 IF(ASC(A$)=89)THEN 960
  188. 1880 PRINT CHR$(&H1A);"THE SUBJECT OF LIFE...":PRINT
  189. 1890 IF(M<.055 OR M>17.6)THEN PRINT"BECAUSE OF THE BAD ATMOSPHERE,":GOTO 2270
  190. 1900 IF(RP<RM OR RP>RX)THEN PRINT"BECAUSE OF THE LEVEL OF RADIATION,":GOTO 2270
  191. 1910 IF(SH<32 OR LL>175)THEN PRINT"BECAUSE THERE IS NO LIQUID WATER,":GOTO 2270
  192. 1920 IF(AS*P<1.5)THEN PRINT"BECAUSE THE PLANET IS TOO YOUNG,":GOTO 2270
  193. 1930 IF(P>.95)THEN PRINT"BECAUSE ";S$;" IS IN ITS DEATH THROES,":GOTO 2270
  194. 1940 IF(P<.05)THEN PRINT"BECAUSE ";S$;" IS SO YOUNG AND UNSTABLE,":GOTO 2270
  195. 1950 PRINT"CONDITIONS ARE RIGHT FOR THERE TO BE SOME ";
  196. 1960 IF(AS*P<2*G)THEN PRINT"BACTERIA AND BLUE-GREEN ALGAE.":GOTO 2250
  197. 1970 IF(AS*P<3*G)THEN PRINT"SINGLE-CELL LIFE WITH NUCLEI.":GOTO 2250
  198. 1980 IF(AS*P<4*G)THEN PRINT"SIMPLE MULTI-CELLED LIFE.":GOTO 2250
  199. 1990 IF(AS*P<4.4*G)THEN PRINT"WATER VERTEBRATES AND LAND PLANTS.":GOTO 2250
  200. 2000 PRINT"MAJOR LAND ANIMALS, PERHAPS INCLUDING INTELLIGENT LIFE."
  201. 2010 IF(G<.95)THEN 2110
  202. 2020 IF(G<1.05)THEN 2180
  203. 2030 PRINT"HIGHER GRAVITY MEANS A THICK ATMOSPHERE WHICH WILL SUPPORT LARGE"
  204. 2040 PRINT"BIRDS.  IT ALSO MEANS THAT SHORT FALLS COULD BE FATAL, SO REACTION"
  205. 2050 PRINT"TIMES WILL BE VERY SHORT.  ALL LIFE FORMS WILL BE SHORT AND STOCKY."
  206. 2060 IF(G>1.2)THEN PRINT"THERE ARE NO 2-LEGGED ANIMALS."ELSE PRINT"THERE MIGHT BE 2-LEGGED ANIMALS."
  207. 2070 PRINT"THE THICK ATMOSPHERE IMPROVES SOUND TRANSMISSION AND REDUCES"
  208. 2080 PRINT"VISIBILITY EXCEPT IN THE INFRARED.  ANIMALS WOULD HAVE TO RELY"
  209. 2090 PRINT"MORE ON HEARING, BUT THEIR EARS WOULD NOT HAVE TO BE LARGE."
  210. 2100 GOTO 2180
  211. 2110 PRINT"LOWER GRAVITY MEANS A THINNER ATMOSPHERE.  BIRDS, IF ANY, WILL HAVE"
  212. 2120 PRINT"WIDE WINGSPANS.  ALL LIFEFORMS WILL BE TALLER AND MORE SLENDER THAN"
  213. 2130 PRINT"THEIR COUNTERPARTS ON EARTH.  THERE PROBABLY ARE MANY 2-LEGGED"
  214. 2140 PRINT"ANIMALS.  THE THIN ATMOSPHERE HURTS SOUND TRANSMISSION, SO ANIMALS"
  215. 2150 PRINT"WILL EITHER HAVE LARGE EARS OR WILL NOT HAVE DEVELOPED THE SENSE OF"
  216. 2160 PRINT"HEARING AT ALL.  LUNGS WILL BE MUCH LARGER."
  217. 2170 IF(TP>75)THEN PRINT"SOME FORM OF RADIATION PROTECTION WILL BE NECESSARY."
  218. 2180 IF(SA>.75)THEN 2210
  219. 2190 PRINT"BECAUSE OF THE SMALL SUN, WE EXPECT ANIMALS EITHER TO HAVE LARGE EYES"
  220. 2200 PRINT"OR TO RELY ON OTHER SENSES, HAVING NEVER DEVELOPED SIGHT."
  221. 2210 IF(SA<1.5)THEN 2240
  222. 2220 PRINT"UNLESS THE ATMOSPHERE IS OBSCURED, WE EXPECT RELIANCE UPON SIGHT"
  223. 2230 PRINT"USING RELATIVELY SMALL EYES, AS UPON EARTH."
  224. 2240 IF(HI-LO>75)THEN PRINT"EXTREME TEMPERATURE VARIATIONS FAVOR UNDERGROUND AND/OR AQUATIC LIFEFORMS."
  225. 2250 HM=((TP-460)>32 AND (TP-460)<90 AND G<1.5 AND G>.65 AND M>.4 AND M<2.35 AND DA<96 AND SH<125 AND LL>-30 AND HI<110 AND LO>-10)
  226. 2260 GOTO 2280
  227. 2270 PRINT"LIFE, AS WE KNOW IT, CANNOT EXIST ON THIS PLANET."
  228. 2280 PRINT"THIS PLANET ";:IF(HM)THEN PRINT"MIGHT BE ";ELSE PRINT"WOULDN'T BE ";
  229. 2290 PRINT"CONSIDERED HABITABLE BY MAN."
  230. 2300 INPUT"WANT ANOTHER PLANET? ",A$
  231. 2310 IF(ASC(A$)=89)THEN 930
  232. 2320 PRINT CHR$(&H1A);"OTHER PLANETS...":PRINT
  233. 2330 INPUT"HOW MANY PLANETS IN THE SYSTEM (1..15)? ",NP
  234. 2340 IF(NP>15)THEN PRINT"TOO MANY...TRY AGAIN.":GOTO 2330
  235. 2350 IF(NP<=1)THEN 2790
  236. 2360 AM=1180/SQR(MS)-M*SQR(RP)
  237. 2370 R(1)=RP:MP(1)=M
  238. 2380 FOR I=2 TO NP
  239. 2390 PRINT CHR$(&H1A);
  240. 2400 PRINT"THE SOLAR SYSTEM IS LAID OUT LIKE THIS:":PRINT
  241. 2410 PRINT"PLANET","MASS","DISTANCE (A.U.)"
  242. 2420 PRINT"MERCURY",.055,.387
  243. 2430 PRINT"VENUS",.815,.723
  244. 2440 PRINT"TERRA",1,1
  245. 2450 PRINT"MARS",.908,1.524
  246. 2460 PRINT"JUPITER",317.9,5.203
  247. 2470 PRINT"SATURN",95.2,9.539
  248. 2480 PRINT"URANUS",14.6,19.18
  249. 2490 PRINT"NEPTUNE",17.2,30.06
  250. 2500 PRINT"PLUTO",.1,39.44
  251. 2510 PRINT:PRINT"MASS FOR PLANET #";I;:INPUT"? ",MP(I)
  252. 2520 IF(MP(I)>1000)THEN PRINT"A BODY THIS LARGE WOULD BECOME A STAR.":GOTO 2510
  253. 2530 PRINT"DISTANCE FROM ";S$;" (A.U.)";:INPUT"? ",R(I)
  254. 2540 IF(R(I)<MS/5)THEN PRINT"PLANET IS TOO CLOSE TO ";S$;".":GOTO 2530
  255. 2550 IF(R(I)>MS*56)THEN PRINT"PLANET IS TOO FAR FROM ";S$;".":GOTO 2530
  256. 2560 FOR K=1 TO I-1:IF(R(K)>.9*R(I) AND R(K)<1.1*R(I))THEN 2620
  257. 2570 NEXT K
  258. 2580 A1=MP(I)*SQR(R(I))
  259. 2590 IF(A1>AM)THEN PRINT"THE PLANET HAS TOO MUCH MASS FOR THE SYSTEM":GOTO 2400
  260. 2600 AM=AM-A1
  261. 2610 NEXT I:GOTO 2640
  262. 2620 PRINT"THE PLANET IS TOO CLOSE TO OTHER PLANETS TO HAVE A STABLE ORBIT."
  263. 2630 GOTO 2400
  264. 2640 FOR I=1 TO NP:F=0:FOR K=1 TO (NP-I)
  265. 2650 IF(R(K+1)=>R(K))THEN 2690
  266. 2660 T=R(K):R(K)=R(K+1):R(K+1)=T
  267. 2670 T=MP(K):MP(K)=MP(K+1):MP(K+1)=T
  268. 2680 F=1
  269. 2690 NEXT K
  270. 2700 IF(F=0)THEN 2720
  271. 2710 NEXT I
  272. 2720 PRINT CHR$(&H1A);"THE SYSTEM OF ";S$;":":PRINT:PRINT"PLANET #","MASS","ORBIT (A.U.)"
  273. 2730 FOR I=1 TO NP
  274. 2740 PRINT I,MP(I),R(I);
  275. 2750 IF(R(I)>RM AND R(I)<RX AND MP(I)>.055 AND MP(I)<17.6)THEN PRINT " LIFE??" ELSE PRINT
  276. 2760 NEXT I
  277. 2770 INPUT"WOULD YOU LIKE TO TRY ANOTHER SYSTEM? ",A$
  278. 2780 IF(ASC(A$)=89)THEN 2320
  279. 2790 INPUT"WOULD YOU LIKE TO TRY ANOTHER STAR? ",A$
  280. 2800 IF(ASC(A$)=89)THEN 210
  281. 2810 END
  282. ,A$
  283. 2780 IF(ASC(A$)=89)THE