CD-ROM Magazine 28 Bonus/CDRomMagazine-SoftKey-ArtPassion-FrenchVersion-Win31Mac.bin/data/lfpplay.dir/00161_Script_161

Text File | 1996-06-11 | 7KB | 281 lines

-- Art Puzzle game Handlers -----------------------------

-- *** NOTE: You must set the correct sprite numbers and cast numbers in the GeoMosaicDrag handler ***

on initializePuzzleGame
  global introNarration,beginnerNarration
  global intermediateNarration,placedItemSprites
  global advancedNarration,terribleNarr,averageNarr,goodNarr,successNarr, finish

  -- set names of soundFiles


  set beginnerNarration     = "LFPLAY5.AIF"
  set intermediateNarration = "LFPLAY4.AIF"
  set advancedNarration     = "LFPLAY3.AIF"
  set terribleNarr          = "LFPLAY6.AIF"
  set goodNarr           = "LFPLAY8.AIF"
  set successNarr              = "LFPLAY9.AIF"
  set averageNarr         = "LFPLAY7.AIF"
  set placedItemSprites = []
  set finish = FALSE
end

on zeroTotalCorrect
  global totalCorrect
  put 0 into totalCorrect
end zeroTotalCorrect


on setTime allotedTime
  global allotedSeconds
  put allotedTime into allotedSeconds
  set the text of cast "GameTimer" to string(allotedSeconds)
end


on playNarration aNarration
  sound playFile 2, aNarration
  waitSound 2
  sound stop 2
end

-- not interruptable by pressing mouse
on playNarrationNoInterrupt aNarration
  sound playFile 2, aNarration
  waitSoundNoInterrupt 2
  sound stop 2
end


on startGeoGame
  global gameStartTicks

  timeOutOff
  when mouseDown then GeoMosaicDrag
  put the ticks into gameStartTicks
  zeroTotalCorrect
  puppetSound "Start Game"
end startGeoGame


on endGeoGame
  when mouseDown then nothing
  --puppetSound 0
end endGeoGame


on setPuppets firstPiece,lastPiece,status
  repeat with currSprite = firstPiece to lastPiece
    puppetSprite currSprite,status
  end repeat
end


on GeoMosaicDrag
  global placedItemSprites
  put the clickOn into whichSprite
  if (whichSprite >= 5) and (whichSprite <= 24) and (the castNum of sprite whichSprite >=1) and (the castNum of sprite whichSprite <=40) and getOne(placedItemSprites,whichSprite) = 0 then TrackAndCheck (whichSprite, 2, 5, 4, "RS")
end GeoMosaicDrag


on updateGameTimer
  global gameStartTicks,allotedSeconds,gameOver

  put allotedSeconds - ((the ticks - gameStartTicks) / 60) into gameSecondsRemain
  set the text of cast "GameTimer" to string(gameSecondsRemain)
  if gameSecondsRemain <= 0 then
    waitticks 30 -- so you hear the "correct" sound onfast computers
    set gameOver = TRUE
    finished
  end if

end updateGameTimer


on gameOutOfTime
  global totalCorrect,terribleNarr,averageNarr,goodNarr
  if TotalCorrect >= 0 AND TotalCorrect < 8 then set result = terribleNarr
  if TotalCorrect >= 8 AND TotalCorrect < 16 then set result = averageNarr
  if TotalCorrect >= 16 AND TotalCorrect <= 20 then set result = goodNarr

  return result

end gameOutOfTime


on addToTotalCorrect
  global totalCorrect
  put totalCorrect + 1 into totalCorrect
  if TotalCorrect = 20 then finishedSpecial
end addToTotalCorrect


on finished
  global finish
  set finish = TRUE
  endGeoGame
  playNarrationNoInterrupt gameOutOfTime()
  waitticks 120
  setPuppets 5,24,FALSE
  go to frame "LfPlSt1"
end

on finishedSpecial
  global finish
  set finish = TRUE
  global successNarr
  endGeoGame
  playNarrationNoInterrupt successNarr
  waitticks 120
  setPuppets 5,24,FALSE
  go to frame "LfPlSt1"
end


on getTotalCorrect
  global totalCorrect
  return totalCorrect
end getTotalCorrect


on doBeginners
  global beginners
  set the visible of sprite beginners to TRUE
  updateStage
  setTime 70

  waitTicks 30

end


on dointermediate
  global intermediate
  set the visible of sprite intermediate to TRUE
  updateStage
  setTime 50
  waitTicks 30
end


on doAdvanced
  global advanced
  set the visible of sprite advanced to  TRUE
  updateStage
  setTime 30
  waitTicks 30
end


-- Reusable handlers --------------------------------

on waitSoundNoInterrupt soundChannel
  repeat while soundBusy (soundChannel)
    processFrame
    updateStage
  end repeat
end


on SpriteFollowMouse whichSprite
  set the locH of sprite whichSprite to the mouseH
  set the locV of sprite whichSprite to the mouseV
  updateGameTimer
  updateStage
end SpriteFollowMouse

on SerialFromCoords GridSprite, NumCols, NumRows, HGlobal, VGlobal
  put the width of sprite GridSprite into GridWidth
  put the height of sprite GridSprite into GridHeight
  put GridWidth / NumCols into CellWidth
  put GridHeight / NumRows into CellHeight
  put HGlobal - the left of sprite GridSprite into HLocal
  put VGlobal - the top of sprite GridSprite into VLocal

  put ( ( VLocal / CellHeight ) * NumCols ) + ( HLocal / CellWidth ) + 1 into theResult

  return theResult
end SerialFromCoords

on GetSerialCenter GridSprite, NumCols, NumRows, whichSerial
  put the width of sprite GridSprite into GridWidth
  put the height of sprite GridSprite into GridHeight
  put GridWidth / NumCols into CellWidth
  put GridHeight / NumRows into CellHeight

  put  ((whichSerial - ( ( (whichSerial-1) / NumCols ) * NumCols))*CellWidth)- (CellWidth / 2 )+ (the left of sprite GridSprite) into TheResult
  put ","&&(( (whichSerial-1) / NumCols ) * CellHeight) + (CellHeight / 2 )+(the top of sprite GridSprite) after theResult

  return theResult
end GetSerialCenter


on TrackAndCheck ClickedSprite, GridSprite, NumCols, NumRows, NewName
  global gameOver,finish
  put the locH of sprite ClickedSprite into storeH
  put the locV of sprite ClickedSprite into storeV

  put Word 2 of the name of cast (the castNum of sprite ClickedSprite) into oldSerial

  repeat while the stillDown
    SpriteFollowMouse( ClickedSprite)
    if gameOver then
      if finish = FALSE then
        finished
      end if

      exit

    end if
  end repeat

  put SerialFromCoords (GridSprite, NumCols, NumRows, the mouseH, the mouseV) into GridSerial

  if oldSerial = GridSerial then
    doMatch (ClickedSprite, GridSerial, NewName, GridSprite, NumCols, NumRows)
  else
    doReturn (ClickedSprite, storeH, storeV)
  end if
end TrackAndCheck


on doMatch ClickedSprite, GridSerial, NewName, GridSprite, NumCols, NumRows
  global placedItemSprites
  puppetSprite ClickedSprite, true
  puppetSound "Correct"
  set the castNum of sprite ClickedSprite to (the number of cast (NewName&&GridSerial))

  put GetSerialCenter (GridSprite, NumCols, NumRows, GridSerial) into serialCenter

  set the locH of sprite ClickedSprite to value(item 1 of serialCenter)
  set the locV of sprite ClickedSprite to value(item 2 of serialCenter)


  addToTotalCorrect
  add placedItemSprites,ClickedSprite
end doMatch


on doReturn ClickedSprite, storeH, storeV
  puppetsound "Missed"
  -- return the sprite to its original location
  set the locH of sprite ClickedSprite to storeH
  set the locV of sprite ClickedSprite to storeV
end doReturn


on buttonStart
  puppetSprite the clickOn, TRUE
  set CastNumber = the castNum of sprite the clickOn
  set CastName = the name of cast CastNumber
  set NumChars = the number of chars in CastName
  set ShortChars = NumChars - 3
  set NewName =  char 1 to ShortChars of CastName &  "in"
  set the castNum of sprite the clickOn = cast NewName
  updateStage
  waitTicks 30
  puppetSprite the clickOn, FALSE
  updateStage
end