home *** CD-ROM | disk | FTP | other *** search
/ Fresh Fish 5 / FreshFish_July-August1994.bin / bbs / dev / rkrm.lha / RKRM / Printer / hp / transfer.asm < prev    next >
Assembly Source File  |  1992-09-03  |  6KB  |  173 lines
  1. *
  2. * Copyright (c) 1992 Commodore-Amiga, Inc.
  3. * 
  4. * This example is provided in electronic form by Commodore-Amiga, Inc. for 
  5. * use with the "Amiga ROM Kernel Reference Manual: Devices", 3rd Edition, 
  6. * published by Addison-Wesley (ISBN 0-201-56775-X).
  7. * 
  8. * The "Amiga ROM Kernel Reference Manual: Devices" contains additional 
  9. * information on the correct usage of the techniques and operating system 
  10. * functions presented in these examples.  The source and executable code 
  11. * of these examples may only be distributed in free electronic form, via 
  12. * bulletin board or as part of a fully non-commercial and freely 
  13. * redistributable diskette.  Both the source and executable code (including 
  14. * comments) must be included, without modification, in any copy.  This 
  15. * example may not be published in printed form or distributed with any
  16. * commercial product.  However, the programming techniques and support
  17. * routines set forth in these examples may be used in the development
  18. * of original executable software products for Commodore Amiga computers.
  19. * 
  20. * All other rights reserved.
  21. * 
  22. * This example is provided "as-is" and is subject to change; no
  23. * warranties are made.  All use is at your own risk. No liability or
  24. * responsibility is assumed.
  25. *
  26. **********************************************************************
  27. *
  28. * Transfer routine for HP_LaserJet
  29. *
  30. **********************************************************************
  31.  
  32.         INCLUDE "exec/types.i"
  33.  
  34.         INCLUDE "intuition/intuition.i"
  35.         INCLUDE "devices/printer.i"
  36.         INCLUDE "devices/prtbase.i"
  37.         INCLUDE "devices/prtgfx.i"
  38.  
  39.         XREF    _PD
  40.  
  41.         XDEF    _Transfer
  42.  
  43.         SECTION         printer,CODE
  44. _Transfer:
  45. ; Transfer(PInfo, y, ptr)
  46. ; struct PrtInfo *PInfo         4-7
  47. ; UWORD y;                      8-11
  48. ; UBYTE *ptr;                   12-15
  49. ;
  50.  
  51.         movem.l d2-d6/a2-a3,-(sp)       ;save regs used
  52.  
  53.         movea.l 32(sp),a0               ;a0 = PInfo
  54.         move.l  36(sp),d0               ;d0 = y
  55.         movea.l 40(sp),a1               ;a1 = ptr
  56.  
  57.         move.w  pi_width(a0),d1         ;d1 = width
  58.         subq.w  #1,d1                   ;adjust for dbra
  59.  
  60.         move.w  pi_threshold(a0),d3     ;d3 = threshold, thresholding?
  61.         beq.s   grey_scale              ;no, grey-scale
  62.  
  63. threshold:
  64. ; a0 - PInfo
  65. ; a1 - ptr
  66. ; d0 - y
  67. ; d1 - width
  68. ; d3 - threshold
  69.  
  70.         eori.b  #15,d3                  ;d3 = dvalue
  71.         movea.l pi_ColorInt(a0),a2      ;a2 = ColorInt ptr
  72.         move.w  pi_xpos(a0),d2          ;d2 = x
  73.         movea.l pi_ScaleX(a0),a0        ;a0 = ScaleX (sxptr)
  74.  
  75. ; a0 - sxptr
  76. ; a1 - ptr
  77. ; a2 - ColorInt ptr
  78. ; a3 - dmatrix ptr (NOT USED)
  79. ; d0 - byte to set (x >> 3)
  80. ; d1 - width
  81. ; d2 - x
  82. ; d3 - dvalue
  83. ; d4 - Black
  84. ; d5 - sx
  85. ; d6 - bit to set
  86.  
  87. twidth_loop:
  88.         move.b  PCMBLACK(a2),d4         ;d4 = Black
  89.         addq.l  #ce_SIZEOF,a2           ;advance to next entry
  90.  
  91.         move.w  (a0)+,d5                ;d5 = # of times to use this pixel (sx)
  92.  
  93.         cmp.b   d3,d4                   ;render this pixel?
  94.         ble.s   tsx_end                 ;no, skip to next pixel.
  95.         subq.w  #1,d5                   ;adjust for dbra
  96.  
  97. tsx_render:                             ;yes, render this pixel sx times
  98.         move.w  d2,d0
  99.         lsr.w   #3,d0                   ;compute byte to set
  100.         move.w  d2,d6
  101.         not.w   d6                      ;compute bit to set
  102.         bset.b  d6,0(a1,d0.w)           ;*(ptr + x >> 3) |= 2 ^ x
  103.  
  104.         addq.w  #1,d2                   ;x++
  105.         dbra    d5,tsx_render           ;sx--
  106.         dbra    d1,twidth_loop          ;width--
  107.         bra.s   exit                    ;all done
  108.  
  109. tsx_end:
  110.         add.w   d5,d2                   ;x += sx
  111.         dbra    d1,twidth_loop          ;width--
  112.         bra.s   exit
  113.  
  114. grey_scale:
  115. ; a0 - PInfo
  116. ; a1 - ptr
  117. ; d0 - y
  118. ; d1 - width
  119.  
  120.         movea.l pi_ColorInt(a0),a2      ;a2 = ColorInt ptr
  121.         moveq.l #3,d2
  122.         and.w   d0,d2                   ;d2 = y & 3
  123.         lsl.w   #2,d2                   ;d2 = (y & 3) << 2
  124.         movea.l pi_dmatrix(a0),a3       ;a3 = dmatrix
  125.         adda.l  d2,a3                   ;a3 = dmatrix + ((y & 3) << 2)
  126.         move.w  pi_xpos(a0),d2          ;d2 = x
  127.         movea.l pi_ScaleX(a0),a0        ;a0 = ScaleX (sxptr)
  128.  
  129. ; a0 - sxptr
  130. ; a1 - ptr
  131. ; a2 - ColorInt ptr
  132. ; a3 - dmatrix ptr
  133. ; d0 - byte to set (x >> 3)
  134. ; d1 - width
  135. ; d2 - x
  136. ; d3 - dvalue (dmatrix[x & 3])
  137. ; d4 - Black
  138. ; d5 - sx
  139. ; d6 - bit to set
  140.  
  141. gwidth_loop:
  142.         move.b  PCMBLACK(a2),d4         ;d4 = Black
  143.         addq.l  #ce_SIZEOF,a2           ;advance to next entry
  144.  
  145.         move.w  (a0)+,d5                ;d5 = # of times to use this pixel (sx)
  146.         subq.w  #1,d5                   ;adjust for dbra
  147.  
  148. gsx_loop:
  149.         moveq.l #3,d3
  150.         and.w   d2,d3                   ;d3 = x & 3
  151.         move.b  0(a3,d3.w),d3           ;d3 = dmatrix[x & 3]
  152.  
  153.         cmp.b   d3,d4                   ;render this pixel?
  154.         ble.s   gsx_end                 ;no, skip to next pixel.
  155.  
  156.         move.w  d2,d0
  157.         lsr.w   #3,d0                   ;compute byte to set
  158.         move.w  d2,d6
  159.         not.w   d6                      ;compute bit to set
  160.         bset.b  d6,0(a1,d0.w)           ;*(ptr + x >> 3) |= 2 ^ x
  161.  
  162. gsx_end
  163.         addq.w  #1,d2                   ;x++
  164.         dbra    d5,gsx_loop             ;sx--
  165.         dbra    d1,gwidth_loop          ;width--
  166.  
  167. exit:
  168.         movem.l (sp)+,d2-d6/a2-a3       ;restore regs used
  169.         moveq.l #0,d0                   ;flag all ok
  170.         rts                             ;goodbye
  171.  
  172.         END
  173.