home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Brotikasten
/
BROTCD01.iso
/
c128
/
c153.d64
/
menu.bas
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-08-09
|
942b
|
27 lines
100 REM SAVE"@0:MENU.BAS",08
110 IF LF=1 THEN 350
120 U = PEEK(186):SA=8500:RS=65533:DD=56584:CU= U:REM CU IS DEVICE FOR CLOCK
130 IF PEEK(RS)=255 THEN POKE 981,15:SYS 40994:POKE 216,0:POKE 7168,0
140 IF PEEK(RS)<>255 THEN PN=PEEK(678):REM 64 MODE
150 IF PEEK(RS)=255 THEN PN=PEEK(2563):REM 128 MODE
160 IF PN=0 THEN POKE DD+6,(PEEK(DD+6) AND 127):REM NTSC
170 IF PN=255 THEN POKE DD+6,(PEEK(DD+6) OR 128):REM PAL
180 :
190 REM CMD RTC CODE
200 OPEN15,CU,15,"T-RB":REM BCD FORMAT
210 FORX=0TO8
220 : GET#15,A$(X):IF A$(X)=""THEN A$(X)=CHR$(0)
230 NEXT X
240 IF(A$(0)<>"3")AND(ST=64)THEN POKE SA-1,0:CLOSE15:GOTO 280:REM CLOCK EXISTS
250 POKE SA-1,128:REM NO CLOCK
260 GET#15,E$:IF ST=0 THEN 260:REM READ ERROR MESSAGE
270 CLOSE15:GOTO 340
280 IF A$(7)<>CHR$(0) THEN A$(4)=CHR$(ASC(A$(4))+128):REM SET AM/PM
290 H=ASC(A$(4)):IF(HAND127)=18 THEN A$(4)=CHR$(H-(SGN(H-128)*128)):REM TOD BUG
300 POKE DD+7,(PEEK(DD+7) AND 127):REM MAKE SURE CLOCK IS SET AND NOT ALARM.
310 FORX=4TO7:POKE DD+7-X,ASC(A$(X)):NEXT:REM STORE TIME IN TOD REGISTERS
320 REM EZ LOADER USES CIA#2 REGISTERS FOR TOD CLOCK
330 :
340 LF = 1:LOAD"MENU.ML",U,1
350 SYS SA