home *** CD-ROM | disk | FTP | other *** search
/ Best Objectech Shareware Selections / UNTITLED.iso / boss / data / foxp / 007 / shadow.asm < prev    next >
Encoding:
Assembly Source File  |  1992-11-27  |  9.9 KB  |  227 lines
  1. ; File......: SHADOW.ASM
  2. ; Author....: Ted Means
  3. ; Date......: $Date:   27 Nov 1992 10:39:18  $
  4. ; Revision..: $Revision:   1.7  $
  5. ; Log file..: $Logfile:   C:/nanfor/src/shadow.asv  $
  6. ; 
  7. ; This is an original work by Ted Means and is placed in the
  8. ; public domain.
  9. ;
  10. ; Modification history:
  11. ; ---------------------
  12. ;
  13. ; $Log:   C:/nanfor/src/shadow.asv  $
  14. ;  
  15. ;     Rev 1.7   27 Nov 1992 10:39:18   GLENN
  16. ;  Another memory related bug fixed by Ted.
  17. ;  
  18. ;     Rev 1.6   21 Nov 1992 11:30:24   GLENN
  19. ;  Ted fixed a bug in which memory was being overwritten if the top and
  20. ;  bottom coordinates were equal.
  21. ;  
  22. ;     Rev 1.5   16 Nov 1992 00:10:26   GLENN
  23. ;  An accidental change to the interface was made when ft_shadow() was
  24. ;  rewritten.  This brings it back to the old calling convention.
  25. ;  
  26. ;     Rev 1.4   16 Oct 1992 00:07:06   GLENN
  27. ;  Just making sure we had Ted's current revision.
  28. ;  
  29. ;     Rev 1.3   28 Sep 1992 21:41:06   GLENN
  30. ;  Ted Means completely and totally rewrote this to compile under TASM's
  31. ;  IDEAL mode, with more features.  See the documentation.  It should be
  32. ;  compatible with the old Reginald Walton function, but is much faster.
  33. ;  
  34. ;     Rev 1.2   15 Aug 1991 23:07:26   GLENN
  35. ;  Forest Belt proofread/edited/cleaned up doc
  36. ;  
  37. ;     Rev 1.1   11 May 1991 00:29:22   GLENN
  38. ;  Major re-write by Ted Means.  He sped it up.  It will also cooperate
  39. ;  with Clipper's internal _gtmaxrow and _gtmaxcol settings.  
  40. ;  
  41. ;     Rev 1.0   02 Apr 1991 18:25:40   GLENN
  42. ;  Nanforum Toolkit
  43. ;
  44. ;
  45.  
  46.  
  47. ;  $DOC$
  48. ;  $FUNCNAME$
  49. ;      FT_SHADOW()
  50. ;  $CATEGORY$
  51. ;      Video
  52. ;  $ONELINER$
  53. ;      Draw a non-destructive shadow on the screen
  54. ;  $SYNTAX$
  55. ;     FT_SHADOW( <nTop>, <nLeft>, <nBottom>, <nRight> [ ,<nAttr>] ) -> NIL
  56. ;  $ARGUMENTS$
  57. ;     <nTop>    is the top row of the shadow area.
  58. ;     <nLeft>   is the upper left column of the shadow area.
  59. ;     <nBottom> is the bottom row of the shadow area.
  60. ;     <nRight>  is the lower right column of the shadow area.
  61. ;     <nAttr>   is optional and is the screen attribute to use for drawing
  62. ;               the shadow.  If not specified, the default is 8.
  63. ;  $RETURNS$
  64. ;     NIL
  65. ;  $DESCRIPTION$
  66. ;     This function allows you to implement the popular "shadow effect."  It
  67. ;     draws a shadow using the specified screen coordinates.  The shadow
  68. ;     is drawn along the bottom and right side of the specified region.
  69. ;
  70. ;     *** INTERNALS ALERT ***  This function uses several Clipper internal 
  71. ;     routines.  If using internals scares you, then stay away from this
  72. ;     function, you gutless weasel.  The use of the internals helps to make
  73. ;     the function more well-behaved.  Clipper's display context is not
  74. ;     violated -- if you use dispbegin() before drawing the shadow, it will
  75. ;     not appear until the corresponding call to dispend().  This makes for
  76. ;     much smoother screen i/o if you have several screen objects that
  77. ;     you wish to shadow.
  78. ;
  79. ;     The source code is written to TASM IDEAL mode.
  80. ;  $EXAMPLES$
  81. ;     FT_Shadow(10,10,15,50, 8)  // draw a dim shadow
  82. ;        
  83. ;     FT_Shadow(10,10,15,40,47)  // draw a green shadow
  84. ;  $END$
  85.  
  86. IDEAL                                        ; Invoke TASM IDEAL mode
  87.  
  88. Public   FT_Shadow
  89.  
  90. Extrn    __ParNI:Far
  91. Extrn    __xGrab:Far
  92. Extrn    __xFree:Far
  93. Extrn    __gtSave:Far                        ; INTERNAL!!!
  94. Extrn    __gtRest:Far                        ; INTERNAL!!!
  95. Extrn    __gtRectSize:Far                    ; INTERNAL!!!
  96.  
  97. nTop     EQU       Word Ptr BP - 2
  98. nLeft    EQU       Word Ptr BP - 4
  99. nBottom  EQU       Word Ptr BP - 6
  100. nRight   EQU       Word Ptr BP - 8
  101. nAttr    EQU       Byte Ptr BP - 10
  102. nSize    EQU       Word Ptr BP - 12
  103.  
  104. Segment  _NanFor   Word      Public    "CODE"
  105.          Assume    CS:_NanFor
  106.  
  107. Proc     FT_Shadow Far
  108.  
  109.          Push      BP                        ; Save BP
  110.          Mov       BP,SP                     ; Set up stack reference
  111.          Sub       SP,12                     ; Allocate locals
  112.  
  113.          Mov       CX,5                      ; Set param count
  114. @@Coord: Push      CX                        ; Put on stack
  115.          Call      __ParNI                   ; Retrieve param
  116.          Pop       CX                        ; Get count back
  117.          Push      AX                        ; Put value on stack
  118.          Loop      @@Coord                   ; Get next value
  119.  
  120.          Pop       [nTop]                    ; Get top coordinate
  121.          Pop       [nLeft]                   ; Get left coordinate
  122.          Pop       [nBottom]                 ; Get bottom coordinate
  123.          Pop       [nRight]                  ; Get right coordinate
  124.          Pop       [Word Ptr BP - 10]        ; Get attribute
  125.          Cmp       [nAttr],0                 ; Is attribute invalid?
  126.          JNE       @@Right                   ; If not, continue
  127.          Mov       [nAttr],8                 ; Default attribute to 8
  128.  
  129. @@Right: Mov       AX,[nBottom]              ; Load bottom coordinate
  130.          Sub       AX,[nTop]                 ; Subtract top
  131.          JZ        @@Bottom                  ; If no room, skip right side
  132.  
  133.          LEA       AX,[nSize]                ; Get size address
  134.          Push      SS                        ; Put segment on stack
  135.          Push      AX                        ; Put offset on stack
  136.  
  137.          Mov       AX,[nTop]                 ; Load top coordinate
  138.          Inc       AX                        ; Drop down a row
  139.          Mov       BX,[nBottom]              ; Load bottom coordinate
  140.          Inc       BX                        ; Drop down a row
  141.          Mov       CX,[nRight]               ; Load right coordinate
  142.          Inc       CX                        ; Move over one
  143.          Mov       DX,CX                     ; Copy to DX
  144.          Inc       DX                        ; Move over another one
  145.  
  146.          Push      DX                        ; Put right coord on stack
  147.          Push      BX                        ; Put bottom coord on stack
  148.          Push      CX                        ; Put left coord on stack
  149.          Push      AX                        ; Put top coord on stack
  150.          Call      __gtRectSize              ; Get size
  151.          
  152.          Push      [nSize]                   ; Put size on stack
  153.          Call      __xGrab                   ; Allocate memory
  154.          Add       SP,2                      ; Realign stack
  155.  
  156.          Mov       [Word Ptr BP - 14],DX     ; Reset segment
  157.          Mov       [Word Ptr BP - 16],AX     ; Reset offset
  158.          Call      __gtSave                  ; Save screen image
  159.  
  160.          Mov       CX,[nSize]                ; Get size
  161.          SHR       CX,1                      ; Divide by 2
  162.          Mov       AL,[nAttr]                ; Load attribute
  163.          LES       BX,[DWord Ptr BP - 16]    ; Load buffer pointer
  164.          Inc       BX                        ; Point to attribute byte
  165. @@RAttr: Mov       [Byte Ptr ES:BX],AL       ; Store attribute
  166.          Add       BX,2                      ; Adjust offset
  167.          Loop      @@RAttr                   ; Do next byte
  168.  
  169.          Call      __gtRest                  ; Put shadowed image onscreen
  170.          Add       SP,8                      ; Remove params from stack
  171.          Call      __xFree                   ; Free buffer
  172.          Add       SP,4                      ; Realign stack
  173.  
  174. @@Bottom:Mov       AX,[nRight]               ; Load right coordinate
  175.          Sub       AX,[nLeft]                ; Subtract top
  176.          Cmp       AX,2                      ; Enough room for shadow?
  177.          JB        @@Done                    ; If not, skip it
  178.  
  179.          LEA       AX,[nSize]                ; Get size address
  180.          Push      SS                        ; Put segment on stack
  181.          Push      AX                        ; Put offset on stack
  182.  
  183.          Mov       AX,[nBottom]              ; Load bottom coordinate
  184.          Inc       AX                        ; Drop down a row
  185.          Mov       BX,AX                     ; Copy to BX
  186.          Mov       CX,[nLeft]                ; Load left coordinate
  187.          Inc       CX                        ; Move over two
  188.          Inc       CX
  189.          Mov       DX,[nRight]               ; Load right coordinate
  190.          Inc       DX                        ; Move over two
  191.          Inc       DX
  192.          Push      DX                        ; Put right coord on stack
  193.          Push      BX                        ; Put bottom coord on stack
  194.          Push      CX                        ; Put left coord on stack
  195.          Push      AX                        ; Put top coord on stack
  196.          Call      __gtRectSize              ; Get size
  197.          
  198.          Push      [nSize]                   ; Put size on stack
  199.          Call      __xGrab                   ; Allocate memory
  200.          Add       SP,2                      ; Realign stack
  201.  
  202.          Mov       [Word Ptr BP - 14],DX     ; Reset segment
  203.          Mov       [Word Ptr BP - 16],AX     ; Reset offset
  204.          Call      __gtSave                  ; Save screen image
  205.  
  206.          Mov       CX,[nSize]                ; Get size
  207.          SHR       CX,1                      ; Divide by 2
  208.          Mov       AL,[nAttr]                ; Load attribute
  209.          LES       BX,[DWord Ptr BP - 16]    ; Load buffer pointer
  210.          Inc       BX                        ; Point to attribute byte
  211. @@BAttr: Mov       [Byte Ptr ES:BX],AL       ; Store attribute
  212.          Add       BX,2                      ; Adjust offset
  213.          Loop      @@BAttr                   ; Do next byte
  214.  
  215.          Call      __gtRest                  ; Put shadowed image onscreen
  216.          Add       SP,8                      ; Remove params from stack
  217.          Call      __xFree                   ; Free buffer
  218.  
  219. @@Done:  Mov       SP,BP                     ; Realign stack
  220.          Pop       BP                        ; Restore BP
  221.          Ret
  222. Endp     FT_Shadow
  223. Ends     _NanFor
  224. End
  225.  
  226.  
  227.