AMOS PD CD/amospdcd.iso/sourcecode/general/sys5intro.amos/sys5intro.amosSourceCode

AMOS Source Code | 1992-02-09 | 4.8 KB | 187 lines

'System 5 Mega Demo Intro
'^------------------------ are DEAD ... TUF are Born
' Def Pixel Software, Andrew Welsh, 1992
'
MAIN
Procedure MAIN
Led Off : Auto View Off : Autoback 0 : Bob Update Off
Unpack 6 To 0
Ink 3 : Draw 0,40 To 320,40 : Draw 0,185 To 320,185
Flash 3,"(000,2)(111,2)(222,2)(333,2)(444,2)(555,2)(666,2)(777,2)(888,2)(999,2)(AAA,2)(BBB,1)(CCC,1)(DDD,1)(FFF,1)"
Get Disc Fonts
Set Font 2
Curs Off
Paper 0 : Ink 2 : Gr Writing 0
Text 100,80,"SYSTEM 5 MEGA DEMO 91"
Text 125,100,"An ADT Production"
Ink 0 : Bar 0,0 To 10,10
LIZER
BBOBS
   Screen Open 1,420,110,4,Lowres : Curs Off : Flash Off : Cls 0
   Screen Open 2,420,110,4,Lowres : Curs Off : Flash Off : Cls 0
Wait Vbl
      Screen Display 1,100,240,420,100
      Screen Display 2,101,241,420,100
Wait Vbl
   Dual Playfield 1,2
BBAR
STARS
Music 1
   Channel 0 To Screen Offset 1
   Amal 0,"M:M 0,10,50;M 0,-10,50:J M:"
   Amal On
   Get Sprite Palette
Def Scroll 1,0,11 To 410,50,-3,0
ST$=" _SYSTEM 5 MEGA-DEMO_    a THE ONE THAT CRASHED AND DIED DUE TO DIRTBAGS LIKE CENTAUR AND KBYTE"
ST$=ST$+" HOPE YOU LIKE THIS PIECE OF CODE >>>            "
I=0 : P=0 : SWP=0
SCOL:
   Led On
   If Mouse Key=1
      End
   End If
   If P>0 : Inc P : Wait Vbl : If P=55 : P=0 : Inc I : View : End If
   Else
   Inc I : End If
   If I=Len(ST$)-1 : I=0 : Goto SCOL : End If
   If P=0 and(Mid$(ST$,I,1)="a") : P=1 : End If
   If P=0
      Paste Bob 390,15,Asc(Mid$(ST$,I,1))-31
      Scroll 1
      Gosub CHANGE
      Wait Vbl
      View
      For J=1 To 4
         Scroll 1
         Gosub CHANGE
         Wait Vbl
         View
      Next J
   Else
      Gosub CHANGE
      Wait Vbl
      View
   End If
      Goto SCOL
CHANGE:
   STARS_SCROLL
   Led Off
   Bob Clear
   Bob Draw
   Screen Swap
Return
End Proc
Procedure BBAR
Rem
Set Rainbow 2,2,150,"(1,1,10)(1,-1,10)","(1,-1,10)(1,1,10)","(1,-1,10)(1,1,10)"
Rainbow 2,0,100,100
Channel 15 To Rainbow 2
Amal 15,"U:M 10,1,10;M -10,-1,10:J U:"
Rem
Set Rainbow 1,5,100,"(1,1,10)(1,-1,10)","",""
Rainbow 1,0,45,40
Channel 1 To Rainbow 1
Amal 1,"K:M 20,1,50;M -20,-1,50:J K"
Amal On
Rem
Set Rainbow 0,2,76,"","",""
Rainbow 0,0,215,76
Colour Back 0
Restore RDATA
For C=0 To 75 : Read CVA : Rain(0,C)=CVA
Next C : View
RDATA:
Data $0,$0,$0,$0,$0,$0,$0,$0
Data $0,$1,$1,$2,$2,$3,$3,$4
Data $4,$5,$5,$6,$6,$7,$7,$8
Data $8,$9,$9,$A,$A,$B,$B,$C
Data $C,$D,$D,$E,$E,$F,$F,$F
Data $F,$E,$E,$D,$D,$C,$C,$B
Data $B,$A,$A,$9,$9,$8,$8,$7
Data $7,$6,$6,$5,$5,$4,$4,$3
Data $3,$2,$2,$1,$1,$0,$0,$0
Data $0,$0,$0,$0,$0,$0,$0,$0
Rem
Channel 2 To Rainbow 0
Amal 2,"K:M 20,1,50;M -20,-1,50:J K"
Amal On
End Proc
Procedure STARS
   '
   ' KBYTE STARSCROLLY ROUTINE 1.1 (1990) -- ADT IMPROVED 91
   ' Bi-Directional StarScrolly Routine 2.1 (June 91)
   '
   Screen 2
   Def Scroll 2,1,0 To 420,5,2,0
   Def Scroll 3,1,5 To 420,10,1,0
   Def Scroll 4,1,10 To 420,15,3,0
   Def Scroll 5,1,15 To 420,20,2,0
   Def Scroll 6,1,20 To 420,30,1,0
   Def Scroll 7,1,30 To 420,45,2,0
   Def Scroll 8,1,45 To 420,55,3,0
   Def Scroll 9,1,55 To 420,60,1,0
   Def Scroll 10,1,60 To 420,65,2,0
   Def Scroll 11,1,65 To 420,70,1,0
   Def Scroll 12,1,70 To 420,75,3,0
   Def Scroll 13,1,75 To 420,80,2,0
   Def Scroll 14,1,80 To 420,85,1,0
   Def Scroll 15,1,85 To 420,90,2,0
   Def Scroll 16,1,90 To 420,105,3,0
   Colour 1,$FFF
   Screen 1
End Proc
Procedure STARS_SCROLL
   '
   ' Scroll Stars from Text Scroller !! By Angeldust
   ' Needs Stars to define scrolls
   '
   Screen 2
   Randomize Timer
   M=110-(B*2)
   Y=Rnd(M)
   Plot 5,(B+Y),1
   Scroll 2 : Scroll 3 : Scroll 4 : Scroll 5 : Scroll 6 : Scroll 7
   Scroll 8 : Scroll 9 : Scroll 10 : Scroll 11 : Scroll 12 : Scroll 13
   Scroll 14 : Scroll 15 : Scroll 16
   View
   Screen 1
End Proc
Procedure LIZER
   '
   ' ADTLIZER V1.1
   '
   A$=A$+"       AUtotest(Let R1=Vu(R0); If R1=0 eXit else Direct Start)"
   A$=A$+"Start: Let R2=R1 Anim 1,(67,2)(68,2)(69,2)(70,2)(71,2)(72,2)(73,2)(74,2)(75,2)(76,2)(77,2)(78,2)(79,2)(80,2)(81,2)(82,2);Pause,1"
   A$=A$+"Wait 1"
   Amreg(0)=200 : Amreg(1)=50
   Set Sprite Buffer 180
   Sprite 8,130,100,67
      Channel 5 To Sprite 8
         Amal 5,"Let R0="+Str$(1)+A$
         Amal On 5
   Sprite 9,130,135,67
      Channel 6 To Sprite 9
         Amal 6,"Let R0="+Str$(2)+A$
         Amal On 6
   Sprite 20,130,185,67
      Channel 12 To Sprite 20
         Amal 12,"Let R0="+Str$(3)+A$
         Amal On 12
   Sprite 11,130,220,67
      Channel 8 To Sprite 11
         Amal 8,"let R0="+Str$(4)+A$
         Amal On 8
End Proc
Procedure BBOBS
'
' MAKE a decent bob (with animation) to do some sort of pattern
'  forget the above crap !!
Priority Off
Sprite 12,200,100,83
Sprite 13,425,210,83
Channel 9 To Sprite 12
Amal 9,"M:M 0,110,50;M 225,0,50;M 0,-110,50;M -225,0,50:J M:"
Channel 10 To Sprite 13
Amal 10,"M:M 0,-110,50;M -225,0,50;M 0,110,50;M 225,0,50:J M:"
Amal On
End Proc