AMOS PD CD/amospdcd.iso/sourcecode/games/dick.amos/dick.amosSourceCode

AMOS Source Code | 1990-11-16 | 25KB | 927 lines

Close Workbench
Close Editor
Dim HINAME$(5),HISCORE(5)
Dir$="Apd97:Dynamite_dick"
Open In 1,"Hi_score"
For N=1 To 5
   Input #1,HINAME$(N),HISCORE(N)
Next N
Close 1
Global XSIZE,YSIZE,LEVEL,X_DD,Y_DD,DYN_ACTIVE,DD_AMAL$,DD_DIRECTION,DD_FRAME,DD_WRAP,X_DYN,Y_DYN,X_MOLE,Y_MOLE
Global MOLE_DIRECTION,BAT_DIRECTION,MOLE_TIMER,BAT_TIMER,BONUS_TIMER,DIGS,DYNAMITE,DYN_FLAG,DIGS_FLAG,BONUS,LIVES,SCORE,TITLE$
Load "Samples.ABK"
Hide
Randomize Timer
Get Disc Fonts
'
Do
   TITLE_PAGE
   Exit If QUIT=True
   SP=2 : XSIZE=32 : YSIZE=32 : LEVEL=1 : SCORE=0 : LIVES=3 : DIGS=3+Rnd(4) : DYNAMITE=4
   Repeat
      SETUP_PLAYING_AREA
      DISPLAY_LEVEL
      SETUP_BOBS
      Repeat
         KY$=Inkey$
         PITS
         T1MER
         MOVE_MOLE
         MOVE_BAT
         BONUS
         If Chanan(5)=0 and PIT_ACTIVE=1 Then PIT_ACTIVE=0 : Bob Off 4
         J0YSTICK
         F1RE_BUTTON
         If Joy(1)=%10000 and Chanan(3)=0 and DYNAMITE>0 Then SPACE_BAR
         If Chanan(3)=0 and DYN_ACTIVE=0 Then Bob Off 2
         X_PLOSION
         PICK_UP
         C0LLISIONS
         OUT_OF_DYNAMITE
         OUT_OF_DIGS
         If KY$=Chr$(13) Then GRAVE_STONE
      Until LIVES<1 or LEVEL_NEXT=True
      If LEVEL_NEXT=True
         LEVEL_NEXT=False
         If BONUS>0
            SCORE=SCORE+BONUS
         End If
         Get Sprite Palette
         Wait 100
         Screen Close 0
         Screen Hide 1
      End If
   Until LIVES<1
Loop
Open Out 1,"Hi_score"
For N=1 To 5
   Print #1,HINAME$(N)
   Print #1,HISCORE(N)
Next N
Close 1
Edit
'
Procedure TITLE_PAGE
   Shared HINAME$(),HISCORE(),QUIT
   QUIT=False
   MES$=String$(" ",40)+"Instructions:-  While cave exploring on his holiday, in 'sunny' Cornwall, Dick "
   MES$=MES$+"hits upon an abandoned smugglers cave filled with loads of dosh! Jumping with joy of being able to buy his "
   MES$=MES$+"dream car, a GT Skoda, he suddenly relieses he's forgotten the way out!   Yep! You've guessed it...you've gotta "
   MES$=MES$+"help him get out.  Plug your joystick in port 2, usual left, right, up & down movements apply. To complete a level "
   MES$=MES$+"you must pick up the key (by walking over it) & taking it to the door. You can also collect bags of gold which "
   MES$=MES$+"adds to your score. Each level consist of granite (indistructable), rock (blown away using dynamite) & dirt "
   MES$=MES$+"(which can be dug away with a spade). You start off with 4 sticks of dynamite, pressing the fire button, while not moving, drops a "
   MES$=MES$+"stick where you are standing so move quickly unless you want to be a fried Dick! When Dick is down to his last "
   MES$=MES$+"stick, another load of dynamite will appear on the screen for him to pick up. Dick can only hold 4 sticks! When "
   MES$=MES$+"the dynamite goes off Dick, The Bat, The Mole, gold & rocks in the area around the dynamite are destroyed! You start "
   MES$=MES$+"with a spade (which is used by holding down the fire button & moving in one of the 4 directions) after a while the spade "
   MES$=MES$+"will break and you will have to pick up another one.  So wots stopping Dick from getting out alive?...The Mole for starters, "
   MES$=MES$+"who wonders around walking into walls (he can't see, ya see??). The Bat moves in a similar manner as The Mole but starts "
   MES$=MES$+"to hunt you down when he detects Dicks movements with his 'sonar'! Every now & again a pit will appear & as we all "
   MES$=MES$+"know 100 foot pits are not healthy to walk on! Also on some levels there's a rail cart...& they hurt!  As you are "
   MES$=MES$+"trying to complete your task a bonus is ticking away. Complete the level and the bonus is yours but if the bonus "
   MES$=MES$+"falls to zero the batteries in Dicks helmet-mounted-lamp die & the hunt is on for another battery, in the dark!!  Pressing "
   MES$=MES$+"the 'ENTER' button while playing the game is the suicide button for when Dick gets stuck. Pressing 'ENTER' on this screen quits "
   MES$=MES$+"the game & saves the Hi-score table.    Credits:-  This game was written by Adam Leech using AMOS 1.1. Graphics by A. Leech & borrowed from "
   MES$=MES$+"'Magic Forest'. Music borrowed from 'Pukadu'. Game concept & play testing by Graham White who first wrote it on a Spectrum+ in BASIC. Thanx Whitie. "
   Load Iff "title.iff",1
   Load "Music.ABK"
   Screen Hide
   Shift Down 2,2,30,1
   Screen Open 0,320,256,4,Lowres
   Screen Hide
   Curs Off
   Cls 0
   Set Font 1
   Music 1
   Ink 1,0
   For N=1 To 5
      Text 50,24*N+97,Mid$(Str$(N),1)+"    "+Str$(HISCORE(N))
      Text 180,24*N+99,HINAME$(N)
   Next N
   Set Rainbow 0,1,120,"(1,-1,12)(1,1,12)","(1,1,12)(1,-1,12)","(1,-1,12)(1,1,12)"
   Rainbow 0,0,151,120
   Screen Show
   Screen Show 1
   Screen To Back
   Paper 0
   Set Rainbow 1,2,16,"","(1,1,8)(1,-1,8)",""
   Rainbow 1,0,277,16
   Def Scroll 1,1,240 To 320,256,-1,
   Do
      For N=1 To Len(MES$)
         Locate 38,30 : Print Mid$(MES$,N,1)
         For M=1 To 8
            Scroll 1
            Wait Vbl
            Exit If Fire(1)<0,3
         Next M
         If Inkey$=Chr$(13) Then QUIT=True : Exit 2
      Next N
   Loop
   For N=63 To 0 Step -1
      Wait 2
      Volume N
   Next N
   Erase 3
   Volume 63
   Screen Close 0
   Screen Close 1
   MES$=""
End Proc
Procedure SETUP_PLAYING_AREA
   DD_DIRECTION=1 : DD_FRAME=1 : X_DD=30 : Y_DD=30 : DD_WRAP=0 : DYN_ACTIVE=0
   PIT_ACTIVE=0 : MOLE_TIMER=0 : BAT_TIMER=0 : GOT_KEY=0 : LEVEL_NEXT=False
   DYN_FLAG=0 : DIGS_FLAG=0
   Update Every 2
   Screen Open 0,640,400,16,Lowres
   Flash Off : Screen Hide
   Load Iff "DDdirt"
   Screen Offset 0,1,1
   Load Iff "panel2",1
   Set Font 2
   Screen Display 1,127,252,352,50
   Screen Hide
   Ink 2,0
   Text 295,15,Str$(LIVES)
   SCORE_UPDATE
   Screen 0
   Reserve Zone 222
   '
   ' -------- AMAL ROUTINES -------
   '
   Bob 10,X_DD,Y_DD,10
   DD_AMAL$="S: L RA=X; L RB=Y; J S"
   S_SCROLL$="L: If RA>303 J R; If X<1 J R; L X=X-1;"
   S_SCROLL$=S_SCROLL$+"R: If RA<304 J U; If X>290 J U; L X=X+1;"
   S_SCROLL$=S_SCROLL$+"U: If RB>178 J D; If Y<1 J D; L Y=Y-1;"
   S_SCROLL$=S_SCROLL$+"D: If RB<179 J L; If Y>175 J L; L Y=Y+1; J L;"
   Channel 1 To Bob 10 : Rem DD
   Channel 2 To Screen Offset 0 : Rem screen
   Channel 3 To Bob 2 : Rem dynamite
   Channel 4 To Bob 3 : Rem rail cart
   Channel 5 To Bob 4 : Rem pit
   Amal 1,DD_AMAL$
   Amal 2,S_SCROLL$
   Amal On
End Proc
Procedure _INTERMITION
   Screen 2
   Screen Show
   Screen To Front
   Ink 1,0
   Cls 0
   Text 130,20,"LEVEL "+Mid$(Str$(LEVEL),2)
   Text 80,52,TITLE$
   Ink 2
   Text 130,86,"Ready ?"
   Set Rainbow 0,1,64,"(1,1,1)","(1,-1,1)",""
   Rainbow 0,2,95,64
   Set Rainbow 1,2,320,"(1,-1,1)","","(1,1,1)"
   Rainbow 1,2,175,32
   Channel 10 To Rainbow 1
   Amal 10,"S: M 320,0,600; J S;"
   Amal On 10
   Wait 250
   Rainbow 0,,300,1
   Rainbow 1,,300,1
   Screen Hide
   Amal Off 10
End Proc
Procedure OUT_OF_DYNAMITE
   If DYNAMITE<2 and DYN_FLAG=0
      DYN_FLAG=0 : FLAG=5
      Repeat
         X=((Rnd(540)/32)*32)+96 : Y=((Rnd(200)/32)*32)+96
         If Zone(X,Y)=0
            Bob 1,X,Y,47
            Inc DYN_FLAG
            Play 1,20,0
         Else
            Dec FLAG
         End If
      Until DYN_FLAG>0 or FLAG<1
   End If
End Proc
Procedure OUT_OF_DIGS
   If DIGS=0 and DIGS_FLAG=0
      DIGS_FLAG=0 : FLAG=5
      Repeat
         X=((Rnd(540)/32)*32)+96 : Y=((Rnd(200)/32)*32)+96
         If Zone(X,Y)=0
            Bob 7,X,Y,46
            Inc DIGS_FLAG
            Shoot
         Else
            Dec FLAG
         End If
      Until DIGS_FLAG>0
   End If
End Proc
Procedure BONUS
   If BONUS=0
      Fade 4,0,0,$222,$222,$222,,$222,$222
      Dec BONUS
      FLAG=0
      Repeat
         X=((Rnd(540)/32)*32)+96 : Y=((Rnd(200)/32)*32)+96
         If Zone(X,Y)=0
            Bob 8,X,Y,54
            Inc FLAG
            Play 1,1,0
         End If
      Until FLAG>0
   End If
End Proc
Procedure PICK_UP
   Shared GOT_KEY,LEVEL_NEXT
   Z0N=Zone(X Bob(10)+15,Y Bob(10)+15)
   If Z0N>19 and Z0N<42
      ' Standing on key?
      If Z0N=20
         Play 1,70,0
         Inc GOT_KEY
         SCORE=SCORE+100
         SCORE_UPDATE
      End If
      ' Standing on door?
      If Z0N=21
         If GOT_KEY=0
            Pop Proc
         End If
         Inc LEVEL
         LEVEL_NEXT=True
         GOT_KEY=0
         For N=10 To 80 : Bell N : Wait 1 : Next N
         Pop Proc
      End If
      ' Standing on some gold?
      If Z0N>21 and Z0N<42
         Play 1,60,0
         SCORE=SCORE+10
         SCORE_UPDATE
      End If
      X=((X Bob(10)+15)/32)*32 : Y=((Y Bob(10)+15)/32)*32
      Bar X,Y To X+31,Y+31
      Paste Icon X,Y,10
      Reset Zone Z0N
   End If
End Proc
Procedure SCORE_UPDATE
   Screen 1
   Text 293,25,Str$(SCORE)+" "
   Screen 0
End Proc
Procedure C0LLISIONS
   C0L=Bob Col(2,3 To 10)
   If C0L<0 and Amreg(2)>148
      If Col(5)<0
         X=X Bob(5) : Y=Y Bob(5)
         Bob Off 5
         Paste Bob X,Y,74
         MOLE_TIMER=Timer/100+7
         Sam Play 2,1,10000
         SCORE=SCORE+50
         SCORE_UPDATE
      End If
      If Col(6)<0
         X=X Bob(6) : Y=Y Bob(6)
         Bob Off 6
         Paste Bob X,Y,74
         BAT_TIMER=Timer/100+7
         Sam Play 2,1,30000
         SCORE=SCORE+50
         SCORE_UPDATE
      End If
      If Col(10)<0
         Get Sprite Palette
         Move Freeze
         Amal 1,"L X=X+16; L Y=Y+16; A 1,(74,50)(74,50)"
         Amal On 1
         Paste Bob X_DD,Y_DD,74
         Sam Loop Off
         Sam Play 2,1,6000
         AFTER_DEATH
      End If
   End If
   C0L=Bob Col(10,3 To 6)
   If C0L<0
      GRAVE_STONE
   End If
   C0L=Bob Col(1)
   If Col(10)<0
      Bob Off 1
      Dec DYN_FLAG
      DYNAMITE=4
      Play 1,50,0
   End If
   C0L=Bob Col(7)
   If Col(10)<0
      Bob Off 7
      Dec DIGS_FLAG
      DIGS=3+Rnd(4)
      Play 1,50,0
   End If
   C0L=Bob Col(8)
   If Col(10)<0
      Bob Off 8
      Get Sprite Palette
      BONUS=200
      Play 1,50,0
   End If
End Proc
Procedure GRAVE_STONE
   Get Sprite Palette
   Move Freeze
   Amal 1,"A 1,(81,30)(80,10)(79,10)(78,10)(77,10)(76,10)(75,50); F R0=0 T 20; M 2,0,3; M -2,0,3; N R0;"
   Amal On 1
   Sam Loop Off
   Sam Play 2,1,6000
   Noise To 4
   For N=1 To 17
      Play 4,1,2 : Play 4,10,2 : Play 4,5,2 : Play 4,10,2
   Next N
   Wait 150
   Paste Bob X_DD,Y_DD,75
   AFTER_DEATH
End Proc
Procedure AFTER_DEATH
   Shared DD_AMAL$
   Dec LIVES
   Screen 1
   Text 293,15,Str$(LIVES)+" "
   Wait 150
   Bob Off 2
   DYN_ACTIVE=0
   If LIVES>0
      Screen Hide 0
      Screen Hide 1
      _INTERMITION
      X_DD=30 : Y_DD=30
      Bob 10,X_DD,Y_DD,10
      Amal 1,DD_AMAL$
      Amal On 1
      Wait 100
      SETUP_BOBS
      DYN_FLAG=0
      DIGS_FLAG=0
      DYNAMITE=4
      DIGS=3+Rnd(4)
      Bob Off 1
      Bob Off 7
      Bob Off 8
      Screen Show 0
      Screen Show 1
   Else
      GAME_OVER
      HISCORE
   End If
End Proc
Procedure HISCORE
   Shared HINAME$(),HISCORE(),SCORE,NAME$
   POS=0
   Repeat
      Inc POS
      Exit If POS>5
   Until SCORE>=HISCORE(POS)
   If POS<6
      Screen Open 0,320,50,2,Lowres
      Screen Display 0,,100,,
      Curs Off
      Set Font 2
      Cls 0
      Text 60,10,"Please Enter Your Name"
      Locate ,3
      Print String$(" ",11)+Mid$(Str$(POS),1)+"   "+String$(".",10)
      LETTER$="ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789 "
      X=0 : NAME$=""
      Set Rainbow 0,1,40,"(1,1,10)(1,-1,10)","(1,2,4)(1,-2,4)",""
      Rainbow 0,0,97,40
      Repeat
         KY$=Inkey$
         If KY$=Chr$(8) and X>0
            Dec X
            NAME$=Left$(NAME$,X)
            Locate 16+X,3 : Print "."
         End If
         If Instr(LETTER$,Upper$(KY$))>0 and X<10
            NAME$=NAME$+Upper$(KY$)
            Locate 16+X,3 : Print Upper$(KY$)
            Inc X
         End If
      Until KY$=Chr$(13)
      If NAME$=""
         RAND_NAME
      Else
         NAME$=Left$(NAME$,1)+Lower$(Right$(NAME$,Len(NAME$)-1))
      End If
      Screen Close 0
      For N=4 To POS Step -1
         HISCORE(N+1)=HISCORE(N)
         HINAME$(N+1)=HINAME$(N)
      Next N
      HISCORE(POS)=SCORE
      HINAME$(POS)=NAME$
   End If
End Proc
Procedure RAND_NAME
   Shared NAME$
   N=Rnd(11)+1
   Restore NAME
   For M=1 To N
      Read NAME$
   Next M
   Print At(16,3);NAME$
   Wait 150
   NAME:
   Data "Her","Him","You","Me","007","Q","M","A.N.Other","A. Glump","Somebody","Nameless","D. Dick"
End Proc
Procedure GAME_OVER
   Screen Hide 0
   Screen Hide 1
   Screen Open 0,400,20,2,Lowres
   Screen Display 0,100,150,,
   Def Scroll 1,0,0 To 199,19,1,
   Def Scroll 2,200,0 To 400,19,-1,
   Set Rainbow 0,1,20,"(1,2,5)(1,-2,5)","(1,2,5)(1,-2,5)","(1,1,18)(1,-1,18)"
   Rainbow 0,0,150,20
   Set Font 1
   Cls 0
   Ink 1
   Text 1,14,"GAME"
   Text 345,14,"OVER"
   For N=0 To 130
      Scroll 1
      Scroll 2
      Wait Vbl
   Next N
   Wait 200
End Proc
Procedure T1MER
   If MOLE_TIMER>0
      If Timer>MOLE_TIMER*100
         POS_MOLE
         MOLE_TIMER=0
      End If
   End If
   If BAT_TIMER>0
      If Timer>BAT_TIMER*100
         POS_BAT
         BAT_TIMER=0
      End If
   End If
   If BONUS>0
      If Timer>BONUS_TIMER
         BONUS=BONUS-10
         BONUS_TIMER=((Timer/100)+2)*100
         Timer=(Timer/100)*100
         Screen 1
         Text 292,37,Str$(BONUS)+" "
         Screen 0
      End If
   End If
End Proc
Procedure SETUP_BOBS
   Screen 0
   RAND_MOLE_DIRECTION
   POS_MOLE
   RAND_BAT_DIRECTION
   POS_BAT
End Proc
Procedure PITS
   Shared PIT_ACTIVE
   If PIT_ACTIVE=0
      A=Rnd(1000)
      While A>990
         Inc PIT_ACTIVE
         X=(Rnd(640)/32)*32 : Y=(Rnd(400)/32)*32
         If Zone(X+3,Y+3)=0
            Bob 4,X,Y,
            A$="L R2=5; A Z(5)+1,(55,100)(56,R2)(57,R2)(58,100)(57,R2)(56,R2)(55,R2)"
            Amal 5,A$
            Amal On 5
         End If
         A=0
      Wend
   End If
End Proc
Procedure POS_BAT
   FLAG=0
   Repeat
      X_BAT=((Rnd(540)/32)*32)+96 : Y_BAT=((Rnd(200)/32)*32)+96
      If Zone(X_BAT+3,Y_BAT+3)=0
         Bob 6,X_BAT,Y_BAT,
         Inc FLAG
      End If
   Until FLAG>0
   Channel 8 To Bob 6 : Rem bat anim
   Channel 9 To Bob 6 : Rem bat movement
   Amal 8,"A 0,(43,6)(44,6)(45,6)(44,6)"
   Amal On 8
End Proc
Procedure MOVE_BAT
   If BAT_TIMER<1
      If Chanmv(9)=0
         If Joy(1)>0
            X=X Bob(10)-X Bob(6)
            Y=Y Bob(10)-Y Bob(6)
            X=Sgn(X)*X
            Y=Sgn(Y)*Y
            If Max(X,Y)=Y
               If Y Bob(10)<Y Bob(6)
                  BAT_DIRECTION=0
               Else
                  BAT_DIRECTION=1
               End If
            Else
               If X Bob(10)<X Bob(6)
                  BAT_DIRECTION=2
               Else
                  BAT_DIRECTION=3
               End If
            End If
         End If
         If BAT_DIRECTION=0
            If Zone(X Bob(6)+16,Y Bob(6)-16)>19 or Y Bob(6)<32
               RAND_BAT_DIRECTION
               Pop Proc
            End If
            Amal 9,"M 0,-32,40"
            Amal On 9
         End If
         If BAT_DIRECTION=1
            If Zone(X Bob(6)+16,Y Bob(6)+48)>19 or Y Bob(6)>323
               RAND_BAT_DIRECTION
               Pop Proc
            End If
            Amal 9,"M 0,32,40"
            Amal On 9
         End If
         If BAT_DIRECTION=2
            If Zone(X Bob(6)-16,Y Bob(6)+16)>19 or X Bob(6)<32
               RAND_BAT_DIRECTION
               Pop Proc
            End If
            Amal 9,"M -32,0,40"
            Amal On 9
         End If
         If BAT_DIRECTION=3
            If Zone(X Bob(6)+48,Y Bob(6)+16)>19 or X Bob(6)>600
               RAND_BAT_DIRECTION
               Pop Proc
            End If
            Amal 9,"M 32,0,40"
            Amal On 9
         End If
      End If
   End If
End Proc
Procedure RAND_BAT_DIRECTION
   BAT_DIRECTION=Rnd(3)
End Proc
Procedure POS_MOLE
   FLAG=0
   Repeat
      X_MOLE=((Rnd(540)/32)*32)+96 : Y_MOLE=((Rnd(200)/32)*32)+96
      If Zone(X_MOLE+3,Y_MOLE+3)=0
         Bob 5,X_MOLE,Y_MOLE,
         Inc FLAG
      End If
   Until FLAG>0
   Channel 6 To Bob 5 : Rem mole anim
   Channel 7 To Bob 5 : Rem mole movement
   Amal 6,"A 0,(39,10)(40,10)(41,10)(42,10)"
   Amal On 6
End Proc
Procedure MOVE_MOLE
   If MOLE_TIMER<1
      If Chanmv(7)=0
         If MOLE_DIRECTION=0
            If Zone(X Bob(5)+16,Y Bob(5)-16)>19 or Y Bob(5)<32
               RAND_MOLE_DIRECTION
               Pop Proc
            End If
            Amal 7,"M 0,-32,30"
            Amal On 7
         End If
         If MOLE_DIRECTION=1
            If Zone(X Bob(5)+16,Y Bob(5)+48)>19 or Y Bob(5)>323
               RAND_MOLE_DIRECTION
               Pop Proc
            End If
            Amal 7,"M 0,32,30"
            Amal On 7
         End If
         If MOLE_DIRECTION=2
            If Zone(X Bob(5)-16,Y Bob(5)+16)>19 or X Bob(5)<32
               RAND_MOLE_DIRECTION
               Pop Proc
            End If
            Amal 7,"M -32,0,30"
            Amal On 7
         End If
         If MOLE_DIRECTION=3
            If Zone(X Bob(5)+48,Y Bob(5)+16)>19 or X Bob(5)>600
               RAND_MOLE_DIRECTION
               Pop Proc
            End If
            Amal 7,"M 32,0,30"
            Amal On 7
         End If
      End If
   End If
End Proc
Procedure RAND_MOLE_DIRECTION
   MOLE_DIRECTION=Rnd(3)
End Proc
Procedure LEVEL_CONTROL
   If LEVEL<5
      Restore "LEVEL"+Mid$(Str$(LEVEL),2)
   Else
      Restore LEVEL5
   End If
   Read X_TRUCK,Y_TRUCK,TRUCK_IMAGE,TRUCK_AMAL$,BONUS,TITLE$
   Bob 3,X_TRUCK,Y_TRUCK,TRUCK_IMAGE
   Amal 4,TRUCK_AMAL$
   Amal On 4
   LEVEL1:
   Data -32,-32,37,"",410,"Dig For That Gold"
   LEVEL2:
   Data 62,223,37,"S: M 480,0,160; M -480,0,160; J S;",510,"That Sodding BAT!!"
   LEVEL3:
   Data 62,0,37,"S: M 512,0,120; M -512,0,200; J S;",610,"Just a Bit Complex!"
   LEVEL4:
   Data 160,100,38,"S: M 0,155,50; M 0,-155,50; P; J S;",710,"  Gold or Bonus ?"
   LEVEL5:
   Data -32,-32,37,"",310," Randomised Level"
End Proc
Procedure J0YSTICK
   Shared SP
   If Jleft(1)<0 and X_DD>0
      X1=X Bob(10)+3 : Y1=Y Bob(10)+5
      X2=X Bob(10)+3 : Y2=Y Bob(10)+27
      If Zone(X1,Y1)<42 and Zone(X2,Y2)<42
         X_DD=X_DD-SP
         DD_DIRECTION=2
         DD_ANIM
      End If
      Pop Proc
   End If
   If Jright(1)<0 and X_DD<605
      X1=X Bob(10)+29 : Y1=Y Bob(10)+5
      X2=X Bob(10)+29 : Y2=Y Bob(10)+27
      If Zone(X1,Y1)<42 and Zone(X2,Y2)<42
         Add X_DD,SP
         DD_DIRECTION=3
         DD_ANIM
      End If
      Pop Proc
   End If
   If Jup(1)<0 and Y_DD>0
      X1=X Bob(10)+6 : Y1=Y Bob(10)+3
      X2=X Bob(10)+26 : Y2=Y Bob(10)+3
      If Zone(X1,Y1)<42 and Zone(X2,Y2)<42
         Y_DD=Y_DD-SP
         DD_DIRECTION=0
         DD_ANIM
      End If
      Pop Proc
   End If
   If Jdown(1)<0 and Y_DD<355
      X1=X Bob(10)+6 : Y1=Y Bob(10)+29
      X2=X Bob(10)+26 : Y2=Y Bob(10)+29
      If Zone(X1,Y1)<42 and Zone(X2,Y2)<42
         Add Y_DD,SP
         DD_DIRECTION=1
         DD_ANIM
      End If
      Pop Proc
   End If
End Proc
Procedure F1RE_BUTTON
   If DIGS>0
      F1RE=Joy(1)
      '  Fire & Up
      If F1RE=%10001
         Z0NE=Zone(X Bob(10)+15,Y Bob(10))
         If Z0NE>161
            X=((X Bob(10)+15)/32)*32 : Y=((Y Bob(10)-15)/32)*32
            Bar X,Y To X+31,Y+31
            Paste Icon X,Y,10
            Reset Zone Z0NE
            Dec DIGS
            Sam Play 1,2,5000
         End If
      End If
      '  Fire & Down
      If F1RE=%10010
         Z0NE=Zone(X Bob(10)+15,Y Bob(10)+31)
         If Z0NE>161
            X=((X Bob(10)+15)/32)*32 : Y=((Y Bob(10)+31)/32)*32
            Bar X,Y To X+31,Y+31
            Paste Icon X,Y,10
            Reset Zone Z0NE
            Dec DIGS
            Sam Play 1,2,5000
         End If
      End If
      '  Fire & Left
      If F1RE=%10100
         Z0NE=Zone(X Bob(10),Y Bob(10)+15)
         If Z0NE>161
            X=((X Bob(10)-15)/32)*32 : Y=((Y Bob(10)+15)/32)*32
            Bar X,Y To X+31,Y+31
            Paste Icon X,Y,10
            Reset Zone Z0NE
            Dec DIGS
            Sam Play 1,2,5000
         End If
      End If
      '  Fire & Right
      If F1RE=%11000
         Z0NE=Zone(X Bob(10)+31,Y Bob(10)+15)
         If Z0NE>161
            X=((X Bob(10)+31)/32)*32 : Y=((Y Bob(10)+15)/32)*32
            Bar X,Y To X+31,Y+31
            Paste Icon X,Y,10
            Reset Zone Z0NE
            Dec DIGS
            Sam Play 1,2,5000
         End If
      End If
   End If
End Proc
Procedure DD_ANIM
   If DD_WRAP=0
      If DD_FRAME=9
         DD_WRAP=1
         Dec DD_FRAME
      End If
      Inc DD_FRAME
   End If
   If DD_WRAP=1
      If DD_FRAME=1
         DD_WRAP=0
         Inc DD_FRAME
      End If
      Dec DD_FRAME
   End If
   Bob 10,X_DD,Y_DD,DD_FRAME+DD_DIRECTION*9
End Proc
Procedure SPACE_BAR
   If DYN_ACTIVE=0
      DYN_ACTIVE=1
      Dec DYNAMITE
      X_DYN=X_DD+16 : Y_DYN=Y_DD+16
      Bob 2,X_DYN,Y_DYN,48
      DYN_ANIM$="L RC=0; A 1,(48,25)(49,25)(50,25)(51,25)(52,25)(53,25); F RC=0 T 150; N RC;"
      DYN_ANIM$=DYN_ANIM$+"A 1,(59,3)(60,3)(61,3)(62,3)(63,3)(64,3)(65,3)(66,3)(67,3)(68,3)(69,3)(70,3)(71,3)(72,3)(73,3); F R3=1 T 46; N R3; L RC=0;"
      Amal 3,DYN_ANIM$
      Amal On 3
      Sam Loop On
      Sam Play 2,2,6000
   End If
End Proc
Procedure X_PLOSION
   If DYN_ACTIVE=1 and Amreg(2)>148
      Sam Loop Off
      Boom
      DYN_ACTIVE=0
      X1=((X_DYN/32)*32)-32 : Y1=((Y_DYN/32)*32)-32
      For Y2=0 To 2
         For X2=0 To 2
            X=X1+X2*32 : Y=Y1+Y2*32
            Z0NE=Zone(X+3,Y+3)
            If Z0NE>101 and Z0NE<162 or Z0NE>21 and Z0NE<42
               Bar X,Y To X+31,Y+31
               Paste Icon X,Y,10
               Reset Zone Z0NE
            End If
         Next X2
      Next Y2
      Boom
   End If
End Proc
Procedure DISPLAY_LEVEL
   If LEVEL<5
      GTMAP[LEVEL]
   Else
      RAND_LEVEL
   End If
   TAMEVIEW[0,0,20,12,XSIZE,YSIZE]
   TAMEMAP[0,0,0]
   Double Buffer
   LEVEL_CONTROL
   Screen Open 2,320,100,4,Lowres
   Screen Hide
   Screen Display 2,,100,,
   Set Font 1
   Set Text %110
   Cls 0
   _INTERMITION
   Screen 0
   Screen Show
   Screen Show 1
   Screen To Front 1
   Get Sprite Palette
   Ink 0
End Proc
Procedure RAND_LEVEL
   Erase 6
   Reserve As Work 6,260
   Bload "DDlvl_1.MAP",6
   For N=4 To 244
      Poke(Start(6)+N),0
   Next N
   For N=1 To Rnd(10)+50
      BLOCK[7]
   Next N
   For N=1 To Rnd(10)+50
      BLOCK[8]
   Next N
   For N=1 To Rnd(20)+20
      BLOCK[9]
   Next N
   For N=1 To Rnd(10)+5
      BLOCK[11]
   Next N
   BLOCK[12]
   BLOCK[13]
End Proc
Procedure BLOCK[T]
   Repeat
      Z=Rnd(240)+4
      FLAG=0
      If Z<7 Then Inc FLAG
      If Z>23 and Z<27 Then Inc FLAG
      If Z>43 and Z<47 Then Inc FLAG
   Until Peek(Start(6)+Z)=0 and FLAG=0
   Poke(Start(6)+Z),T
End Proc
Rem _________________________________________________________________
Rem
Rem TAME Engine Routines
Rem use these in your own programs if you wish (see MAGIC FOREST)
Rem
Procedure GTMAP[M]
   Rem  This loads in the levels map - M=level
   Erase 6
   Reserve As Work 6,260
   Bload "DDlvl_"+Mid$(Str$(M),2)+".MAP",Start(6)
End Proc
Procedure TAMEVIEW[TX,TY,TW,TH,XS,YS]
   Rem This routine sets up the window for TAME, and what size tiles you wish
   Rem to use
   Shared XSIZE,YSIZE,MAPX,MAPY,TAMEW,TAMEH,TLX,TLY,BRX,BRY
   MAPX=Deek(Start(6)) : MAPY=Deek(Start(6)+2)
   XSIZE=XS : YSIZE=YS
   TLX=TX : TLY=TY
   TAMEW=TW : TAMEH=TH
   BRX=TLX+TW*XSIZE
   BRY=TLY+TH*YSIZE
End Proc
Procedure TAMEMAP[S,X,Y]
   Rem This routine draws the map in the window set by the TAMEVIEW procedure
   Rem on screen S, at map co-ordinates X,Y
   Shared T,XSIZE,YSIZE,MAPX,MAPY,TAMEW,TAMEH,TLX,TLY,BRX,BRY
   A=0 : RAIL=0 : KEY=20 : D0OR=21 : GOLD=22 : GRANITE=42 : STONE=102 : MUD=162
   Repeat
      B=0
      Repeat
         T=1+Peek(Start(6)+4+((B+X) mod MAPX)+((A+Y) mod MAPY)*MAPX) mod 20
         If T>1
            Dec T
            Paste Icon TLX+B*XSIZE,TLY+A*YSIZE,T
            If T<3
               Inc RAIL
               TEMP_NO=RAIL
            End If
            If T=11
               TEMP_NO=GOLD
               Inc GOLD
            End If
            If T=12
               TEMP_NO=KEY
            End If
            If T=13
               TEMP_NO=D0OR
            End If
            If T>2 and T<7 or T=9
               TEMP_NO=GRANITE
               Inc GRANITE
            End If
            If T=7
               TEMP_NO=STONE
               Inc STONE
            End If
            If T=8
               TEMP_NO=MUD
               Inc MUD
            End If
            Set Zone TEMP_NO,TLX+B*XSIZE,TLY+A*YSIZE To TLX+B*XSIZE+XSIZE,TLY+A*YSIZE+YSIZE
         End If
         Inc B
      Until B>=TAMEW
      Inc A
   Until A>=TAMEH
End Proc