AMOS PD CD/amospdcd.iso/476-500/apd492/amos_source/no-refund.amos/no-refund.amosSourceCode

AMOS Source Code | 1993-08-11 | 165KB | 7,150 lines

'                            -  NO-REFUND!  -

'                   -  A Cybornetics Production 1993  -

'                     -  Released 11th August 1993  -



'  -  System requirements -

'      -  At least 1 Meg of RAM (1.5 if you want to run it from editor)
'      -  External floppy drive supported (but not required)
'      -  Fully A1200 compatible
'      -  Both Amos 1.3x and Amos Pro Compatible



'  -  Anybody can contact us at -

'     -  Rob (Swapping)                  Matt & Dug (Coding + General)
'     -  14 Buckingham Drive,            18 Marroway Lane,
'     -  Ely,                            Witchford,
'     -  Cambs,                          Ely,  Cambs,
'     -  CB6 1DR                         CB6 2HU



'  -  Ahead, Warp factor nine Mr. Sulu!


' - Initialise system
Set Buffer 100
Break Off
Amos Lock
Close Editor
Close Workbench

' - Main procedure calls
_INTRO
_END_INTRO
THE_MEANING_OF_LIFE
EAGLE_PART
FIT_EQU_LINES
FIRST_DOT_CUBE
COOL_DOT_CUBE
INSERT_DISK_TWO
SLIDE_STARS_CYCLE_FACES
PLASMA
PATT_VECSCRL_LOGO
MORPH_MAN
MAIN_MENU


' - Change disk procedures
Procedure INSERT_DISK_ONE
   ' - Ah... ha ha ha ha ha ha haaaaaaaaaaa!

   ' - Only do this if no-refund! is not in any drive

   Load "no-refund2!:stuff/tv_screen2",14
   Load "no-refund2!:stuff/font",13
   If Not Exist("No-Refund!:")
      SETUP_FONT
      NEW_TEXT_SCREEN["insert_disk1"]
      Repeat
         ' - Do absolutely nothing until they insert disk one!
      Until Exist("No-Refund!:")
      CLEAR_TEXT_SCREEN
      SHUT_TEXT_SCREENS
   End If

End Proc
Procedure INSERT_DISK_TWO
   ' - Ah... ha ha ha ha ha ha haaaaaaaaaaa!

   ' - Only do this if no-refund2! is not in any drive

   If Not Exist("No-Refund2!:")
      SETUP_FONT
      NEW_TEXT_SCREEN["insert_disk2"]
      Repeat
         ' - Do absolutely nothing until they insert disk two!
      Until Exist("No-Refund2!:")
      CLEAR_TEXT_SCREEN
      SHUT_TEXT_SCREENS
   End If

End Proc


' - Intro stuff
Procedure _INTRO

   ' - GFX - Matt
   ' - Code - Matt & Rob
   ' - SFX - Rob

   Load "no-refund!:stuff/Loading",1

   Screen Open 0,320,256,4,Lowres
   Curs Off : Cls 0 : Hide : Flash Off : Get Sprite Palette

   ' - Display loading bob while intro loads
   Bob 1,240,190,1
   Wait Vbl

   ' - Load intro stuff
   Load "no-refund!:stuff/intro_text",9
   Load "no-refund!:stuff/intro_sam",10
   Load "no-refund!:stuff/headtitle",8
   Load "no-refund!:stuff/grin_face",7
   Load "no-refund!:stuff/laugh_sam",11

   ' - Remove loading bob
   Fade 1 : Wait 15
   Bob Off
   Erase 1
   Screen Close 0

   ' - 8 holds the title screen
   Unpack 8 To 0
   Screen Hide 0
   Erase 8

   ' - 9 holds the text screen
   Unpack 9 To 1
   Screen Hide 1
   Erase 9

   ' - Screen 2 shows the output
   Screen Open 2,320,256,4,Lowres
   Curs Off : Cls 0 : Hide : Flash Off
   Palette 0,0,0,0
   Screen To Front 2 : Screen 2

   ' - HEY...
   Screen Copy 1,0,0,320,50 To 2,0,90
   Sam Raw 15,Start(10),Length(10),14400

   ' - Slight pause before starting text
   For CTR=1 To 7
      Wait Vbl
   Next CTR

   ' fade on text and wait
   Fade 1,0,$FFF,$999,
   For CTR=1 To 30
      Wait Vbl
   Next CTR
   Fade 1 : Wait 10

   ' - Scuse me sir
   Cls 0
   Screen Copy 1,0,50,320,100 To 2,0,90
   Fade 1,0,$FFF,$999,
   For CTR=1 To 50
      Wait Vbl
   Next CTR
   Fade 1 : Wait 10

   ' - Can We...
   Cls 0
   Screen Copy 1,0,100,320,200 To 2,0,70
   Fade 1,0,$FFF,$999,
   For CTR=1 To 100
      Wait Vbl
   Next CTR
   Fade 1 : Wait 10

   ' - STOP!
   Cls 0
   Screen Copy 1,0,200,320,250 To 2,0,100
   Fade 1,0,$FFF,$999,
   For CTR=1 To 45
      Wait Vbl
   Next CTR

   ' - Flash screen to white and then fade to picture
   Screen To Front 0
   Screen 1
   Get Palette 0
   Screen 0
   W=$FFF
   Palette W,W,W,W,W,W,W,W,W,W,W,W,W,W,W,W
   Screen Show 0
   Fade 2 To 1

   ' - Wait a bit and then remove unused stuff
   Wait 100
   Screen Close 1
   Screen Close 2
   Erase 10

   ' - Laugh etc.
   Unpack 7 To 1 : Screen Hide 1
   Erase 7
   Screen 0
   Fade 1 : Wait 15
   Screen Copy 1,0,0,640,256 To 0,0,0
   Fade 1 To 1
   Screen Close 1
   Sam Raw 15,Start(11)+500,Length(11),14400

End Proc
Procedure _END_INTRO

   ' - Load while laugh picture is displayed
   Load "no-refund!:stuff/tv_screen2",14
   Load "no-refund!:stuff/font",13
   Fade 1
   Wait 15
   Erase 11
   Screen Close 0

End Proc


' - Text printer procedures
Procedure SETUP_FONT

   ' - Unpacks once only per group of text screens.
   ' - Allows us to display more than one text screen without loading.
   Unpack 13 To 1
   Screen Hide 1

End Proc
Procedure NEW_TEXT_SCREEN[PAGE_NUM$]

   ' - This isn't a NEW text screen routine, you've seen it before.... Unless you haven't got the Awakening!  If not, WHY NOT!
   ' - (new font though)

   ' - T.V. screens
   Unpack 14 To 0
   Screen Hide 0

   ' - Initialise Constants.
   Dim LINE$(8)
   FONT_SCREEN=1
   DISPLAY_SCREEN=0
   FONTX=13
   FONTY=16

   ' - Initialise text positions
   XDEST=63
   YDEST=61

   Screen 0
   Restore PAGE_NUM$
   Read NUM_OF_LINES
   For CTR=1 To NUM_OF_LINES
      ' - Reads a page of text into the array.
      Read LINE$(CTR)
   Next CTR

   ' - Main Loop.
   For CTR=1 To NUM_OF_LINES
      XDEST=(320-(Len(LINE$(CTR))*FONTX))/2
      ' - Writes the next line of text.
      For LOP=1 To Len(LINE$(CTR))
         L$=Mid$(LINE$(CTR),LOP,1)
         If L$<>" "
            If Asc(L$)<58
               If Asc(L$)=46
                  Restore "PFS"
               Else
                  If Asc(L$)=39
                     Restore "PAP"
                  Else
                     If Asc(L$)=44
                        Restore "PCM"
                     Else
                        If Asc(L$)=33
                           Restore "PEX"
                        Else
                           If Asc(L$)=43
                              Restore "PPL"
                           Else
                              If Asc(L$)=47
                                 Restore "PSL"
                              Else
                                 If Asc(L$)=45
                                    Restore "PDA"
                                 Else
                                    If Asc(L$)=40
                                       Restore "PLB"
                                    Else
                                       If Asc(L$)=41
                                          Restore "PRB"
                                       Else
                                          Restore "C"+L$
                                       End If
                                    End If
                                 End If
                              End If
                           End If
                        End If
                     End If
                  End If
               End If
            Else
               If Asc(L$)=63
                  Restore "PQM"
               Else
                  Restore "Q"+L$
               End If
            End If
            Read X,Y

            ' - The X and Y are just the position, not the coordinates
            X=X*FONTX
            Y=Y*FONTY
            Screen Copy FONT_SCREEN,X,Y,X+FONTX,Y+FONTY To DISPLAY_SCREEN,XDEST,YDEST
         End If
         ' - Move one character to the left
         Add XDEST,FONTX
      Next LOP
      ' - Move down a line
      Add YDEST,FONTY
   Next CTR

   Palette 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
   Screen Show 0

   ' - Fade the screen on after all text is in place
   Fade 1,0,$444,$FFF,$888,$CCC,0,0,0,0,0,0,0,0,0,0,$777
   Wait 16 : Rem - WHY? 15 would do!
   Shift Up 3,4,15,1

   Pop Proc

   '-  Font Data.
   QA:
   Data 0,0
   QB:
   Data 1,0
   QC:
   Data 2,0
   QD:
   Data 3,0
   QE:
   Data 4,0
   QF:
   Data 5,0
   QG:
   Data 6,0
   QH:
   Data 7,0
   QI:
   Data 8,0
   QJ:
   Data 9,0
   QK:
   Data 10,0
   QL:
   Data 11,0
   QM:
   Data 12,0
   QN:
   Data 13,0
   QO:
   Data 14,0
   QP:
   Data 15,0
   QQ:
   Data 16,0
   QR:
   Data 17,0
   QS:
   Data 18,0
   QT:
   Data 19,0
   QU:
   Data 20,0
   QV:
   Data 21,0
   QW:
   Data 22,0
   QX:
   Data 23,0
   QY:
   Data 0,1
   QZ:
   Data 1,1
   C1:
   Data 2,1
   C2:
   Data 3,1
   C3:
   Data 4,1
   C4:
   Data 5,1
   C5:
   Data 6,1
   C6:
   Data 7,1
   C7:
   Data 8,1
   C8:
   Data 9,1
   C9:
   Data 10,1
   C0:
   Data 11,1
   PAP:
   Data 12,1
   PCM:
   Data 13,1
   PFS:
   Data 14,1
   PEX:
   Data 15,1
   PQM:
   Data 16,1
   PPL:
   Data 17,1
   PDA:
   Data 18,1
   PSL:
   Data 19,1
   PLB:
   Data 20,1
   PRB:
   Data 21,1


   '- Text data.

   ' -- "|||||||||||||||"
   INSERT_DISK2:
   Data 7
   Data " "
   Data "insert"
   Data " "
   Data "no-refund!"
   Data "disk 2"
   Data " "
   Data "in any drive"

   ' -- "|||||||||||||||"
   INSERT_DISK1:
   Data 7
   Data " "
   Data "insert"
   Data " "
   Data "no-refund!"
   Data "disk 1"
   Data " "
   Data "in any drive"

   ' -- "|||||||||||||||"
   PAGE1:
   Data 8
   Data "welcome!"
   Data " "
   Data "to 24 hour"
   Data "cybornetics t.v"
   Data " "
   Data "with our latest"
   Data "demo called"
   Data "!no-refund!"

   ' -- "|||||||||||||||"
   PAGE2:
   Data 8
   Data "let's get this"
   Data "thing started"
   Data "properly!"
   Data " "
   Data "you can try"
   Data "the left button"
   Data "to skip most"
   Data "parts..."

   ' -- "|||||||||||||||"
   PAGE3:
   Data 8
   Data "this is the"
   Data "first ever"
   Data "cybornetics"
   Data "TWO DISK"
   Data "production!"
   Data " "
   Data "greetz + credz"
   Data "coming up..."

   ' -- "|||||||||||||||"
   PAGE4:
   Data 8
   Data "mike"
   Data "-solo pd-"
   Data " "
   Data "thanx for the"
   Data "cool reviews!"
   Data " "
   Data "how are you"
   Data "coping alone?"

   ' -- "|||||||||||||||"
   PAGE5:
   Data 8
   Data "overdose"
   Data "(enhance)"
   Data " "
   Data "thanx for the"
   Data "disks you sent!"
   Data " "
   Data "is chip ahoy 2"
   Data "out yet?"

   ' -- "|||||||||||||||"
   PAGE6:
   Data 8
   Data "andy"
   Data "(a.p.u.g.)"
   Data " "
   Data "keep up the"
   Data "cool trading!"
   Data " "
   Data "r! r! r! r! r!"
   Data " r! r! r! r!"
   '
   ' -- "|||||||||||||||"
   PAGE7:
   Data 7
   Data "Lloyd"
   Data "(quartz prod.)"
   Data " "
   Data "when will we"
   Data "get to see the"
   Data "wheel of"
   Data "fortune???"

   ' -- "|||||||||||||||"
   PAGE8:
   Data 7
   Data "now for some"
   Data "brief credz..."
   Data " "
   Data "this cool music"
   Data "was composed by"
   Data "stew!"
   Data "(as usual)"

   ' -- "|||||||||||||||"
   PAGE9:
   Data 7
   Data " "
   Data "next up is"
   Data "the menu!"
   Data " "
   Data "use the lmb to"
   Data "choose what you"
   Data "want to do."

   ' -- "|||||||||||||||"
   PAGE10:
   Data 7
   Data "you chose it..."
   Data " "
   Data "the cybornetics"
   Data "questionnaire!"
   Data " "
   Data "lmb to answer,"
   Data "rmb to leave!"

   ' -- "|||||||||||||||"
   PAGE11:
   Data 7
   Data "ahhh, back to"
   Data "the demo!"
   Data " "
   Data "here's a shadow"
   Data "vector and some"
   Data "juicy big"
   Data "vector balls"

   ' -- "|||||||||||||||"
   PAGE12:
   Data 8
   Data "thats it!"
   Data "the last"
   Data "loading screen!"
   Data " "
   Data "we don't care"
   Data "- so there!"
   Data " "
   Data "cys posse 1993"

   ' -- "|||||||||||||||"
   PAGE13:
   Data 7
   Data "you chose the"
   Data "shoot 'em up!"
   Data " "
   Data "nuke 'em is"
   Data "now loading..."
   Data " "
   Data "please wait"

   ' -- "|||||||||||||||"
   PAGE14:
   Data 7
   Data "wait up!"
   Data " "
   Data "we've got to"
   Data "re-load some of"
   Data "the demo stuff!"
   Data " "
   Data "won't be long.."
   '
   ' -- "|||||||||||||||"
   PAGE15:
   Data 7
   Data " "
   Data "that was cool!"
   Data " "
   Data "but now..."
   Data " "
   Data "witness"
   Data "this!"
   '
   ' -- "|||||||||||||||"
   PAGE16:
   Data 8
   Data "a disgusting"
   Data "green blob..."
   Data " "
   Data "i hate jello!"
   Data " "
   Data "aw, come on!"
   Data "there's always"
   Data "room for jello!"
   ' - Abruptly the sound ceased.......

End Proc
Procedure CLEAR_TEXT_SCREEN

   ' - Stop colour cycling and then fade screen
   ' - This should be called after all of the loads
   Shift Off
   Fade 1 : Wait 15
   Cls 0

End Proc
Procedure SHUT_TEXT_SCREENS

   ' - Should be called when no more text screen are required for a while.
   Screen Close 1
   Screen Close 0

End Proc

' - Main Demo procedures start here!
Procedure THE_MEANING_OF_LIFE
   ' - Definition procedure for tomato anim etc.

   SETUP_FONT
   NEW_TEXT_SCREEN["page1"]
   ' - Load stuff
   Load "no-refund!:stuff/tomato_bobs",1
   Load "no-refund!:stuff/tom_sam",5
   Load "no-refund!:stuff/monty_pic",9
   Load "no-refund!:stuff/monty_sam",6
   Track Load "no-refund!:stuff/music",3
   CLEAR_TEXT_SCREEN
   SHUT_TEXT_SCREENS
   _KILLER_TOMATOES_FROM_OUTER_SPACE
   MONTY_PYTHON
   Wait 25

   ' - OK! Roll the drums!
   Track Loop On
   Track Play 3
End Proc
Procedure _KILLER_TOMATOES_FROM_OUTER_SPACE

   ' - Code -  Matt
   ' - GFX - Matt

   Screen Open 0,320,100,16,Lowres
   Curs Off : Cls 0 : Hide : Flash Off : Get Sprite Palette

   Double Buffer
   Screen Display 0,,100,,100

   Bob 1,-20,50,1
   Bob 2,145,-150,22
   Channel 1 To Bob 1
   Channel 2 To Bob 2


   ' - Roll on tomato

   A$="Anim 2,(2,4)(3,4)(4,4)(5,4)(6,4)(7,4)(8,4)(1,4);"
   A$=A$+"M 160,0,64 ; "

   Amal 1,A$
   Amal On 1

   Wait 75


   ' -Move on foot

   B$="M 0,125,25 ;"
   Amal 2,B$
   Amal On 2

   Wait 18


   ' - Squish like grape!

   C$="Anim 1,(9,4)(10,4)(11,20)(12,4)(13,4)(14,30)(15,4)"
   Amal 1,C$
   Amal On 1
   Wait 5
   Sam Play 2

   Wait 70

   ' - Start Your Engines!

   D$="Anim 9,(23,4)(24,4);"
   Amal 2,D$

   E$="Anim 1,(17,8)(21,8)(18,8)(19,4)(20,4)(19,4)(20,4)(19,4)(20,4)"
   E$=E$+"(19,4)(20,4)(19,4)(20,4)(19,4)(20,4)(19,4)(20,4);"
   Amal 1,E$

   Sam Loop On
   Sam Play 1

   Amal On
   Wait 80

   F$="Anim 1,(23,4)(25,4);"
   Amal 2,F$

   G$="Anim 1,(19,6)(17,6)(21,6);"
   Amal 1,G$

   Amal On
   Wait 18

   Sam Loop Off
   Music Off

   Wait 15

   H$="M 0,-125,75 ;"
   Amal 2,H$
   Amal On

   Wait 75
   Bob Off 2

   Bob 3,320,50,26
   Channel 3 To Bob 3

   I$="M -225,0,45 ; M 0,0,50 ; M -275,0,55 ;"
   Amal 3,I$

   Amal On 3
   Wait 200

   Fade 1 : Wait 15
   Erase 1
   Erase 5
   Screen Close 0

End Proc
Procedure MONTY_PYTHON
   ' - GFX - Matt
   ' - Code - Matt
   ' - SFX - Rob

   Unpack 9 To 1
   Screen Hide 1
   Erase 9

   Screen Open 0,320,256,32,Lowres
   Curs Off : Cls 0 : Hide : Flash Off
   Palette 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0

   Screen Copy 1,0,0,320,256 To 0,0,0

   Wait Vbl
   Fade 1 To 1 : Wait 15
   Screen Close 1

   Sam Raw 15,Start(6)+150,Length(6)-150,11000

   Shift Down 7,2,19,1

   COUNT=0
   Repeat

      For C=21 To 30
         Colour C,$FF0
         Wait 5
         Colour C,$220
      Next C

      Inc COUNT

   Until COUNT>4

   Shift Off
   Fade 1 : Wait 15
   Erase 6
   Screen Close 0

End Proc

' - Eagle part
Procedure EAGLE_PART

   ' - Calling procedure for Eagle Part (?)

   SETUP_FONT
   NEW_TEXT_SCREEN["page2"]
   Load "no-refund!:stuff/new_eagle",9
   Load "no-refund!:stuff/cys_logo_bob",1
   Wait 100

   ' - Clear second text screen
   CLEAR_TEXT_SCREEN
   SHUT_TEXT_SCREENS

   ' - Start Eagle part
   SET_UP_EAGLE_SCREENS
   CYS_LOGO_BOBS
   VECTOR_INCONVEX[50]
   GO_LANDSCAPES[5]

   ' - End Eagle part
   _CLOSE_EAGLE_SCREENS
End Proc
Procedure SET_UP_EAGLE_SCREENS

   ' - open Screen 2 to cover the text and get the palette
   Screen Open 2,320,130,8,Lowres
   Curs Off : Cls 0 : Hide : Flash Off
   Screen Display 2,,117,320,140

   ' - Unpack the main picture (including text)
   Unpack 9 To 1
   Screen Hide 1
   Erase 9
   Screen 2

   ' - Store the palette of screen 1 in screen 2
   Get Palette 1
   Screen 1

   ' - set screen 1 to black
   Palette 0,0,0,0,0,0,0,0
   Screen Show 1
   Screen To Back 1
   Screen To Front 2

   ' - Make screen 1 fade on with correct colours
   Fade 1 To 2
   Wait 15

   ' - Open screen 0 as 4 colour
   Screen Open 0,320,130,4,Lowres
   Curs Off : Cls 0 : Hide : Flash Off

   ' - Position it over the font (on screen 1)
   Screen Display 0,,117,320,140
   Double Buffer
   Screen To Front 0

   ' - close the 8 colour screen 2
   Screen Close 2

End Proc
Procedure CYS_LOGO_BOBS
   ' - Code - Matt
   ' - GFX - Matt

   ' - Big Bobs! - NOT!

   ' - Paste message at bottom
   For Y=0 To 27 Step 2
      Screen Copy 1,0,84+Y,320,84+Y+1 To 1,0,218+Y
      Wait Vbl
   Next Y
   For Y=27 To 0 Step -2
      Screen Copy 1,0,84+Y,320,84+Y+1 To 1,0,218+Y
      Wait Vbl
   Next Y
   ' - That was quite nice wasn't it!

   Screen 0
   MAKE_RAINBOW
   Colour 1,$F

   For A=0 To 11
      Channel A To Bob A+1
   Next A

   For B=1 To 12
      Bob B,30,95,1
   Next B

   ' - Assign the movement to the bobs on channels 0 to 15. This uses AMAL
   ' - and MOVE (X and Y) strings.
   For C=0 To 11
      Amal C,"Loop : M 250,-50,150 ; M -250,50,150 ; J L"

      M$="(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3)"
      M$=M$+"(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3)L"
      Move Y C,M$
      Wait 5
      Move X C,M$
      Move On C
      Amal On C

   Next C

   ' - Determining how long you suffer for.....
   COUNTER=0
   TIME=250
   Repeat
      Inc COUNTER
      Wait Vbl
   Until COUNTER=TIME or Mouse Key=1
   Amal Off : Move Off

   ' - Move the bobs off to the left
   X$=" M 320,0,20 "
   For MB=0 To 11
      Amal MB,X$
      Amal On MB
   Next MB

   ' - Clean up
   Wait 30
   Amal Off : Move Off
   Bob Off
   Erase 1
   Rainbow Del
   Wait Vbl

End Proc
Procedure MAKE_RAINBOW
   Rem   Created with RainMaker 2.0
   Rem   By Dan Murrell Jr. - Thanks Dan!
   NUM_LINES=130
   Set Rainbow 0,1,NUM_LINES+1,"","",""
   Restore _RAINBOW_DATA :
   For COUNTER=0 To NUM_LINES
      Read SCANLINE
      Rain(0,COUNTER)=SCANLINE
   Next COUNTER

   _RAINBOW_DATA:
   Data $F0,$E0,$E0,$E0,$E0,$E0,$E0,$E0,$E0,$E0,$D0,$D0,$D0,$D0,$D0,$D0
   Data $D0,$D0,$D0,$D0,$C0,$C0,$C0,$C0,$C0,$C0,$C0,$C0,$C0,$C0,$B0,$B0
   Data $B0,$B0,$B0,$B0,$B0,$B0,$B0,$B0,$A0,$A0,$A0,$A0,$A0,$A0,$A0,$A0
   Data $A0,$A0,$90,$90,$90,$90,$90,$90,$90,$90,$90,$90,$80,$80,$80,$80
   Data $80,$80,$80,$80,$80,$80,$70,$70,$70,$70,$70,$70,$70,$70,$70,$70
   Data $60,$60,$60,$60,$60,$60,$60,$60,$60,$60,$50,$50,$50,$50,$50,$50
   Data $50,$50,$50,$50,$40,$40,$40,$40,$40,$40,$40,$40,$40,$40,$30,$30
   Data $30,$30,$30,$30,$30,$30,$30,$30,$20,$20,$20,$20,$20,$20,$20,$20
   Data $20,$20,$10,$10,$10,$10,$10,$10,$10,$10,$10,$10,$10
   Rainbow 0,1,118,NUM_LINES
   View
End Proc
Procedure VECTOR_INCONVEX[TIME]
   ' - Code - Dug

   ' - Paste message at bottom
   For Y=0 To 27 Step 2
      Screen Copy 1,0,119+Y,320,119+Y+1 To 1,0,218+Y
      Wait Vbl
   Next Y
   For Y=27 To 0 Step -2
      Screen Copy 1,0,119+Y,320,119+Y+1 To 1,0,218+Y
      Wait Vbl
   Next Y

   Screen 0
   Autoback 0
   Degree
   Palette 0,$4,$7,0

   _MAX=4*10 : Rem                      No. of points-1 (because 0's included)
   Dim FX(_MAX),FY(_MAX),FZ(_MAX) : Rem                    constant 3d coords
   Dim X(_MAX),Y(_MAX),Z(_MAX) : Rem              used/recalculated 3d coords
   Dim SX(_MAX),SY(_MAX) : Rem                  2d coords (from the 3d coords)
   Dim _SORTED(20,4) : Rem   n surfaces with 4 points +1 ink each

   XO=160 : Rem x,y origin (middle of screen)
   YO=70
   DVP=300 : Rem Vanishing point

   THETA=0 : Rem         - Rotation about   X axis
   PHI=0 : Rem           - Rotation about      Y axis
   GAMMA=0 : Rem         - Rotation about         Z axis
   XSPEED=5 : Rem        - Speed of rotation
   YSPEED=15
   ZSPEED=10

   NUM_OBJECTS=1 : Rem   - Max no. of objects
   OBJECT=1 : Rem        - Number of next object to show (1.. NUM_OBJECTS)
   NUMSURFACES=0 : Rem No. of surfaces to object

   Gosub SETUP_RAINBOW
   Gosub SETUP_OBJECT
   COUNTER=0
   Repeat
      Screen Swap : Wait Vbl
      Cls 0
      Gosub ANGLES
      Gosub ROT_ALL
      Gosub _SORT_SURFACES
      Gosub COORD_CONV
      Gosub DRW_OBJECT
      Inc COUNTER
   Until COUNTER=TIME or Mouse Key=1

   ' - Clean up
   Fade 1 : Wait 15
   Rainbow Del
   Autoback 2
   Synchro On
   Cls 0
   Pop Proc


   SETUP_RAINBOW:
   Set Rainbow 0,3,4096,"","",""
   RGB=0
   Y=0
   WIDTH=5
   RGB_ADD=$110
   RGB_SUB=-$110
   Repeat
      For L=1 To 15
         For L1=0 To WIDTH
            Rain(0,Y)=RGB
            Inc Y
         Next L1
         Add RGB,RGB_ADD
      Next L
      For L=1 To 15
         For L1=0 To WIDTH
            Rain(0,Y)=RGB
            Inc Y
         Next L1
         Add RGB,RGB_SUB
      Next L
   Until Y>260
   Rainbow 0,3,117,130
   Return


   ANGLES:
   Add GAMMA,ZSPEED,0 To 360-ZSPEED
   Add PHI,YSPEED,0 To 360-YSPEED
   Add THETA,XSPEED,0 To 360-XSPEED
   Return


   ' -- Rotate all points through the specified angle
   ROT_ALL:
   For L=0 To NUMPOINTS-1

      ' rotate about x
      X1=FX(L)
      Y1=(FY(L)*Cos(THETA))-(FZ(L)*Sin(THETA))
      Z1=(FY(L)*Sin(THETA))+(FZ(L)*Cos(THETA))

      ' rotate about y
      X2=(X1*Cos(PHI))+(Z1*Sin(PHI))
      Y2=Y1
      Z2=-(X1*Sin(PHI))+(Z1*Cos(PHI))

      ' rotate about z
      X(L)=(X2*Cos(GAMMA))-(Y2*Sin(GAMMA))
      Y(L)=(X2*Sin(GAMMA))+(Y2*Cos(GAMMA))
      Z(L)=Z2
   Next L
   Return


   ' -- Convert the 3d coords into 2d coords (allows for relocation of object)
   COORD_CONV:
   For L=0 To NUMPOINTS-1
      ZDIV=Z(L)+OBJECTX+DVP
      SX(L)=XO+((X(L)+OBJECTX)*DVP)/ZDIV
      SY(L)=YO+((Y(L)+OBJECTY)*DVP)/ZDIV
   Next L
   Return

   ' -- Sort the surfaces to give the object a hidden surface look.
   _SORT_SURFACES:
   Repeat
      _SWAP=False
      For L=0 To NUMSURFACES-1
         P1Z=Z(_SORTED(L,0))
         P2Z=Z(_SORTED(L,1))
         P3Z=Z(_SORTED(L,2))
         P4Z=Z(_SORTED(L,3))
         P1NZ=Z(_SORTED(L+1,0))
         P2NZ=Z(_SORTED(L+1,1))
         P3NZ=Z(_SORTED(L+1,2))
         P4NZ=Z(_SORTED(L+1,3))
         S=0
         If P1Z<P1NZ or P1Z<P2NZ or P1Z<P3NZ or P1Z<P4NZ
            Inc S
         End If
         If P2Z<P1NZ or P2Z<P2NZ or P2Z<P3NZ or P2Z<P4NZ
            Inc S
         End If
         If P3Z<P1NZ or P3Z<P2NZ or P3Z<P3NZ or P3Z<P4NZ
            Inc S
         End If
         If P4Z<P1NZ or P4Z<P2NZ or P4Z<P3NZ or P4Z<P4NZ
            Inc S
         End If
         If S=4
            Swap _SORTED(L,0),_SORTED(L+1,0) : Rem Swap 3d coords
            Swap _SORTED(L,1),_SORTED(L+1,1)
            Swap _SORTED(L,2),_SORTED(L+1,2)
            Swap _SORTED(L,3),_SORTED(L+1,3)
            Swap _SORTED(L,4),_SORTED(L+1,4) : Rem Swap ink colour
            _SWAP=True
         End If
      Next L
   Until _SWAP=False
   Return


   DRW_OBJECT:

   ' -- Read the connections and join the dots!
   For L=0 To NUMSURFACES
      P1=_SORTED(L,0)
      P2=_SORTED(L,1)
      P3=_SORTED(L,2)
      P4=_SORTED(L,3)
      I=_SORTED(L,4)
      Ink I
      Polygon SX(P1),SY(P1) To SX(P2),SY(P2) To SX(P3),SY(P3) To SX(P4),SY(P4) To SX(P1),SY(P1)
   Next L
   Return


   SETUP_OBJECT:

   ' -- Simple - just read in the coords for the object ( -3d )
   Restore "OBJECT"+Str$(OBJECT)-" "
   Read NUMPOINTS
   For L=0 To NUMPOINTS-1
      Read FX(L),FY(L),FZ(L)
   Next L
   Restore "CONNECT"+Str$(OBJECT)-" "
   Read NUMC : Rem       No of connections is effectively the no. of surfaces
   S=0
   For L=0 To NUMC-1
      Read P1,P2,P3,P4,_INK
      _SORTED(S,0)=P1
      _SORTED(S,1)=P2
      _SORTED(S,2)=P3
      _SORTED(S,3)=P4
      _SORTED(S,4)=_INK
      Inc S
   Next L
   NUMSURFACES=NUMC-1
   Return


   OBJECT1:
   Data 16
   Data -30,30,-30
   Data 30,30,-30
   Data 30,-30,-30
   Data -30,-30,-30
   Data -20,20,-40
   Data 20,20,-40
   Data 20,-20,-40
   Data -20,-20,-40
   Data -30,30,30
   Data 30,30,30
   Data 30,-30,30
   Data -30,-30,30
   Data -20,20,40
   Data 20,20,40
   Data 20,-20,40
   Data -20,-20,40

   ' p1,p2,p3,p4, ink colour
   CONNECT1:
   Data 6
   Data 0,8,11,3,1
   Data 0,8,9,1,2
   Data 1,9,10,2,1
   Data 2,10,11,3,2
   Data 4,5,6,7,3
   Data 12,13,14,15,3

End Proc
Procedure GO_LANDSCAPES[SCAPES]
   ' - Code - Dug

   ' - Paste message at bottom
   For Y=0 To 33 Step 2
      Screen Copy 1,0,153+Y,320,153+Y+1 To 1,0,218+Y
      Wait Vbl
   Next Y
   For Y=33 To 0 Step -2
      Screen Copy 1,0,153+Y,320,153+Y+1 To 1,0,218+Y
      Wait Vbl
   Next Y

   ' - Define array (uses a lot of memory)
   Dim Z(50,50),X(50,50),Y(50,50)

   ' - Open screen 2 so we can cover the font while we close
   ' - screen 0 to remove the double buffer
   Screen Open 2,320,130,4,Lowres
   Flash Off : Curs Off : Cls 0 : Hide
   Screen Display 2,,117,320,130
   Screen To Front 2
   Screen Close 0

   Screen Open 0,320,130,4,Lowres
   Curs Off : Cls 0 : Hide : Flash Off
   Screen Display 0,,117,320,130
   Screen To Front 0
   Screen Close 2

   ' - Define constants
   NC=20
   NR=12
   RANDS=15
   BASE=-5
   SEALEVEL=0
   X=120
   Y=60
   COUNTER=0

   ' - Main loop
   M_PRESSED=False
   Repeat
      Gosub CALCULATE_LANDSCAPE
      Gosub DRW_LANDSCAPE
      Inc COUNTER
   Until COUNTER=SCAPES or Mouse Key=1 or M_PRESSED

   Wait 30
   Fade 1 : Wait 15

   ' - End of part
   Pop Proc


   CALCULATE_LANDSCAPE:

   XADD=0
   For R=0 To NR
      For C=0 To NC
         If C=0 and R=0 : Rem Initial peek (Z not determined by any neighbours)
            Z(R,C)=BASE+Rnd(RANDS)
         Else
            If C=0 : Rem One neighbour above
               Z1=Z(R-1,C)
               Z(R,C)=Z1-RANDS/2+Rnd(RANDS)
            Else
               If R=0 : Rem One neighbour to the left
                  Z1=Z(R,C-1)
                  Z(R,C)=Z1-RANDS/2+Rnd(RANDS)
               Else
                  Rem Two neighbours - left and above
                  Z1=Z(R-1,C)
                  Z2=Z(R,C-1)
                  Z(R,C)=(Z1+Z2)/2-RANDS/2+Rnd(RANDS)
               End If
            End If
         End If

         If Mouse Key=1
            M_PRESSED=True
            Exit 2
         End If

      Next C
   Next R

   For R=0 To NR
      For C=0 To NC
         If Z(R,C)<SEALEVEL : Rem Sea level?
            Z(R,C)=0
         End If

         X(R,C)=C*10+XADD : Rem Adjust X/Y coords
         Y(R,C)=R*5-Z(R,C)

         If Mouse Key=1
            M_PRESSED=True
            Exit 2
         End If
      Next C
      Add XADD,-10
   Next R

   Fade 1 : Wait 15
   Cls 0
   Colour 0,0
   Colour 1,$843
   Colour 2,$F84
   Return


   DRW_LANDSCAPE:
   For R=1 To NR
      For C=1 To NC
         X1=X(R-1,C-1)+X
         Y1=Y(R-1,C-1)+Y
         X2=X(R-1,C)+X
         Y2=Y(R-1,C)+Y
         X3=X(R,C)+X
         Y3=Y(R,C)+Y
         X4=X(R,C-1)+X
         Y4=Y(R,C-1)+Y
         Ink 2
         Polygon X1,Y1 To X2,Y2 To X3,Y3 To X4,Y4 To X1,Y1
         Ink 1 : Polyline X1,Y1 To X2,Y2 To X3,Y3 To X4,Y4 To X1,Y1
         If Mouse Key=1
            M_PRESSED=True
            Exit 2
         End If
      Next C
   Next R
   Return

End Proc
Procedure _CLOSE_EAGLE_SCREENS

   ' - Fade and close screens 1 and 0
   Screen 1
   Fade 1 : Wait 15
   Screen Close 1

   Screen 0
   Fade 1 : Wait 15
   Screen Close 0

End Proc

' - Fit Time and Equalizer and Lines
Procedure FIT_EQU_LINES

   ' - Calling procedure for Fit, Equalizer and Bob lines

   SETUP_FONT
   NEW_TEXT_SCREEN["page3"]
   Load "no-refund!:stuff/circles",1
   Load "no-refund!:stuff/equalizer_pic",9
   Wait 100
   CLEAR_TEXT_SCREEN
   SHUT_TEXT_SCREENS

   ' - Call PARTS
   FIT_TIME[400]
   THE_EQUALIZER[4500]
   _BOB_BOXES[1008]

End Proc
Procedure FIT_TIME[TIME]
   ' - Code - Matt
   ' - GFX - Matt

   ' - Open two 2 colour screens
   Screen Open 0,500,400,2,Lowres
   Palette 0,0
   Curs Off : Cls 0 : Hide : Flash Off
   Screen Offset 0,90,75
   Autoback 0

   Screen Open 1,500,400,2,Lowres
   Palette 0,0
   Curs Off : Cls 0 : Hide : Flash Off
   Screen Offset 1,90,75
   Autoback 0

   ' - Paste the circles on screen 0
   Screen To Front 0
   Screen 0
   For Y=0 To 468 Step 52
      X=0
      For _ROW=1 To 12
         Paste Bob X,Y,1
         X=X+52
      Next _ROW
   Next Y

   ' - And on screen 1
   Screen To Front 1
   Screen 1
   For Y=0 To 468 Step 52
      X=0
      For _ROW=1 To 12
         Paste Bob X,Y,1
         X=X+52
      Next _ROW
   Next Y

   Screen To Back 1

   Dual Playfield 0,1
   Wait Vbl

   ' - Set up the lovely flash
   Screen 0
   Flash 1,"(eef,1)(aaf,1)"
   Flash 9,"(aaf,1)(eef,1)"
   Flash 0,"(f00,1)(000,1)"

   ' - Define the move string
   M$="(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)"
   M$=M$+"(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)L"

   N$="(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)"
   N$=N$+"(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)L"

   Channel 0 To Screen Offset 0
   Channel 1 To Screen Offset 1

   ' - Start the screens moving with a sligh pause between each
   Move Y 0,N$
   Move X 1,N$
   Move On 0
   Move On 1

   Wait 30

   Move X 0,N$
   Move Y 1,N$
   Move On 0
   Move On 1

   ' - Main loop
   COUNTER=0
   Repeat
      Screen 0
      Screen Swap
      Screen 1
      Screen Swap

      Wait Vbl

      Screen 0
      Synchro
      Screen 1
      Synchro
      Inc COUNTER
   Until COUNTER>=TIME or Mouse Key=1

   ' - Fade the screens and clean up
   Screen 0
   Flash Off
   Fade 1 : Wait 15
   Move Off
   Synchro On
   Autoback 2
   Bob Update On

   Screen 1
   Autoback 2
   Bob Update On
   Screen Close 0
   Screen Close 1
   Erase 1

End Proc
Procedure THE_EQUALIZER[TIME]
   ' - Code - Rob
   ' - GFX - Rob

   ' - If you have a problem,
   ' - If no one else can help
   ' - And if you can't find the A-Team
   ' - Maybe YOU should hire THE EQUALIZER! (aka THE OLD GIT)

   ' - Open small screen to store palette
   Screen Open 0,20,20,8,Lowres
   Curs Off : Cls 0 : Flash Off : Hide
   Palette 0,0,0,0,0,0,0,0

   ' - Unpack equalizer screen
   Unpack 9 To 1
   Screen Hide 1
   Erase 9

   ' - Store the palette on screen 0
   Screen 0
   Get Palette 1

   ' - Set all colours to black and then show screen
   Screen 1
   Palette 0,0,0,0,0,0,0,0
   Screen Show 1

   ' - Create rainbow for equalizer bar
   Set Rainbow 0,5,257,"","",""
   For CTR=0 To 256
      Rain(0,CTR)=$0
   Next CTR
   Rainbow 0,0,40,256

   ' - Fade the screen up from the palette stored on 0
   Fade 1 To 0
   Wait 15
   Screen Close 0


   ' - Move the rainbow about a bit
   COUNTER=0
   CURRENT=256
   RED=70
   Repeat
      Rainbow 0,0,60,256
      If Vumeter(2)<10
         ' - Music is off
         If CURRENT<256
            Rain(0,CURRENT)=$0
            Inc CURRENT
            PAUSE[20]
         End If
      Else
         ' - Music is on
         If CURRENT>RED
            For Y=CURRENT To RED Step -1
               ' - Draw green
               Rain(0,Y)=$B0
            Next Y
            CURRENT=RED
            For Y=CURRENT To 1 Step -1
               ' - Draw red
               Rain(0,Y)=$B00
            Next Y
            CURRENT=1
         Else
            If CURRENT>1
               For Y=CURRENT To 1 Step -1
                  ' - Draw red
                  Rain(0,Y)=$B00
               Next Y
               CURRENT=1
            End If
         End If
         PAUSE[5]
      End If
      Inc COUNTER
   Until COUNTER=TIME or Mouse Key=1

   For Y=CURRENT To 256
      View
      Rain(0,Y)=$0
   Next Y

   Fade 1 : Wait 15
   Rainbow Del
   Screen Close 1

   ' - END!

End Proc
Procedure PAUSE[TIME]
   ' - When a wait 1 is too long you need - SUPER PAUSE!
   For CTR=0 To TIME
      ' - Very complicated!
   Next CTR
End Proc
Procedure _BOB_BOXES[TIME]
   ' - Code - Matt & Rob

   Screen Open 0,320,256,2,Lowres
   Curs Off : Cls 0 : Flash Off : Hide : Cls 0

   ' - Set ink colour to Dark blue and background to Black
   Palette 0,$44D
   Gr Writing 2
   Ink 1
   Synchro Off

   ' - Setup bobs
   For B=1 To 4
      Channel B To Bob B
   Next B

   Bob 1,100,80,0
   Bob 2,200,80,0
   Bob 3,200,180,0
   Bob 4,100,180,0

   ' - Define Bob Movement string
   M$="(1,-6,3)(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3)(1,6,3) "
   M$=M$+"(1,6,3)(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3)(1,-6,3)L"

   N$="(1,-7,3)(1,-6,3)(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3)(1,6,3)(1,7,3)"
   N$=N$+"(1,7,3)(1,6,3)(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3)(1,-6,3)(1,-7,3)L"

   ' - Start movement (with delay)
   Move X 1,M$
   Move X 2,N$
   Move On
   Wait 15

   Move Y 1,M$
   Move Y 2,N$
   Move On
   Wait 15

   Move X 3,M$
   Move X 4,N$
   Move On
   Wait 15

   Move Y 3,M$
   Move Y 4,N$
   Move On

   ' - Main loop - until time is up or mouse button is pressed
   TIME_COUNTER=0
   Repeat

      ' - Define variables
      X1=X Bob(1)
      Y1=Y Bob(1)
      X2=X Bob(2)
      Y2=Y Bob(2)
      X3=X Bob(3)
      Y3=Y Bob(3)
      X4=X Bob(4)
      Y4=Y Bob(4)

      ' - Draw lines and boxes (comment the others out to see what each does)
      Polyline X1,Y1 To X2,Y2 To X3,Y3 To X4,Y4 To X1,Y1
      Box X Bob(1),Y Bob(1) To X Bob(2),Y Bob(2)
      Box X Bob(2),Y Bob(2) To X Bob(3),Y Bob(3)
      Box X Bob(3),Y Bob(3) To X Bob(4),Y Bob(4)
      Box X Bob(4),Y Bob(4) To X Bob(1),Y Bob(1)
      '
      Synchro
      Inc TIME_COUNTER
   Until TIME_COUNTER=TIME or Mouse Key=1

   ' - Clean up
   Fade 1 : Wait 15
   Bob Off
   Move Off
   Synchro On

   Screen Close 0

End Proc

' - Dot cubes
Procedure FIRST_DOT_CUBE

   ' - Calling procedure for Dot cubes

   SETUP_FONT
   NEW_TEXT_SCREEN["page4"]
   Load "no-refund!:stuff/dot_cube_pic",8
   Load "no-refund!:stuff/new_cube",6
   CLEAR_TEXT_SCREEN
   SHUT_TEXT_SCREENS

   ' - Call PARTS
   _DOT_CUBE[8,6]
   _RANDOM_SCR_FILL
End Proc
Procedure COOL_DOT_CUBE

   ' - Calling procedure for Dot cubes

   SETUP_FONT
   NEW_TEXT_SCREEN["page15"]
   Load "no-refund!:stuff/cube_restrict_pic",10
   Load "no-refund!:stuff/cube_restrict",7
   CLEAR_TEXT_SCREEN
   SHUT_TEXT_SCREENS

   ' - Call PART
   _DOT_CUBE[10,7]
   _RANDOM_SCR_FILL

End Proc
Procedure _DOT_CUBE[PIC,PATH]
   ' - Code - Dug
   ' - Gfx - Matt

   ' - Setup background graphics
   Unpack PIC To 1
   Palette 0,0
   Erase PIC

   ' - Open screen for cube
   Screen Open 0,320,256,2,Lowres
   Flash Off : Curs Off : Cls 0 : Hide
   Double Buffer
   Autoback 0

   ' - Set dual playfield
   Screen To Front 1
   Screen 0
   Wait Vbl
   Dual Playfield 0,1
   Wait Vbl
   Palette 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0

   ' - Fade it on
   Screen 0
   Fade 1,$12,$DDF,,,,,,,0,$23
   Wait 15

   NUM_FRAMES=200
   NUM_POINTS=125

   _OFFSET=0
   For F=1 To NUM_FRAMES : Rem Do all of 36 frames one by one.. then repeat
      Screen Swap : Wait Vbl
      Cls 0
      Gosub _DO_SINGLE_PLT
      Exit If Mouse Key=1
   Next F
   Erase PATH

   Pop Proc

   _DO_SINGLE_PLT:
   For P=1 To NUM_POINTS : Rem 36 coords of x,y
      SXN=Deek(Start(PATH)+_OFFSET) : Add _OFFSET,2
      SYN=Deek(Start(PATH)+_OFFSET) : Add _OFFSET,2
      Plot SXN,SYN
   Next P
   Return

   ' Hmmm, That wasn't very complicated for a 125 point dot cube!

End Proc
Procedure _RANDOM_SCR_FILL
   ' - Code - Matt

   Screen 0
   Fade 2,,,,,,,,,,$DDF
   Screen 1
   Ink 9
   X=160
   Y=125
   For CTR=0 To 55

      X1=Rnd(250)
      Y1=Rnd(200)
      X2=Rnd(250)
      Y2=Rnd(200)
      X3=Rnd(250)
      Y3=Rnd(200)
      X4=Rnd(250)
      Y4=Rnd(200)
      Bar X+X1,Y+Y1 To X+X1+100,Y+Y1+100
      Bar X-X2,Y-Y2 To X-X2+100,Y-Y2+100
      Bar X+X3,Y-Y3 To X+X3+100,Y-Y3+100
      Bar X-X4,Y+Y4 To X-X4+100,Y+Y4+100

      Wait Vbl

   Next CTR

   Wait 30
   Screen 0
   Fade 1 : Wait 15
   Screen Close 1
   Screen Close 0

End Proc


' --------------- DISK TWO ---------------


' - Big Circles, Star bobs, colour cycling piccy and vector faces
Procedure SLIDE_STARS_CYCLE_FACES

   ' - Display text screen and load stuff!
   SETUP_FONT
   NEW_TEXT_SCREEN["page5"]
   Load "no-refund2!:stuff/green_ball",1
   Load "no-refund2!:stuff/cycle_pic",9
   Load "no-refund2!:stuff/big_circle1",7
   Wait 100
   CLEAR_TEXT_SCREEN
   SHUT_TEXT_SCREENS

   ' - Call procedures
   WEIRD_COMA_THING[25]
   STAR_BOBS
   BRIGHT_COLOURS[55000]
   TWO_FACES

End Proc
Procedure WEIRD_COMA_THING[TIME]
   ' - Code - Rob
   ' - GFX - Rob

   ' - Upack circle pic
   Unpack 7 To 2
   Screen Hide 2
   Erase 7

   ' - Open two big screen to play with
   Screen Open 0,500,500,2,Lowres
   Curs Off : Cls 0 : Hide : Flash Off
   Palette 0,0

   Screen Open 1,500,500,2,Lowres
   Curs Off : Cls 0 : Hide : Flash Off
   Palette 0,0

   ' - Paste picture on screen 0
   Screen Copy 2,0,0,400,400 To 0,50,50
   Screen Offset 0,80,120

   ' - Paste picture on screen 1
   Screen Copy 2,0,0,400,400 To 1,50,50
   Screen Offset 1,80,120

   ' - Lose the original
   Screen Close 2

   ' - Set dual playfield
   Screen Hide 0
   Wait Vbl
   Dual Playfield 0,1
   Wait Vbl

   ' - Define move strings
   M$="(1,-3,2)(1,-2,2)(1,-1,2)(1,1,2)(1,2,2)(1,3,2) "
   M$=M$+"(1,3,2)(1,2,2)(1,1,2)(1,-1,2)(1,-2,2)(1,-3,2)L"

   M1$="(1,3,2)(1,2,2)(1,1,2)(1,-1,2)(1,-2,2)(1,-3,2) "
   M1$=M1$+"(1,-3,2)(1,-2,2)(1,-1,2)(1,1,2)(1,2,2)(1,3,2)L"

   ' - Define screen movement channels
   For SCRN=0 To 1
      Channel SCRN To Screen Offset SCRN
   Next SCRN

   ' - Start movement
   Move X 1,M1$
   Move X 0,M$
   Move On
   Wait 8
   Move Y 0,M$
   Move Y 1,M1$
   Move On

   ' - Get ready
   Screen 0
   Randomize Timer
   Screen Show 0
   Wait Vbl
   CTR=0

   ' - GO!
   Repeat
      W=Rnd($FFF)
      W2=Rnd($FFF)
      W3=$202

      ' - Randomly fade colours around.
      Fade 1,W3,W,,,,,,,,W2
      Wait 15
      Inc CTR
   Until CTR=TIME or Mouse Key=1

   ' - Clean up
   Fade 2 : Wait 30
   Screen Close 0
   Screen Close 1

End Proc
Procedure STAR_BOBS
   ' - Code - Dug
   ' - GFX - Matt

   ' - Smart Stars!

   ' - Open screen and define palette
   Screen Open 0,320,256,4,Lowres
   Curs Off : Cls 0 : Hide : Flash Off
   Palette $0,$F0,$B0,$60
   Double Buffer

   ' - Define stuff
   MP=False
   PATTERN=1
   CHANGE_PATTERN[PATTERN]

   ' - Main loop
   Repeat

      For L=0 To 250
         Amal On
         If Mouse Key=1
            MP=True
            Exit
         End If
         Wait Vbl
      Next L

      If Not MP
         Inc PATTERN
         CHANGE_PATTERN[PATTERN]
      End If

   Until PATTERN>3 or MP

   ' - Clean up
   Fade 1 : Wait 15
   Bob Off
   Erase 1
   Screen Close 0

End Proc
Procedure CHANGE_PATTERN[P]
   ' - Code - Dug

   ' - Fade the bobs
   Fade 1,0,0,0,0
   Wait 15

   ' - Clear the bobs
   Bob Off
   SIZE=3
   SPEED=1

   ' - Set the colours back up
   Fade 1,$0,$F0,$B0,$60
   Wait 15

   On P Gosub OVAL,PATTERN4,PATTERN3

   Pop Proc

   ' - Bob patterns...

   OVAL:
   S$=Str$(3)
   Q$=Str$(1)

   MX$="("+Q$+",5,"+S$+")("+Q$+",4,"+S$+")("+Q$+",3,"+S$+")("+Q$+",2,"+S$+")("+Q$+",1,"+S$+")("+Q$+",-1,"+S$+")("+Q$+",-2,"+S$+")("+Q$+",-3,"+S$+")("+Q$+",-4,"+S$+")("+Q$+",-5,"+S$+")"
   MX$=MX$+"("+Q$+",-5,"+S$+")("+Q$+",-4,"+S$+")("+Q$+",-3,"+S$+")("+Q$+",-2,"+S$+")("+Q$+",-1,"+S$+")("+Q$+",1,"+S$+")("+Q$+",2,"+S$+")("+Q$+",3,"+S$+")("+Q$+",4,"+S$+")("+Q$+",5,"+S$+")L"

   A$="Let R0=160 ; Let R1=125"
   A$=A$+"Move R0-X,R1-Y,25 "

   For B=0 To 10

      Bob B,160-B*2-15,30+B*10+15,1
      Channel B To Bob B

      Move X B,MX$
      Move On B
      Wait 10
      Move Y B,MX$
      Move On B

      Channel B To Bob B
      Amal B,A$

   Next B
   Return


   PATTERN3:
   S$=Str$(SIZE+2)
   Q$=Str$(SPEED)

   MX$="("+Q$+",5,"+S$+")("+Q$+",4,"+S$+")("+Q$+",3,"+S$+")("+Q$+",2,"+S$+")("+Q$+",1,"+S$+")("+Q$+",-1,"+S$+")("+Q$+",-2,"+S$+")("+Q$+",-3,"+S$+")("+Q$+",-4,"+S$+")("+Q$+",-5,"+S$+")"
   MX$=MX$+"("+Q$+",-5,"+S$+")("+Q$+",-4,"+S$+")("+Q$+",-3,"+S$+")("+Q$+",-2,"+S$+")("+Q$+",-1,"+S$+")("+Q$+",1,"+S$+")("+Q$+",2,"+S$+")("+Q$+",3,"+S$+")("+Q$+",4,"+S$+")("+Q$+",5,"+S$+")L"

   S$=Str$(SIZE+2-1)

   MY$="("+Q$+",5,"+S$+")("+Q$+",4,"+S$+")("+Q$+",3,"+S$+")("+Q$+",2,"+S$+")("+Q$+",1,"+S$+")("+Q$+",-1,"+S$+")("+Q$+",-2,"+S$+")("+Q$+",-3,"+S$+")("+Q$+",-4,"+S$+")("+Q$+",-5,"+S$+")"
   MY$=MY$+"("+Q$+",-5,"+S$+")("+Q$+",-4,"+S$+")("+Q$+",-3,"+S$+")("+Q$+",-2,"+S$+")("+Q$+",-1,"+S$+")("+Q$+",1,"+S$+")("+Q$+",2,"+S$+")("+Q$+",3,"+S$+")("+Q$+",4,"+S$+")("+Q$+",5,"+S$+")L"
   A$="Let R0=160 ; Let R1=125"
   A$=A$+"Move 160-X,125-Y,25"

   For B=0 To 9

      Bob B,160,80+B,1
      Channel B To Bob B
      Amal B,A$

      Move X B,MX$
      Move On B

      Move Y B,MY$
      Move On B

      Wait 5

   Next B
   Return


   PATTERN4:
   S$=Str$(SIZE)
   Q$=Str$(SPEED)

   MX$="("+Q$+",5,"+S$+")("+Q$+",4,"+S$+")("+Q$+",3,"+S$+")("+Q$+",2,"+S$+")("+Q$+",1,"+S$+")("+Q$+",-1,"+S$+")("+Q$+",-2,"+S$+")("+Q$+",-3,"+S$+")("+Q$+",-4,"+S$+")("+Q$+",-5,"+S$+")"
   MX$=MX$+"("+Q$+",-5,"+S$+")("+Q$+",-4,"+S$+")("+Q$+",-3,"+S$+")("+Q$+",-2,"+S$+")("+Q$+",-1,"+S$+")("+Q$+",1,"+S$+")("+Q$+",2,"+S$+")("+Q$+",3,"+S$+")("+Q$+",4,"+S$+")("+Q$+",5,"+S$+")L"

   S$=Str$(SIZE+2)

   MY$="("+Q$+",5,"+S$+")("+Q$+",4,"+S$+")("+Q$+",3,"+S$+")("+Q$+",2,"+S$+")("+Q$+",1,"+S$+")("+Q$+",-1,"+S$+")("+Q$+",-2,"+S$+")("+Q$+",-3,"+S$+")("+Q$+",-4,"+S$+")("+Q$+",-5,"+S$+")"
   MY$=MY$+"("+Q$+",-5,"+S$+")("+Q$+",-4,"+S$+")("+Q$+",-3,"+S$+")("+Q$+",-2,"+S$+")("+Q$+",-1,"+S$+")("+Q$+",1,"+S$+")("+Q$+",2,"+S$+")("+Q$+",3,"+S$+")("+Q$+",4,"+S$+")("+Q$+",5,"+S$+")L"
   A$="Let R0=160 ; Let R1=125"
   A$=A$+"Move 160-X,125-Y,25"

   For B=0 To 9

      Bob B,160,140,1
      Channel B To Bob B
      Amal B,A$

      Move X B,MX$
      Move On B

      Wait Vbl

      Move Y B,MY$
      Move On B

      Wait 3

   Next B
   Return

End Proc
Procedure BRIGHT_COLOURS[TIME]
   ' - Code - Matt
   ' - GFX - Matt

   ' - Unpack cycle picture
   Unpack 9 To 1
   Screen Hide 1
   Erase 9

   ' - Open 3 screens. (THREE?  Yes Three!)
   ' - Screen 0 hold the picture
   Screen Open 0,640,256,32,Lowres
   Curs Off : Cls 0 : Flash Off : Hide
   Get Palette 1
   Screen Offset 0,160,
   Screen Copy 1,0,0,320,256 To 0,170,0
   Screen Close 1

   ' - Screens 1 and 2 move over the top of it
   Screen Open 1,320,100,2,Lowres
   Screen Hide 1
   Curs Off : Cls 0 : Hide : Flash Off
   Screen Display 1,,-64,,
   Screen Show 1
   Screen To Front 1

   Screen Open 2,320,100,2,Lowres
   Screen Hide 2
   Curs Off : Cls 0 : Flash Off : Hide
   Screen Display 2,,300,,
   Screen Show 2
   Screen To Front 2

   ' Define screen movement
   Channel 0 To Screen Offset 0
   Channel 2 To Screen Display 2
   Channel 1 To Screen Display 1

   X$="(1,-6,4)(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3)(1,6,4)"
   X$=X$+"(1,6,4)(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3)(1,-6,4)L"

   Y$="(1,6,4)(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3)(1,-6,4)L"

   Y2$="(1,-6,4)(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3)(1,6,4)L"

   ' - Move the screens
   Move X 0,X$
   Move Y 1,Y$
   Move Y 2,Y2$
   Move On

   ' - Start the cycling
   Screen 0
   Shift Up 1,1,31,1

   ' - main loop
   COUNTER=0
   Repeat
      Inc COUNTER
   Until COUNTER=TIME or Mouse Key=1

   ' - Clean up
   Shift Up 1,0,31,0
   Wait 50

   Screen Close 0
   Screen Close 1
   Screen Close 2

End Proc
Procedure TWO_FACES
   ' - Code - Dug

   ' - Set up screen
   Screen Open 0,320,256,4,Lowres
   Flash Off : Curs Off : Cls 0 : Hide
   Double Buffer
   Autoback 0
   Degree
   Palette $1,$77A,$DDD,$0

   M=15
   Dim FX(M),FY(M),FZ(M) : Rem Frame coords (3D)
   Dim X(M),Y(M),Z(M) : Rem  Rotated coords (used by coord convert routines) (2D)
   Dim SUBFX(M),SUBFY(M),SUBFZ(M) : Rem Coords of rotated sub-face on base-face
   Dim SX(M),SY(M) : Rem     Screen coords of total rotated objects (2D)

   DVP=-200
   _XORG=Screen Width/2
   _YORG=Screen Height/2

   Gosub SETUP_FACES
   _DELAY=0
   Repeat
      Screen Swap : Wait Vbl
      Cls 0
      Gosub ROT_SUB_FACE
      Gosub SUB_FACE_2_3D_PLANE
      Gosub ROT_BOTH_FACES
      Gosub COORD_CONVERT
      Gosub DRW_ALL
      Add SPHI,10
      Add SGAMMA,15
      Add STHETA,5
      Inc _DELAY
      If _DELAY>15
         Add BPHI,5
         Add BGAMMA,10
         Add BTHETA,5
      End If
   Until _DELAY>100 or Mouse Key=1

   ' - Clean up
   Fade 1,$FFF,$FFF,$FFF,$FFF : Wait 15
   Fade 1 : Wait 15
   Autoback 2
   Screen Close 0

   Pop Proc


   DRW_ALL:

   ' -- Base face
   Ink 1
   Polygon SX(0),SY(0) To SX(1),SY(1) To SX(2),SY(2) To SX(3),SY(3) To SX(0),SY(0)
   ' -- Sub face
   Ink 2
   Polygon SX(4),SY(4) To SX(5),SY(5) To SX(6),SY(6) To SX(7),SY(7) To SX(4),SY(4)
   Return


   COORD_CONVERT:
   For L=0 To 1+BASEF_NP+SUBF_NP
      ZF=DVP+Z(L)
      SX(L)=_XORG+(X(L)*DVP)/ZF
      SY(L)=_YORG-(Y(L)*DVP)/ZF
   Next L
   Return


   SUB_FACE_2_3D_PLANE:
   ' -- Convert 3D coords of sub-face into 2D so we can use these as coords
   '    on the 'base-face'.
   For L=1+BASEF_NP To 1+BASEF_NP+SUBF_NP
      ZF=DVP+Z(L)
      SUBFX(L-1-BASEF_NP)=(X(L)*DVP)/ZF
      SUBFY(L-1-BASEF_NP)=(Y(L)*DVP)/ZF
      SUBFZ(L-1-BASEF_NP)=20
   Next L
   ' -- The Z coord of this object is now used as the Z of the 'base-face'
   Return


   ROT_SUB_FACE:
   For L=1+BASEF_NP To 1+BASEF_NP+SUBF_NP

      ' rotate about z
      X1=(FX(L)*Cos(SGAMMA))-(FY(L)*Sin(SGAMMA))
      Y1=(FX(L)*Sin(SGAMMA))+(FY(L)*Cos(SGAMMA))
      Z1=FZ(L)

      ' rotate about y
      X2=(X1*Cos(SPHI))+(Z1*Sin(SPHI))
      Y2=Y1
      Z2=-(X1*Sin(SPHI))+(Z1*Cos(SPHI))

      ' rotate about x
      X(L)=X2
      Y(L)=(Y2*Cos(STHETA))-(Z2*Sin(STHETA))
      Z(L)=(Y2*Sin(STHETA))+(Z2*Cos(STHETA))
   Next L
   Return


   ROT_BOTH_FACES:
   For L=0 To BASEF_NP

      ' rotate about z
      X1=(FX(L)*Cos(BGAMMA))-(FY(L)*Sin(BGAMMA))
      Y1=(FX(L)*Sin(BGAMMA))+(FY(L)*Cos(BGAMMA))
      Z1=FZ(L)

      ' rotate about y
      X2=(X1*Cos(BPHI))+(Z1*Sin(BPHI))
      Y2=Y1
      Z2=-(X1*Sin(BPHI))+(Z1*Cos(BPHI))

      ' rotate about x
      X(L)=X2
      Y(L)=(Y2*Cos(BTHETA))-(Z2*Sin(BTHETA))
      Z(L)=(Y2*Sin(BTHETA))+(Z2*Cos(BTHETA))
   Next L
   For L=0 To SUBF_NP

      ' rotate about z
      X1=(SUBFX(L)*Cos(BGAMMA))-(SUBFY(L)*Sin(BGAMMA))
      Y1=(SUBFX(L)*Sin(BGAMMA))+(SUBFY(L)*Cos(BGAMMA))
      Z1=SUBFZ(L)

      ' rotate about y
      X2=(X1*Cos(BPHI))+(Z1*Sin(BPHI))
      Y2=Y1
      Z2=-(X1*Sin(BPHI))+(Z1*Cos(BPHI))

      ' rotate about x
      X(1+L+BASEF_NP)=X2
      Y(1+L+BASEF_NP)=(Y2*Cos(BTHETA))-(Z2*Sin(BTHETA))
      Z(1+L+BASEF_NP)=(Y2*Sin(BTHETA))+(Z2*Cos(BTHETA))
   Next L
   Return


   SETUP_FACES:
   Restore BASE_FACE : Read BASEF_NP
   For P=0 To BASEF_NP
      Read FX(P),FY(P),FZ(P)
      X(P)=FX(P)
      Y(P)=FY(P)
      Z(P)=FZ(P)
   Next P
   Restore SUB_FACE : Read SUBF_NP
   For L=0 To SUBF_NP
      P=L+BASEF_NP+1
      Read FX(P),FY(P),FZ(P)
      X(P)=FX(P)
      Y(P)=FY(P)
      Z(P)=FZ(P)
   Next L
   Return


   BASE_FACE:
   Data 3
   Data -45,45,20
   Data 45,45,20
   Data 45,-45,20
   Data -45,-45,20

   SUB_FACE:
   Data 3
   Data -25,25,20
   Data 25,25,20
   Data 25,-25,20
   Data -25,-25,20

End Proc

' - Plasma, Pattern
Procedure PLASMA

   ' - Calling procedure for the Plasma section

   SETUP_FONT
   NEW_TEXT_SCREEN["page6"]
   ' - Load plasma stuff
   Load "no-refund2!:stuff/plasma_bob",1
   Load "no-refund2!:stuff/new_plasma",9
   Load "no-refund2!:stuff/plasma_pic2",10
   CLEAR_TEXT_SCREEN
   SHUT_TEXT_SCREENS

   ' - Call plasma procedure
   PLASMA_HB
   FLAG[150]
End Proc
Procedure PLASMA_HB
   ' - Code - Matt & Rob
   ' - Plasma screens were generated using the CYS plasma generator
   ' - It was written by Dug and eats memory like a big red memory eater!
   ' - BOB - Matt

   ' - Plasma screen 1
   Unpack 10 To 1
   Screen Hide 1
   Erase 10
   Hide
   '
   ' - Plasma screen 2
   Unpack 9 To 0
   Palette 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
   Erase 9

   ' - BIG half-bright bob
   Double Buffer
   Set Bob 1,1,%100000,
   Bob 1,15,65,1

   ' - Move bob
   Channel 1 To Bob 1
   M$="(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)"
   M$=M$+"(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3) L"
   Move Y 1,M$
   Move On

   Fade 1 To 1 : Wait 15

   ' - Start colour cycling
   Shift Up 1,1,31,1

   Wait 150

   ' - Paste new plasma screen on
   For Y=0 To 256
      Screen Copy 1,0,Y,320,Y+1 To 0,0,Y
      Screen Swap
      Screen Copy 1,0,Y,320,Y+1 To 0,0,Y
      Screen Swap
      Wait Vbl
   Next Y
   Wait 150

   ' - End part
   Fade 1 : Wait 15
   Erase 1
   Screen Close 0
   Screen Close 1

End Proc
Procedure FLAG[TIME]
   ' - Code - Rob

   ' - Open 2 colour screen
   Screen Open 0,320,256,2,Lowres
   Curs Off : Cls 0 : Hide : Flash Off
   Palette 0,$FFF
   Ink 1

   ' - Turn everything on/off
   Double Buffer
   Autoback 0
   Bob Update Off
   Synchro Off

   ' - Set a few constants
   XB1=50
   XB2=100
   XB3=150
   XB4=200
   XB5=250

   ' - Set a few more
   YB1=50
   YB2=100
   YB3=150
   YB4=200


   ' - Position the bobs

   ' - Bob layout...

   '   0--1--2--3--4
   '   |  |  |  |  |
   '   5--6--7--8--9
   '   |  |  |  |  |
   '  10-11-12-13-14
   '   |  |  |  |  |
   '  15-16-17-18-19

   ' - Top row
   Bob 0,XB1,YB1,0
   Bob 1,XB2,YB1,0
   Bob 2,XB3,YB1,0
   Bob 3,XB4,YB1,0
   Bob 4,XB5,YB1,0

   ' - Second row
   Bob 5,XB1,YB2,0
   Bob 6,XB2,YB2,0
   Bob 7,XB3,YB2,0
   Bob 8,XB4,YB2,0
   Bob 9,XB5,YB2,0

   ' - Er, Third row, I think
   Bob 10,XB1,YB3,0
   Bob 11,XB2,YB3,0
   Bob 12,XB3,YB3,0
   Bob 13,XB4,YB3,0
   Bob 14,XB5,YB3,0

   ' - Could well be the fourth row
   Bob 15,XB1,YB4,0
   Bob 16,XB2,YB4,0
   Bob 17,XB3,YB4,0
   Bob 18,XB4,YB4,0
   Bob 19,XB5,YB4,0



   ' - Define the move string for all bobs
   MOVE$="(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3)"
   MOVE$=MOVE$+"(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3)L "

   ' - Assign the move string to all bobs
   For CTR=0 To 19
      Channel CTR To Bob CTR
      Move Y CTR,MOVE$
      Move On
      Wait Vbl
      Synchro
      Move X CTR,MOVE$
      Move On
      Wait Vbl
      Synchro
   Next CTR

   ' - Main Loop

   COUNTER=0
   Repeat

      ' - Draw lots of lines
      Gr Locate X Bob(0),Y Bob(0)
      Draw To X Bob(5),Y Bob(5)
      Draw To X Bob(10),Y Bob(10)
      Draw To X Bob(15),Y Bob(15)
      Draw To X Bob(16),Y Bob(16)
      Draw To X Bob(11),Y Bob(11)
      Draw To X Bob(6),Y Bob(6)
      Draw To X Bob(1),Y Bob(1)
      Draw To X Bob(2),Y Bob(2)
      Draw To X Bob(7),Y Bob(7)
      Draw To X Bob(12),Y Bob(12)
      Draw To X Bob(17),Y Bob(17)
      Draw To X Bob(18),Y Bob(18)
      Draw To X Bob(13),Y Bob(13)
      Draw To X Bob(8),Y Bob(8)
      Draw To X Bob(3),Y Bob(3)
      Draw To X Bob(4),Y Bob(4)
      Draw To X Bob(9),Y Bob(9)
      Draw To X Bob(14),Y Bob(14)
      Draw To X Bob(19),Y Bob(19)
      Draw To X Bob(18),Y Bob(18)

      Gr Locate X Bob(0),Y Bob(0)
      Draw To X Bob(1),Y Bob(1)

      Gr Locate X Bob(2),Y Bob(2)
      Draw To X Bob(3),Y Bob(3)

      Gr Locate X Bob(5),Y Bob(5)
      Draw To X Bob(6),Y Bob(6)
      Draw To X Bob(7),Y Bob(7)
      Draw To X Bob(8),Y Bob(8)
      Draw To X Bob(9),Y Bob(9)

      Gr Locate X Bob(10),Y Bob(10)
      Draw To X Bob(11),Y Bob(11)
      Draw To X Bob(12),Y Bob(12)
      Draw To X Bob(13),Y Bob(13)
      Draw To X Bob(14),Y Bob(14)

      Gr Locate X Bob(16),Y Bob(16)
      Draw To X Bob(17),Y Bob(17)

      ' - Manual update
      Screen Swap : Wait Vbl : Cls 0 : Synchro
      Inc COUNTER
   Until COUNTER=TIME or Mouse Key=1

   ' - Clean up this town!
   Fade 1
   Wait 15
   Autoback 2
   Bob Update On
   Synchro On
   Screen Close 0

   ' - Bye Bye!
End Proc

' - Patterns, Vector Scroll, Big Logo
Procedure PATT_VECSCRL_LOGO

   ' - Green patter things, Cheezy and Swaying Logo
   SETUP_FONT
   NEW_TEXT_SCREEN["page7"]
   Load "no-refund2!:stuff/sway_logo",7
   Wait 100
   CLEAR_TEXT_SCREEN
   SHUT_TEXT_SCREENS

   ' - Call stuff
   _TOP
   VECTOR_SCROLL
   SWAYING_LOGO

End Proc
Procedure _TOP
   ' - Code - Matt

   Screen Open 1,640,200,2,Hires
   Curs Off : Cls 0 : Hide : Flash Off : Palette 0,$50
   Screen Display 1,,60,,

   Double Buffer
   Autoback 0
   Bob Update Off

   For A=1 To 6
      Channel A To Bob A
      Bob A,100,100,0
   Next A

   M0$="(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)"
   M0$=M0$+"(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3) L"

   M1$="(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)"
   M1$=M1$+"(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3) L"

   M2$="(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3)"
   M2$=M2$+"(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3) L"

   M3$="(1,-6,3)(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3)(1,6,3)"
   M3$=M3$+"(1,6,3)(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3)(1,-6,3) L"

   M4$="(1,-7,3)(1,-6,3)(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3)(1,6,3)(1,7,3)"
   M4$=M4$+"(1,7,3)(1,6,3)(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3)(1,-6,3)(1,-7,3) L"

   Move Y 6,M0$
   Move On
   Wait 13
   Move X 6,M0$
   Move On

   Move X 1,M1$
   Move On
   Wait 13
   Move Y 1,M1$
   Move On

   Move Y 2,M2$
   Move On
   Wait 17
   Move X 2,M2$
   Move On

   Move X 3,M3$
   Move On
   Wait 20
   Move Y 3,M3$
   Move On

   Move Y 4,M4$
   Move On
   Wait 23
   Move X 4,M4$
   Move On

   Synchro Off

   COUNTER=0

   Repeat

      Q=X Bob(1)
      Q2=X Bob(2)
      Q3=X Bob(3)
      Q4=X Bob(4)
      Q5=X Bob(5)
      W=Y Bob(1)
      W2=Y Bob(2)
      W3=Y Bob(3)
      W4=Y Bob(4)
      W5=Y Bob(5)

      Screen Swap : Wait Vbl : Screen Swap
      Ink 1
      Draw Q,W To Q2,W2
      Draw Q2,W2 To Q3,W3
      Draw Q3,W3 To Q4,W4
      Draw Q4,W4 To Q5,W5

      Screen Copy 1,0,0,190,256 To 1,205,0
      Screen Copy 1,0,0,190,256 To 1,410,0
      Synchro
      Inc COUNTER

   Until COUNTER=200 or Mouse Key=1

   Screen Swap
   Fade 3,$5,$5
   Wait 15*3

   Move Off
   Synchro On
   Autoback 2
   Bob Update On

   ' - Don't close the screens here!  That's done in Vector Scroll

End Proc
Procedure VECTOR_SCROLL
   ' - Code - Dug

   ' - Setup display screen
   Screen Open 0,320,200,2,Lowres
   Flash Off : Curs Off : Hide : Palette $5,$772
   Double Buffer
   Autoback 0
   Screen Display 0,,60,,
   Screen Close 1
   Screen To Front 0

   ' -- Function to return the code of a letter (a=0 z=25)
   Def Fn CHAR_OBJ(CO$)=Asc(CO$)-97

   X_ORG=100
   Y_ORG=115
   DVP=-240

   LINE_MAX=5 : Rem      Max no. of objects on screen at once
   NUM_CHARS=26 : Rem      No. of letters in char set

   Dim LINE(LINE_MAX,3) : Rem     Objects used in current line (x,y,z,letter to draw)
   Dim OBJECT(NUM_CHARS,13) : Rem Detail of each letter (7 pairs connected)
   Dim OBJ_COMP(5,2) : Rem        X/Y/Z offsets for each point


   ' The text to be scrolled through
   S$="     cheezy realtime vector scroll        "

   SLEN=Len(S$) : Rem        Length of the scroll text
   NXT_CHAR=1 : Rem          Next char in text to be put on-screen


   ' Setup everything..
   Gosub SETUP_LETTER_DETAILS
   Gosub SETUP_OBJECT_POINTS
   Gosub INIT_SCROLL

   ' Scroll the text on a friendly but slightly warm surface..
   Repeat
      Screen Swap : Wait Vbl
      Cls 0
      Gosub _SCROLL_TEXT
   Until NXT_CHAR=SLEN or Mouse Key=1


   ' - Shut up!
   Fade 2 : Wait 15*2
   Autoback 2
   Screen Close 0

   Pop Proc


   ' Give the scroll letters (in the line of text on-screen) some default coords
   INIT_SCROLL:
   SPACING=20
   For L=0 To LINE_MAX

      ' -- Which character should be output
      C$=Mid$(S$,NXT_CHAR,1)
      Inc NXT_CHAR
      If NXT_CHAR>SLEN Then NXT_CHAR=1

      LINE(L,0)=-20+L*SPACING : Rem x-coord
      LINE(L,1)=3 : Rem             y-coord
      LINE(L,2)=190-L*SPACING : Rem z-coord
      If C$=" "
         LINE(L,3)=26
      Else
         LINE(L,3)= Fn CHAR_OBJ(C$) : Rem letter to use for the graphic
      End If
   Next L
   Return


   ' Details of how letters are formed (by connecting certain points)..
   SETUP_LETTER_DETAILS:
   For L=0 To NUM_CHARS
      For C=0 To 13
         Read OBJECT(L,C)
      Next C
   Next L
   Return


   ' p1,p2 p1,p2 p1,p2 p1,p2
   ' p1,p2 p1,p2 p1,p2  -- Each letter is formed by joining 7 pairs
   ' (some may be overwritten if 7 pairs are not required - keeps time constant)
   LETTER_DETAILS:
   A: Data 0,1,2,3,0,2,2,4,1,3,3,5,0,1
   B: Data 0,1,2,3,4,5,0,4,2,4,1,3,3,5
   C: Data 1,0,0,2,0,4,4,5,4,5,4,5,4,5
   D: Data 0,3,3,4,4,0,4,0,4,0,4,0,4,0
   E: Data 0,1,2,3,4,5,0,2,2,4,2,4,2,4
   F: Data 0,1,2,3,0,2,2,4,2,4,2,4,2,4
   G: Data 1,0,0,2,2,4,4,5,5,3,5,3,5,3
   H: Data 2,3,1,3,3,5,0,2,2,4,2,4,2,4
   I: Data 1,3,3,5,3,5,3,5,3,5,3,5,3,5
   J: Data 1,3,3,5,5,4,4,2,4,2,4,2,4,2
   K: Data 0,2,2,4,2,1,2,5,2,5,2,5,2,5
   L: Data 0,2,2,4,4,5,4,5,4,5,4,5,4,5
   M: Data 0,2,2,4,1,3,3,5,1,2,1,2,1,2
   N: Data 0,2,2,4,1,3,3,5,0,5,3,5,3,5
   O: Data 0,1,4,5,0,2,2,4,1,3,3,5,3,5
   P: Data 0,1,1,3,3,2,0,2,2,4,2,4,2,4
   Q: Data 0,1,1,3,3,5,5,4,4,2,2,0,5,2
   R: Data 0,1,1,3,3,2,0,2,2,4,2,5,2,5
   S: Data 1,0,0,2,2,3,3,5,5,4,5,4,5,4
   T: Data 0,1,1,3,3,5,3,5,3,5,3,5,3,5
   U: Data 0,2,2,4,4,5,5,3,3,1,3,1,3,1
   V: Data 0,2,2,4,4,1,4,1,4,1,4,1,4,1
   W: Data 0,2,2,4,4,3,5,3,3,1,3,1,3,1
   X: Data 0,5,1,4,1,4,1,4,1,4,1,4,1,4
   Y: Data 0,2,2,3,5,3,3,1,3,1,3,1,3,1
   Z: Data 0,1,1,4,4,5,4,5,4,5,4,5,4,5
   SPACE: Data 0,0,0,0,0,0,0,0,0,0,0,0,0,0


   ' Details of how each point of a letter is offset relative to the object's
   ' X/Y/Z position..


   SETUP_OBJECT_POINTS:
   Restore _POINT_OFFSETS
   For P=0 To 5
      For C=0 To 2
         Read OBJ_COMP(P,C)
      Next C
   Next P
   Return

   ' 0---1
   ' |   |
   ' 2---3
   ' |   |
   ' 4---5

   _POINT_OFFSETS:
   Data 0,20,0
   Data 10,20,-10
   Data 0,0,0
   Data 10,0,-10
   Data 0,-20,0
   Data 10,-20,-10



   _SCROLL_TEXT:

   ' x = LINE( L, 0 )
   ' y = LINE( L, 1 )
   ' z = LINE( L, 2 )

   SPEED=10
   For L=0 To LINE_MAX
      Add LINE(L,2),SPEED : Rem   z-coord of object
      Add LINE(L,0),-SPEED : Rem   x-coord of object
      If LINE(L,0)<-35 : Rem object has scrolled off so fetch new letter
         LINE(L,0)=80 : Rem reset coords x,y,z
         LINE(L,1)=3
         LINE(L,2)=90
         C$=Mid$(S$,NXT_CHAR,1)
         Inc NXT_CHAR
         If NXT_CHAR>SLEN : NXT_CHAR=1 : End If
         LINE(L,3)=Asc(C$)-97 : Rem letter to use for the graphic
         If C$=" "
            LINE(L,3)=26
         End If
      End If
      Gosub DRW_LETTER
   Next L
   Return


   DRW_LETTER:

   OX=LINE(L,0)
   OY=LINE(L,1)
   OZ=LINE(L,2)
   OBJ=LINE(L,3)

   For C=0 To 13 Step 2 : Rem 7 connections (2 points each)..

      ' -- points to connect..
      P1=OBJECT(OBJ,C)
      P2=OBJECT(OBJ,C+1)

      ' -- Get offsets for those points..
      XOFST1=OBJ_COMP(P1,0) : Rem p1
      YOFST1=OBJ_COMP(P1,1)
      ZOFST1=OBJ_COMP(P1,2)
      XOFST2=OBJ_COMP(P2,0) : Rem p2
      YOFST2=OBJ_COMP(P2,1)
      ZOFST2=OBJ_COMP(P2,2)

      ' -- Calculate real coords of points
      X1=OX+XOFST1 : Rem p1
      Y1=OY+YOFST1
      Z1=OZ+ZOFST1
      X2=OX+XOFST2 : Rem p2
      Y2=OY+YOFST2
      Z2=OZ+ZOFST2

      ' -- Connect the two points..
      If OBJ<>26 : Rem 26=space so don't join any dots
         Gosub CONNECT_PTS
      End If
   Next C

   Return


   CONNECT_PTS:

   ' -- Calculate screen coords of the two points..
   ZF=DVP+Z1
   X1=X_ORG+(DVP*X1)/ZF : Rem p1
   Y1=Y_ORG-(DVP*Y1)/ZF
   ZF=DVP+Z2
   X2=X_ORG+(DVP*X2)/ZF : Rem p2
   Y2=Y_ORG-(DVP*Y2)/ZF

   ' -- Connect the dots!
   Polyline X1,Y1 To X2,Y2

   Return

End Proc
Procedure SWAYING_LOGO
   ' - Code - Matt
   ' - GFX - Matt

   Unpack 7 To 0
   Screen Hide 0
   Erase 7

   Screen Open 1,640,500,16,Lowres
   Curs Off : Cls 0 : Hide : Flash Off : Get Palette 0
   Screen Hide 1
   Screen Offset 1,160,
   Screen Copy 0,0,0,400,110 To 1,145,0

   M$="(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)"
   M$=M$+"(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3) L"

   Channel 0 To Screen Offset 1
   Move X 0,M$
   Screen Show 1
   Move On

   Y=-100
   Repeat
      Screen Display 1,,Y*2,,
      Inc Y
      Wait Vbl
   Until Y>200 or Mouse Key=1

   Fade 1

   For _WAIT=0 To 15
      Screen Display 1,,Y*2,,
      Inc Y
      Wait Vbl
   Next _WAIT

   Move Off

   Screen Close 0
   Screen Close 1

End Proc

' - Man thing
Procedure MORPH_MAN

   SETUP_FONT
   NEW_TEXT_SCREEN["page8"]
   ' - I know! Shall we load some stuff in?
   Load "no-refund2!:stuff/man_wipe",1
   Load "no-refund2!:stuff/manpic",9
   Load "no-refund2!:stuff/cred_pic1",10
   Load "no-refund2!:stuff/cred_pic2",8
   Load "no-refund2!:stuff/cred_pic3",7
   CLEAR_TEXT_SCREEN
   SHUT_TEXT_SCREENS

   ' - And now we can run it!
   MORPH
   MAN
End Proc
Procedure MORPH
   ' - Code - Rob & Matt
   ' - GFX - Matt

   ' - Setup the screens
   Screen Open 0,320,256,8,Lowres
   Cls 0 : Curs Off : Flash Off : Hide : Cls 0
   Palette 0,0,0,0

   Unpack 10 To 1
   Screen Hide 1
   Palette 0,0,0,0

   Unpack 8 To 2
   Screen Hide 2
   Palette 0,0,0,0

   Unpack 7 To 3
   Screen Hide 3

   ' - Setup Dual Playfield
   Screen Show 1
   Screen To Front 0
   Wait Vbl
   Dual Playfield 1,0
   Wait Vbl
   Screen 1
   Palette 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0

   ' - Setup screen 0
   Screen 0
   Double Buffer
   Synchro Off
   Autoback 0
   Bob Update Off

   ' - Array used to store X and Y
   Dim X(12),Y(12)

   ' - Gosubs were only used to keep the procedure self contained!!!
   Gosub SETUP_BAR
   Gosub DUG
   Gosub _BAR_TO_D
   Gosub _PLAY_ANIM
   Gosub BITMAP_D
   Gosub D_TO_M
   Gosub MATT
   Gosub _PLAY_ANIM
   Gosub BITMAP_M
   Gosub M_TO_R
   Gosub _AND_ROB
   Gosub _PLAY_ANIM
   Gosub BITMAP_R
   Gosub R_TO_C
   Gosub _OF_CYS
   Gosub _PLAY_ANIM
   Gosub C_TO_Y
   Gosub _PLAY_ANIM
   Gosub Y_TO_S
   Gosub _PLAY_ANIM
   Gosub _S_TO_LINE
   Gosub CLR_CYS
   Gosub _PLAY_ANIM
   Gosub CLR_LINE

   ' - Clean up
   Autoback 2
   Synchro On
   Bob Update On
   Screen Close 0
   Screen Close 2
   Screen 1

   _SCREEN_BRUSH
   Erase 7
   Erase 8
   Erase 10

   ' - End of part
   Pop Proc


   _BAR_TO_D:
   For X=1 To 12
      Channel X To Bob X
   Next X

   ' - Define animations
   Amal 1," M 80,0,20 "
   Amal 2," M 53,0,20 "
   Amal 3," M 26,80,20 "
   Amal 4," M -160,160,20 "
   Amal 5," M -240,103,20 "
   Amal 6," M -240,-54,20 "
   Amal 7," M -200,-110,20 "
   Amal 8," M -94,-50,20 "
   Amal 9," M 43,-50,20 "
   Amal 10," M 190,-90,20 "
   Amal 11," M 150,-74,20 "
   Amal 12," M 80,-17,20 "
   Return


   D_TO_M:
   For X=2 To 12
      Channel X To Bob X
   Next X

   Amal 2," M -40,0,20 "
   Amal 3," M -80,-40,20 "
   Amal 4," M 40,-160,20 "
   Amal 5," M 160,-160,20 "
   Amal 6," M 160,100,20 "
   Amal 7," M 80,100,20 "
   Amal 8," M 80,-40,20 "
   Amal 9," M 10,0,20 "
   Amal 10," M -70,0,20 "
   Amal 11," M -30,120,20 "
   Amal 12," M 0,120,20 "
   Return


   M_TO_R:
   For X=2 To 12
      Channel X To Bob X
   Next X

   Amal 2," M 120,0,20 "
   Amal 3," M 80,60,20 "
   Amal 4," M 0,100,20 "
   Amal 5," M 0,160,20 "
   Amal 6," M -120,-60,20 "
   Amal 7," M -80,0,20 "
   Amal 8," M -120,80,20 "
   Amal 9," M -80,-60,20 "
   Amal 10," M 80,-20,20 "
   Amal 11," M 80,-120,20 "
   Amal 12," M 0,-120,20 "
   Return


   R_TO_C:
   For X=3 To 12
      Channel X To Bob X
   Next X

   Amal 3," M 0,-40,20 "
   Amal 4," M 0,-40,20 "
   Amal 5," M -40,-120,20 "
   Amal 6," M 0,-60,20 "
   Amal 7," M 0,-40,20 "
   Amal 8," M 120,-40,20 "
   Amal 9," M 120,40,20 "
   Amal 10," M 40,40,20 "
   Amal 11," M 40,120,20 "
   Amal 12," M 0,120,20 "
   Return


   C_TO_Y:
   For X=2 To 12
      Channel X To Bob X
   Next X

   Amal 2," M -120,0,20 "
   Amal 3," M -120,-20,20 "
   Amal 4," M 0,-20,20 "
   Amal 5," M 0,-40,20 "
   Amal 6," M 120,-40,20 "
   Amal 7," M 120,40,20 "
   Amal 8," M -120,40,20 "
   Amal 9," M -120,20,20 "
   Amal 10," M -40,20,20 "
   Amal 11," M -40,-80,20 "
   Amal 12," M 0,-80,20 "
   Return


   Y_TO_S:
   For X=2 To 12
      Channel X To Bob X
   Next X

   Amal 2," M 120,0,20 "
   Amal 3," M 120,0,20 "
   Amal 4," M -80,0,20 "
   Amal 5," M -80,60,20 "
   Amal 6," M 0,60,20 "
   Amal 11," M 0,20,20 "
   Amal 12," M 0,20,20 "
   Return


   _S_TO_LINE:
   For X=1 To 12
      Channel X To Bob X
   Next X

   Amal 1," M -80,90,20 "
   Amal 2," M -210,90,20 "
   Amal 3," M -180,50,20 "
   Amal 4," M -30,50,20 "
   Amal 5," M 0,30,20 "
   Amal 6," M -90,30,20 "
   Amal 7," M -60,-70,20 "
   Amal 8," M 130,-70,20 "
   Amal 9," M 160,-30,20 "
   Amal 10," M 70,-30,20 "
   Amal 11," M 100,-10,20 "
   Amal 12," M 240,-10,20 "
   Return


   CLR_LINE:
   Screen 0
   Ink 8
   For X=0 To 161
      Screen Swap
      Draw 0,130 To X,130
      Draw 320,130 To 320-X,130
   Next X

   Return


   SETUP_BAR:
   Bob 1,0,40,0
   Bob 2,107,40,0
   Bob 3,214,40,0
   Bob 4,320,40,0
   Bob 5,320,97,0
   Bob 6,320,154,0
   Bob 7,320,210,0
   Bob 8,214,210,0
   Bob 9,107,210,0
   Bob 10,0,210,0
   Bob 11,0,154,0
   Bob 12,0,97,0
   For CTR=1 To 12
      X(CTR)=X Bob(CTR)
      Y(CTR)=Y Bob(CTR)
   Next CTR

   Polygon X(1),Y(1) To X(2),Y(2) To X(3),Y(3) To X(4),Y(4) To X(5),Y(5) To X(6),Y(6) To X(7),Y(7) To X(8),Y(8) To X(9),Y(9) To X(10),Y(10) To X(11),Y(11) To X(12),Y(12)
   Screen Swap
   Polygon X(1),Y(1) To X(2),Y(2) To X(3),Y(3) To X(4),Y(4) To X(5),Y(5) To X(6),Y(6) To X(7),Y(7) To X(8),Y(8) To X(9),Y(9) To X(10),Y(10) To X(11),Y(11) To X(12),Y(12)
   Screen 1
   Fade 2,,,,$FFF,,,,,,,$C11
   Wait 30
   Screen 0
   Return


   _PLAY_ANIM:
   Amal On
   COUNTER=0
   Repeat

      For CTR=1 To 12
         X(CTR)=X Bob(CTR)
         Y(CTR)=Y Bob(CTR)
      Next CTR

      Screen Swap : Wait Vbl : Cls 0
      Polygon X(1),Y(1) To X(2),Y(2) To X(3),Y(3) To X(4),Y(4) To X(5),Y(5) To X(6),Y(6) To X(7),Y(7) To X(8),Y(8) To X(9),Y(9) To X(10),Y(10) To X(11),Y(11) To X(12),Y(12)
      Synchro
      Inc COUNTER

   Until COUNTER=25
   Return


   DUG:
   Screen 1
   Ink 0
   Bar 180,220 To 320,262
   Screen Copy 2,0,0,128,22 To 1,200,220
   Fade 1,,$FFF
   Screen 0
   Return


   MATT:
   Screen 1
   Fade 2,,$0
   Wait 30
   Ink 0
   Bar 180,220 To 320,262
   Screen Copy 2,0,22,128,44 To 1,180,220
   Fade 1,,$FFF
   Screen 0
   Return


   _AND_ROB:
   ' - And
   Screen 1
   Fade 1,,$0
   Wait 15
   Ink 0
   Bar 180,220 To 320,262
   Screen Copy 2,0,44,128,66 To 1,200,220
   Fade 1,,$FFF
   Wait 30

   ' - Rob
   Fade 1,,$0
   Wait 15
   Ink 0
   Bar 180,220 To 320,262
   Screen Copy 2,0,66,128,88 To 1,200,220
   Fade 1,,$FFF
   Screen 0
   Return


   _OF_CYS:
   ' - Of
   Screen 1
   Fade 1,,$0
   Wait 15
   Ink 0
   Bar 180,220 To 320,262
   Screen Copy 2,0,88,128,110 To 1,220,220
   Fade 1,,$FFF
   Wait 30

   ' - CYS
   Fade 1,,$0
   Wait 15
   Ink 0
   Bar 180,220 To 320,262
   Screen Copy 2,0,110,128,132 To 1,200,220
   Fade 1,,$FFF
   Screen 0
   Return


   CLR_CYS:
   Screen 1
   Fade 1,,$0
   Wait 15
   Ink 0
   Bar 180,220 To 320,262
   Screen 0
   Return


   ' -- Flash on 'D' graphics
   BITMAP_D:
   ' screen 0 = background
   '        3 = picture
   Screen Copy 3,0,0,161,161 To 0,80,40 : Rem copy D
   Screen Swap : Wait Vbl
   Screen 1

   ' fade to white
   Palette ,,,,,,,,,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF

   ' fade to blue range
   Fade 1,,,,,,,,,,$F00,$900,$400,$F,$B,$7,$4
   Wait 15*1

   For L=0 To 35 : Wait Vbl : Next L

   ' fade back to original colour
   Fade 1,,,,,,,,,,$C11,$C11,$C11,$C11,$C11,$C11,$C11
   Wait 15*1
   Screen 0

   Return


   ' -- Flash on graphics for 'M'
   BITMAP_M:
   ' screen 0 = background
   '        3 = picture
   Screen Copy 3,169,0,330,161 To 0,80,40 : Rem copy M
   Screen Swap : Wait Vbl
   Screen 1

   ' fade to white
   Palette ,,,,,,,,,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF

   ' fade to blue range
   Fade 1,,,,,,,,,,$F00,$900,$400,$F,$B,$7,$4
   Wait 15*1

   For L=0 To 35 : Wait Vbl : Next L

   ' fade back to original colour
   Fade 1,,,,,,,,,,$C11,$C11,$C11,$C11,$C11,$C11,$C11
   Wait 15*1
   Screen 0

   Return


   ' -- flash on graphics for 'R'
   BITMAP_R:
   ' screen 0 = background
   '        3 = picture
   Screen Copy 3,0,162,161,323 To 0,80,40 : Rem copy R
   Screen Swap : Wait Vbl
   Screen 1

   ' fade to white
   Palette ,,,,,,,,,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF

   ' fade to blue range
   Fade 1,,,,,,,,,,$F00,$900,$400,$F,$B,$7,$4
   Wait 15*1

   For L=0 To 35 : Wait Vbl : Next L

   ' fade back to original colour
   Fade 1,,,,,,,,,,$C11,$C11,$C11,$C11,$C11,$C11,$C11
   Wait 15*1
   Screen 0

   Return

End Proc
Procedure _SCREEN_BRUSH
   ' - Code - Rob

   ' - Set the colours (both of them!)
   Palette 0,$FFF

   ' - Define the movement for the brush bob
   Channel 1 To Bob 1
   M$="L: M 320,-40,20 ; M -320,-40,20 ; J L"
   Set Bob 1,-1,,
   Bob 1,-30,250,7
   Amal 1,M$

   ' - Start it
   Amal On

   ' - Wait for it to finish
   Wait 180
   Amal Off
   Bob Off

End Proc
Procedure MAN
   ' - Code - Matt & Rob
   ' - GFX - Dug (Matt - Wall + Policeman)

   ' - Fade it up to white
   Fade 1,$FFF,$FFF
   Wait 15

   ' - Open screen and clear it to white
   Screen Open 0,320,256,8,Lowres
   Curs Off : Cls 1 : Hide : Flash Off

   W=$FFF
   Palette W,W,W,W,W,W,W,W

   ' - Unpack th background picture
   Unpack 9 To 1
   Screen Hide 1
   Screen To Front 0

   ' - Paste the backgroud picture on screen 0
   Screen Copy 1,0,0,320,256 To 0,0,0
   Screen 0

   ' - Fade it on
   Fade 1 To 1
   Wait 15
   Screen Close 1

   ' - Give them some time to read the posters (gee, they're funny!)
   Wait 150
   Double Buffer

   ' - Define animation
   ' - Green dudes
   A$="Anim 0,(1,5)(2,5)(3,5)(2,5);"
   A$=A$+" M 250,0,250 : M 70,200,100"

   ' - It's a police dude OK! - He is not wearing a blue dustbin!
   B$="Anim 0,(4,5)(4,5)(6,5)(5,5);"
   B$=B$+" M 250,0,250 : M 70,200,100"

   ' - Define movement string
   Y$="(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)L"

   ' - Start the green dude animation
   For A=1 To 3
      Bob A,-20,100,1
      Channel A To Bob A
      Amal A,A$
      Move Y A,Y$
      Amal On A
      Move On A
      Wait 15
   Next A

   Amal On
   Move On
   Wait 90

   ' - Start the police dude animation
   Bob 4,-20,100,4
   Channel 4 To Bob 4
   Amal 4,B$
   Move Y 4,Y$
   Amal On 4
   Move On 4

   ' - Wait for the animation to finish or Mouse Key
   Repeat
   Until Y Bob(4)>260 or Mouse Key=1

   ' - Shut the screens up
   Wait 50
   Fade 1 : Wait 15
   Screen Close 0
   Bob Off
   Amal Off
   Move Off

   ' - Bye Bye Banks!
   Erase 1
   Erase 9

End Proc

' - Menu options..
Procedure MAIN_MENU
   SETUP_FONT
   NEW_TEXT_SCREEN["page9"]
   Load "no-refund2!:stuff/menu_options",8
   Load "no-refund2!:stuff/menu_logo",7
   Load "no-refund2!:stuff/menu_spr",1
   Wait 50
   CLEAR_TEXT_SCREEN
   SHUT_TEXT_SCREENS

   ' - Start the stuff
   MENU
End Proc
Procedure MENU
   ' - Code - Matt (Dug)
   ' - GFX - Matt

   Unpack 8 To 1
   Screen Hide 1
   Erase 8

   Unpack 7 To 0
   Palette $2,,,,,,,
   Double Buffer
   Erase 7

   Screen Open 2,320,200,2,Lowres
   Curs Off : Cls 0 : Hide : Flash Off : Palette 0,0
   Screen Display 2,,124,,

   Screen 0

   ' - Animate saw

   SAW_MOVE$="Anim 0,(1,3)(2,3)(3,3)(4,3)(5,3)(4,3)(3,3)(2,3);"
   SAW_MOVE$=SAW_MOVE$+"M -360,0,225;"
   Bob 1,320,44,1
   Channel 1 To Bob 1

   Amal 1,SAW_MOVE$
   Amal On 1

   ' - Wait for animation to finish or mouse key
   Repeat
   Until Mouse Key=1 or X Bob(1)<-15

   Screen To Back 1
   Screen Show 1
   Wait Vbl

   Amal Off
   Bob Off

   ' - Move screen off
   SCR_MOVE$="M 0,200,10"
   Channel 2 To Screen Display 2
   Amal 2,SCR_MOVE$

   Amal On 2
   Wait 40


   ' -- Wait for user to chose one of the silky smooth and sexy programs..
   Screen 1

   ' - Set sprite colours
   Colour 17,$FF0
   Colour 18,$F80
   Colour 19,$F00
   Limit Mouse 128,135 To 420,265

   ' - Define zones
   Reserve Zone 3
   Set Zone 1,56,191 To 84,219
   Set Zone 2,146,191 To 174,219
   Set Zone 3,236,191 To 264,219
   Hot Spot 6,3,7
   Hot Spot 7,3,7

   IMAGE=6
   _CHOSEN=False

   ' - Main loop
   Repeat
      MX=X Mouse
      MY=Y Mouse
      MZ=Zone(X Screen(X Sprite(0)),Y Screen(Y Sprite(0)))
      Sprite 0,MX,MY,IMAGE
      If Mouse Key=1
         IMAGE=7
         Sprite 0,MX,MY,IMAGE
         Wait Vbl
         If MZ>0
            On MZ Proc SETUP_QUEST,CONTINUE,NUKE_EM
            _CHOSEN=True
         End If
      Else
         IMAGE=6
      End If
   Until _CHOSEN

End Proc
Procedure _CLOSE_MENU

   ' - Close the menu screens a lose the sprite!
   Screen 0 : Fade 1
   Screen 1 : Fade 1
   Wait 15
   Sprite Off
   Screen Close 0
   Screen Close 1
   Screen Close 2
   Erase 1

End Proc
Procedure CONTINUE
   ' - Simply calls the close menu procedure and then
   ' - allows the demo to carry on...

   _CLOSE_MENU
   VECTOR_BALLS
   JELLO_DUCK
   KANO_TEXT_AEROSOL
End Proc

' - The Cybornetics questionnaire
Procedure SETUP_QUEST

   _CLOSE_MENU
   SETUP_FONT
   NEW_TEXT_SCREEN["page10"]
   Load "no-refund2!:stuff/quest_pic",7
   Wait 150
   CLEAR_TEXT_SCREEN
   SHUT_TEXT_SCREENS

   ' - Start the stuff
   QUEST
   MAIN_MENU
End Proc
Procedure QUEST
   ' - Code - Dug
   ' - GFX - Matt
   ' - Questions - Matt & Rob

   Unpack 7 To 1
   Screen To Back 1
   Erase 7

   Screen Open 0,640,100,8,Hires
   Flash Off : Curs Off : Cls 0 : Hide
   Screen Display 0,,200,,
   Screen To Front 0

   Screen 0

   Dim CLR(7),RGB_FADE(7),LINE$(5)
   SCORE=0


   Restore _PALETTE
   For C=0 To 7
      Read CLR(C)
   Next C
   Palette 1,1,1,1,1,1,1,1

   Y Mouse=2

   Restore QUESTIONS
   Read NUMQ
   For L=1 To NUMQ
      Read Q$,A$,B$,C$,D$,RIGHT_ANSWER,COMMENT1$,COMMENT2$,COMMENT3$,COMMENT4$
      Gosub DISPLAY_QUESTION
      If QUIT
         Exit
      End If
      Gosub REPLY
   Next L
   If Not QUIT
      Gosub FINAL_COMMENT
   End If
   Gosub FAD_SCREEN
   Pop Proc


   DISPLAY_QUESTION:

   Limit Mouse 0,2 To 320,8

   ' - Copy question and answers into an array
   LINE$(0)=Q$
   LINE$(1)=A$
   LINE$(2)=B$
   LINE$(3)=C$
   LINE$(4)=D$

   ' - Fade the questions and answers onto the screen

   ' - Reset the RGB_FADE values and print the line onto the screen
   For C=0 To 7 : RGB_FADE(C)=1 : Next C
   I=Rnd(6)+1
   Ink I,0
   Text 10,10,LINE$(0) : Rem                     The Question
   Draw 10,12 To 10+Text Length(LINE$(0)),12

   ' - Fade the right colour on
   RGB_FADE(I)=CLR(I)
   Fade 2,RGB_FADE(0),RGB_FADE(1),RGB_FADE(2),RGB_FADE(3),RGB_FADE(4),RGB_FADE(5),RGB_FADE(6),RGB_FADE(7)
   Wait 15


   Add I,1,1 To 7 : Rem Use next colour
   For A=1 To 4
      Ink I
      Text 10,25+A*10,LINE$(A) : Rem             The Answers...
      '
      RGB_FADE(I)=CLR(I)
      Fade 2,RGB_FADE(0),RGB_FADE(1),RGB_FADE(2),RGB_FADE(3),RGB_FADE(4),RGB_FADE(5),RGB_FADE(6),RGB_FADE(7)
      Wait 5

      Add I,1,1 To 7 : Rem    - Use next colour
   Next A
   Wait 40

   ' - Rainbow to hilight chosen option
   Set Rainbow 0,0,4096,"","",""
   Rain(0,1)=$248
   For Y=2 To 10
      Rain(0,Y)=$48F
   Next Y
   Rain(0,11)=$248
   Rainbow 0,0,0,13

   ' - Get the user to pick an option
   OPTION_CHOSEN=0
   QUIT=False
   Repeat
      Y=Y Mouse/2 : Rainbow 0,0,216+Y*10,
      If Mouse Key=2
         QUIT=True
         OPTION_CHOSEN=Y
      Else
         If Mouse Key=1
            OPTION_CHOSEN=Y
         End If
      End If
      Wait Vbl
   Until OPTION_CHOSEN
   Rainbow 0,0,40,1

   Add I,1,1 To 7
   Ink I,0
   RGB_FADE(I)=CLR(I)

   Return


   REPLY:

   If OPTION_CHOSEN=RIGHT_ANSWER
      Inc SCORE
   End If

   If OPTION_CHOSEN=1
      Text 10,80,COMMENT1$
   Else
      If OPTION_CHOSEN=2
         Text 10,80,COMMENT2$
      Else
         If OPTION_CHOSEN=3
            Text 10,80,COMMENT3$
         Else
            If OPTION_CHOSEN=4
               Text 10,80,COMMENT4$
            End If
         End If
      End If
   End If

   Fade 2,RGB_FADE(0),RGB_FADE(1),RGB_FADE(2),RGB_FADE(3),RGB_FADE(4),RGB_FADE(5),RGB_FADE(6),RGB_FADE(7)
   Wait 30

   Wait 100
   Fade 2,1,1,1,1,1,1,1,1,1 : Wait 30 : Cls 0

   Return


   FINAL_COMMENT:
   Ink 7,0
   SCORE$=Str$(SCORE)
   NUMQ$=Str$(NUMQ)

   If SCORE<3
      RATING$="Are you Cheezy Hawkes?"
   Else
      If SCORE<6
         RATING$="Come on! It wasn't THAT hard!"
      Else
         If SCORE<9
            RATING$="Look!  Stop choosing the funny answers!"
         Else
            If SCORE<12
               RATING$="Approx. 50% Not good enough."
            Else
               If SCORE<15
                  RATING$="It's good, but not that good!"
               Else
                  If SCORE<17
                     RATING$="This is more than we got! (we've forgotten the answers!)"
                  Else
                     If SCORE<NUMQ
                        RATING$="Sooooo Close - a bit more effort needed."
                     Else
                        If SCORE=NUMQ
                           RATING$="!TOP SCORE! (you cheating git!)"
                        End If
                     End If
                  End If
               End If
            End If
         End If
      End If
   End If

   ' - Change end message appropriately
   MSG$="Well that's all folks!"
   MSG1$="You scored"+SCORE$+" out of"+NUMQ$
   MSG2$="Your rating is : "+RATING$

   ' - Print end message
   Text 10,20,MSG$
   Text 10,35,MSG1$
   Text 10,50,MSG2$

   ' - Fade on message and wait for a bit, then fade off
   Fade 3,1,1,1,1,1,1,1,$FA4 : Wait 45
   Repeat
   Until Mouse Key=1
   Return

   FAD_SCREEN:

   Fade 2
   Screen 1
   Fade 1 : Wait 15

   Screen Close 0
   Screen Close 1

   Return


   _PALETTE:
   Data 0,$33F,$D0,$D40,$D3D,$DD4,$3DD,$FA4

   ' - Structure of question data....

   ' Data "<The Question>"
   ' Data "<Option A>"
   ' Data "<Option B>"
   ' Data "<Option C>"
   ' Data "<Option D>"
   ' Data <Right_Answer>
   ' Data "<Comment for option A>"
   ' Data "<Comment for option B>"
   ' Data "<Comment for option C>"
   ' Data "<Comment for option D>"

   QUESTIONS:
   Data 20
   1
   Data "Which of the following is the best Amiga mag?"
   Data "a) Just 17"
   Data "b) CU Amiga"
   Data "c) 2000 AD"
   Data "d) Bella"
   Data 2
   Data "No, but it has good articles."
   Data "Yeah! And it has good disks!"
   Data "Cool graphics, good stories, no Amigas!"
   Data "Includes a knitting pattern for an Amiga dust cover!!"
   2
   Data "What is CaMg3(CO3)2 ?"
   Data "a) Hammerite"
   Data "b) Dolomite"
   Data "c) Chesney Hawkes"
   Data "d) Do you use it in AMAL?"
   Data 2
   Data "Any old iron, any old iron... NO!"
   Data "Yeah! - An easy one for all you geologists."
   Data "They do look similar!!!"
   Data "Only Cubic does!"
   3
   Data "Who killed Laura Palmer?"
   Data "a) Lee Harvey Oswald"
   Data "b) Chesney Hawkes"
   Data "c) Mr. Benn"
   Data "d) Her dad! Or was it that bloke with long hair?"
   Data 4
   Data "He could never have made that shot!"
   Data "Death by serenade."
   Data "As if by magic, she disappeared!"
   Data "Twin Peaks, did you understand it?"
   4
   Data "... and the best game of all time is..."
   Data "a) Necronom"
   Data "b) Wing Commander"
   Data "c) Frenetic"
   Data "d) Chesney Hawkes"
   Data 3
   Data "It plays like one of Dugs!!!"
   Data "Good, but TOO slow."
   Data "The ultimate 2 player blast!"
   Data "No playability whatsoever!"
   5
   Data "Which is the cool AMOS group?"
   Data "a) Fanatix"
   Data "b) Cubic"
   Data "c) Chesney Hawkes"
   Data "d) Arc Angel"
   Data 1
   Data "They were, but they are no more! (Where are you Jag?)"
   Data "Major attitude problem!"
   Data "Didn't he write AMOS?"
   Data "Now we're going back too far!"
   6
   Data "and the best band?"
   Data "a) Chesney Hawkes"
   Data "b) 2 (Un)limited"
   Data "c) Rumblefish"
   Data "d) Faith No More"
   Data 4
   Data "He is the one and only (too many)!"
   Data "Techno, Techno, Techno, Techno! - NO!"
   Data "That's Stews band you muppet!"
   Data "Is Mike Patton weird or wot!?!"
   7
   Data "best food????"
   Data "a) Vitafruits"
   Data "b) Chesney Hawkes"
   Data "c) Fizzy chewits"
   Data "d) Toffee Crisp"
   Data 4
   Data "Good during lectures, but a bit too tangy!"
   Data "He sucks!"
   Data "Lemonade, Orangeade or Cola?  Descisions, descisions!"
   Data "Yeah! - Go and release the crispy bits!"
   8
   Data "In an emergency..."
   Data "a) Grab your Amiga and run"
   Data "b) Jump"
   Data "c) Don't Panic"
   Data "d) Call Chesney"
   Data 3
   Data "You sad git!  Claim on the insurance for a new A4000!"
   Data "Van Halen - Aka. Perms R us!"
   Data "Put a babel fish in your ear, and grab your towel!"
   Data "You could use him as a life raft or something!"
   9
   Data "You're driving down the street when Chesney Hawkes suddenly appears, do you"
   Data "a) Hit the gas"
   Data "b) Ask him to sign your fav' Chesney album"
   Data "c) Slow down, taking evasive action"
   Data "d) Chesney who?"
   Data 1
   Data "Kersplat!  Yee Haa!"
   Data "AAAAAARRRRRGGGGHHHHHHH!!!!!!!"
   Data "Why?  Are you mental?"
   Data "Well said!  But we won't tell you!"
   10
   Data "Cybornetics remind me of..."
   Data "a) God"
   Data "b) Chesney Hawkes"
   Data "c) Long summer days in the algarve"
   Data "d) Right Said Fred"
   Data 3
   Data "Close... Same sandals!"
   Data "We have just deducted three points!!!"
   Data "Yeah!  They're boring too!"
   Data "We're too sexy for this demo!"
   11
   Data "Rnd(53278)"
   Data "a) What?"
   Data "b) Chesney Hawkes"
   Data "c) 42"
   Data "d) 2 Oranges and a Bap"
   Data 3
   Data "See Amos Professional manual, page 5.3.10"
   Data "Are you a fan or what?"
   Data "Yeah!  Anyone for scrabble?"
   Data "No!  1 Lemon and 2 Baps!"
   12
   Data "To be this good takes..."
   Data "a) Game Boy"
   Data "b) Shredded Wheat"
   Data "c) Chesney Hawkes"
   Data "d) About 5 minutes"
   Data 4
   Data "Yeah, only if you're playing Tetris!"
   Data "You need to eat THREE! (That's hard!)"
   Data "I wish I'd never started this Chesney thing now!"
   Data "Slightly less if you hurry!"
   13
   Data "Whats soft, strong and very very long?"
   Data "a) The M25"
   Data "b) Snigger"
   Data "c) Bog roll"
   Data "d) Chesney Hawkes"
   Data 2
   Data "Depends how many times you go round!"
   Data "Snigger, Snigger"
   Data "Too obvious!"
   Data "He's soft... but that's all!"
   14
   Data "If you were on blind date, which question would you ask... number 2"
   Data "a) Are you rich?"
   Data "b) Are you Chesney Hawkes?"
   Data "c) Does BO put you off?"
   Data "d) Which flower describes you best?"
   Data 4
   Data "Essential knowledge!"
   Data "You have to be careful these days!"
   Data "Slightly less than nasal hair!"
   Data "Rob - Tulip, Matt - Rose, Dug - Rhubarb!"
   15
   Data "Which of the following is the best arctic survival tip?"
   Data "a) Wrap up warm"
   Data "b) Mind how you go"
   Data "c) Don't forget to phone"
   Data "d) Send Chesney Hawkes"
   Data 2
   Data "Don't forget your KYTV T-Shirt"
   Data "Why do people say that!  As if you aren't going to!"
   Data "If you've got a 10p it'll be a Phone-Card only phone!"
   Data "The further the better!"
   16
   Data "Who is the one and only?"
   Data "a) Rob"
   Data "b) Chesney Hawkes"
   Data "c) Matt"
   Data "d) Dug"
   Data 2
   Data "The one and only LAZY coder of the year! (3 years running)"
   Data "I couldn't cope with any more of him!"
   Data "The one and only A1200 owner in Cybornetics!"
   Data "The one and only person who actually read the AMOS manual!"
   17
   Data "Are you still awake?"
   Data "a) .........."
   Data "b) eh?"
   Data "c) hello? CN-FM play the best music?"
   Data "d) This is most interesting!"
   Data 3
   Data "Zzzzz... EH! What? Whaaaaaa!"
   Data "Why do we bother? (Don't answer that!)"
   Data "Well done!  You have just won a years supply of toothpaste!"
   Data "Yeah, so is eating a bowl of lentil soup! (with chives)"
   18
   Data "What's on page 51 of the August 93 issue of Amiga Mart?"
   Data "a) Ikari Warriors extensive preview."
   Data "b) A rather excellent review of a rather excellent disk!"
   Data "c) Everything you ever wanted to know about tape streamers"
   Data "d) A500 found on Moon!  In-depth report."
   Data 2
   Data "No, that was in last months"
   Data "The Awakening, by some group called CYBONETICS (Wot No R?)"
   Data "They stream tapes they do!"
   Data "Investigative journalism at its most Dim(BAD)"
   19
   Data "Who is the best suited to change a light-bulb?"
   Data "a) An analyst"
   Data "b) An electrician"
   Data "c) Chesney Hawkes"
   Data "d) A coder"
   Data 2
   Data "No, leave that to the programmer"
   Data "Was this one too easy?"
   Data "He would do it!  But you would never hear from him again!"
   Data "Gosub CALL_ELECTRICIAN"
   20
   Data "What is AKIRA?"
   Data "a) Special fried rice"
   Data "b) A Japanese Bugs Bunny"
   Data "c) AAAAAAAAHHHHHHHHH!  MANGA!"
   Data "d) A super solid, steel framed, city shopper bike!"
   Data 3
   Data "Prawn Balls!"
   Data "NO!"
   Data "Yeah!  R U N2 Anime 2?"
   Data "Weighing in at 200lbs"

End Proc

' - Nuke 'em goes here!
Procedure NUKE_EM
   _CLOSE_MENU
   SETUP_FONT
   NEW_TEXT_SCREEN["page13"]
   ' - Clear out the demo
   Track Stop
   Erase 3
   Erase 13
   Erase 14
   Load "no-refund2!:stuff/nuke_title",9
   Wait 50
   CLEAR_TEXT_SCREEN
   SHUT_TEXT_SCREENS

   ' - Run Nuke 'em
   _SHOOT_EM_UP

   ' - Restore the demo
   RESET_DEMO
   MAIN_MENU
End Proc
Procedure _SHOOT_EM_UP
   ' - Code - Rob
   ' - GFX - Matt (Rob - Title Pic)

   ' - Intro stuff...

   ' - Title screen
   Unpack 9 To 0
   Screen Hide 0
   Erase 9
   Screen Open 1,320,256,16,Lowres
   Curs Off : Cls 0 : Flash Off : Hide
   Get Palette 0
   Screen 0
   Palette 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
   Screen Show 0
   Screen To Front 0
   Fade 1 To 1
   Wait 15
   Screen Close 1

   ' - Loads while title screen is displayed
   Load "no-refund2!:stuff/nuke_bobs",1
   Load "no-refund2!:stuff/nuke_sams",5
   Load "no-refund2!:stuff/nuke_back1",6
   Load "no-refund2!:stuff/nuke_back2",7
   Load "no-refund2!:stuff/nuke_back3",10
   Load "no-refund2!:stuff/nuke_ins",11

   ' - Instructions screen
   Fade 1 : Wait 15
   Screen Close 0
   Unpack 11 To 0
   Palette 0,0
   Erase 11
   Fade 1,0,$FFF
   Wait 15

   ' - Loads while it is displayed
   Load "no-refund2!:stuff/nuke_stat",8
   Load "no-refund2!:stuff/nuke_scroll",9

   ' - Wait for them to continue
   Repeat
   Until Fire(1)

   Fade 1 : Wait 15
   Screen Close 0



   ' -----  MAIN SHOOT EM UP CODE!  -----



   ' ----- Definitions -----

   ' - Define some stuff
   Dim ALIEN_HIT(5) : Rem - Stores the hits required by each alien
   _START_LIVES=7 : Rem   - No CHEATING!
   NUM_OF_WAVES=20 : Rem  - Includes Bonus Levels
   SPEED=3 : Rem          - Main Ship speed - 1=Slow, 3=Fast
   NUM_BOBS=7 : Rem       - Main Ship, Bullet and the rest are Aliens

   ' - Define some more stuff
   TIME_BETWEEN_WAVES=50

   ' - Used for inertia calculations
   _UP=1
   _DOWN=2
   _LEFT=3
   _RIGHT=4

   ' - Define some Bob numbers
   _TEXT_BOB=8
   P_Q=9

   ' - Define some Bob Image numbers
   MAIN_SHIP=1
   BULLET=2
   ALIEN_SHIP=3
   BALL=4
   SUPER_DAN=5
   _WAVE_CLEAR=6
   _GET_READY=7
   GAME_OVER=8
   ACID=9
   DISK=10
   _PLAY_OR_QUIT=11
   WASP=12
   _MINE=13
   BAT=14
   _MINE_SHOT=19
   _AST1=20
   _AST2=21
   _AST3=22
   GUARDIAN1=23
   GUARDIAN1_EYE=24
   PAUSED_IMAGE=25
   _1UP=26
   _20_POINTS=27
   _10_POINTS=28
   BONUS_TEXT=29
   _FIRE_BALL=30
   _DONUT=31
   SPIKE1=32
   SPIKE2=33
   SPIKE3=34
   SPIKE4=35
   WHEEL=36
   SCARF=37
   SKULL_SHOT=38
   SKULL_EYE=39
   SKULL=40
   LADYBIRD=41
   ARROW=42
   BEAST_GUARD=43
   BEAST_EYE=44
   BEAST_SHOT=45
   UPPER_GUN=46
   LOWER_GUN=47
   CON_TEXT=48

   ' - Define sample numbers
   MAIN_SHIP_LASER=1
   MAIN_SHIP_BOOM=3
   CHINK=2
   ALIEN_BOOM=3


   ' ----- Define screens -----

   ' - Open main play area screen
   Screen Open 0,340,125,8,Lowres
   Curs Off : Cls 0 : Hide : Flash Off
   Screen Display 0,,86,,125

   ' - Open status screen - 2 Colour, Lowres (numbers are hidden off bottom)
   Unpack 8 To 2
   Screen Hide 2
   Screen Display 2,,260,320,
   Gosub _UPDATE_LIVES
   Gosub _UPDATE_LEVEL
   Gosub _UPDATE_SCORE

   ' - Unpack background screen - 8 Colour, Lowres
   Unpack 9 To 1
   Screen Hide 1

   ' - Flash bar on border
   Flash 1,"(f00,20)(c00,5)(900,5)(500,5)(200,40)(500,5)(900,5)(c00,5)"

   ' - Set screen priority
   Screen To Front 2
   Screen To Front 0

   ' - Show Screens (should be done with a fade but I don't know the colours!)
   Screen Show 2
   Screen Show 1
   Screen Show 0
   Screen 0
   Double Buffer
   Get Sprite Palette


   ' ----- Setup Bobs -----

   ' - Define channels for ship, bullet and aliens
   For CTR=1 To NUM_BOBS
      Channel CTR To Bob CTR
   Next CTR

   ' - Position baddies off screen for starters
   For ALIEN=3 To NUM_OF_BOBS
      Bob ALIEN,340,240,ALIEN_SHIP
   Next ALIEN

   ' - Define Bullet movement and position initial bullet
   BULLET$="M 340,0,40 : Let X=800 : Let Y=500"
   Bob BULLET,540,-60,BULLET

   ' - Define Alien death movement
   ALIEN_DIE$="M 0,330,30"

   ' - Define Main Ship death animation
   MAIN_DIE$="A 1,(15,3)(16,3)(17,3)(18,3)"

   ' - Define Text bob
   Channel _TEXT_BOB To Bob _TEXT_BOB
   _TEXT_ON$="M 0,50,25 ;"
   _TEXT_OFF$="M 0,-50,25 ;"
   Bob _TEXT_BOB,40,-30,_TEXT

   ' - Play or Quit text
   Channel P_Q To Bob P_Q
   P_Q_ON$="M 0,-50,25 ;"
   P_Q_OFF$="M 0,50,25 ;"



   ' ----- Main Loop -----

   _PLAYED_AND_DIED=False
   Repeat
      YOU_DIED_SCUMBAG=False

      ' - Display Play or Quit message
      Bob P_Q,80,130,_PLAY_OR_QUIT
      Amal P_Q,P_Q_ON$
      Amal On
      Wait 25

      ' - Do you want to play?
      CHOSEN=False
      Clear Key
      Repeat
         If Fire(1)
            ' - They want to play again - Hurrah!
            _PLAY=True
            CHOSEN=True
         End If
         If Inkey$=Chr$(27)
            ' - Oh No! They can't take any more!
            _PLAY=False
            CHOSEN=True
         End If
      Until CHOSEN

      If _PLAY
         Amal P_Q,P_Q_OFF$
         If _PLAYED_AND_DIED
            ' - Remove Game Over text
            Amal _TEXT_BOB,_TEXT_OFF$
            _PLAYED_AND_DIED=False
         End If
         Amal On
         Wait 25
         Bob Off P_Q

         ' - Define variables - Variables are storage spaces which have been assigned names.  The values held by these variables can change.
         ALIENS_ALIVE=0
         _WAVE_CTR=1
         LIVES=_START_LIVES
         SCORE=0
         _TEXT=_GET_READY
         BONUS_STAGE=False
         GUARDIAN_STAGE=False
         BACKGROUND=7
         INERTIA=0
         CONST_INERTIA=6
         CONST_X_MAX=250
         X_MAX=CONST_X_MAX
         FINAL_STAGE=False

         Gosub SETUP_BACKGROUND

         ' - Reset status screen
         Gosub _UPDATE_SCORE
         Gosub _UPDATE_LIVES
         Gosub _UPDATE_LEVEL

         ' - Animate background screen (That's not animation!)
         Screen 1 : Shift Down 1,2,7,1 : Screen 0


         ' ----- Game Loop -----

         Repeat

            ' - Set alien wave - When all aliens are dead
            If ALIENS_ALIVE=0
               ' - Firstly, make sure all aliens are off screen
               Wait 10

               ' - Reset the max x movement
               X_MAX=CONST_X_MAX

               If GUARDIAN_STAGE
                  GUARDIAN_STAGE=False
                  If FINAL_STAGE
                     Gosub WELL_DONE
                  End If
                  Gosub SETUP_BACKGROUND
               End If

               ' - Then test if they can go on the bonus stage
               ' - Proceed to the next level
               On _WAVE_CTR Gosub _WAVE3,_WAVE1,_WAVE4,_WAVE10,_WAVE8,GUARD1,BONUS_WAVE,_WAVE5,_WAVE2,_WAVE7,_WAVE6,_WAVE13,BEAST,BONUS_WAVE,_WAVE14,_WAVE15,_WAVE9,_WAVE11,_WAVE12,GUARD_SKULL
               Gosub _UPDATE_LEVEL
               ' - Then increase the level counter
               Add _WAVE_CTR,1,1 To NUM_OF_WAVES
            End If

            ' - Pause Mode
            If Key State(25)
               ' - If they press P or p
               Gosub PAUSE
            End If


            ' ----- Ship controls -----

            ' - Move up
            If Jup(1) and Y Bob(MAIN_SHIP)>-5
               Bob MAIN_SHIP,,Y Bob(MAIN_SHIP)-SPEED,MAIN_SHIP
               LASTDIR=_UP
               INERTIA=CONST_INERTIA
            End If

            ' - Move Down
            If Jdown(1) and Y Bob(MAIN_SHIP)<100
               Bob MAIN_SHIP,,Y Bob(MAIN_SHIP)+SPEED,MAIN_SHIP
               LASTDIR=_DOWN
               INERTIA=CONST_INERTIA
            End If

            ' - Move Left
            If Jleft(1) and X Bob(MAIN_SHIP)>0
               Bob MAIN_SHIP,X Bob(MAIN_SHIP)-SPEED,,MAIN_SHIP
               LASTDIR=_LEFT
               INERTIA=CONST_INERTIA
            End If

            ' - Move Right
            If Jright(1) and X Bob(MAIN_SHIP)<X_MAX
               Bob MAIN_SHIP,X Bob(MAIN_SHIP)+SPEED,,MAIN_SHIP
               LASTDIR=_RIGHT
               INERTIA=CONST_INERTIA
            End If

            ' - If the joystick is central - Calculate inertia
            If(Joy(1) and $F)=0 and INERTIA>0
               Dec INERTIA
               If LASTDIR=_UP and Y Bob(MAIN_SHIP)>-5
                  Bob MAIN_SHIP,,Y Bob(MAIN_SHIP)-1,MAIN_SHIP
               Else
                  If LASTDIR=_DOWN and Y Bob(MAIN_SHIP)<100
                     Bob MAIN_SHIP,,Y Bob(MAIN_SHIP)+1,MAIN_SHIP
                  Else
                     If LASTDIR=_LEFT and X Bob(MAIN_SHIP)>0
                        Bob MAIN_SHIP,X Bob(MAIN_SHIP)-1,,MAIN_SHIP
                     Else
                        If LASTDIR=_RIGHT and X Bob(MAIN_SHIP)<X_MAX
                           Bob MAIN_SHIP,X Bob(MAIN_SHIP)+1,,MAIN_SHIP
                        End If
                     End If
                  End If
               End If
            End If

            ' - Fire bullet
            If Fire(1)
               If X Bob(BULLET)>320
                  Wait Vbl
                  Bob BULLET,X Bob(MAIN_SHIP)+26,Y Bob(MAIN_SHIP)+9,BULLET
                  Sam Play %1001,MAIN_SHIP_LASER,14000
                  Amal BULLET,BULLET$
                  Amal On BULLET
               End If
            End If


            ' ----- Test Collision -----

            ' - Kill Alien
            If Bob Col(BULLET,3 To _MAX_KILL+2)
               ALIEN=Col(-1)
               Wait Vbl
               Gosub YEAH_GOT_ONE
            End If

            ' - Kill main ship
            If Bob Col(MAIN_SHIP)
               ALIEN=Col(-1)
               Wait Vbl
               Gosub AARRGH_THEY_GOT_ME
            End If

            Wait Vbl
         Until Inkey$=Chr$(27) or YOU_DIED_SCUMBAG

         If Not _PLAYED_AND_DIED
            ' - If they pressed escape...
            Gosub GAME_OVER_DUDE
         End If
      End If
   Until Not _PLAY


   ' ----- Clean up ----

   Screen 0
   Fade 1
   Screen 1
   Fade 1
   Screen 0
   Fade 1
   Wait 15

   ' - Close screens
   Screen Close 0
   Screen Close 1
   Screen Close 2

   ' - Erase banks (with all those banks you could start a bank!)
   Erase 1
   Erase 5
   Erase 6
   Erase 7
   Erase 8
   Erase 9
   Erase 10

   Pop Proc

   ' -------------------- THE END --------------------

   ' - Until we release the sequel! (Dug's already started it!!!)

   Pop Proc



   ' ----- Alien wave definitions -----

   _WAVE1:
   ' - Alien Wave 1 (Blue ships that wobble)
   Gosub _DEFINE_NEW_WAVE

   ' - Set colours
   Palette ,,,,$44F,$77F,$99F,$CCF

   ' - Define wave movement
   ALIEN_WAVE1$="(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3) "
   ALIEN_WAVE1$=ALIEN_WAVE1$+"(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3) L"

   ' - Define speed and direction
   ALIEN_MOVE1$="L : Let X=340 ; M -400,0,300 ; J L"

   ' - Position baddies
   Bob 3,340,7,ALIEN_SHIP
   Bob 4,340,29,ALIEN_SHIP
   Bob 5,340,51,ALIEN_SHIP
   Bob 6,340,73,ALIEN_SHIP
   Bob 7,340,95,ALIEN_SHIP

   ' - Assign movement to aliens
   For ALIEN=3 To NUM_BOBS
      Move X ALIEN,ALIEN_WAVE1$
      Move On
      Wait 2
      Amal ALIEN,ALIEN_MOVE1$

      ' - Set number of hits required by each alien
      ALIEN_HIT(ALIEN-3)=10
   Next ALIEN

   Gosub _START_NEW_WAVE

   ' - Aliens alive decreases every time an alien is killed
   ALIENS_ALIVE=5
   ' - Max Kill is a constant number that have to be killed
   _MAX_KILL=ALIENS_ALIVE
   Return



   _WAVE2:
   ' - Alien Wave 2 (is it a bird? - no!)
   Gosub _DEFINE_NEW_WAVE

   ' - Set colours
   Palette ,,,,$FFF,$CCC,$F00,$B00

   ' - Define wave movement
   ALIEN_MOVE3$="M 0,0,40 ; L : Let X=340 ; M -400,0,100 ; J L"
   ALIEN_MOVE5$="M 0,0,20 ; L : Let X=340 ; M -400,0,100 ; J L"
   ALIEN_MOVE7$="L : Let X=340 ; M -400,0,100 ; J L"

   ALIEN_WAVE$="(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3) L"

   ' - Position aliens
   Bob 3,340,7,SUPER_DAN
   Bob 5,340,29,SUPER_DAN
   Bob 7,340,51,SUPER_DAN
   Bob 6,340,73,SUPER_DAN
   Bob 4,340,95,SUPER_DAN

   For ALIEN=3 To 7
      Move Y ALIEN,ALIEN_WAVE$
      ALIEN_HIT(ALIEN-3)=3
   Next ALIEN
   Move On

   ' - Assign movement to aliens
   Amal 3,ALIEN_MOVE3$
   Amal 4,ALIEN_MOVE3$
   Amal 5,ALIEN_MOVE5$
   Amal 6,ALIEN_MOVE5$
   Amal 7,ALIEN_MOVE7$

   Gosub _START_NEW_WAVE
   ALIENS_ALIVE=5
   _MAX_KILL=ALIENS_ALIVE
   Return



   _WAVE3:
   ' - Alien Wave 3 (Round balls - What other shape balls are there?)
   Gosub _DEFINE_NEW_WAVE

   ' - Set colours
   Palette ,,,,$444,$777,$999,$CCC

   ' - Define wave movement
   ALIEN_WAVE1$="(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3) "
   ALIEN_WAVE1$=ALIEN_WAVE1$+"(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3) L"

   ' - Define wave direction and speed
   ALIEN_MOVE3$="M 0,0,10 ; L : Let X=340 ; M -400,0,200 ; J L"
   ALIEN_MOVE4$="M 0,0,30 ; L : Let X=340 ; M -400,0,200 ; J L"
   ALIEN_MOVE5$="M 0,0,50 ; L : Let X=340 ; M -400,0,200 ; J L"
   ALIEN_MOVE6$="M 0,0,70 ; L : Let X=340 ; M -400,0,200 ; J L"
   ALIEN_MOVE7$="M 0,0,90 ; L : Let X=340 ; M -400,0,200 ; J L"

   ' - Position aliens and begin movement
   For ALIEN=3 To 7
      Bob ALIEN,340,51,BALL
      Move Y ALIEN,ALIEN_WAVE1$
      Move On
      Wait 5
      ALIEN_HIT(ALIEN-3)=3
   Next ALIEN

   ' - Assign amal strings to baddies
   Amal 3,ALIEN_MOVE3$
   Amal 4,ALIEN_MOVE4$
   Amal 5,ALIEN_MOVE5$
   Amal 6,ALIEN_MOVE6$
   Amal 7,ALIEN_MOVE7$

   Gosub _START_NEW_WAVE
   ALIENS_ALIVE=5
   _MAX_KILL=ALIENS_ALIVE
   Return



   _WAVE4:
   ' - Alien Wave 4 (Acid Men? - I was running out of ideas for aliens!)
   Gosub _DEFINE_NEW_WAVE

   ' - Set colours
   Palette ,,,,,$330,$F00,$FF0

   ' - Define wave direction and speed
   ALIEN_MOVE4$="L : Let X=350 ; M -400,0,200 ; J L"

   ' - Define wave movement
   ALIEN_WAVE1$="(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3) "
   ALIEN_WAVE1$=ALIEN_WAVE1$+"(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3) L"

   ' - Position aliens and begin movement
   For ALIEN=3 To NUM_BOBS
      Bob ALIEN,350,60,ACID
      Move X ALIEN,ALIEN_WAVE1$
      Move On
      Wait 6
      Move Y ALIEN,ALIEN_WAVE1$
      Move On
      Amal ALIEN,ALIEN_MOVE4$
      ALIEN_HIT(ALIEN-3)=3
   Next ALIEN

   Gosub _START_NEW_WAVE
   ALIENS_ALIVE=5
   _MAX_KILL=ALIENS_ALIVE
   Return



   _WAVE5:
   ' - Alien Wave 5 (Little Disk Dudes! - Now we're really getting desparate!)
   Gosub _DEFINE_NEW_WAVE

   ' - Set colours
   Palette ,,,,$33F,$999,$111

   ' - Define wave direction and speed
   ALIEN_MOVE1$="M 0,0,80 ; L : Let X=340 ; M -400,0,200 ; J L"
   ALIEN_MOVE2$="M 0,0,80 ; L : Let X=-20 ; M 400,0,200 ; J L"

   ' - Define wave movement
   ALIEN_WAVE1$="(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3) "
   ALIEN_WAVE1$=ALIEN_WAVE1$+"(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3) L"

   ' - Position aliens and begin movement
   Bob 3,340,50,DISK
   Bob 4,340,50,DISK
   Bob 5,-20,50,DISK
   Bob 6,-20,50,DISK

   For ALIEN=3 To 6
      Move Y ALIEN,ALIEN_WAVE1$
      Move On
      Wait 10
      ALIEN_HIT(ALIEN-3)=4
   Next ALIEN

   Amal 5,ALIEN_MOVE2$
   Amal 3,ALIEN_MOVE1$ : Amal On
   Wait 10
   Amal 4,ALIEN_MOVE1$
   Amal 6,ALIEN_MOVE2$
   Amal On

   Gosub _START_NEW_WAVE

   ' - Only four this time! - This is getting too easy!
   ALIENS_ALIVE=4
   _MAX_KILL=ALIENS_ALIVE
   Return



   _WAVE6:
   ' - Alien Wave 6 (Wasps)
   Gosub _DEFINE_NEW_WAVE

   ' - Set colours
   Palette ,,,,$444,$875,$BA4,$FC0

   ' - Define wave direction and speed
   ALIEN_MOVE3$="M 0,0,140 ; L : Let X=380 ; M -115,50,20 ; M -230,-100,40 ; M -115,50,20 ; J L"

   ' - Define wave movement
   ALIEN_WAVE1$="(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3) "
   ALIEN_WAVE1$=ALIEN_WAVE1$+"(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3) L"

   ' - Position aliens and begin movement
   For ALIEN=3 To 7
      Bob ALIEN,370,50,WASP
      Move X ALIEN,ALIEN_WAVE1$
      Move On
      Amal ALIEN,ALIEN_MOVE3$
      Amal On
      Wait 5
      ALIEN_HIT(ALIEN-3)=4
   Next ALIEN

   Gosub _START_NEW_WAVE

   ' - Hooray! - Back to five aliens!
   ALIENS_ALIVE=5
   _MAX_KILL=ALIENS_ALIVE
   Return



   _WAVE7:
   ' - Alien Wave 7 (Asteroids / MeatBalls / Chappie / Dumps)
   Gosub _DEFINE_NEW_WAVE

   ' - Set colours
   Palette ,,,,$431,$653,$764,$875

   ' - Define wave direction and speed
   ALIEN_MOVE1$="M 0,0,80 ; L : Let X=380 ; M -400,0,200 ; J L"
   ALIEN_MOVE2$="M 0,0,80 ; L : Let X=-60 ; M 400,0,200 ; J L"

   ' - Define wave movement
   ALIEN_WAVE1$="(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3) "
   ALIEN_WAVE1$=ALIEN_WAVE1$+"(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3) L"

   ALIEN_WAVE2$="(1,2,3)(1,1,3)(1,-1,3)(1,-2,3) "
   ALIEN_WAVE2$=ALIEN_WAVE2$+"(1,-2,3)(1,-1,3)(1,1,3)(1,2,3) L"

   ' - Position aliens and begin movement
   Bob 3,380,7,_AST1
   Bob 4,380,51,_AST2
   Bob 5,380,95,_AST3
   Bob 6,-60,29,_AST2
   Bob 7,-60,73,_AST1

   For ALIEN=3 To 7
      Move X ALIEN,ALIEN_WAVE1$
      Move Y ALIEN,ALIEN_WAVE2$
      Move On
      ALIEN_HIT(ALIEN-3)=5
   Next ALIEN

   ' - Assign movement
   Amal 3,ALIEN_MOVE1$
   Amal 4,ALIEN_MOVE1$
   Amal 5,ALIEN_MOVE1$
   Amal 6,ALIEN_MOVE2$
   Amal 7,ALIEN_MOVE2$
   Amal On

   Gosub _START_NEW_WAVE
   ALIENS_ALIVE=5
   _MAX_KILL=ALIENS_ALIVE
   Return



   _WAVE8:
   ' - Alien Wave 8 (Mine with bullets! - Now we're getting there!)
   Gosub _DEFINE_NEW_WAVE

   ' - Set colours
   Palette ,,,,$444,$777,$999,$CCC

   ' - Define wave direction and speed
   ALIEN_MOVE1$="L : Let X=340 ; M -180,0,20 ; M 0,0,50 ; M -180,0,20 ;J L"
   SHOT_MOVE1$="L : M 0,0,45 ; Let X=167 ; Let Y=67 ; M 0,-70,20 ; M 0,0,25 ; J L"
   SHOT_MOVE2$="L : M 0,0,45 ; Let X=167 ; Let Y=67 ; M 0,70,20 ; M 0,0,25 ; J L"
   SHOT_MOVE3$="L : M 0,0,45 ; Let X=167 ; Let Y=67 ; M -180,0,20 ; M 0,0,25 ; J L"
   SHOT_MOVE4$="L : M 0,0,45 ; Let X=167 ; Let Y=67 ; M 180,0,20 ; M 0,0,25 ; J L"

   ' - Position aliens and begin movement
   Bob 3,340,60,_MINE
   Bob 4,340,95,_MINE_SHOT
   Bob 5,340,95,_MINE_SHOT
   Bob 6,340,95,_MINE_SHOT
   Bob 7,340,95,_MINE_SHOT

   Amal 3,ALIEN_MOVE1$
   Amal 4,SHOT_MOVE1$
   Amal 5,SHOT_MOVE2$
   Amal 6,SHOT_MOVE3$
   Amal 7,SHOT_MOVE4$
   ALIEN_HIT(0)=20

   Gosub _START_NEW_WAVE

   ' - ONE!  ONE!  WHAT USE IS ONE!
   ALIENS_ALIVE=1
   _MAX_KILL=ALIENS_ALIVE
   Return



   _WAVE9:
   ' - Alien Wave 9 (Bat type things - Thanx Core!)
   Gosub _DEFINE_NEW_WAVE

   ' - Set colours
   Palette ,,,,$444,$777,$999,$CCC

   ' - Define wave direction and speed
   ALIEN_MOVE1$="L : Let X=340 ; M -400,0,200 ; J L"

   ' - Define wave movement
   ALIEN_WAVE1$="(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3) "
   ALIEN_WAVE1$=ALIEN_WAVE1$+"(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3) L"

   ALIEN_WAVE2$="(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3) "
   ALIEN_WAVE2$=ALIEN_WAVE2$+"(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3) L"

   ' - Position aliens and begin movement
   Bob 3,340,7,BAT
   Bob 4,340,7,BAT
   Bob 5,340,95,BAT
   Bob 6,340,95,BAT

   Move Y 3,ALIEN_WAVE2$
   Move Y 6,ALIEN_WAVE1$
   Move On
   Wait 20
   Move Y 4,ALIEN_WAVE2$
   Move Y 5,ALIEN_WAVE1$
   Move On

   For ALIEN=3 To 6
      Amal ALIEN,ALIEN_MOVE1$
      ALIEN_HIT(ALIEN-3)=7
   Next ALIEN

   Gosub _START_NEW_WAVE
   ALIENS_ALIVE=4
   _MAX_KILL=ALIENS_ALIVE
   Return



   _WAVE10:
   ' - Alien Wave 10 (Firey star thing)
   Gosub _DEFINE_NEW_WAVE

   ' - Set colours
   Palette ,,,,$400,$720,$960,$CC0

   ' - Define wave direction and speed
   ALIEN_MOVE1$="L: M -50,-50,25 ; M 50,50,25 ;J L"
   ALIEN_MOVE2$="L: M 50,-50,25 ; M -50,50,25 ;J L"
   ALIEN_MOVE3$="L: M -50,50,25 ; M 50,-50,25 ;J L"
   ALIEN_MOVE4$="L: M 50,50,25 ; M -50,-50,25 ;J L"

   ' - Define wave movement
   SPIKE_MOVE$="(1,-1,400)(1,400,1)L"

   ' - Position aliens and begin movement
   Bob 3,340,47,SPIKE1
   Bob 4,355,47,SPIKE2
   Bob 5,340,62,SPIKE3
   Bob 6,355,62,SPIKE4

   Amal 3,ALIEN_MOVE1$
   Amal 4,ALIEN_MOVE2$
   Amal 5,ALIEN_MOVE3$
   Amal 6,ALIEN_MOVE4$

   For ALIEN=3 To 6
      Move X ALIEN,SPIKE_MOVE$
      ALIEN_HIT(ALIEN-3)=10
   Next ALIEN

   Gosub _START_NEW_WAVE
   ALIENS_ALIVE=4
   _MAX_KILL=ALIENS_ALIVE
   Move On
   Return



   _WAVE11:
   ' - Alien Wave 11 (Ammonite (scarf))
   Gosub _DEFINE_NEW_WAVE

   ' - Set colours
   Palette ,,,,$420,$741,$974,$CA8

   ' - Define wave direction and speed
   ALIEN_MOVE1$="L: Let X=380 ; M -480,0,240 ; J L"
   ALIEN_MOVE2$="L: Let X=-80 ; M 480,0,240 ; J L"

   ' - Define wave movement
   ALIEN_WAVE1$="(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3) "
   ALIEN_WAVE1$=ALIEN_WAVE1$+"(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3) L"

   ALIEN_WAVE2$="(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3) "
   ALIEN_WAVE2$=ALIEN_WAVE2$+"(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3) L"

   ' - Position aliens and begin movement
   Bob 3,380,47,SCARF
   Bob 4,-80,47,SCARF

   Amal 3,ALIEN_MOVE1$
   Amal 4,ALIEN_MOVE2$

   Move X 3,ALIEN_WAVE1$
   Move X 4,ALIEN_WAVE2$
   Move On
   Wait 15
   Move Y 3,ALIEN_WAVE1$
   Move Y 4,ALIEN_WAVE2$
   Move On

   ALIEN_HIT(0)=10
   ALIEN_HIT(1)=10

   Gosub _START_NEW_WAVE
   ALIENS_ALIVE=2
   _MAX_KILL=ALIENS_ALIVE
   Return



   _WAVE12:
   ' - Alien Wave 12 (Wasps and doughnuts!)
   Gosub _DEFINE_NEW_WAVE

   ' - Set colours
   Palette ,,,,$444,$875,$BA4,$FC0

   ' - Define wave direction and speed
   ALIEN_MOVE1$="L: Let X=X+500 ; M -500,0,250 ; J L"

   ' - Define wave movement
   ALIEN_WAVE1$="(1,7,3)(1,6,3)(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3)(1,-6,3)(1,-7,3) "
   ALIEN_WAVE1$=ALIEN_WAVE1$+"(1,-7,3)(1,-6,3)(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3)(1,6,3)(1,7,3) L"

   ' - Position aliens and begin movement
   Bob 3,-120,51,WASP
   Bob 4,-120,51,_DONUT
   Bob 5,-120,51,_DONUT
   Bob 6,-120,51,_DONUT
   Bob 7,-120,51,_DONUT

   For ALIEN=3 To 7
      Amal ALIEN,ALIEN_MOVE1$
      ALIEN_HIT(ALIEN-3)=2
   Next ALIEN
   ALIEN_HIT(0)=6

   For ALIEN=4 To 7
      Move X ALIEN,ALIEN_WAVE1$
      Move On
      Wait 28
      Move Y ALIEN,ALIEN_WAVE1$
      Move On
      Wait 7
   Next ALIEN

   Gosub _START_NEW_WAVE
   ALIENS_ALIVE=5
   _MAX_KILL=ALIENS_ALIVE
   Return



   _WAVE13:
   ' - Alien Wave 13 (Wheeeeeeeeel - Ya know what it is?)
   Gosub _DEFINE_NEW_WAVE

   ' - Set colours
   Palette ,,,,$F,$33E,$66D,$88C

   ' - Define wave direction and speed
   ALIEN_MOVE1$="M 0,0,50 ; L: Let X=380 ; M -150,0,50 ; M 50,0,25 ; M -100,0,50 ; M 50,0,25  M -100,0,50 ; M 50,0,25  M -100,0,50 ; M 50,0,25  M -100,0,50 ; M 50,0,25  M -100,0,50 ; M 50,0,25  M -100,0,50 ; M 50,0,25 ; M -100,0,50 ; M 50,0,25 ; J L"
   ALIEN_MOVE2$="M 0,0,60 ; L: Let X=380 ; M -150,0,50 ; M 50,0,25 ; M -100,0,50 ; M 50,0,25  M -100,0,50 ; M 50,0,25  M -100,0,50 ; M 50,0,25  M -100,0,50 ; M 50,0,25  M -100,0,50 ; M 50,0,25  M -100,0,50 ; M 50,0,25 ; M -100,0,50 ; M 50,0,25 ; J L"
   ALIEN_MOVE3$="M 0,0,70 ; L: Let X=380 ; M -150,0,50 ; M 50,0,25 ; M -100,0,50 ; M 50,0,25  M -100,0,50 ; M 50,0,25  M -100,0,50 ; M 50,0,25  M -100,0,50 ; M 50,0,25  M -100,0,50 ; M 50,0,25  M -100,0,50 ; M 50,0,25 ; M -100,0,50 ; M 50,0,25 ; J L"

   ' - Define wave movement
   ALIEN_WAVE1$="(1,8,3)(1,7,3)(1,6,3)(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3)(1,-6,3)(1,-7,3)(1,-8,3) L"

   ' - Position aliens and begin movement
   Bob 3,380,0,WHEEL
   Bob 4,380,0,WHEEL
   Bob 5,380,0,WHEEL
   '
   Amal 3,ALIEN_MOVE1$
   Amal 4,ALIEN_MOVE2$
   Amal 5,ALIEN_MOVE3$

   For ALIEN=3 To 5
      ALIEN_HIT(ALIEN-3)=5
      Move Y ALIEN,ALIEN_WAVE1$
      Move On
      Wait 10
   Next ALIEN
   ALIEN_HIT(0)=10

   Gosub _START_NEW_WAVE
   ALIENS_ALIVE=3
   _MAX_KILL=ALIENS_ALIVE
   Return



   _WAVE14:
   ' - Alien Wave 14 (Ladybird)
   Gosub _DEFINE_NEW_WAVE

   ' - Set colours
   Palette ,,,,$C44,$C11,$606,$222

   ' - Define wave direction and speed
   ALIEN_MOVE1$="L: Let X=380 ; Let Y=7 ; M 0,0,10 ; M -210,0,21 ; M 0,0,20 ; M -200,0,20 ; J L"
   ALIEN_MOVE2$="L: Let X=380 ; Let Y=29 ; M 0,0,20 ; M -230,0,23 ; M 0,0,20 ; M -180,0,18 ; J L"
   ALIEN_MOVE3$="L: Let X=380 ; Let Y=53 ; M 0,0,30 ; M -250,0,25 ; M 0,0,20 ; M -160,0,16 ; J L"
   ALIEN_MOVE4$="L: Let X=380 ; Let Y=75 ; M 0,0,20 ; M -230,0,23 ; M 0,0,20 ; M -180,0,18 ; J L"
   ALIEN_MOVE5$="L: Let X=380 ; Let Y=97 ; M 0,0,10 ; M -210,0,21 ; M 0,0,20 ; M -200,0,20 ; J L"

   ' - Position aliens and begin movement
   For ALIEN=3 To 7
      Bob ALIEN,380,0,LADYBIRD
      ALIEN_HIT(ALIEN-3)=5
   Next ALIEN

   ' - Assign movement
   Amal 3,ALIEN_MOVE1$
   Amal 4,ALIEN_MOVE2$
   Amal 5,ALIEN_MOVE3$
   Amal 6,ALIEN_MOVE4$
   Amal 7,ALIEN_MOVE5$

   Gosub _START_NEW_WAVE
   ALIENS_ALIVE=5
   _MAX_KILL=ALIENS_ALIVE
   Return



   _WAVE15:
   ' - Alien Wave 14 (Arrow)
   Gosub _DEFINE_NEW_WAVE

   ' - Set colours
   Palette ,,,,$830,$666,$CCC,$FB8

   ' - Define wave direction and speed
   ALIEN_MOVE1$="L: Let X=380 ; Let Y=7 ;  M -400,0,100 ; J L"
   ALIEN_MOVE2$="L: Let X=380 ; Let Y=29 ; M -400,0,100 ; J L"
   ALIEN_MOVE3$="L: Let X=380 ; Let Y=53 ; M -400,0,100 ; J L"
   ALIEN_MOVE4$="L: Let X=380 ; Let Y=75 ; M -400,0,100 ; J L"
   ALIEN_MOVE5$="L: Let X=380 ; Let Y=97 ; M -400,0,100 ; J L"

   ' - Position aliens and begin movement
   ALIEN_WAVE1$="(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3) "
   ALIEN_WAVE1$=ALIEN_WAVE1$+"(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3) L"

   ALIEN_WAVE2$="(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3) "
   ALIEN_WAVE2$=ALIEN_WAVE2$+"(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3) L"

   ALIEN_WAVE3$="(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3) "
   ALIEN_WAVE3$=ALIEN_WAVE3$+"(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3) L"

   ALIEN_WAVE4$="(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3) "
   ALIEN_WAVE4$=ALIEN_WAVE4$+"(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3) L"

   For ALIEN=3 To 7
      Bob ALIEN,380,0,ARROW
      ALIEN_HIT(ALIEN-3)=4
   Next ALIEN

   Amal 3,ALIEN_MOVE1$
   Move Y 3,ALIEN_WAVE3$

   Amal 4,ALIEN_MOVE2$
   Move Y 4,ALIEN_WAVE1$

   Amal 5,ALIEN_MOVE3$
   Amal 6,ALIEN_MOVE4$
   Move Y 6,ALIEN_WAVE2$

   Amal 7,ALIEN_MOVE5$
   Move Y 7,ALIEN_WAVE4$

   Move On

   Gosub _START_NEW_WAVE
   ALIENS_ALIVE=5
   _MAX_KILL=ALIENS_ALIVE
   Return



   GUARD1:
   ' - 1st Guardian (Snake Thing)
   Gosub _DEFINE_NEW_WAVE

   ' - Set colours
   Palette ,,,,$40,$60,$80,$A0

   ' - Define wave direction and speed
   GUARDIAN_ON$="M -130,0,26 "

   GUARD_SHOT1$="M 0,0,10 ; L : F R1=0 To Z(50) ; N R1 ; Let X=280 ; Let Y=80 ; M -320,-80,50 ; J L"
   GUARD_SHOT2$="M 0,0,10 ; L : F R1=0 To Z(50) ; N R1 ; Let X=280 ; Let Y=80 ; M -320,-50,50 ; J L"
   GUARD_SHOT3$="M 0,0,10 ; L : F R1=0 To Z(50) ; N R1 ; Let X=280 ; Let Y=80 ; M -320,-20,50 ; J L"

   SHOT_MOVE$="(1,2,3)(1,1,3)(1,-1,3)(1,-2,3) "
   SHOT_MOVE$=SHOT_MOVE$+"(1,-2,3)(1,-1,3)(1,1,3)(1,2,3) L"

   ' - Position aliens and begin movement
   Bob 3,394,43,GUARDIAN1_EYE
   Bob 4,340,37,GUARDIAN1
   Bob 5,340,7,_MINE_SHOT
   Bob 6,340,95,_MINE_SHOT
   Bob 7,340,95,_MINE_SHOT

   Amal 3,GUARDIAN_ON$
   Amal 4,GUARDIAN_ON$
   Amal On
   Wait 30
   Paste Bob 210,37,GUARDIAN1
   Bob Off 4
   Amal 5,GUARD_SHOT1$
   Amal 6,GUARD_SHOT2$
   Amal 7,GUARD_SHOT3$

   For ALIEN=5 To 7
      ' - Bullets
      Move Y ALIEN,SHOT_MOVE$
   Next ALIEN
   Move On

   ' - The EYE is the only thing which can be hit!
   ALIEN_HIT(0)=10

   Gosub _START_NEW_WAVE
   ALIENS_ALIVE=1
   _MAX_KILL=ALIENS_ALIVE
   GUARDIAN_STAGE=True
   X_MAX=182
   Return



   GUARD_SKULL:
   ' - 2nd Guardian (Skull - The big jerky one!)
   Gosub _DEFINE_NEW_WAVE

   ' - Set colours
   Palette ,,,,$441,$773,$996,$CCA

   ' - Define wave direction and speed
   GUARDIAN_ON$="M -130,0,26 "

   GUARD_SHOT1$="M 0,0,50 ; L: Let X=216 ; M -250,0,40 ; J L"
   GUARD_SHOT2$="M 0,0,70 ; L: Let X=216 ; M -250,0,40 ; J L"

   SHOT_MOVE$="(1,2,3)(1,1,3)(1,-1,3)(1,-2,3) "
   SHOT_MOVE$=SHOT_MOVE$+"(1,-2,3)(1,-1,3)(1,1,3)(1,2,3) L"

   ' - Position aliens and begin movement
   Bob 3,345,50,SKULL_EYE
   Bob 4,340,3,SKULL
   Bob 5,340,55,SKULL_SHOT
   Bob 6,340,55,SKULL_SHOT

   For ALIEN=5 To 6
      Move X ALIEN,SHOT_MOVE$
      Move On
      Wait 2
      Move Y ALIEN,SHOT_MOVE$
      Move On
   Next ALIEN

   Amal 3,GUARDIAN_ON$
   Amal 4,GUARDIAN_ON$
   Amal On
   Wait 30
   Paste Bob 210,3,SKULL
   Bob Off 4
   Amal 5,GUARD_SHOT1$
   Amal 6,GUARD_SHOT2$


   ' - The EYE is the only thing which can be hit!
   ALIEN_HIT(0)=10

   ' -So they can't hit the skull image
   X_MAX=180

   Gosub _START_NEW_WAVE
   ALIENS_ALIVE=1
   _MAX_KILL=ALIENS_ALIVE
   GUARDIAN_STAGE=True
   FINAL_STAGE=True

   Return



   BEAST:
   ' - 3rd Guardian (Beast)
   Gosub _DEFINE_NEW_WAVE

   ' - Set colours
   Palette ,,,,$AAA,$666,$444,$66F

   ' - Define wave direction and speed
   GUARDIAN_ON$="M -130,0,26 "

   GUARD_SHOT$="M 0,0,80 ; L: Let X=208 ; M -250,0,40 ; J L"

   GUN_MOVE$="(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3) "
   GUN_MOVE$=GUN_MOVE$+"(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3) L"

   ' - Position aliens and begin movement
   Bob 3,410,61,BEAST_EYE
   Bob 4,380,40,BEAST_GUARD
   Bob 5,340,40,UPPER_GUN
   Bob 6,340,80,LOWER_GUN

   For ALIEN=3 To 6
      Amal ALIEN,GUARDIAN_ON$
   Next ALIEN
   Amal On
   Wait 30

   Paste Bob 250,40,BEAST_GUARD

   Bob 4,340,44,BEAST_SHOT
   Bob 7,340,84,BEAST_SHOT

   For ALIEN=4 To 7
      Move Y ALIEN,GUN_MOVE$
   Next ALIEN
   Move On

   Amal 4,GUARD_SHOT$
   Amal 7,GUARD_SHOT$
   Amal On

   ' - The EYE is the only thing which can be hit!
   ALIEN_HIT(0)=10

   ' - So they can't hit the beast image
   X_MAX=180

   Gosub _START_NEW_WAVE
   ALIENS_ALIVE=1
   _MAX_KILL=ALIENS_ALIVE
   GUARDIAN_STAGE=True

   Return


   BONUS_WAVE:
   ' - This is just an interesting way of getting an extra life!
   _TEXT=BONUS_TEXT
   Gosub _DEFINE_NEW_WAVE
   BONUS_STAGE=True

   ' - Set colours
   Palette ,,,,$444,$777,$999,$F00

   ' - Define wave direction and speed
   BONUS_MOVE$="L : Let X=340 ; Let Y=Z(68)+30 ; M 0,0,Z(100)+50 ; M -400,0,200 ; J L"
   ALIEN_MOVE1$="L : Let X=340 ; Let Y=42 ; M -400,0,50 ; J L"
   ALIEN_MOVE2$="L : Let X=340 ; Let Y=84 ; M -400,0,50 ; J L"

   ' - Define movement strings
   ALIEN_WAVE1$="(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3) "
   ALIEN_WAVE1$=ALIEN_WAVE1$+"(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3) L"

   ALIEN_WAVE2$="(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3) "
   ALIEN_WAVE2$=ALIEN_WAVE2$+"(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3) L"

   BONUS_WAVE1$="(1,2,3)(1,1,3)(1,-1,3)(1,-2,3) "
   BONUS_WAVE1$=BONUS_WAVE1$+"(1,-2,3)(1,-1,3)(1,1,3)(1,2,3) L"


   ' - Position aliens and begin movement
   Bob 3,340,0,_1UP
   Bob 4,340,0,_20_POINTS
   Bob 5,340,0,_10_POINTS
   Bob 6,340,0,_FIRE_BALL
   Bob 7,340,0,_FIRE_BALL

   Amal 3,BONUS_MOVE$
   Amal 4,BONUS_MOVE$
   Amal 5,BONUS_MOVE$
   Amal 6,ALIEN_MOVE1$
   Amal 7,ALIEN_MOVE2$

   For ALIEN=3 To 5
      Move Y ALIEN,BONUS_WAVE1$
   Next ALIEN
   Move Y 6,ALIEN_WAVE1$
   Move Y 7,ALIEN_WAVE2$
   Move On

   ' - Two bad dudes
   ALIEN_HIT(3)=2
   ALIEN_HIT(4)=2

   Gosub _START_NEW_WAVE
   ALIENS_ALIVE=3
   _MAX_KILL=ALIENS_ALIVE
   Return



   ' ----- Wave procedures -----

   _DEFINE_NEW_WAVE:
   ' - This should be called at the start of each wave definition!
   Gosub _KILL_ALL_ALIENS

   ' - Display Message
   Bob _TEXT_BOB,40,-30,_TEXT
   Amal _TEXT_BOB,_TEXT_ON$
   Amal On _TEXT_BOB
   ' - Set text for next time
   _TEXT=_WAVE_CLEAR
   Return


   _START_NEW_WAVE:
   ' - This should be called at the END of each wave definition!
   ' - Remove text bob
   Wait TIME_BETWEEN_WAVES
   Amal _TEXT_BOB,_TEXT_OFF$
   Amal On _TEXT_BOB
   Wait 25 : Rem - Wait for text to dissappear
   Bob Off _TEXT_BOB
   ' - Go!
   Amal On
   Return


   _KILL_ALL_ALIENS:
   ' - Kills all aliens! - No! - Yes! - No! - Yes! - No! - Yes! - No! - Yes! - No! - Yes! - No! - Yes! - No! - Yes! - No! - Yes! - This could go on all night!
   For ALIEN=3 To 7
      Bob ALIEN,400,200,ALIEN_SHIP
      Amal Off ALIEN
      Move Off ALIEN
      Wait Vbl
   Next ALIEN
   Return


   ' ----- Dead Dude stuff -----

   AARRGH_THEY_GOT_ME:
   ' - Main ship death sequence

   If Not BONUS_STAGE
      ' - Explode ship
      Amal MAIN_SHIP,MAIN_DIE$
      Amal On MAIN_SHIP
      Sam Play %1001,MAIN_SHIP_BOOM,5000
      Wait 12
      Bob Off MAIN_SHIP

      If Not GUARDIAN_STAGE
         ' - Cos guardians use all eight colous! (Yes all EIGHT!)
         ' - Fade aliens
         Fade 2,,,,,0,0,0,0
         Wait 30
      Else
         If LIVES>0
            Fade 1 : Wait 15
            If BACKGROUND=6
               BACKGROUND=7
            Else
               If BACKGROUND=10
                  BACKGROUND=6
               Else
                  If BACKGROUND=7
                     BACKGROUND=10
                  End If
               End If
            End If
            Gosub SETUP_BACKGROUND
         End If
      End If

      ' - Delete aliens
      Gosub _KILL_ALL_ALIENS

      If LIVES>0
         ' - Re-Start current wave
         If _WAVE_CTR>1
            Dec _WAVE_CTR
         Else
            _WAVE_CTR=NUM_OF_WAVES
         End If
         ALIENS_ALIVE=0
         _TEXT=_GET_READY

         ' - Position Main Ship
         Amal Off MAIN_SHIP
         Bob MAIN_SHIP,60,60,MAIN_SHIP

         ' - Update life counter
         Dec LIVES
         Gosub _UPDATE_LIVES

         ' - Ensure that the background is not changed etc.
         GUARDIAN_STAGE=False
      Else
         ' - No lives left!
         Gosub GAME_OVER_DUDE
      End If
   Else

      ' ----- Bonus Stage Stuff -----

      If I Bob(ALIEN)=_1UP
         ' - If they collected the Extra Life
         Inc LIVES
         Sam Play %110,CHINK,10000
         Gosub _UPDATE_LIVES
         Dec ALIENS_ALIVE
         Bob Off 3
      Else
         If I Bob(ALIEN)=_20_POINTS
            ' - If they collected a score bonus
            Add SCORE,20
            Sam Play %110,CHINK,10000
            Gosub _UPDATE_SCORE
            Dec ALIENS_ALIVE
            Bob Off 4
         Else
            If I Bob(ALIEN)=_10_POINTS
               ' - If they collected a score bonus
               Add SCORE,10
               Sam Play %110,CHINK,10000
               Gosub _UPDATE_SCORE
               Dec ALIENS_ALIVE
               Bob Off 5
            Else
               ' If I died! (Highly unlikely! - It's too easy!)
               ALIENS_ALIVE=0
               BONUS_STAGE=False
               Inc _WAVE_CTR : Rem - So you don't repeat the bonus stage
               Inc LIVES : Rem - So you don't lose a life for dying here!
               Gosub AARRGH_THEY_GOT_ME
            End If
         End If
      End If
      If ALIENS_ALIVE=0
         ' - End of Bonus Stage!
         BONUS_STAGE=False
         Gosub _KILL_ALL_ALIENS
      End If
   End If
   Return


   GAME_OVER_DUDE:

   ' - Remove aliens from screen...
   Gosub _KILL_ALL_ALIENS
   ' - ...and the main ship
   Bob Off MAIN_SHIP

   ' - Clear the screen
   Fade 1 : Wait 15
   Cls 0
   ' - And again!
   Bob Off
   Palette 0,0,0,0,0,0,0,0
   Cls 0
   Wait Vbl
   Get Sprite Palette

   ' - Display game over text
   Bob _TEXT_BOB,40,-30,GAME_OVER
   Amal _TEXT_BOB,_TEXT_ON$
   Amal On _TEXT_BOB

   '- Stop colour cycling. (I thought it was supposed to be animation!)
   Screen 1 : Shift Off : Screen 0

   ' - Set appropriate stuff! (I do like meaningful variable names!)
   YOU_DIED_SCUMBAG=True
   _PLAYED_AND_DIED=True
   _TEXT=_GET_READY
   Return


   YEAH_GOT_ONE:
   ' - They actually managed to hit an alien! - It's a miracle!
   If Not BONUS_STAGE
      If ALIEN_HIT(ALIEN-3)=1
         ' - If the alien was on its last legs (poor soul)
         ' - Move an alien off the screen
         Amal ALIEN,ALIEN_DIE$
         Amal On ALIEN
         Sam Play %110,ALIEN_BOOM,10000

         ' - Decrement alien counter
         Dec ALIENS_ALIVE
      Else
         ' - Decrement alien hit counter (The shield is down!  Commence attack on the Death-Stars main reactor!)
         Dec ALIEN_HIT(ALIEN-3)
         Sam Play %110,CHINK,10000
      End If

      ' - Increment the score
      Inc SCORE
      Gosub _UPDATE_SCORE
   End If
   ' - If it's the Bonus Stage... Nothing happens!

   ' - Erase the bullet from the screen
   Bob BULLET,540,-60,BULLET

   Return


   ' ----- Status screen updates -----

   _UPDATE_LEVEL:
   ' - Hmmm, I wonder what this does?
   TXT$=Str$(_WAVE_CTR)
   Screen 2
   Ink 0 : Bar 177,1 To 200,9
   Ink 1 : Text 177,8,TXT$
   Screen 0
   Return


   _UPDATE_LIVES:
   ' - They either died or they got an Extra!
   TXT$=Str$(LIVES)
   Screen 2
   Ink 0 : Bar 70,1 To 85,9
   Ink 1 : Text 70,8,TXT$
   Screen 0
   Return


   _UPDATE_SCORE:
   ' - Re-draw the score (Look at the size of that sausage!)
   TXT$=Str$(SCORE)
   Screen 2
   Ink 0 : Bar 280,1 To 320,9
   Ink 1 : Text 285,8,TXT$
   Screen 0
   Return


   ' ----- Pause Mode Code (Woah! Freud Dude!) -----

   PAUSE:
   ' - Stop animation and cycling (ah! so it is cycling!)
   Amal Freeze
   Move Freeze
   Screen 1 : Shift Off : Screen 0
   Bob _TEXT_BOB,120,50,PAUSED_IMAGE
   Wait 5

   Repeat
      ' - Wait until they release the P key - Depending on key-repeat time
   Until Not Key State(25)

   Repeat
      ' - Wait for them to press P, Fire or Escape (or for hell to freeze over!)
      Wait Vbl
      If Key State(69)
         ' - They pressed Escape - That wasn't very polite!
         YOU_DIED_SCUMBAG=True
      End If
   Until Key State(25) or YOU_DIED_SCUMBAG or Fire(1)

   Repeat
      ' - Wait until they release the P key - Depending on key-repeat time
   Until Not Key State(25)

   ' - Re-start it all - Weeeeee...
   Bob Off _TEXT_BOB
   Screen 1 : Shift Down 1,2,7,1 : Screen 0
   Amal On
   Move On
   Return


   ' ----- BACKGROUND SETUP -----

   SETUP_BACKGROUND:
   ' - This should be called after each guardian to fade it
   ' - and set new the background picture.

   Fade 1 : Wait 15

   ' - Unpack appropriate background
   Unpack BACKGROUND To 0
   Screen Display 0,,86,,125
   Palette 0,0,0,0,0,0,0,0
   Double Buffer

   ' - Fade it on
   Fade 1,0,$CCC,$888,$22F,,,
   Wait 15

   ' - Set next background bank
   If BACKGROUND=7
      BACKGROUND=6
      ' - Change scrolly colour (Yellow and Black)
      Screen 1
      Shift Off
      Fade 1,,,$FF0,$FF0,$FF0,$222,$222,$222 : Wait 15
      Shift Down 1,2,7,1
      ' - Flash bar on border
      Flash 1,"(f00,20)(c00,5)(900,5)(500,5)(200,40)(500,5)(900,5)(c00,5)"
      Screen 0
   Else
      If BACKGROUND=6
         BACKGROUND=10
         ' - Change scrolly colour (Red and Blue)
         Screen 1
         Shift Off
         Fade 1,,,$F00,$F00,$F00,$225,$225,$225 : Wait 15
         Shift Down 1,2,7,1
         ' - Flash bar on border
         Flash 1,"(ff0,20)(cc0,5)(990,5)(550,5)(220,40)(550,5)(990,5)(cc0,5)"
         Screen 0
      Else
         If BACKGROUND=10
            BACKGROUND=7
            ' - Change scrolly colour (Pink and Green) (nice!)
            Screen 1
            Shift Off
            Fade 1,,,$FC0,$FC0,$FC0,$252,$252,$252 : Wait 15
            Shift Down 1,2,7,1
            ' - Flash bar on border
            Flash 1,"(00f,20)(00c,5)(009,5)(005,5)(002,40)(005,5)(009,5)(00c,5)"
            Screen 0
         End If
      End If
   End If

   ' - Re-initialise all bobs on new screen
   Gosub INIT_BOBS
   Return


   ' ----- Initialise Bobs -----

   INIT_BOBS:
   ' - Needs to be called each time a new background is used!

   ' - Define channels for ship, bullet and aliens
   For CTR=1 To NUM_BOBS
      Channel CTR To Bob CTR
   Next CTR

   ' - Position baddies off screen for starters
   For ALIEN=3 To NUM_OF_BOBS
      Bob ALIEN,340,240,ALIEN_SHIP
   Next ALIEN

   ' - Define Bullet movement and position initial bullet
   BULLET$="M 340,0,40 : Let X=800 : Let Y=500"
   Bob BULLET,540,-60,BULLET

   ' - Define Alien death movement
   ALIEN_DIE$="M 0,330,30"

   ' - Define Main Ship death animation
   MAIN_DIE$="A 1,(15,3)(16,3)(17,3)(18,3)"

   ' - Define Text bob
   Channel _TEXT_BOB To Bob _TEXT_BOB
   _TEXT_ON$="M 0,50,25 ;"
   _TEXT_OFF$="M 0,-50,25 ;"
   Bob _TEXT_BOB,40,-30,_TEXT

   ' - Play or Quit text
   Channel P_Q To Bob P_Q
   P_Q_ON$="M 0,-50,25 ;"
   P_Q_OFF$="M 0,50,25 ;"

   ' - Position Main Ship
   Bob MAIN_SHIP,60,60,MAIN_SHIP

   Return



   WELL_DONE:
   ' - Display Message
   Fade 1 : Wait 15
   Bob Off
   Cls 0
   Get Sprite Palette
   Bob _TEXT_BOB,60,-30,CON_TEXT
   Amal _TEXT_BOB,_TEXT_ON$
   Amal On _TEXT_BOB
   Wait 100

   Fade 1 : Wait 15 : Cls 0
   ' - Set text for next time
   _TEXT=_GET_READY
   Return

End Proc
Procedure RESET_DEMO
   ' - Re-load the music and continue the demo
   INSERT_DISK_ONE
   SETUP_FONT
   NEW_TEXT_SCREEN["page14"]
   Track Load "no-refund!:stuff/music",3
   Track Loop On
   Track Play 3
   CLEAR_TEXT_SCREEN
   SHUT_TEXT_SCREENS
   INSERT_DISK_TWO
End Proc

' - Vectorballs bit
Procedure VECTOR_BALLS
   SETUP_FONT
   NEW_TEXT_SCREEN["page11"]
   Load "no-refund2!:stuff/pyramid",6
   Load "no-refund2!:stuff/cross",7
   Load "no-refund2!:stuff/box",8
   Load "no-refund2!:stuff/plane",9
   Load "no-refund2!:stuff/green_ball",1
   CLEAR_TEXT_SCREEN
   SHUT_TEXT_SCREENS

   SHADOW_3D
   Erase 1

   Load "no-refund2!:stuff/vecball",1
   _PLAY_ANIM[54,1,6,$C00,$900,$500]
   _PLAY_ANIM[53,1,7,$C,$9,$5]
   _PLAY_ANIM[43,1,8,$CC0,$990,$550]
   _PLAY_ANIM[24,1,9,$C0C,$909,$505]
   Erase 1

End Proc
Procedure SHADOW_3D
   ' - Code - Dug

   Screen Open 0,320,256,4,Lowres
   Flash Off : Curs Off : Cls 0 : Hide
   Double Buffer
   Autoback 0
   For C=0 To 31 : Colour C,0 : Next C
   Limit Mouse 0,0 To 320,320
   Clip 0,0 To 320,255


   MP=4
   NP=MP*2-1
   Dim FX(MP-1),FY(MP-1),FZ(MP-1)
   Dim X(NP),Y(NP),Z(NP),SX(NP),SY(NP)


   Gosub _SETUP_PLATE


   X_ORG=160
   Y_ORG=150
   DVP=-200
   FLOOR=-50 : Rem Y coord of floor (or sea level)
   SUNX=0
   SUNY=50
   SUNZ=0


   OBJX=30
   OBJY=80
   OBJZ=-181

   TIME=70
   S=5
   Sprite 1,X Hard(140),Y Hard(50),1
   Fade S,1,$454,$2,$4,,,,,,,,,,,,,,$FF0,$880,$330

   For SHADOW=1 To TIME
      Screen Swap : Wait Vbl
      Cls 0
      Add OBJZ,2
      Add OBJX,-2
      Add OBJY,-1
      Gosub _DRW_SEA
      Gosub _MOVE_PLATE
      Gosub _CALCULATE_SHADOW
      Gosub _CONV_DRW_COORDS
      If SHADOW>TIME-15 Then Fade 4
   Next SHADOW

   Autoback 2
   Sprite Off 1
   Screen Close 0

   Pop Proc


   _DRW_SEA:
   Ink 3 : Bar 0,Y_ORG To Screen Width,Screen Height
   Return


   _MOVE_PLATE:
   For L=0 To NUMP-1
      X(L)=FX(L)+OBJX
      Y(L)=FY(L)+OBJY
      Z(L)=FZ(L)+OBJZ
   Next L
   Return


   _CALCULATE_SHADOW:
   For L=0 To NUMP-1
      SCALE#=Max(Abs(5.0-Y(L)/20.0),1)
      X(L+NUMP)=X(L)*SCALE#
      Y(L+NUMP)=FLOOR
      Z(L+NUMP)=Z(L)*SCALE#
   Next L
   Return


   _CONV_DRW_COORDS:
   For L=0 To NP
      ZF=DVP+Z(L)
      SX(L)=X_ORG+(X(L)*DVP)/ZF
      SY(L)=Y_ORG-(Y(L)*DVP)/ZF
   Next L
   Gosub _DRW_PLATE
   Gosub _DRW_SHADOW
   Return


   _DRW_PLATE:
   Ink 1
   Polygon SX(0),SY(0) To SX(1),SY(1) To SX(2),SY(2) To SX(3),SY(3) To SX(0),SY(0)
   Return


   _DRW_SHADOW:
   Ink 2
   Polygon SX(4),SY(4) To SX(5),SY(5) To SX(6),SY(6) To SX(7),SY(7) To SX(4),SY(4)
   Return


   _SETUP_PLATE:
   Restore PLATE
   Read NUMP
   For L=0 To NUMP-1
      Read FX(L),FY(L),FZ(L)
      X(L)=FX(L)
      Y(L)=FY(L)
      Z(L)=FZ(L)
   Next L
   Return


   PLATE:
   Data 4
   Data -30,0,20
   Data 30,0,20
   Data 30,0,40
   Data -30,0,40


End Proc
Procedure _PLAY_ANIM[NUM_POINTS,_REPEAT,_BANK,C1,C2,C3]
   ' - Code - Dug
   ' - GFX - Rob
   ' - Movement - Matt & Dug


   ' == Vector bob screen ==
   Screen Open 2,320,256,4,Lowres
   Flash Off : Curs Off : Cls 0 : Hide
   Palette 0,C1,C2,C3
   Double Buffer
   Autoback 0
   Screen To Front 2
   ' =======================


   ' ==  Play animation   ==


   Gosub _READ_ITEM
   NUM_FRAMES=ITEM

   If NUM_FRAMES>0
      For R=1 To _REPEAT
         _BANK_OFFSET=8
         For F=1 To NUM_FRAMES
            Screen Swap : Wait Vbl
            Cls 0
            Gosub _PLAY_ANIM
            If Mouse Key=1 : Fade 2 : Wait 30 : Exit 2 : End If
         Next F
      Next R
   End If

   ' =======================
   Erase _BANK
   Screen Close 2
   Pop Proc
   ' =======================


   _PLAY_ANIM:
   For L=0 To NUM_POINTS
      Gosub _READ_ITEM : X=ITEM
      Gosub _READ_ITEM : Y=ITEM
      Gosub _READ_ITEM : IMAGE=ITEM
      Paste Bob X,Y,IMAGE
   Next L
   Return

   _READ_ITEM:
   ITEM=Leek(Start(_BANK)+_BANK_OFFSET)
   Add _BANK_OFFSET,4
   Return
   ' =======================


End Proc

' - Green Jello & Duck part
Procedure JELLO_DUCK

   ' - Calling procedure for the duck and jello vector

   SETUP_FONT
   NEW_TEXT_SCREEN["page16"]
   ' - Load plasma stuff
   Load "no-refund2!:stuff/duck",8
   Wait 50
   CLEAR_TEXT_SCREEN
   SHUT_TEXT_SCREENS

   ' - Call me Al!
   JELLY_SHAPE[200]
   DUCK
End Proc
Procedure JELLY_SHAPE[TIME]
   ' - Dug - Code


   ' ===================================================================

   Screen Open 0,320,256,8,Lowres
   Flash Off : Curs Off : Cls 0 : Hide
   Double Buffer
   Autoback 0
   Palette 1,1,1,1,1,1,1,1
   Limit Mouse 0,0 To 320,320


   ' ===================================================================
   ' -- Screen's palette
   Dim RGB(Screen Colour-1)
   For C=0 To Screen Colour-1
      RGB(C)=$1+(C*$120)
   Next C

   ' ===================================================================

   NICE_RAINBOW:
   Set Rainbow 0,0,4096,"","",""
   RY=0
   For LOP=0 To 10
      For LOP2=0 To 1
         Rain(0,RY)=LOP*$110
         Inc RY
      Next LOP2
   Next LOP
   For LOP=1 To 135
      Rain(0,RY)=$BB0
      Inc RY
   Next LOP
   Rainbow 0,0,Y Hard(140),120


   ' ===================================================================


   NP=7 : Rem Max no. of points
   NS=5 : Rem Max no. of surfaces per object
   NN=3 : Rem Max no. of nodes within a surface
   Dim FX(NP),FY(NP),FZ(NP) : Rem - Object's frame
   Dim X(NP),Y(NP),Z(NP) : Rem    - Coords of manipulated points
   Dim SX(NN),SY(NN) : Rem        - Screen coords of the points to be drawn
   Dim CONNECT(NS,NN) : Rem       - How to connect the object's points
   Dim PADD(NP,2) : Rem           - X/Y/Z/ movements
   Dim _DIR(NP,2) : Rem        - Direction of point's components (0=x,1=y,2=z)


   DVP=-200 : Rem       - Z coord of the vanishing point
   X_ORG=160 : Rem      - Screen coords of the axes' origin
   Y_ORG=140


   SHAPE_NUMBER=1 : Rem - No. of shape to be used
   NUM_OBJECTS=1 : Rem  - No. of objects to go through

   NUM_POINTS=0 : Rem   - No. of points to the shape
   NUM_CONNECTS=0 : Rem - No. of connections to make in this object


   OBJX=0 : Rem         - Coords of the 3d shape itself
   OBJY=0
   OBJZ=0
   OBJ_YMAX=10
   OBJ_YADD=0
   OBJ_DELAY=0


   ' ===================================================================

   Gosub SETUP_SHAPE
   For OBJECT=1 To NUM_OBJECTS
      For MAIN_LOOP=1 To TIME : Rem Manipulate objects for specified TIME
         Screen Swap : Wait Vbl
         Cls 0
         Gosub _DRAW_JELLY_VECTOR
      Next MAIN_LOOP
   Next OBJECT
   For DEL=0 To 20
      Screen Swap : Wait Vbl
      Cls 0
      Gosub _DRAW_JELLY_VECTOR
      Add OBJY,-4
   Next DEL


   ' ===================================================================

   Rem -- End Of Part --
   Fade 2,1,$BB0,$BB0,$BB0,$BB0,$BB0,$BB0,$BB0 : Wait 30
   Autoback 2
   Cls 0
   RY=Y Hard(140)
   Repeat
      Rainbow 0,,RY,
      Inc RY
      Wait Vbl
   Until Y Screen(RY)>260
   Rainbow Del 0
   Screen Close 0
   Pop Proc


   ' ===================================================================

   _DRAW_JELLY_VECTOR:
   Gosub _MOVE_JELLY_VECTOR : Rem Move the jelly vector

   I=1
   For CJV=0 To 5 : Rem Draw one surface at a time
      Gosub _CONV_COORDS : Rem Only SX(0),SY(0) - SX(3),SY(3) are used

      Ink I
      Inc I
      Polygon SX(0),SY(0) To SX(1),SY(1) To SX(2),SY(2) To SX(3),SY(3) To SX(0),SY(0)
   Next CJV
   Return


   _CONV_COORDS:
   For L=0 To NN
      Rem CJV is used in above For.. Next loop
      P=CONNECT(CJV,L) : Rem Surface CJV, node L

      ZF=Z(P)+DVP
      SX(L)=X_ORG+(X(P)*DVP)/ZF : Rem Convert 3D to 2D screen coords
      SY(L)=Y_ORG-(Y(P)*DVP)/ZF

   Next L
   Return


   ' ===================================================================

   _MOVE_JELLY_VECTOR:
   Add OBJY,OBJ_YADD
   Add OBJ_YADD,-1,-OBJ_YMAX To OBJ_YMAX
   If OBJ_YADD=-OBJ_MAX Then Dec OBJ_YMAX

   For P=0 To NUM_POINTS
      Add FX(P),PADD(P,0) : Rem Add movements to the point's coords
      Add FY(P),PADD(P,1)
      Add FZ(P),PADD(P,2)
      ' - Do X direction
      Add PADD(P,0),_DIR(P,0) : Rem Add direction
      If PADD(P,0)=2 Then _DIR(P,0)=-1
      If PADD(P,0)=-2 Then _DIR(P,0)=1

      ' - Do Y direction
      Add PADD(P,1),_DIR(P,1) : Rem Add direction
      If PADD(P,1)=2 Then _DIR(P,1)=-1
      If PADD(P,1)=-2 Then _DIR(P,1)=1

      ' - Do Z direction
      Add PADD(P,2),_DIR(P,2) : Rem Add direction
      If PADD(P,2)=2 Then _DIR(P,2)=-1
      If PADD(P,2)=-2 Then _DIR(P,2)=1

      X(P)=FX(P)+OBJX : Y(P)=FY(P)+OBJY : Z(P)=FZ(P)+OBJZ
      If Y(P)<-40
         Y(P)=-40
         Add X(P),X(P)/Abs(X(P))*3
         Add Y(P),Y(P)/Abs(Y(P))*3
      End If
   Next P
   Return


   ' ===================================================================

   SETUP_SHAPE:
   Fade 1,RGB(0),RGB(0),RGB(0),RGB(0),RGB(0),RGB(0),RGB(0),RGB(0) : Wait 15
   Restore "SHAPE_"+Str$(SHAPE_NUMBER)-" " : Rem - Read next object's points
   Read NUM_POINTS
   For P=0 To NUM_POINTS
      Read FX(P),FY(P),FZ(P)
      X(P)=FX(P)
      Y(P)=FY(P)
      Z(P)=FZ(P)
      A=Rnd(1)
      B=Rnd(1)
      C=Rnd(1)
      _DIR(P,0)=-1 : Rem X Add
      If A=1 Then _DIR(P,0)=1
      _DIR(P,1)=-1 : Rem Y Add
      If B=1 Then _DIR(P,1)=1
      _DIR(P,2)=-1 : Rem Z Add
      If C=1 Then _DIR(P,2)=1
      PADD(P,0)=-1+Rnd(2)
      PADD(P,1)=-1+Rnd(2)
      PADD(P,2)=-1+Rnd(2)
   Next P

   Restore "SHAPE_CONNECT_"+Str$(SHAPE_NUMBER)-" "
   Read NUM_CONNECTS
   For C=0 To NUM_CONNECTS
      Read CONNECT(C,0),CONNECT(C,1),CONNECT(C,2),CONNECT(C,3)
   Next C

   Fade 1,RGB(0),RGB(1),RGB(2),RGB(3),RGB(4),RGB(5),RGB(6),RGB(7)
   Return


   ' -- Coords of the points relative to the object's coords --
   SHAPE_1:
   Data 7
   Data -30,30,-30
   Data 30,30,-30
   Data 30,-30,-30
   Data -30,-30,-30
   Data -30,30,30
   Data 30,30,30
   Data 30,-30,30
   Data -30,-30,30


   ' -- How to connect the points --
   SHAPE_CONNECT_1:
   Data 5
   Data 0,1,2,3
   Data 4,5,6,7
   Data 0,1,5,4
   Data 2,3,7,6
   Data 1,5,6,2
   Data 0,4,7,3


End Proc
Procedure DUCK
   ' - Code - Matt
   ' - GFX - Matt

   Screen Open 1,100,100,16,Lowres
   Curs Off : Cls 0 : Hide : Flash Off
   Screen Hide 1

   Unpack 8 To 0
   Screen Hide 0
   Erase 8

   Screen 1
   Get Palette 0
   Screen 0
   Palette 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
   Screen Show 0
   Fade 2 To 1 : Wait 15*2
   Screen Close 1

   Autoback 0

   Channel 0 To Screen Offset 0

   Amal 0,"M -610,0,30 ;"
   Amal On

   COUNTER=0
   Repeat
      Screen Swap : Wait Vbl
      Inc COUNTER
   Until COUNTER=30 or Mouse Key=1

   Amal Off

   Wait 30
   Fade 2 : Wait 15*2
   Autoback 2
   Screen Close 0

End Proc

' - Aerosol bit
Procedure KANO_TEXT_AEROSOL
   SETUP_FONT
   NEW_TEXT_SCREEN["page12"]
   Load "no-refund2!:stuff/aerosol_pic",8
   Load "no-refund2!:stuff/rdfsm",5
   Load "no-refund2!:stuff/kano_pic",9
   Load "no-refund2!:stuff/clrscrbob",1
   Load "no-refund2!:stuff/pattern_font",7
   CLEAR_TEXT_SCREEN
   SHUT_TEXT_SCREENS

   ' - Start the stuff
   CLR_SCREEN
   THE_TEXT_SCREENS
   AEROSOL
End Proc
Procedure CLR_SCREEN
   ' - Code - Matt
   ' - GFX - Rob

   ' - Open screen to display bobs
   Screen Open 0,400,256,8,Lowres
   Curs Off : Cls 0 : Hide : Flash Off
   Screen Display 0,100,,,

   ' - Open screen to store palette
   Screen Open 2,60,60,16,Lowres
   Curs Off : Cls 0 : Flash Off : Hide
   Screen Hide 2

   ' - Unpack picture to hidden screen
   Unpack 9 To 1
   Screen To Front 0

   ' - Store pictures palette in another screen
   Screen 2
   Get Palette 1

   ' - Set picture to totally white
   Screen 1
   W=$FFF
   Palette W,W,W,W,W,W,W,W,W,W,W,W,W,W,W,W

   ' - Start the bob stuff
   Screen 0
   Colour 1,W
   For C=2 To 7
      Colour C,$0
   Next C

   ' - Paste a column of bobs
   For X=0 To 400 Step 15
      Paste Bob X,0,1
   Next X

   ' - Paste lots of columns
   Get Block 1,0,1,400,15
   For Y=0 To 256 Step 15
      Put Block 1,0,Y
   Next Y

   ' - Cycle the colours
   Shift Up 2,1,7,0
   Wait 15

   ' - Display the picture
   Screen Close 0
   Screen To Front 1
   Screen 1
   Wait Vbl
   Fade 1 To 2 : Wait 15

   ' - Wait for a while (or a mouse key)
   TIME=0
   Repeat
      Inc TIME
      Wait Vbl
   Until Mouse Key=1 or TIME=350

   ' - Clean up
   Fade 1 : Wait 15
   Screen Close 1
   Screen Close 2
   Erase 9
   Erase 1

End Proc
Procedure THE_TEXT_SCREENS
   ' - Code - Rob
   ' - GFX - Matt (font)
   ' - Text - Matt & Rob

   ' - Open text screen
   Screen Open 0,320,255,4,Lowres
   Curs Off : Cls 0 : Flash Off : Hide

   ' - Open pattern screen
   Screen Open 2,320,256,4,Lowres
   Curs Off : Cls 0 : Flash Off : Hide

   ' - Unpack font
   Unpack 7 To 1
   Screen Hide 1
   Erase 7
   Screen 0
   Get Palette 1

   ' - Setup dual playfield
   Screen To Front 2
   Screen 0
   Wait Vbl
   Dual Playfield 0,2
   Wait Vbl

   ' - Set colours to black to begin with
   Screen 0
   Palette 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0

   ' - Main loop
   NUM_PATTERNS=7
   COUNTER=1
   Restore MESSAGES
   Repeat
      Read MSG$,YCOORD
      If Left$(MSG$,1)<>"%"
         TXT[MSG$,YCOORD]
      Else
         If MSG$="%CLEAR"
            NEW_PATTERN[COUNTER]
            Add COUNTER,1,1 To NUM_PATTERNS
            Gosub CLRDWN
         End If
      End If
   Until MSG$="%END"

   ' - Clean up
   Erase 9
   Screen Close 1
   Screen Close 0
   Screen Close 2

   Pop Proc



   CLRDWN:

   ' - Fade everything off
   Screen 0
   Fade 1
   Wait 15
   Cls 0

   ' - Clear the pattern and turn off the movement
   Screen 2
   Cls 0
   Move Off
   Amal Off

   Screen 0
   Return



   ' ----- Text Pages -----


   ' %COMMANDS:
   ' %CLEAR=CLEAR Screen( Using CLRDWN)
   ' %END   = End of messages.

   '     |-------------------------------------|
   MESSAGES:
   Data "welcome to the aftermath......",15
   Data "well, you certainly have patience, as",45
   Data "this is our biggest demo yet!",60
   Data "this part was inspired by the hidden",90
   Data "text printer in >how 2 skin a cat< by",105
   Data "melon, & we thought it was a cool idea!",120
   Data "we're making this stuff up on the spot",150
   Data "so don't take it too seriously...",165
   Data "left button for next page $",200
   Data "%CLEAR",$FFFF

   '     |-------------------------------------|
   Data "credits waffle -",15
   Data "the sample sources were.......",45
   Data "1) rage against the machine",60
   Data "   - >bullet in the head< (single)",75
   Data "2) young guns 2 - the soundtrack",90
   Data "3) manga video - >akira<",105
   Data "4) tomato sfx - rob & stew",120
   Data "5) monty python - >the meaning of life<",135
   Data "6) channel 4 t.v. - mr. drums",150
   Data "7) nuke 'em sfx - rob & matt",165
   Data "8) backwards speech - rob",180
   Data "as usual, most demo code was by dug",210
   Data "with contributions from rob and matt.",225
   Data "%CLEAR",$FFFF

   '     |-------------------------------------|
   Data "now for individual talkie bits.....",15
   Data "right then this is matt bashing the",30
   Data "keys -",45
   Data "well i'm afraid i will have to start",75
   Data "with a grumble (grumble), why do we",90
   Data "have to use the god awful amos logo at",105
   Data "the start of our programs?",120
   Data "when dug writes anything in c, he",135
   Data "doesn't have to slap a <this program",150
   Data "was written in sas c v6.0> poster",165
   Data "at the start!",180
   Data "is europress feeling insecure? 'coz it",195
   Data "ain't hard to spot an amos program!",210
   Data "%CLEAR",$FFFF

   '     |-------------------------------------|
   Data "the shoot 'em up >nuke 'em< was written",10
   Data "as a disk filler, after we realised",25
   Data "that >no-refund!< would have to be a",40
   Data "2 disk demo. it was done entirely by",55
   Data "rob and i (my gfx, robs' code), while",70
   Data "dug got on with the vector routines.",85
   Data "as you may or may not have discovered",115
   Data "you can boot the second disk straight",130
   Data "to nuke 'em.",145
   Data "any funny jerking or bobs with trailing",175
   Data "images means you are running out of",190
   Data "chip mem! i've got a 1200 and it runs",205
   Data "like project x on steroids (tough if",220
   Data "you're using a 500(+) or 600!)",235
   Data "%CLEAR",$FFFF

   '     |-------------------------------------|
   Data "hmm, that's it from him! now your stuck",15
   Data "with me (rob) for a while!",30
   Data "first up, i have got to explain about",60
   Data "a few un-documented features (ok! so",75
   Data "they're bugs!) in >nuke 'em<.",90
   Data "the first has come to be known as >free",105
   Data "alien syndrome<.  i'm positive that",120
   Data "this is just the intelligent aliens",135
   Data "giving you a hand when you need it, but",150
   Data "really they sometimes just disappear!",165
   Data "secondly, you can't actually collide",180
   Data "with the guardians.  i did have them",195
   Data "as bobs but it struggled so badly i",210
   Data "had to scrap it! (it's not my fault!)",225
   Data "%CLEAR",$FFFF

   '     |-------------------------------------|
   Data "arrrgghhh! not more complaints....",15
   Data "the first thing is matt!  when we were",45
   Data "doing the samples for the tomato anim",60
   Data "he had me sitting in the bathroom with",75
   Data "my head in the sink, slurping! (it got",90
   Data "the right effect didn't it? stop",105
   Data "whinging! - matt)  it's not that i",120
   Data "didn't enjoy it, i just got a bit wet!",135
   Data "matt also drew some really nice gfx",150
   Data "which we never actually used because",165
   Data "he decided to low-level partition his",180
   Data "hard disk without backing them up!",195
   Data "not to worry though 'cos now he's got",210
   Data "his hard disk taped into his machine!",225
   Data "%CLEAR",$FFFF

   '     |-------------------------------------|
   Data "if you want to contact us then don't",15
   Data "delay.  we really are nice people and",30
   Data "we're always interested to hear from",45
   Data "other amos users or just demo freaks!,",60
   Data "the address to write to was shown",75
   Data "earlier next to the kano pic which was",90
   Data "inspired by 2000ad.  come to think of",105
   Data "it, most of the gfx in this demo were",120
   Data "inspired by 2000ad!!!.",135
   Data "anyway, in case you missed the address",150
   Data "here it is again -",165
   Data "            cybornetics (rob),",180
   Data "            14 buckingham drive,",195
   Data "            ely, cambs",210
   Data "            cb6 1dr.  (england) ",225
   Data "%CLEAR",$FFFF

   '     |-------------------------------------|
   Data "now for the definitive cybornetics",15
   Data "greeting list....",30
   Data "rob, matt and dug all send greetz to -",60
   Data "overdose - enhance, mike - solo p.d.,",90
   Data "andy - amos programmers user group,",105
   Data "lloyd & flynn - quartz productions,",120
   Data "andy - kick-start amiga (bbs),",135
   Data "roy (hemel hempstead), dr. john foley,",150
   Data "anne and len - amos p.d., steve (devon),",165
   Data "and we can't forget those nice people",180
   Data "at >amiga mart< who reviewed our last",195
   Data "demo so well. (we thought so anyway!)",210
   Data "%CLEAR",$FFFF

   '     |-------------------------------------|
   Data "i'm realy getting in to this list lark",15
   Data "now so here is some technical info....",30
   Data "the demo was written while we were all",60
   Data "on holiday from college.  we used two",75
   Data "bog standard amiga 500s and a 1200.",90
   Data "the source code weighs in at over 7000",105
   Data "lines and there are over 1meg of data",120
   Data "banks spread over the two disks!",135
   Data "the music is a stonking 130k and took",150
   Data "stew about 3 months to finally complete",165
   Data "the demo was compiled using the new",180
   Data "amos pro compiler and this gave us",195
   Data "hell once it got over 5000 lines!",210
   Data "hmmm, so much for the amos help-line!",225
   Data "%CLEAR",$FFFF

   '     |-------------------------------------|
   Data "....and finally,",15
   Data "has anyone actullay got blitz basic?",30
   Data "we were thinking about using that for",45
   Data "our next release but we don't have a",60
   Data "clue what it's like!",75
   Data "if you've got it, write and let us know",90
   Data "how you think it compares to little",105
   Data "old amos professional.",120
   Data "finally, finally... (pack that in now!)",150
   Data "it could well be some time before our",165
   Data "next release coz we all go back to",180
   Data "skool soon and the non-stop partying",195
   Data "will have to start again!!!",210
   Data "life's hard when you're a student...",225
   Data "%CLEAR",$FFFF

   Data "%END",$FFFF

End Proc
Procedure TXT[_TEXT$,Y_COORD]

   ' - Initialise Constants.
   ' fntxsize should be fntxsize + 1
   _FNTXSIZE=8
   _FNTYSIZE=14
   XACCROSS=1

   ' - Writes the next line of text.
   For _LOOP=1 To Len(_TEXT$)
      _CHAR$=Mid$(_TEXT$,_LOOP,1)
      If _CHAR$<>" "
         If Asc(_CHAR$)<58
            If Asc(_CHAR$)=46
               Restore "GFS"
            Else
               If Asc(_CHAR$)=44
                  Restore "GCM"
               Else
                  If Asc(_CHAR$)=33
                     Restore "GEX"
                  Else
                     If Asc(_CHAR$)=45
                        Restore "GDA"
                     Else
                        If Asc(_CHAR$)=40
                           Restore "GLB"
                        Else
                           If Asc(_CHAR$)=41
                              Restore "GRB"
                           Else
                              If Asc(_CHAR$)=43
                                 Restore "GPL"
                              Else
                                 If Asc(_CHAR$)=39
                                    Restore "GAP"
                                 Else
                                    If Asc(_CHAR$)=42
                                       Restore "GCR"
                                    Else
                                       If Asc(_CHAR$)=38
                                          Restore "GAA"
                                       Else
                                          If Asc(_CHAR$)=36
                                             Restore "GRT"
                                          Else
                                             ' - Numbers
                                             Restore "N"+_CHAR$
                                          End If
                                       End If
                                    End If
                                 End If
                              End If
                           End If
                        End If
                     End If
                  End If
               End If
            End If
         Else
            If Asc(_CHAR$)=63
               Restore "GQM"
            Else
               If Asc(_CHAR$)=62
                  Restore "GGT"
               Else
                  If Asc(_CHAR$)=60
                     Restore "GST"
                  Else
                     ' - Letters
                     Restore "LL"+_CHAR$
                  End If
               End If
            End If
         End If

         ' - Read font position
         Read X99,Y99
         ' - Translate to coordinates
         X99=X99*_FNTXSIZE : Y99=Y99*_FNTYSIZE
         ' - Paste the letter
         Screen Copy 1,X99,Y99,X99+_FNTXSIZE,Y99+_FNTYSIZE To 0,XACCROSS,Y_COORD
      End If
      Add XACCROSS,_FNTXSIZE
   Next _LOOP


   ' -  Font Data.

   ' - Letters ( - and why not?)
   LLA:
   Data 0,0
   LLB:
   Data 1,0
   LLC:
   Data 2,0
   LLD:
   Data 3,0
   LLE:
   Data 4,0
   LLF:
   Data 5,0
   LLG:
   Data 6,0
   LLH:
   Data 7,0
   LLI:
   Data 8,0
   LLJ:
   Data 9,0
   LLK:
   Data 10,0
   LLL:
   Data 11,0
   LLM:
   Data 12,0
   LLN:
   Data 13,0
   LLO:
   Data 14,0
   LLP:
   Data 15,0
   LLQ:
   Data 16,0
   LLR:
   Data 17,0
   LLS:
   Data 18,0
   LLT:
   Data 19,0
   LLU:
   Data 20,0
   LLV:
   Data 21,0
   LLW:
   Data 22,0
   LLX:
   Data 23,0
   LLY:
   Data 24,0
   LLZ:
   Data 25,0

   ' - Punctuation (graphics)
   ' - GEX - Exclamation mark
   GEX:
   Data 28,0
   ' - GFS - Full stop
   GFS:
   Data 26,0
   ' - GCM - Comma (BABY!)
   GCM:
   Data 27,0
   ' - GLB - Left bracket (Parenthesis)
   GLB:
   Data 30,0
   ' - GRB - Right bracket
   GRB:
   Data 31,0
   ' - GQM - Question Mark
   GQM:
   Data 29,0
   ' - GDA - Dash (Minus sign)
   GDA:
   Data 33,0
   ' - GPL - Plus sign
   GPL:
   Data 32,0
   ' - GAP - Apost.
   GAP:
   Data 34,0
   ' - GCR - Copyright
   GCR:
   Data 35,0
   ' - GAA - Ampersand
   GAA:
   Data 36,0
   ' - GGT - Greater than
   GGT:
   Data 37,0
   ' - GST - Smaller than
   GST:
   Data 38,0
   ' - GRT - Return
   GRT:
   Data 39,0
   '
   '
   ' - Numbers
   N1:
   Data 0,1
   N2:
   Data 1,1
   N3:
   Data 2,1
   N4:
   Data 3,1
   N5:
   Data 4,1
   N6:
   Data 5,1
   N7:
   Data 6,1
   N8:
   Data 7,1
   N9:
   Data 8,1
   N0:
   Data 9,1
End Proc
Procedure NEW_PATTERN[COUNTER]

   Screen 2

   ' - Define bob channels
   For CTR=1 To 2
      Channel CTR To Bob CTR
   Next CTR

   ' - Select next pattern
   On COUNTER Gosub PATTERN1,PATTERN2,PATTERN3,PATTERN4,PATTERN5,PATTERN6,PATTERN7

   ' - Show the text
   Screen 0
   Fade 1,0,$FFF,$999,$444,,,,,,,CUL
   Screen 2

   ' - Main loop
   Repeat
      Draw X Bob(1),Y Bob(1) To X Bob(2),Y Bob(2)
   Until Mouse Key=1

   Pop Proc


   PATTERN1:

   ' - Define movement strings
   M1$="(1,6,2)(1,5,2)(1,4,2)(1,3,2)(1,2,2)(1,1,2)(1,-1,2)(1,-2,2)(1,-3,2)(1,-4,2)(1,-5,2)(1,-6,2) "
   M1$=M1$+"(1,-6,2)(1,-5,2)(1,-4,2)(1,-3,2)(1,-2,2)(1,-1,2)(1,1,2)(1,2,2)(1,3,2)(1,4,2)(1,5,2)(1,6,2) L"

   M2$="(3,9,3)(3,8,3)(3,7,3)(3,6,3)(3,5,3)(3,4,3)(3,3,3)(3,2,3)(3,1,3)(3,-1,3)(3,-2,3)(3,-3,3)(3,-4,3)(3,-5,3)(3,-6,3)(3,-7,3)(3,-8,3)(3,-9,3) "
   M2$=M2$+"(3,-9,3)(3,-8,3)(3,-7,3)(3,-6,3)(3,-5,3)(3,-4,3)(3,-3,3)(3,-2,3)(3,-1,3)(3,1,3)(3,2,3)(3,3,3)(3,4,3)(3,5,3)(3,6,3)(3,7,3)(3,8,3)(3,9,3) L"

   ' - Position bobs
   Bob 1,160,125,0
   Bob 2,160,125,0

   ' - Begin movement
   Move X 1,M1$
   Move On
   Wait 12
   Move Y 1,M1$
   Move On

   Move X 2,M2$
   Move On
   Wait 70
   Move Y 2,M2$
   Move On

   ' - Set colours
   CUL=$300
   Return


   PATTERN2:

   ' - Define movement strings
   M1$="(1,8,3)(1,7,3)(1,6,3)(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3)(1,-6,3)(1,-7,3)(1,-8,3) "
   M1$=M1$+"(1,-8,3)(1,-7,3)(1,-6,3)(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3)(1,6,3)(1,7,3)(1,8,3) L"

   ' - Position bobs
   Bob 1,160,125,0
   Bob 2,160,125,0

   ' - Begin movement
   Move X 1,M1$
   Move On
   Wait 25
   Move Y 2,M1$
   Move On

   ' - Set colours
   CUL=$30
   Return


   PATTERN3:

   ' - Define movement strings
   M1$="(1,8,3)(1,7,3)(1,6,3)(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3)(1,-6,3)(1,-7,3)(1,-8,3) "
   M1$=M1$+"(1,-8,3)(1,-7,3)(1,-6,3)(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3)(1,6,3)(1,7,3)(1,8,3) L"

   M2$="(3,9,3)(3,8,3)(3,7,3)(3,6,3)(3,5,3)(3,4,3)(3,3,3)(3,2,3)(3,1,3)(3,-1,3)(3,-2,3)(3,-3,3)(3,-4,3)(3,-5,3)(3,-6,3)(3,-7,3)(3,-8,3)(3,-9,3) "
   M2$=M2$+"(3,-9,3)(3,-8,3)(3,-7,3)(3,-6,3)(3,-5,3)(3,-4,3)(3,-3,3)(3,-2,3)(3,-1,3)(3,1,3)(3,2,3)(3,3,3)(3,4,3)(3,5,3)(3,6,3)(3,7,3)(3,8,3)(3,9,3) L"

   ' - Position bobs
   Bob 1,160,125,0
   Bob 2,160,125,0

   ' - Begin movement
   Move X 1,M1$
   Move Y 2,M2$
   Move On
   Wait 30
   Move X 2,M1$
   Move On

   ' - Set colours
   CUL=$3
   Return


   PATTERN4:

   ' - Define movement strings
   M1$="(1,8,3)(1,7,3)(1,6,3)(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3)(1,-6,3)(1,-7,3)(1,-8,3) "
   M1$=M1$+"(1,-8,3)(1,-7,3)(1,-6,3)(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3)(1,6,3)(1,7,3)(1,8,3) L"

   M2$="(3,9,3)(3,8,3)(3,7,3)(3,6,3)(3,5,3)(3,4,3)(3,3,3)(3,2,3)(3,1,3)(3,-1,3)(3,-2,3)(3,-3,3)(3,-4,3)(3,-5,3)(3,-6,3)(3,-7,3)(3,-8,3)(3,-9,3) "
   M2$=M2$+"(3,-9,3)(3,-8,3)(3,-7,3)(3,-6,3)(3,-5,3)(3,-4,3)(3,-3,3)(3,-2,3)(3,-1,3)(3,1,3)(3,2,3)(3,3,3)(3,4,3)(3,5,3)(3,6,3)(3,7,3)(3,8,3)(3,9,3) L"

   ' - Position bobs
   Bob 1,60,125,0
   Bob 2,260,125,0

   ' - Begin movement
   Move X 1,M2$
   Move Y 2,M1$
   Move On
   Wait 10
   Move X 2,M2$
   Move Y 1,M1$
   Move On

   ' - Set colours
   CUL=$303
   Return


   PATTERN5:

   ' - Define movement strings
   M1$="(1,6,2)(1,5,2)(1,4,2)(1,3,2)(1,2,2)(1,1,2)(1,-1,2)(1,-2,2)(1,-3,2)(1,-4,2)(1,-5,2)(1,-6,2) "
   M1$=M1$+"(1,-6,2)(1,-5,2)(1,-4,2)(1,-3,2)(1,-2,2)(1,-1,2)(1,1,2)(1,2,2)(1,3,2)(1,4,2)(1,5,2)(1,6,2) L"

   M2$="(3,9,3)(3,8,3)(3,7,3)(3,6,3)(3,5,3)(3,4,3)(3,3,3)(3,2,3)(3,1,3)(3,-1,3)(3,-2,3)(3,-3,3)(3,-4,3)(3,-5,3)(3,-6,3)(3,-7,3)(3,-8,3)(3,-9,3) "
   M2$=M2$+"(3,-9,3)(3,-8,3)(3,-7,3)(3,-6,3)(3,-5,3)(3,-4,3)(3,-3,3)(3,-2,3)(3,-1,3)(3,1,3)(3,2,3)(3,3,3)(3,4,3)(3,5,3)(3,6,3)(3,7,3)(3,8,3)(3,9,3) L"

   ' - Position bobs
   Bob 1,60,125,0
   Bob 2,260,125,0

   ' - Begin movement
   Move Y 2,M2$
   Move X 1,M2$
   Move On
   Wait 30
   Move Y 1,M2$
   Move X 2,M1$
   Move On

   ' - Set colours
   CUL=$33
   Return


   PATTERN6:

   ' - Define movement strings
   M1$="(1,8,3)(1,7,3)(1,6,3)(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3)(1,-6,3)(1,-7,3)(1,-8,3) "
   M1$=M1$+"(1,-8,3)(1,-7,3)(1,-6,3)(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3)(1,6,3)(1,7,3)(1,8,3) L"

   AM1$="L : M 300,0,300 ; M -300,0,300 ; J L"

   ' - Position bobs
   Bob 1,10,125,0
   Bob 2,160,125,0

   ' - Begin movement
   Move X 2,M1$
   Move On
   Wait 25
   Move Y 2,M1$
   Move On

   Amal 1,AM1$
   Amal On 1

   ' - Set colours
   CUL=$330
   Return


   PATTERN7:

   ' - Define movement strings
   M1$="(1,8,3)(1,7,3)(1,6,3)(1,5,3)(1,4,3)(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3)(1,-4,3)(1,-5,3)(1,-6,3)(1,-7,3)(1,-8,3) "
   M1$=M1$+"(1,-8,3)(1,-7,3)(1,-6,3)(1,-5,3)(1,-4,3)(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3)(1,4,3)(1,5,3)(1,6,3)(1,7,3)(1,8,3) L"

   M2$="(1,3,3)(1,2,3)(1,1,3)(1,-1,3)(1,-2,3)(1,-3,3) "
   M2$=M2$+"(1,-3,3)(1,-2,3)(1,-1,3)(1,1,3)(1,2,3)(1,3,3) L"

   AM1$="L : M 300,200,250 ; M -300,-200,250 ; J L"
   AM2$="L : M -300,0,300 ; M 300,0,300 ; J L"

   ' - Position bobs
   Bob 1,10,25,0
   Bob 2,310,125,0

   ' - Begin movement
   Move X 2,M1$
   Move X 1,M2$
   Move On
   Wait 25
   Move Y 2,M1$
   Move Y 1,M2$
   Move On

   Amal 1,AM1$
   Amal 2,AM2$
   Amal On

   ' - Set colours
   CUL=$33
   Return


End Proc
Procedure AEROSOL
   ' - Code - Matt & Rob
   ' - GFX - Matt

   Screen Open 1,100,100,32,Lowres
   Curs Off : Cls 0 : Hide : Flash Off

   Unpack 8 To 0
   Screen Hide 0
   Erase 8
   Double Buffer
   Screen 1 : Get Palette 0

   Ink 15 : Plot 10,10
   Get Bob 1,10,10 To 11,11

   Screen 0 : Palette 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
   Screen Show 0

   Fade 2 To 1 : Wait 15
   Screen Close 1

   Wait 30

   M1$="M 300,1,50"
   M2$="M 300,8,50"
   M3$="M 300,-8,50"
   M4$="M 300,-1,50"

   For X=16 To 28

      For C=0 To 15
         Bob C,63,97,1
         Channel C To Bob C
      Next C

      Amal 0,M1$
      Amal 1,M1$
      Amal 2,M1$
      Amal 3,M1$
      Amal 4,M2$
      Amal 5,M2$
      Amal 6,M2$
      Amal 7,M2$
      Amal 8,M3$
      Amal 9,M3$
      Amal 10,M3$
      Amal 11,M3$
      Amal 12,M4$
      Amal 13,M4$
      Amal 14,M4$
      Amal 15,M4$

      Amal On 7
      Amal On 11
      Amal On 3
      Amal On 15

      Wait Vbl

      Amal On 10
      Amal On 6
      Amal On 2
      Amal On 14

      Wait Vbl

      Amal On 9
      Amal On 5
      Amal On 1
      Amal On 13

      Wait Vbl

      Amal On 8
      Amal On 4
      Amal On 0
      Amal On 12

      Wait X-12
      Colour X,$467
      Wait X/10
      Amal Off

   Next X

   Bob Off
   Wait 20

   W=$FFF
   Fade 1,,,,,,,,,,,,,,,,,W,W,W,W,W,W,W,W,W,W,W,W,W
   Wait 50
   Fade 5,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,W
   Wait 15
   Fade 5,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,W,W
   Wait 15
   Fade 5,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,W,W,W

   Erase 1

   Wait 150

   ' - Fade off main picture
   Fade 3,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,W,W,W
   Wait 150

   ' - End music
   Track Stop
   Sam Play 2
   Wait 150

   ' - Play sample (But what does it say?)
   Sam Play 1
   Wait 100

   ' - Clean up
   FINISH_DEMO
   Wait 1000
   Fade 1 : Wait 15
   Screen Close 0
End Proc

' - The end of an era! (Good ridance, that's what I say matey!)
Procedure FINISH_DEMO
   ' - Erase any leftover banks
   Erase 3
   Erase 5
   Erase 14
   Erase 13
End Proc