home *** CD-ROM | disk | FTP | other *** search
/ Between Heaven & Hell 2 / BetweenHeavenHell.cdr / 100 / 31 / wndchil.bas < prev    next >
BASIC Source File  |  1983-09-14  |  2KB  |  40 lines
  1. 100 ' The Weather Channel's Wind Chill Chart
  2. 110 ' Copyright J.T.Norman 1982
  3. 120 ' The Weather Channel
  4. 130 ' 2840 Mount Wilkinson Parkway
  5. 140 ' Atlanta, Georgia 30339
  6. 150 '
  7. 160 ' A Cable programming service of Landmark Communications, Inc.
  8. 170 '
  9. 180 ' Tested on Microsoft Basic on IBM Personal Computer
  10. 190 ' Should function on Apple, and TRS-80 with minimum change
  11. 200 '
  12. 210 LPRINT "__________________________________________________________________"
  13. 220 LPRINT "                        Wind Chill Chart  "
  14. 230 U$ = "#####"
  15. 240 LPRINT "                   Actual Thermometer Reading (F)  "
  16. 250 U1$ = "##."
  17. 260 LPRINT "Est. Wind  "
  18. 270 LPRINT " Speed   50   40   30   20   10   0  -10  -20  -30  -40  -50  -60"
  19. 280 LPRINT " in MPH              Equivalent Temperature (F)
  20. 290 LPRINT "__________________________________________________________________"
  21. 300 LPRINT "  Calm";
  22. 310 FOR MH = 0  TO 40  STEP 5
  23. 320 IF MH < 4 THEN MH = 4:GOTO 340
  24. 330 LPRINT "    ";USING U1$;MH;
  25. 340 FOR TF = 50  TO -60  STEP -10
  26. 350 TC  = ((5*TF)-160)/9      'Degrees F to Degrees C
  27. 360 MS = (.447 * MH)        'meters per second
  28. 370 WI = (10.45 + (10* (SQR(MS)))-MS)*(33-TC)  'Calculation
  29. 380 WT = (-.04544 * WI) + 33 ' wind temp centigrade
  30. 390 FT = (160+ (9*WT))/5     'degrees f
  31. 400 FT = INT (FT + .5)       'rounding
  32. 410 LPRINT USING U$;FT;
  33. 420 NEXT TF
  34. 430 LPRINT
  35. 440 IF MH= 4 THEN MH = 0
  36. 450 NEXT MH
  37. 460 LPRINT "__________________________________________________________________"
  38. 470 END
  39. 0 IF MH= 4 THEN MH = 0
  40. 450 N