home *** CD-ROM | disk | FTP | other *** search
/ Between Heaven & Hell 2 / BetweenHeavenHell.cdr / 100 / 31 / heatcalc.bas < prev    next >
BASIC Source File  |  1983-04-03  |  11KB  |  218 lines
  1. 10 REM*******************************************************************
  2. 20 REM*****  Heat Loss Calculations                                 *****
  3. 30 REM*****  Based on:                                              *****
  4. 40 REM*****     Jackson, David R., John M. Callahan                 *****
  5. 50 REM*****      Energy Conservation with a Microcomputer           *****
  6. 60 REM*****      BYTE, June 1981, pp. 178-208                       *****
  7. 70 REM*****  Programmed by:                                         *****
  8. 80 REM*****     David Hopper                                        *****
  9. 90 REM*****     SENES Consultants Ltd.                              *****
  10. 100 REM*****     499 McNicoll Ave.                                   *****
  11. 110 REM*****     Willowdale, Ontario                                 *****
  12. 120 REM*****     M2H 2C9                                             *****
  13. 130 REM*****     (416) 499-5030                                      *****
  14. 140 REM*****                                                         *****
  15. 150 REM*****    Data Definition                                      *****
  16. 160 REM*****                                                         *****
  17. 170 REM*******************************************************************
  18. 180 DIM S$(25)            :REM SURFACE NAMES
  19. 190 DIM A(25)             :REM SURFACE AREA
  20. 200 DIM R(25)             :REM SURFACE R-VALUE
  21. 210 DIM UA(25)            :REM SURFACE UA'S
  22. 220 DIM WA(25)           :REM SURFACE WATTAGE HEAT LOSS
  23. 230 T$=""                :REM TITLE
  24. 240 AC=0                 :REM INFILTRATION RATE
  25. 250 VI=0                 :REM FORCED VENTILATION
  26. 260 RT=0                 :REM RUN TIME OF FANS
  27. 270 DD(1)=0              :REM HEATING DEGREE DAYS
  28. 280 DD(2)=0              :REM COLLING DEGREE DAYS
  29. 290 V=0                  :REM BUILDING VOLUME
  30. 300 SU=0                 :REM UA ACCUMULATOR
  31. 310 SW=0                 :REM WA ACCUMULATOR
  32. 320 WI=0                 :REM INFILTRATION WATTAGE
  33. 330 REM*******************************************************************
  34. 340 REM*****  INPUT SECTION  *********************************************
  35. 350 REM*******************************************************************
  36. 360 CLS:KEY OFF
  37. 370 PRINT :PRINT
  38. 380 PRINT "   SENES BUILDING ENERGY LOAD MODEL"
  39. 390 PRINT "   ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~"
  40. 400 PRINT :PRINT
  41. 410 INPUT " Title of the output                ";T$
  42. 420 INPUT " Air infiltration rate(AC/HR)       ";AC
  43. 430 INPUT " Installed fan capacity(CFM)        ";VI
  44. 440 INPUT " On time of fans(MIN/DAY)           ";RT
  45. 450 INPUT " Total # of heating degree days     ";DD(1)
  46. 460 INPUT " Total # of cooling degree days     ";DD(2)
  47. 470 INPUT " Outdoor design temperature(DEG F)  ";JI
  48. 480 INPUT " Indoor design temperature (DEG F)  ";JT
  49. 490 INPUT " Building volume (FT^3)             ";V
  50. 500 INPUT " Enter the # of building elements   ";N
  51. 510 PRINT
  52. 520 DT=JT-JI
  53. 530 FOR I=1 TO N
  54. 540  INPUT " Surface name       ";S$(I)
  55. 550  INPUT " Surface area(FT^2) ";A(I)
  56. 560  INPUT " Surface R-Value    ";R(I)
  57. 570 PRINT
  58. 580 REM***********************************************************************
  59. 590 REM******  Calculate UA's,WA's and conduction loads    *******************
  60. 600 REM***********************************************************************
  61. 610 UA(I)=(1/R(I))*A(I)
  62. 620 SU=SU+UA(I)
  63. 630 WA(I)=UA(I)*DT*.29299/1000
  64. 640 SW=SW+WA(I)
  65. 650 NEXT I
  66. 660 REM***********************************************************************
  67. 670 REM*****  Calculational section  *****************************************
  68. 680 REM***********************************************************************
  69. 690 IL=.24*.074*V*AC
  70. 700 VI=VI*RT/24
  71. 710 VL=.24*.074*VI
  72. 720 IN=IL+VL
  73. 730 TL=SU+IN
  74. 740 WI=IN*DT*.29299/1000
  75. 750 HL=(SU+IN)*24*DD(1)/10^6
  76. 760 CL=(SU+IN)*24*DD(2)/10^6
  77. 770 REM***********************************************************************
  78. 780 REM***** SCREEN output section  ******************************************
  79. 790 REM***********************************************************************
  80. 800 CLS:KEY OFF
  81. 810 PRINT :PRINT :PRINT
  82. 820 PRINT TAB(10) "Conduction and Ventilation Loads"
  83. 830 PRINT TAB(10) "~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~"
  84. 840 PRINT :PRINT
  85. 850 PRINT TAB(10) ;T$
  86. 860 LT=LEN(T$)
  87. 870 TU$=STRING$(LT,126)
  88. 880 PRINT TAB(10) ;TU$
  89. 890 PRINT TAB(15) " Conduction Load Table"
  90. 900 PRINT TAB(15) " ~~~~~~~~~~~~~~~~~~~~~"
  91. 910 PRINT :PRINT
  92. 920 PRINT "|~~~~~~~~~~~~~~~~|~~~~~~~~~~~|~~~~~~~~~~~~|~~~~~~~~~~~~~~|~~~~~~~~~~|~~~~~~~~|"
  93. 930 PRINT "|    SURFACE     |   AREA    |     R      |     UA       |   LOAD   | WA(JAN)|"
  94. 940 PRINT "|     NAME       |  (FT^2)   |            |BTU/HR DEG F  |   (%)    |  (KW)  |"
  95. 950 PRINT "|~~~~~~~~~~~~~~~~|~~~~~~~~~~~|~~~~~~~~~~~~|~~~~~~~~~~~~~~|~~~~~~~~~~|~~~~~~~~|"
  96. 960 FOR I=1 TO N
  97. 970 PRINT "|";
  98. 980 PRINT USING " \           \  ";S$(I);
  99. 990 PRINT USING "|#######.## ";A(I);R(I);
  100. 1000 PRINT USING " | #######.##   |";UA(I);
  101. 1010 PRINT USING "  ###.##  |";UA(I)/TL*100;
  102. 1020 PRINT USING "  ##.###|";WA(I)
  103. 1030 NEXT I
  104. 1040 PRINT "~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~"
  105. 1050 PRINT :PRINT
  106. 1060 PRINT TAB(15)" Ventilation Table"
  107. 1070 PRINT TAB(15)" ~~~~~~~~~~~~~~~~~"
  108. 1080 PRINT :PRINT
  109. 1090 PRINT "|~~~~~~~~~~~~~~~~|~~~~~~~|~~~~~~~~~~~~|~~~~~~~~~~~~~~~~|~~~~~~~~~|"
  110. 1100 PRINT "|     AIR        |AC RATE|  VENT RATE |  ENERGY LOAD   |  LOAD   |"
  111. 1110 PRINT "|   SOURCE       | AC/HR |  FT^3/HR   |  BTU/HR DEG F  |  (%)    |"
  112. 1120 PRINT "|~~~~~~~~~~~~~~~~|~~~~~~~|~~~~~~~~~~~~|~~~~~~~~~~~~~~~~|~~~~~~~~~|"
  113. 1130 PRINT "| Infiltration   |";
  114. 1140 PRINT USING " ###.##|";AC;
  115. 1150 PRINT USING " #######.## |";AC*V;
  116. 1160 PRINT USING "    #####.###   |";IL;
  117. 1170 PRINT USING "  ###.## |";IL/TL*100
  118. 1180 PRINT "|  Ventilation   |";
  119. 1190 PRINT USING " ###.##|";VI/V;
  120. 1200 PRINT USING " #######.## |";VI;
  121. 1210 PRINT USING "    #####.###   |";VL;
  122. 1220 PRINT USING "  ###.## |";VL/TL*100
  123. 1230 PRINT "~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~"
  124. 1240 PRINT :PRINT
  125. 1250 PRINT " Yearly heating requirements for ";DD(1);" Heating degree days"
  126. 1260 PRINT USING " ###.## Million BTU ";HL
  127. 1270 PRINT :PRINT
  128. 1280 PRINT " Installed heater capacity for "
  129. 1290 PRINT USING " an outdoor design temperature of ### deg F";JI
  130. 1300 PRINT USING " and indoor design temperature of ### deg F";JT
  131. 1310 PRINT USING " neglecting infiltration should be ###.## KW";SW
  132. 1320 PRINT :PRINT
  133. 1330 PRINT " Total installed heater capacity for "
  134. 1340 PRINT USING " an outdoor design temperature of ### deg F";JI
  135. 1350 PRINT USING " and indoor design temperature of ### deg F";JT
  136. 1360 PRINT USING " including infiltration should be ###.## KW";SW+WI
  137. 1370 PRINT :PRINT
  138. 1380 PRINT " Yearly cooling requirements for ";DD(2);" Cooling degree days"
  139. 1390 PRINT USING " ###.## Million BTU ";CL
  140. 1400 PRINT :PRINT :PRINT
  141. 1410 PRINT "  Do you wish to print out these results(P)"
  142. 1420 INPUT "   or correct the input data(C)            ";Q$
  143. 1430 IF Q$="" THEN BEEP:GOTO 1410
  144. 1440 QQ=INSTR("PC",Q$):IF QQ=0 THEN BEEP:GOTO 1410
  145. 1450 ON QQ GOTO 1480,180
  146. 1460 REM***********************************************************************
  147. 1470 REM*****  printer output section  ****************************************
  148. 1480 REM***********************************************************************
  149. 1490 PRINT "  IS THE PRINTER TURNED ON ???"
  150. 1500 PRINT "  ############################"
  151. 1510 PRINT "  Press any KEY to continue"
  152. 1520 X$=INKEY$: IF X$="" THEN 1520
  153. 1530 LPRINT CHR$(15):WIDTH "LPT1:",132
  154. 1540 LPRINT "   SENES BUILDING ENERGY LOAD MODEL "
  155. 1550 LPRINT "   ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~"
  156. 1560 LPRINT :LPRINT
  157. 1570 LPRINT TAB(10) "Conduction and Ventilation Loads"
  158. 1580 LPRINT TAB(10) "~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~"
  159. 1590 LPRINT :LPRINT :LPRINT
  160. 1600 LPRINT TAB(10) ;T$
  161. 1610 LT=LEN(T$)
  162. 1620 TU$=STRING$(LT,126)
  163. 1630 LPRINT TAB(10) ;TU$
  164. 1640 LPRINT TAB(15) " Conduction Load Table"
  165. 1650 LPRINT TAB(15) " ~~~~~~~~~~~~~~~~~~~~~"
  166. 1660 LPRINT :LPRINT
  167. 1670 LPRINT "|~~~~~~~~~~~~~~~~|~~~~~~~~~~~|~~~~~~~~~~~~|~~~~~~~~~~~~~~|~~~~~~~~~~|~~~~~~~~|"
  168. 1680 LPRINT "|    SURFACE     |   AREA    |     R      |     UA       |   LOAD   | WA(JAN)|"
  169. 1690 LPRINT "|     NAME       |  (FT^2)   |            |BTU/HR DEG F  |   (%)    |  (KW)  |"
  170. 1700  LPRINT "|~~~~~~~~~~~~~~~~|~~~~~~~~~~~|~~~~~~~~~~~~|~~~~~~~~~~~~~~|~~~~~~~~~~|~~~~~~~~|"
  171. 1710 FOR I=1 TO N
  172. 1720 LPRINT "|";
  173. 1730 LPRINT USING " \           \  ";S$(I);
  174. 1740 LPRINT USING "|#######.## ";A(I);R(I);
  175. 1750 LPRINT USING " | #######.##   |";UA(I);
  176. 1760 LPRINT USING "  ###.##  |";UA(I)/TL*100;
  177. 1770 LPRINT USING "  ##.###|";WA(I)
  178. 1780 NEXT I
  179. 1790 LPRINT "~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~"
  180. 1800 LPRINT:LPRINT
  181. 1810 LPRINT TAB(15)" Ventilation Table"
  182. 1820 LPRINT TAB(15)" ~~~~~~~~~~~~~~~~~"
  183. 1830 LPRINT:LPRINT
  184. 1840 LPRINT "|~~~~~~~~~~~~~~~~|~~~~~~~|~~~~~~~~~~~~|~~~~~~~~~~~~~~~~|~~~~~~~~~|
  185. 1850 LPRINT "|     AIR        |AC RATE|  VENT RATE |  ENERGY LOAD   |  LOAD   |
  186. 1860 LPRINT "|   SOURCE       | AC/HR |  FT^3/HR   |  BTU/HR DEG F  |  (%)    |
  187. 1870 LPRINT "|~~~~~~~~~~~~~~~~|~~~~~~~|~~~~~~~~~~~~|~~~~~~~~~~~~~~~~|~~~~~~~~~|
  188. 1880 LPRINT "| Infiltration   |";
  189. 1890 LPRINT USING " ###.##|";AC;
  190. 1900 LPRINT USING " #######.## |";AC*V;
  191. 1910 LPRINT USING "    #####.###   |";IL;
  192. 1920 LPRINT USING "  ###.## |";IL/TL*100
  193. 1930 LPRINT "|  Ventilation   |";
  194. 1940 LPRINT USING " ###.##|";VI/V;
  195. 1950 LPRINT USING " #######.## |";VI;
  196. 1960 LPRINT USING "    #####.###   |";VL;
  197. 1970 LPRINT USING "  ###.## |";VL/TL*100
  198. 1980 LPRINT "~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~"
  199. 1990 LPRINT:LPRINT
  200. 2000 LPRINT " Yearly heating requirements for ";DD(1);" Heating degree days"
  201. 2010 LPRINT USING " ###.## Million BTU ";HL
  202. 2020 LPRINT:LPRINT
  203. 2030 LPRINT " Installed heater capacity for "
  204. 2040 LPRINT USING " an outdoor design temperature of ### deg F";JI
  205. 2050 LPRINT USING " and indoor design temperature of ### deg F";JT
  206. 2060 LPRINT USING " neglecting infiltration should be ###.## KW";SW
  207. 2070 LPRINT:LPRINT
  208. 2080 LPRINT " Total installed heater capacity for "
  209. 2090 LPRINT USING " an outdoor design temperature of ### deg F";JI
  210. 2100 LPRINT USING " and indoor design temperature of ### deg F";JT
  211. 2110 LPRINT USING " including infiltration should be ###.## KW";SW+WI
  212. 2120 LPRINT :LPRINT
  213. 2130 LPRINT " Yearly cooling requirements for ";DD(2);" Cooling degree days"
  214. 2140 LPRINT USING " ###.## Million BTU ";CL
  215. 2150 KEY ON
  216. 2160 LPRINT CHR$(18)
  217. 2170 END
  218.  for ";D