home *** CD-ROM | disk | FTP | other *** search
/ Between Heaven & Hell 2 / BetweenHeavenHell.cdr / 100 / 31 / chekbook.bas < prev    next >
BASIC Source File  |  1983-05-29  |  4KB  |  78 lines
  1. 80 MAINMENU$="no"
  2. 100 CLS
  3. 110 PRINT TAB(20)"Checkbook Balance Program"
  4. 120 PRINT TAB(20)"AUTHOR--Bruce T. Filbeck"
  5. 121 PRINT TAB(20)"        4240 KILGORE RD "
  6. 122 PRINT TAB(20)"        CROSWELL, MI 48422"
  7. 130 'Set the 10-key pad to numeric shift
  8. 140 DEF SEG=&H40:POKE &H17,PEEK(&H17) OR 32
  9. 150 'Clear the screen and begin
  10. 160 PRINT :PRINT :PRINT :PRINT
  11. 170 INPUT;"Enter the NEW BALANCE from your statement:",NEWBAL$ :PRINT
  12. 180 IF NEWBAL$="" THEN BEEP:GOTO 170
  13. 190 IF LEFT$(NEWBAL$,1)="$" THEN NEWBAL$=RIGHT$(NEWBAL$,(LEN(NEWBAL$)-1))
  14. 200 NEWBAL=VAL(NEWBAL$)
  15. 210 PRINT :PRINT :PRINT :PRINT
  16. 220 'Total the deposits made but not shown on statement
  17. 230 INPUT;"Enter DEPOSITS not shown on statement (Enter 0 to end or REDO to restart):",DEP$:PRINT
  18. 240 IF DEP$="" THEN BEEP:GOTO 230
  19. 250 IF LEFT$(DEP$,1)="0" THEN 290
  20. 260 IF DEP$="redo" OR DEP$="REDO" THEN DEPOSITS=0: PRINT "CLEARED": GOTO 230
  21. 270 IF LEFT$(DEP$,1)="$" THEN DEP$=RIGHT$(DEP$,(LEN(DEP$)-1))
  22. 280 DEPOSITS=DEPOSITS +VAL(DEP$):GOTO 230
  23. 290 PRINT :PRINT :PRINT :PRINT
  24. 300 'Total the checks that haven't cleared
  25. 310 INPUT;"Enter any CHECKS not returned (Enter 0 to end or REDO to start over):",CHECK$:PRINT
  26. 320 IF CHECK$="" THEN BEEP:GOTO 310
  27. 330 IF LEFT$(CHECK$,1)="0" THEN 370
  28. 340 IF (CHECK$="REDO") OR (CHECK$="redo") THEN CHECKS=0:PRINT "CLEARED":GOTO 310
  29. 350 IF LEFT$(CHECK$,1)="$" THEN CHECK$=RIGHT$(CHECK$,(LEN(CHECK$)-1))
  30. 360 CHECKS=CHECKS+VAL (CHECK$):GOTO 310
  31. 370 PRINT :PRINT
  32. 380 'Calculate the checkbook balance
  33. 390 BALANCE=NEWBAL+DEPOSITS-CHECKS
  34. 400 PRINT "After you have deducted all charges, etc. shown on your statement
  35. 410 PRINT USING "your CHECKBOOK BALANCE should be $ ###.##";BALANCE
  36. 420 'Does the calculated balance match the checkbook?
  37. 430    PRINT  :PRINT :INPUT "Does this match your CHECKBOOK BALANCE";ANSWER$
  38. 440 IF ANSWER$="" THEN BEEP:GOTO 430
  39. 450 'If so, great.  Go to END.
  40. 460 IF LEFT$(ANSWER$,1)="Y" OR LEFT$(ANSWER$,1)="y" THEN 800
  41. 470 'If not, try to find the error
  42. 480 PRINT :PRINT "Please check to see if you have deducted all bank charges"
  43. 490 PRINT "such as new checks, etc. from your checkbook balance."
  44. 500 'Find out how much the balance is off then look for obvious errors of that amount
  45. 510 PRINT :INPUT "Enter your CHECKBOOK BALANCE";CHKBKBAL$ :PRINT
  46. 520 IF CHKBKBAL$="" THEN BEEP:GOTO 510
  47. 530 IF LEFT$(CHKBKBAL$,1)="$" THEN CHKBKBAL$=RIGHT$(CHKBKBAL$,(LEN(CHKBKBAL$)-1))
  48. 540 CHKBKBAL=VAL(CHKBKBAL$):DIFFERENCE=BALANCE-CHKBKBAL
  49. 550 PRINT :PRINT USING "Your checkbook is out of balance by $ ###.##";DIFFERENCE
  50. 560 PRINT "Check to see if there are any checks that have not cleared or "
  51. 570 PRINT "deposits not cleared, etc. that are for this amount."
  52. 580 PRINT :PRINT :INPUT "Did you find the error";ANSWER$
  53. 590 IF ANSWER$="" THEN BEEP:GOTO 570
  54. 600 IF LEFT$(ANSWER$,1)="y" OR LEFT$(ANSWER$,1)="Y" THEN 800
  55. 610 'The error has not been found so let's refigure the checkbook
  56. 620 PRINT :INPUT "Enter your last GOOD BALANCE";GDBAL$ :PRINT
  57. 630 IF GDBAL$="" THEN BEEP:GOTO 620
  58. 640 IF LEFT$(GDBAL$,1)="$" THEN GDBAL$=RIGHT$(GDBAL$,(LEN(GDBAL$)-1))
  59. 650 GDBAL=VAL(GDBAL$)
  60. 660 PRINT :PRINT
  61. 670 INPUT "Enter all CHECKS since the last good balance (0 to end, REDO to redo)";CHK$:PRINT
  62. 680 IF CHK$="" THEN BEEP:GOTO 670
  63. 690 IF LEFT$(CHK$,1)="0" THEN 730
  64. 700 IF CHK$="REDO" OR CHK$="redo" THEN CHKS=0:PRINT "CLEARED":GOTO 670
  65. 710 IF LEFT$(CHK$,1)="$" THEN CHK$=RIGHT$(CHK$,(LEN(CHK$)-1))
  66. 720 CHKS=CHKS-VAL(CHK$):GOTO 670
  67. 730 PRINT :PRINT :INPUT "Enter all DEPOSITS since last good balance (0 to end)";DEP$
  68. 740 IF DEP$="" THEN BEEP:GOTO 730
  69. 750 IF LEFT$(DEP$,1)="0" THEN 780
  70. 760 IF LEFT$(DEP$,1)="$" THEN DEP$=RIGHT$(DEP$,(LEN(DEP$)-1))
  71. 770 DEPS=DEPS+VAL(DEP$):GOTO 730
  72. 780 GDBAL=GDBAL+DEPS+CHKS
  73. 790 PRINT :PRINT USING "The BALANCE IN YOUR CHECKBOOK should be $ ###.## ";GDBAL
  74. 800 IF MAINMENU$="no" OR MAINMENU$="NO" THEN 820
  75. 810 CHAIN "mainmenu.mnu"
  76. 820 END
  77. OUR CHECKBOOK should be $ ###.## ";GDBAL
  78. 800 IF MAINM