Creative Computers/CreativeComputers.iso/shareware/intuition/dragit4.0/install/install-dragit

Text File | 1994-11-17 | 24.7 KB | 907 lines

;++++++++++++++++++++++++++++++++++++++++++++++++++
; $VER: Install-DragIt v4.0 (2.11.93)
; Installation script by Jan and Erik Simonson
;++++++++++++++++++++++++++++++++++++++++++++++++++

(set OSVersion      (/ (getversion) 65536))
(set WBVersion      (/ (getversion "LIBS:version.library" ) 65536))

;++++++++++++++++++++++++++++++
;Set up variables in English.
;++++++++++++++++++++++++++++++

(set #Language 0)
(set LanguageID 0)
(set DocID 1)

(set #LowVersion "Sorry, you need at least OS/WB version 2.0 to use DragIt")

(set #SetDirPathPrompt "Please select the directory ")

(set #DragItDirPrompt "where you want to install DragIt.")
(set #DragItDirHelp
  (cat "  If you want DragIt to start automatically every time your Amiga "
       "starts you should not change the suggested directory "
       "(SYS:WBStartup).\n  You should choose another directory for DragIt "
       "if you do not wish the program to start automatically.\n"
  )
)
(set #DragDirPrompt "where you want to install Drag.")
(set #DragDirHelp
  (cat "  Normally Drag, which is a preference program, should always be "
       "installed in the suggested directory (SYS:Prefs).\n  If you for "
       "some reason do not want it installed there, please choose another "
       "directory.\n"
  )
)
(set #SelectLanguagePrompt
  (cat "Besides English, select the preferred languages in which you might "
       "want to run the Drag program."
  )
)
(set #SelectLanguageHelp
  (cat "  You should select all the possible languages you want menu and "
       "requester text to be displayed in.\n  At this time, the "
       "alternatives to English are French and Swedish.\n\n"
       "French\n  This should be selected if you want the French versions "
       "of menus and requester text.\n\n"
       "Swedish\n  This should be selected if you want the Swedish versions "
       "of menus and requester text.\n\n"
  )
)
(set #LanguageEnglish "English")
(set #LanguageFrench "French")
(set #LanguageSwedish "Swedish")

(set #AskNoviceDoc "\nDo you want to install the documentation?")
(set #AskNoviceDocHelp
  (cat "  Do you want to install DragIt's documentation press the \"Yes\" "
       "button, if not press the \"No\" button."
  )
)

(set #SelectDocPrompt
       "Select the languages in which you want to install the documentation.")
(set #SelectDocHelp
  (cat "  You should select all the languages in which you want the "
       "documentation available on your Amiga.\n  At this time, the "
       "alternatives to English are French and Swedish.\n\n"
       "English\n  This should be selected if you want the English "
       "documentation.\n\n"
       "French\n  This should be selected if you want the French "
       "documentation.\n\n"
       "Swedish\n  This should be selected if you want the Swedish "
       "documentation.\n\n"
  )
)

(set #DocDirPrompt "where you want to install the documentation.")
(set #DocDirHelp
  (cat "  Install the documentation in a directory where it can be easely "
       "reached and preferably together with the documentation for other "
       "commodities.\n\n"
  )
)

(set #Proceed1 "You have choosen to install DragIt in the\n")
(set #Proceed2 " directory.\n\nYou have also choosen to install Drag in the\n")
(set #Proceed3 " directory.\n\n\Further the selected programlanguages are\n")
(set #Proceed4 "\nand documentation in ")
(set #Proceed5 "and no documentation will be installed.")
(set #Proceed6 "will be installed in ")
(set #Proceed7 "\n\nShall I proceed with the installation?")
(set #ProceedHelp
  (cat "  Once you press the \"Proceed\" button, the selected items will be "
       "installed. This is your last chance to abort this procedure without "
       "partially installing the selected files.\n\n  After you press "
       "Proceed, you can use the Esc key to abort the installation "
       "procedure."
  )
)

(set #InstallPrompt "Installing")

(set #NoLocaleMessage
  (cat "\nYou do not seem to have LOCALE: assigned to the directory where "
       "the localization files are stored.\nPlease install the system "
       "software localization files before retrying this installation.\n\n"
       "Press either the \"Proceed\" or \"Abort Install\" button to abort "
       "this installation."
  )
)
(set #NoLocaleCatalogMessage
  (cat "\nThere is no  LOCALE:Catalogs  directory. This installation "
       "requires that directory to be present to install the selected "
       "locale support files.\n\nPress either the \"Proceed\" or \"Abort "
       "Install\" button to abort this installation."
  )
)
(set #CopyLanguage "catalog files...")
(set #CopyDoc "AmigaGuide file...")

(set #ReadDoc "\nDo you want to read the documentation?")

(set #ReadDocHelp
  (cat "  If you want to read the documentation for DragIt press the \"Yes\" "
       "button, if you don't want to read it, press the \"No\" button.\n"
  )
)

(set #DocIDPrompt "Which documentation do you want to read?")

(set #DocIDHelp
  (cat "  Choose the documentation which you now want to read, as a reference "
       "when you configurate DragIt.\n"
  )
)

(set #RunDragIt "\nDo you want to run DragIt?")

(set #RunDragItHelp
  (cat "  If you press the \"Yes\" button, DragIt will be executed so you "
       "can take advantage of the program whithout resetting the computer."
  )
)

(set #RunDrag
       "\nDragIt is now running, do you want to run the preference program?")

(set #RunDragHelp
  (cat "  If you press the \"Yes\" button the preference program will be "
       "executed so that you can configurate DragIt to your own liking, and "
       "then, if you want to, save the configurations."
  )
)

;++++++++++++++++++++++++++++++
; Set up variables in French.
;++++++++++++++++++++++++++++++

(if (= @language "franτais")
(
(set #Language 1)
(set LanguageID 1)
(set DocID 2)

(set #LowVersion "DΘsolΘ, vous devez avoir au minimum l'OS/WB 2.0 pour faire fonctionner DragIt")

(set #SetDirPathPrompt "Choisir le rΘpertoire o∙ vous ")

(set #DragItDirPrompt "voulez installer DragIt.")
(set #DragItDirHelp
  (cat "  Si vous voulez que DragIt soit dΘmarer automatiquement au boot de "
       "l'Amiga, ne changer pas le rΘpertoire suggΘrΘ suivant "
       "(SYS:WBStartup).\n  Vous devez choisir une autre rΘpertoire que si "
       "vous ne voulez pas le dΘpart automatique du programme.\n"
  )
)
(set #DragDirPrompt "voulez installer le programme Drag.")
(set #DragDirHelp
  (cat "  Normalement le programme de prΘfΘrence Drag doit Ωtre copiΘ dans "
       "le rΘpertoire suggΘrΘ suivant (SYS:Prefs).\n  Si vous voulez pour "
       "pour certaines raisons qu'il soit installΘ ailleur, choisisser un "
       "autre rΘpertoire.\n"
  )
)
(set #SelectLanguagePrompt
  (cat "Autre qu'anglais, choisisser les languages prΘfΘrΘes pour l'utilisation "
       "du prΘfΘrence Drag."
  )
)
(set #SelectLanguageHelp
  (cat "  Vous devez choisir toutes les langues qui seront utilisΘes dans "
       "les menus et fenΩtres du programme.\n  PrΘsentement, les alternatives α "
       "l'anglais sont franτais et suΘdois.\n\n"
       "Franτais\n  A sΘlectionner si vous voulez la version franτaise des "
       "menus et des textes.\n\n"
       "SuΘdois\n  A sΘlectionner si vous voulez la version suΘdoise des "
       "menus et des textes.\n\n"
  )
)
(set #LanguageEnglish "Anglais")
(set #LanguageFrench "Franτais")
(set #LanguageSwedish "SuΘdois")

(set #AskNoviceDoc "\nVoulez-vous installer la documentation?")
(set #AskNoviceDocHelp
  (cat "  Si vous voulez installer la documentation de DragIt appuyer sur le bouton \"Oui\" "
       ", sinon appuyer sur le bouton \"Non\"."
  )
)

(set #SelectDocPrompt
       "SΘlectionner les langues de la documentation α installer.")
(set #SelectDocHelp
  (cat "  Vous devez choisir toutes les langues qui seront installΘes pour "
       "la documentation du programme.\n  PrΘsentement, les alternatives α "
       "l'anglais sont franτais et suΘdois.\n\n"
       "Anglais\n  A sΘlectionner si vous voulez la version anglaise des "
       "menus et des textes.\n\n"
       "Franτais\n  A sΘlectionner si vous voulez la version franτaise des "
       "menus et des textes.\n\n"
       "SuΘdois\n  A sΘlectionner si vous voulez la version suΘdoise des "
       "menus et des textes.\n\n"
  )
)

(set #DocDirPrompt "voulez installer la documentation.")
(set #DocDirHelp
  (cat "  Installer la documentation dans un rΘpertoire facile d'accΦs "
       "prΘfΘrablement au mΩme endroit que la documentation des autres applications "
       "du systΦme.\n\n"
  )
)

(set #Proceed1 "Vous avez choisi d'installer DragIt dans le rΘpertoire ")
(set #Proceed2 ".\n\nVous avez aussi choisi d'installer le prΘfΘrence Drag dans le rΘpertoire ")
(set #Proceed3 ".\n\n\Les langues sΘlectionnΘes sont\n")
(set #Proceed4 "\net la documentation ")
(set #Proceed5 "\nsans documentation ")
(set #Proceed6 "sera installΘe dans ")
(set #Proceed7 "\n\nDois-je procΘder α l'installation?")
(set #ProceedHelp
  (cat "  Un fois que vous aurez appuyΘ sur le bouton \"Proceed\", les items "
       "sΘlectionnΘs seront installΘs. Ceci est la derniΦre chance d'annuler "
       "l'opΘration sans installer les fichiers.\n\n AprΦs avoir appuyΘ sur "
       "Proceed il sera toujours possible d'arrΩter l'installation en appuyant "
       "sur la touche Esc."
  )
)

(set #InstallPrompt "Installation")

(set #NoLocaleMessage
  (cat "\nVous ne semblez pas avoir de rΘpertoire LOCALE: o∙ sont situΘ les fichiers "
       "de traduction.\nVeulliez installer les fichiers nΘcessaires α la "
       "localisation avant de continuer.\n\nAppuyer sur \"Proceed\" ou sur "
       "\"Abort\" annulera l'installation."
  )
)
(set #NoLocaleCatalogMessage
  (cat "\nVous ne semblez pas avoir de rΘpertoire LOCALE:Catalogs. Cette "
       "installation requier qu'il soit prΘsent pour installer correctement "
       "les fichiers de traduction.\n\nAppuyer sur \"Proceed\" ou sur "
       "\"Abort\" annulera l'installation."
  )
)
(set #CopyLanguage "Fichiers catalog...")
(set #CopyDoc "Fichiers AmigaGuide...")

(set #ReadDoc "\nVoulez-vous lire la documentation?")

(set #ReadDocHelp
  (cat "  Si vous voulez lire la documentation de DragIt appuyer sur le bouton \"Oui\" "
       ", sinon appuyez sur le bouton \"Non\"."
  )
)

(set #DocIDPrompt "Quelle documentation voulez-vous lire?")

(set #DocIDHelp
  (cat "  Choisisser la documentation α lire, ceci vous aidera α configurer "
       "DragIt dΦs maintenant.\n"
  )
)

(set #RunDragIt "\nVoulez-vous exΘcuter DragIt maintenant?")

(set #RunDragItHelp
  (cat "  Si vous appuyer sur le bouton \"Oui\", DragIt sera exΘcutΘ maintenant sans "
       "avoir α redΘmarer l'ordinateur."
  )
)

(set #RunDrag
       "\nDragIt est maintenant fonctionnel, voulez-vous exΘcuter le programme de prΘfΘrence?")

(set #RunDragHelp
  (cat "  Si vous appuyer sur le bouton \"Oui\" le prΘfΘrence sera exΘcutΘ "
       "vous permettant de configurer dΦs maintenant DragIt comme vous "
       "l'aimez. Vous pourrez aussi sauver la configuration."
  )
)
)
)


;++++++++++++++++++++++++++++++
; Set up variables in Swedish.
;++++++++++++++++++++++++++++++

(if (= @language "svenska")
(
(set #Language 3)
(set LanguageID 4)
(set DocID 8)

(set #LowVersion
  "TyvΣrr, du mσste ha minst OS/WB version 2.0 f÷r att kunna anvΣnda DragIt")

(set #SetDirPathPrompt "VΣlj den katalog ")

(set #DragItDirPrompt "dΣr du vill installera DragIt.")
(set #DragItDirHelp
  (cat "  Om du vill att Dragit skall starta automatiskt vid varje start av "
       "din Amiga skall du inte Σndra den f÷reslagna katalogen "
       "(SYS:WBStartup).\n  Vill du inte att DragIt skall starta automatiskt "
       "skall du vΣlja en annan katalog f÷r programmet.\n"
  )
)
(set #DragDirPrompt "dΣr du vill installera Drag.")
(set #DragDirHelp
  (cat "  Normalt skall Drag, som Σr ett instΣllningsprogram, alltid "
       "installeras i den f÷reslagna katalogen (SYS:Prefs).\n  Om du av "
       "nσgon anledning inte vill detta, vΣlj en annan katalog.\n"
  )
)
(set #SelectLanguagePrompt
  (cat "F÷rutom engelska, vΣlj de sprσk i vilka du vill ha m÷jliget att "
       "kunna k÷ra Dragprogrammet."
  )
)
(set #SelectLanguageHelp
  (cat "  Du skall vΣlja alla de sprσk som du vill ha m÷jlighet att fσ "
       "menyer och vΣljartext i.\n  Just nu Σr alternativen till engelskan "
       "endast franska och svenska.\n\n"
       "Franska\n  VΣlj denna om du vill ha den franska versionen av menyer "
       "och vΣljartext.\n\n"
       "Svenska\n  VΣlj denna om du vill ha den svenska versionen av menyer "
       "och vΣljartext.\n\n"
  )
)
(set #LanguageEnglish "Engelska")
(set #LanguageFrench "Franska")
(set #LanguageSwedish "Svenska")

(set #AskNoviceDoc "\nVill du installera dokumentationen?")
(set #AskNoviceDocHelp
  (cat "  Vill du installera dokumentationen till DragIt sσ ska du klicka pσ "
       "\"Ja\" knappen, vill du inte detta tryck pσ \"Nej\" knappen."
  )
)

(set #SelectDocPrompt
       "VΣlj de sprσk i vilka du vill installera dokumentationen.")
(set #SelectDocHelp
  (cat "  Du skall vΣlja alla de sprσk som du vill ha dokumentationen "
       "tillgΣnglig i.\n  Just nu Σr alternativen till engelskan endast "
       "franska och svenska.\n\n"
       "Engelska\n  VΣlj denna om du vill ha den engelska "
       "dokumentationen.\n\n"
       "Franska\n  VΣlj denna om du vill ha den franska dokumentationen.\n\n"
       "Svenska\n  VΣlj denna om du vill ha den svenska dokumentationen.\n\n"
  )
)

(set #DocDirPrompt "dΣr du vill installera dokumentationen.")
(set #DocDirHelp
  (cat "  Installera dokumentationen i en  katalog dΣr du kan nσ den lΣtt "
       "och helst ocksσ tillsammans med dokumentationen f÷r de ÷vriga "
       "commodities programmen.\n\n"
  )
)

(set #Proceed1 "Du har valt att installera DragIt i\n")
(set #Proceed2 " katalogen.\n\nDu har ocksσ valt att installera Drag i\n")
(set #Proceed3 " katalogen.\n\nVidare Σr de valda programsprσken\n")
(set #Proceed4 "\noch dokumentation pσ ")
(set #Proceed5 "och ingen dokumentation kommer att installeras.")
(set #Proceed6 "kommer att installeras i ")
(set #Proceed7 "\n\nSkall jag fullf÷lja installationen?")
(set #ProceedHelp
  (cat "  NΣr du klickar pσ \"FortsΣtt\" knappen, kommer de valda "
       "programdelarna att installeras. Det hΣr Σr din sista chans att "
       "avbryta installationen utan att delvis installera de valda "
       "programdelarna.\n\n  NΣr du har klickat pσ \"FortsΣtt\" knappen, "
       "kan du avbryta installationen genom att trycka pσ \"Esc\" tangenten."
  )
)

(set #InstallPrompt "Installerar")

(set #NoLocaleMessage
  (cat "\nDu verkar inte ha LOCALE: katalogen dΣr lokalisationsfilerna finns "
       "lagrade assignad.\nInstallera systemmjukvarans lokalisationsfiler "
       "innan du f÷rs÷ker med den hΣr installationen igen.\n\nTryck antingen "
       "pσ \"FortsΣtt\" eller \"Avbryt Installation\" knappen f÷r att "
       "avbryta den hΣr installationen."
  )
)
(set #NoLocaleCatalogMessage
  (cat "\nKatalogen LOCALE:Catalogs finns inte. Installationen krΣver att "
       "denna existerar f÷r att de valda sprσken skall kunna installeras.\n\n"
       "Tryck antingen pσ \"FortsΣtt\" eller \"Avbryt Installation\" "
       "knappen f÷r att avbryta den hΣr installationen."
  )
)
(set #CopyLanguage "katalogfilen...")
(set #CopyDoc "AmigaGuidefilen...")

(set #ReadDoc "\nVill du lΣsa dokumentationen?")

(set #ReadDocHelp
  (cat "  Om du vill lΣsa dokumentationen till DragIt ska du klicka pσ "
       "\"Ja\" knappen, om du inte vill lΣsa den klicka pσ \"Nej\" knappen.\n"
  )
)

(set #DocIDPrompt "Vilken dokumentation vill du lΣsa?")

(set #DocIDHelp
  (cat "  VΣlj den dokumentation till DragIt som du vill lΣsa, f÷r att sedan "
       "kunna stΣlla in programmet.\n"
  )
)

(set #RunDragIt "\nVill du k÷ra DragIt?")

(set #RunDragItHelp
  (cat "  Om du trycker pσ \"Ja\" knappen kommer DragIt att startas sσ du kan "
       "dra nytta av programmet utan att starta om datorn."
  )
)

(set #RunDrag "\nDragIt gσr nu, vill du k÷ra instΣllningsprogrammet?")

(set #RunDragHelp
  (cat "  Om du nu trycker pσ \"Ja\" knappen kommer instΣllningsprogrammet "
       "att startas sσ att du kan stΣlla in DragIt enligt dina egna "
       "÷nskemσl, f÷r att sedan om du vill, kunna spara instΣllningarna."
  )
)
)
)


(procedure SetDirPath
;
; Ask the user for a directory name.
; Variables:
;    #SetDirPathWhy
;    #SetDirPathHelp
;    #DirPath
  (
  (set Done FALSE)
  (while (NOT Done)
    (
    (set #DirPath
      (askdir
        (prompt #SetDirPathPrompt #SetDirPathWhy)
        (help ("%s\n" #SetDirPathHelp) @askdir-help)
        (default #DirPath)
      )
    )

    (if (= (exists #DirPath) 0)
      (makedir #DirPath)
      (set Done TRUE)
    )
    )
  )
  )
)

(procedure IncrementMeter
;
; Variables:
;    #TotalFiles
;    #AddToMeter
;
  (
  (set #DoneFiles (+ #DoneFiles #AddToMeter))
  (complete (/ (* #DoneFiles 100) #TotalFiles))
  )
)

;++++++++++++++++++++++++++++
; The Installer script starts here.
;++++++++++++++++++++++++++++

(if (OR (< OSVersion 37) (< WBVersion 37))
  (abort #LowVersion)
)
(set #TotalFiles 0)
(set #DoneFiles 0)
(set @default-dest "")
(set #user-level @user-level)

;++++++++++++++++++++++++++++++
; Ask for DragIt destination directory.
;++++++++++++++++++++++++++++++

(set #SetDirPathWhy #DragItDirPrompt)
(set #SetDirPathHelp #DragItDirHelp)
(set #DirPath "SYS:WBStartup")
(SetDirPath)
(set #DragItPath #DirPath)
(set #TotalFiles (+ #TotalFiles 2))

;++++++++++++++++++++++++++++++
; Ask for Drag destination directory.
;++++++++++++++++++++++++++++++

(set #SetDirPathWhy #DragDirPrompt)
(set #SetDirPathHelp #DragDirHelp)
(set #DirPath "SYS:Prefs")
(SetDirPath)
(set #DragPath #DirPath)
(set #TotalFiles (+ #TotalFiles 2))

;++++++++++++++++++++++++++++++
; Ask for languages to install.
;++++++++++++++++++++++++++++++

(if (AND (> OSVersion 37) (> WBVersion 37))
  (
  (set LanguageID
    (askoptions
      (prompt #SelectLanguagePrompt)
      (help #SelectLanguageHelp @askoptions-help)
      (choices
        #LanguageFrench
        #LanguageSwedish
      )
      (default LanguageID)
    )
  )
  )
  (set LanguageID 0)
)
(if (<> LanguageID 0)
  (
    (set Language 0)
    (set MaxLanguage 2)
    (while (< Language MaxLanguage)
      (
      (if (IN LanguageID Language)
        (set #TotalFiles (+ #TotalFiles 1))
      )
      (set Language (+ Language 1))
      )
    )
  )
)


;++++++++++++++++++++++++++++++
; Ask which documentation to install.
;++++++++++++++++++++++++++++++

(if (= @user-level 0)
  (
    (user 2)
    (if (= 0
          (askbool
            (prompt #AskNoviceDoc)
            (help #AskNoviceDocHelp)
            (default 1)
          )
        )
      (
      (set #TotalFiles (+ #TotalFiles 2))
      (set DocID 0)
      )
    )
    (user #user-level)
  )
  (
  (set DocID
    (askoptions
      (prompt #SelectDocPrompt)
      (help #SelectDocHelp @askoptions-help)
      (choices
        #LanguageEnglish
        #LanguageFrench
        #LanguageSwedish
      )
      (default DocID)
    )
  )
  (if (<> DocID 0)
    (
      (set Doc 0)
      (set MaxDoc 3)
      (while (< Doc MaxDoc)
        (
        (if (IN DocID Doc)
          (set #TotalFiles (+ #TotalFiles 2))
        )
        (set Doc (+ Doc 1))
        )
      )
    )
  )
  )
)

;++++++++++++++++++++++++++++++
; Ask for documentation destination directory.
;++++++++++++++++++++++++++++++

(if (<> DocID 0)
  (
    (user 2)
    (set #SetDirPathWhy #DocDirPrompt)
    (set #SetDirPathHelp #DocDirHelp)
    (set #DirPath "RAM:")
    (SetDirPath)
    (set #DocPath #DirPath)
    (user #user-level)
  )
)

;++++++++++++++++++++++++++++++
; Ask if proceed with installation.
;++++++++++++++++++++++++++++++

(complete 0)
(set #LocalLanguage (cat #LanguageEnglish " "))
(set LocalLanguage 0)
(set MaxLocal 2)
(while (< LocalLanguage MaxLocal)
(
  (set #LocalLang
    (select LocalLanguage
      #LanguageFrench
      #LanguageSwedish
      ""
    )
  )
  (if (IN LanguageID LocalLanguage)
    (set #LocalLanguage (cat #LocalLanguage #LocalLang " "))
  )
  (set LocalLanguage (+ LocalLanguage 1))
)
)

(set #DocLanguage "")
(set DocLanguage 0)
(set MaxDoc 3)
(while (< DocLanguage MaxDoc)
(
  (set #DocLang
    (select DocLanguage
      #LanguageEnglish
      #LanguageFrench
      #LanguageSwedish
      ""
    )
  )
  (if (IN DocID DocLanguage)
    (set #DocLanguage (cat #DocLanguage #DocLang " "))
  )
  (set DocLanguage (+ DocLanguage 1))
)
)

(if (<> DocID 0)
  (message  #Proceed1 #DragItPath #Proceed2 #DragPath #Proceed3 #LocalLanguage
            #Proceed4 #DocLanguage #Proceed6 #DocPath #Proceed7
   (help #ProceedHelp)
  )
  (message  #Proceed1 #DragItPath #Proceed2 #DragPath #Proceed3 #LocalLanguage
            #Proceed5 #Proceed7
   (help #ProceedHelp)
  )
)

;++++++++++++++++++++++++++++++
; Install the DragIt program and Icon.
;++++++++++++++++++++++++++++++

(copyfiles
    (prompt ("%s DragIt..." #InstallPrompt))
    (help @copyfiles-help)
    (source "/WBStartUp/DragIt")
    (dest #DragItPath)
    (confirm)
)
(if (exists (tackon #DragItPath "DragIt") (noreq))
  (copyfiles
    (source "/WBStartUp/DragIt.info")
    (dest #DragItPath)
  )
)
(set #AddToMeter 2)
(IncrementMeter)

;++++++++++++++++++++++++++++++
; Install the Drag program and Icon.
;++++++++++++++++++++++++++++++

(copyfiles
    (prompt ("%s Drag..." #InstallPrompt))
    (help @copyfiles-help)
    (source "/Prefs/Drag")
    (dest #DragPath)
    (confirm)
)
(if (exists (tackon #DragPath "Drag") (noreq))
  (copyfiles
    (source "/Prefs/Drag.info")
    (dest #DragPath)
  )
)
(set #AddToMeter 2)
(IncrementMeter)

;++++++++++++++++++++++++++++++
; Install selected languages.
;++++++++++++++++++++++++++++++

(if (<> LanguageID 0)
(
  (if (= (getassign "LOCALE" "a") "")
  (
    (message #NoLocaleMessage)
  )
  (
    (if (<> (exists "LOCALE:Catalogs") 2)
    (message #NoLocaleCatalogMessage)
    (
      (set Language 0)
      (set MaxLanguage 2)
      (while (< Language MaxLanguage)
      (
        (if (IN LanguageID Language)
        (
          (set #LanguageName
            (select Language
              #LanguageFrench
              #LanguageSwedish
              ""
            )
          )
          (set LanguageName
            (select Language
              "franτais"
              "svenska"
              ""
            )
          )
          (copyfiles
            (prompt ("%s %s %s" #InstallPrompt #LanguageName #CopyLanguage))
            (help @copyfiles-help)
            (source ("/Catalogs/%s" LanguageName))
            (dest ("LOCALE:Catalogs/%s" LanguageName))
            (all)
            (confirm)
          )
          (set #AddToMeter 1)
          (IncrementMeter)
        )
        )
        (set Language (+ Language 1))
      )
      )
    )
    )
  )
  )
)
)

;++++++++++++++++++++++++++++++
; Install selected documentation.
;++++++++++++++++++++++++++++++

(set Doc 0)
(set MaxDoc 3)
(set DocIn 0)
(while (< Doc MaxDoc)
(
  (if (IN DocID Doc)
  (
    (set #DocName
      (select Doc
        #LanguageEnglish
        #LanguageFrench
        #LanguageSwedish
        ""
      )
    )
    (set DocName
      (select Doc
        "DragIt.guide"
        "DragIt.guide.franτais"
        "DragIt.guide.svenska"
        ""
      )
    )
    (copyfiles
      (prompt ("%s %s %s" #InstallPrompt #DocName #CopyDoc))
      (help @copyfiles-help)
      (source ("/Documentation/%s" DocName))
      (dest #DocPath)
      (confirm)
    )
    (if (exists (tackon #DocPath DocName) (noreq))
    (
      (copyfiles
        (source ("/Documentation/%s.info" DocName))
        (dest #DocPath)
      )
      (if (< WBVersion 38)
        (tooltype
          (dest (tackon #DocPath DocName))
          (setdefaulttool "SYS:Utilities/More")
        )
      )
    )
    )
    (set DocIn (+ DocIn 1))
    (set #AddToMeter 2)
    (IncrementMeter)
  )
  )
  (set Doc (+ Doc 1))
)
)

;++++++++++++++++++++++++++++++
; Ask and read documentation.
;++++++++++++++++++++++++++++++

(user 2)
(if (askbool
      (prompt #ReadDoc)
      (help #ReadDocHelp)
      (default 1)
    )
  (
    (user #user-level)
    (if (<> DocIn 1)
      (set DocName
        (select (askchoice
                  (prompt #DocIDPrompt)
                  (help #DocIDHelp @askchoice-help)
                  (choices
                    #LanguageEnglish
                    #LanguageFrench
                    #LanguageSwedish
                  )
                  (default #Language)
                )
          "DragIt.guide"
          "DragIt.guide.franτais"
          "DragIt.guide.svenska"
        )
      )
    )
    (if (> WBVersion 37)
      (run ("Run SYS:Utilities/MultiView /Documentation/%s" DocName))
      (run ("Run SYS:Utilities/More /Documentation/%s" DocName))
    )
  )
)

;++++++++++++++++++++++++++++++
; Ask and run DragIt and Drag.
;++++++++++++++++++++++++++++++

(user 2)
(if (askbool
      (prompt #RunDragIt)
      (help #RunDragItHelp)
      (default 1)
    )
  (
    (user #user-level)
    (run ("Run /WBStartUp/DragIt"))
    (if (askbool
          (prompt #RunDrag)
          (help #RunDragHelp)
          (default 0)
        )
      (
        (set #RunDragPath (tackon #DragPath "Drag"))
        (run ("Run %s" #RunDragPath))
      )
    )
  )
)

;++++++++++++++++++++++++++++++
; End of installation script
;++++++++++++++++++++++++++++++