home *** CD-ROM | disk | FTP | other *** search
/ The Devil's Doorknob BBS Capture (1996-2003) / devilsdoorknobbbscapture1996-2003.iso / Dloads / SYSOP / KERMIT.ZIP / DATAPORT.SCR < prev    next >
Text File  |  1994-10-17  |  5KB  |  133 lines
  1. ; FILE DATAPORT.SCR (MSMDATAP.SCR)
  2. ; 
  3. ; An MS-DOS Kermit script program for dialing the AT&T / Paradyne Dataport
  4. ; 14400 modem, internal or external, to be used with MS-DOS Kermit 3.12 or
  5. ; later.  The modem is set for V.32bis, compression, error correction, all
  6. ; types of fallback, RTS/CTS flow control, fixed interface speed of 57600.
  7. ; 
  8. ; Rename this file to DATAPORT.SCR if necessary.
  9. ;
  10. ; To use: SET MODEM=DATAPORT (in DOS, before starting Kermit)
  11. ; or:     DEFINE _MODEM DATAPORT (in Kermit, before dialing)
  12. ; and:    Make sure Kermit executes the standard MSKERMIT.INI file.
  13. ;
  14. ; Authors: Christine M. Gianone, Frank da Cruz; Columbia U, September 1993
  15. ; Revised Oct 94.
  16. ;
  17. def errfail echo \%1, hangup, goto fail ; Macro to handle failures.
  18. if < VERSION 312 errfail {MS-DOS Kermit 3.12 or later required.}
  19.  
  20. define chkerr if fail stop 1 \%1
  21. define chkok input 3 OK, if fail stop 1 \%1
  22.  
  23. set input echo on        ; So we can watch what happens.
  24. set input timeout proceed       ; Allow IF SUCCESS, IF FAILURE.
  25. set input case ignore        ; Use caseless string comparisons
  26.  
  27. set parity none            ; Avoid parity foulups
  28. set flow none            ; Avoid flow control deadlocks
  29. hangup                ; Begin by dropping DTR
  30.  
  31. ; Speed.  Don't worry about modem, it autobauds up to 57600 bps.
  32. ; NOTE: This modem doesn't seem to have a command for locking the
  33. ; interface speed.  But it seems to do it anyway.
  34. ;
  35. set speed 57600
  36. wait 5 dsr            ; Time to recover from HANGUP...
  37.  
  38. echo Configuring AT&T DataPort on \v(line).
  39.  
  40. :INIT
  41. output ATQ0V1\13        ; Enable word result codes
  42. chkok {Can't get modem's attention}
  43. ; X6 = Verbose result codes, show modulation speed
  44. ; &C1 = CD follows RS232
  45. ; &D2 = DTR follows RS232
  46. ; &Q0 = Asynchronous data mode, use AT command set
  47. ; S84=0 = Normal ERROR response to bad commands
  48. output AAAT E1 X6 &C1 &D2 &Q0 S84=0\13
  49. chkok {Can't initialize modem}
  50. output AT \92Q3\13        ; RTS/CTS hardware flow control
  51. chkok {Can't enable RTS/CTS}    ; On modem
  52. wait 5 cts
  53. if fail errfail {Modem is not asserting CTS!}
  54. set flow rts/cts        ; And in Kermit too, but only now
  55. pause 2                ; This is needed for internal model
  56. output AT %B14400 S41=1 S78=0\13 ; Modulation = V.32bis with fallback
  57. chkok {Can't enable modulation fallback}
  58. output AT \92N7%C1\13        ; Compression and EC enabled
  59. chkok {Can't enable compression and EC}
  60. output AT \92K5\13        ; Make modem pass BREAK transparently
  61. chkok {Can't become transparent to BREAK}
  62.  
  63. if def \%1 if not equal "\%1" "=" goto BEGIN
  64. echo Modem initialization complete, no number to dial
  65. end 0
  66.  
  67. :BEGIN                ; Now DIAL.
  68. clear                ; Clear INPUT buffer.
  69. set count 5                     ; Dialing retry counter, 5 tries allowed.
  70. echo Dialing \%1 on \v(line) at \v(speed) bps, wait...
  71. echo
  72. pause 1
  73. goto dial                       ; 1st time, skip pause and Redialing message
  74.  
  75. :REDIAL
  76. set alarm 30
  77. pause 30            ; Wait 30 seconds before redialing.
  78. if not alarm errfail {Dialing canceled.}
  79. echo Redialing...               ; Message for redialing.
  80. pause 1
  81.  
  82. :DIAL
  83. output ATD\%1\13                ; Dial the number.
  84. set alarm 90            ; (For detecting keyboard interruptions.)
  85. if > VERSION 312 clear input    ; Clear echo from INPUT buffer.
  86. if < VERSION 313 clear
  87. input 30 \10                    ; Wait for the linefeeds...
  88.  
  89. :GETMSG
  90. input 60 \10            ; ...that surround the response message.
  91. if success goto gotmsg        ; Got a message.
  92. if alarm errfail {No response from modem.} ; No response in 90 seconds.
  93. hangup                ; User interrupted from keyboard,
  94. output \13            ; cancel dialing by sending carriage return,
  95. goto again            ; and go try again right away.
  96.  
  97. :GOTMSG
  98. reinput 1 CONNECT               ; Got a message, was it CONNECT?
  99. if success goto done            ; If so, we're done.
  100. reinput 1 BUSY            ; Line is busy.
  101. if success goto busy        ; Go wait a while and then dial again.
  102. reinput 1 ERROR            ; Command syntax error.
  103. if success errfail {Dialing command error}
  104. reinput 1 NO CARRIER        ; Phone didn't answer or no carrier.
  105. if success errfail {No answer or no carrier}
  106. reinput 1 NO ANSWER        ; No answer
  107. if success errfail {No answer - try again later}
  108. reinput 1 NO DIALTONE        ; No dialtone when phone taken off hook.
  109. if success errfail {No dialtone - Is your modem connected to the phone line\63}
  110. goto getmsg            ; None of the above, get another message.
  111.  
  112. :BUSY
  113. if < \v(count) 2 goto quit    ; Don't wait 30 seconds if tries are used up.
  114. Echo Line is busy, will dial again in 30 seconds.
  115. echo Press any key to cancel...
  116. output \13            ; CR cancels dialing
  117. hangup                          ; Hang up.
  118. :AGAIN
  119. if count goto redial            ; Then go redial.
  120. :QUIT
  121. errfail {It never answers!  I give up.} ; Too many tries.
  122.  
  123. :DONE                           ; Connected.
  124. echo \7                         ; Celebrate with a beep.
  125. define errfail            ; Erase local macro definitions...
  126. end 0                ; Finished, return success code.
  127.  
  128. :FAIL                ; Dialing failed, no beep.
  129. define errfail            ; Erase local macro definitions...
  130. end 1                ; Return failure code.
  131.  
  132. ; End of DATAPORT.SCR
  133.