home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
FM Towns: Free Software Collection 1
/
FREEWARE.BIN
/
basic
/
dump
/
dump.bas
next >
Wrap
BASIC Source File
|
1989-10-17
|
2KB
|
40 lines
10000 '★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★
10010 '★ ★
10020 '★ データ・ダンプ・プログラム Version 1.0 ★
10030 '★ ★
10040 '★ H.Ishihara at 1989 4/25 ★
10050 '★ ★
10060 '★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★
10070 CLS
10080 LOCATE 16,8 : LINE INPUT "ファイル名を入力して下さい。";F$
10090 ON ERROR GOTO *FILE : OPEN "I",#1,F$ : ON ERROR GOTO 0 : CLS : K&=0
10100 *DUMP
10110 PRINT "addr/offset 0 1 2 3 4 5 6 7 8 9 A B C D E F"
10120 PRINT
10130 FOR I%=0 TO 15 : P$="" : Q$=""
10140 FOR J%=0 TO 15
10150 IF EOF(1) THEN P$=P$+" " : Q$=Q$+" " : GOTO 10180
10160 R$=INPUT$(1,#1) : P$=P$+" "+RIGHT$("0"+HEX$(ASC(R$)),2)
10170 IF R$<CHR$(32) THEN Q$=Q$+"." ELSE Q$=Q$+R$
10180 NEXT J%
10190 PRINT RIGHT$("000000"+HEX$(K&),6);HEX$(I%);"0 :";P$;" : ";Q$
10200 IF EOF(1) THEN 10290
10210 Q$=INKEY$ : IF Q$ ="" THEN 10270
10220 IF Q$="q" OR Q$="Q" OR Q$=CHR$(27) THEN 10290
10230 IF Q$=" " OR Q$="s" OR Q$="S" THEN 10240 ELSE 10270
10240 Q$=INKEY$ : IF Q$ ="" THEN 10240
10250 IF Q$="q" OR Q$="Q" OR Q$=CHR$(27) THEN 10290
10260 IF Q$=" " OR Q$="s" OR Q$="S" THEN 10270 ELSE 10240
10270 NEXT I%
10280 PRINT : PRINT : K&=K&+1 : GOTO *DUMP
10290 CLOSE #1 : END
10300 *FILE
10310 E%=ERR : L%=ERL : BEEP : CLS : LOCATE 16,10 : IF E%<>55 THEN 10340
10320 COLOR 6 : PRINT "ファイル名"; :COLOR 4 :PRINT "(";F$;")";
10330 COLOR 6 : PRINT "の形式に誤りが有ります!" : COLOR 7 : GOTO 10380
10340 IF E%<>63 THEN 10370
10350 COLOR 6 : PRINT "該当するファイル"; : COLOR 4 : PRINT "(";F$;")";
10360 COLOR 6 : PRINT "はありません!" : COLOR 7 : GOTO 10380
10370 PRINT "エラーだょん!!line =";L%;" error =";E%
10380 RESUME 10080