home *** CD-ROM | disk | FTP | other *** search
/ Beijing Paradise BBS Backup / PARADISE.ISO / software / BBSDOORW / UUPC11XO.ZIP / UUCLEAN.BAT < prev    next >
Encoding:
DOS Batch File  |  1992-11-30  |  3.0 KB  |  61 lines
  1. echo off
  2. REM *------------------------------------------------------------------*
  3. REM *    Written and contributed by Michael Morrett                    *
  4. REM *    (ICBJ100@INDYVAX.IUPUI.EDU).  Support for by Snuffles P.      *
  5. REM *    Bear (Snuffles@kew.com).  Comments by Drew Derbyshire         *
  6. REM *    (help@kew.com); delete the comments to make this run faster.  *
  7. REM *------------------------------------------------------------------*
  8. rem     $Id: UUCLEAN.BAT 1.2 1992/12/01 04:39:48 ahd Exp $
  9. rem
  10. rem     $log$
  11. REM *------------------------------------------------------------------*
  12. REM *   Define your spool and temp directories on following lines      *
  13. REM *------------------------------------------------------------------*
  14. if "%1" == "" %0 \uupc\spool %temp%
  15. if "%2" == "" %0 %1 %temp%
  16. if "%1" == "cleanit" goto cleanit:
  17. echo Cleaning UUPC/extended directories %1 and %2
  18. REM *------------------------------------------------------------------*
  19. REM *     Temporary files created by UUCICO in spool directory         *
  20. REM *------------------------------------------------------------------*
  21. if exist %1\*.$$$ erase %1\*.$$$
  22. REM *------------------------------------------------------------------*
  23. REM * Temporary files created by MAIL and RMAIL.  (and their           *
  24. REM * backups created by many editors)                                 *
  25. REM *------------------------------------------------------------------*
  26. if exist %2\UUPC*.tmp erase %2\UUPC*.tmp
  27. if exist %2\UUPC*.txt erase %2\UUPC*.txt
  28. if exist %2\UUPC*.bak erase %2\UUPC*.bak
  29. REM *------------------------------------------------------------------*
  30. REM *                 Clean the various log files                      *
  31. REM *------------------------------------------------------------------*
  32. call %0 cleanit %1\linedata
  33. call %0 cleanit %1\rmail
  34. call %0 cleanit %1\rnews
  35. call %0 cleanit %1\uuxqt
  36. call %0 cleanit %1\uucico
  37. call %0 cleanit %1\expire
  38. if exist %1\syslog     rename %1\syslog syslog.log
  39. call %0 cleanit %1\syslog
  40. REM *------------------------------------------------------------------*
  41. REM *                      Clean up old news                           *
  42. REM *------------------------------------------------------------------*
  43. if exist %1\..\active expire
  44. goto exit
  45. REM *------------------------------------------------------------------*
  46. REM *                  Clean up a single log file                      *
  47. REM *------------------------------------------------------------------*
  48. :cleanit
  49. if not exist %2.log goto :exit
  50. echo Cleaning %2.log files.
  51. if exist %2.004    del %2.004
  52. if exist %2.003 rename %2.003 *.004
  53. if exist %2.002 rename %2.002 *.003
  54. if exist %2.001 rename %2.001 *.002
  55. if exist %2.log rename %2.log *.001
  56. goto exit
  57. REM *------------------------------------------------------------------*
  58. REM *                        All done, exit                            *
  59. REM *------------------------------------------------------------------*
  60. :exit
  61.