Beijing Paradise BBS Backup/PARADISE.ISO/software/BBSDOORW/PCLPACK.ZIP/NICE.ZIP/MACS.ZIP/MENTER.CTL

Text File | 1992-09-04 | 5.8 KB | 211 lines

If (%MSGFNET%)=(Y) Then SetEqual(v=Y)
If (%MSGFNET%)=(Y) Then Goto (nonet)
If (%MSGNET%)=(N) Then Goto (nonet)
Say(      &3&Would you like to send this via NetMail? &9&[   ]&14&*)
Back(4)
YesNoAsk(*)
SetEqual(v=%RESP%)

  *nonet
NotIf (%GRAPHICS%)=(ANSI) Then Goto (STMESSG)
SetMode(Line)
Say(&CR&&3& Would you like to use the &11&full-screen&3& editor? &9&[   ]&14&*)
Back(4)
YesNoAsk(*)
If (%RESP%)=(Yes) Then SetMode(full)

  *stmessg
If (%FULL%)=(Yes) Then Goto (fmode)
Say(&CR&&14&You can start typing in your message now.  When you're finished with)
Say(the message, press (&11&ENTER&14&) on a blank line.&CR&&CR&&3&    (--------/---------/---------/---------/---------/---------/---------/----))
NotIf (&k)=(20) Then inittxt
If (&k)=(20) Then setmax(%var%p) ;If editing existing msg, set maxline to max in that msg
If (&k)=(20) Then Goto (stedit)
GetText(15,7,1,99)

  *ent
NotIf (&z)=(15) Then display (display\ENTER)
If (&z)=(15) Then display(display\REPLY)
Say(&3&What would you like to do with the message?&12&: &15&*)
MenuKey
BigNiceSay (t:Throw Away,s:Save,e:Edit,a:Add,L:List,c:Change,m:Modify,d:Delete Line,h:help)
If (&z)=(15) Then bignicesay(q:Quote)
If (&k)=(30) Then BigIf (m:modi,c:modi)
BigIf (t:abort,s:save,e:edit,L:list,a:add,m:mod,d:del,h:help)
NotIf(&z)=(15) Then BigIf(c:chg)  ;If entering a new msg, let them change user to send to
If (&z)=(15) Then BigIf(q:quote)  ;If replying let them quote...
Say(&CR&&12&Invalid selection ... Please try again.&CR&)
FlushOut
Goto (ent)
  *modi
Say(&CR&%hRed%Option not available in Comment.&CR&)
Goto (ent)

  *help
NotIf (&z)=(15) Then display(display\help\enter,/:SEC/)
If (&z)=(15) Then display(display\help\reply,/:SEC/)
Goto (ent)

  *Quote
linefeed(1)
lView(quote.%NODE%,11,3)
cMenuAsk %CRON% (&CR&&3&Enter the first line of the message you want to quote&12&: &15&*)
SetEqual(s=%RESP%)
If (%RESP%)=(<CR>) Then SetEqual(s=1)
cMenuAsk %CRON% (&3&Enter the last line of the message to quote&12&: &15&*)
SetEqual(t=%RESP%)
If (%RESP%)=(<CR>) Then SetEqual(t=%var%s)
Import (quote.%NODE%,=> ,%var%s,%var%t)  ;import text from quote.%NODE% tmp file
Goto (add)
*netImp

  *del
showtxtl(11,3)
cMenuAsk (&CR& &3&Please enter the first line to delete&12&: &15&*)
Number(%RESP%)
IfNotTrue (Goto (invn))
cmpval(%RESP%,%MAXLINE%)
IfNotTrue (NotIf (%RESP%)=(%MAXLINE%) Then Goto (invn))
SetEqual(e=%RESP%)
Say(&CR&&10&If you only want to delete one line, press (&11&ENTER&10&) here.)
cMenuAsk %CRON% (&3&  Please enter the last line to delete&12&: &15&*)
SetEqual(g=%RESP%)
If (&g)=(<CR>) Then SetEqual(g=%var%e)
DelLines(%var%e,%var%g)
If (%ARESP%)=(ERROR) Then Goto (invn)
Say(&CR&&11&Lines %var%e to %var%G have been deleted.)
Goto (ent)

  *chg
Say(&CR&  &3&Who do you want us to send the message to?&12&:&11&(                    )&15&*)
Back(21)
SetFill(%var%a)
cMenuAsk(*)
SetEqual(a=%RESP%)
SeekUser(%RESP%)
SetEqual(c=%NDNUMB%)
SetEqual(d=2)
If (%ARESP%)=(No) Then Goto (notfound)
Goto (ent)

  *mod
Say(&CR&&3&                 What is this message about?&12&:&11&(                    )&15&*)
Back(21)
SetFill(%var%b)
cAsk%LEN20%(*)
SetEqual(b=%RESP%)
Goto (ent)

  *edit
If (%FULL%)=(Yes) Then Goto (add)
cMenuAsk (&CR&&3&Which line would you like to edit?&12&: &15&*)
Number(%RESP%)
IfNotTrue (Goto (invn))
If (%RESP%)=(%MAXLINE%) Then Goto (goedit)
linefeed(1)
cmpval(%RESP%,%MAXLINE%)
If (%ARESP%)=(No) Then Goto (Invn)

  *goedit
SetEqual(h=%MAXLINE%)
gettext(15,7,%RESP%,%RESP%)
setmax(%var%h)
Goto (ent)

  *invn
Say(&14&That line number doesn't exist in this message.  &11&Try again, please.&CR&)
Goto (ent)

  *add
If (%FULL%)=(Yes) Then Goto (fmode)
Say(&CR&&14&You may now continue your message.  Press (&11&ENTER&14&) to end the message.&CR&)
showtxt2(15,7)
gettext(15,7,%MAXLINE%,99)
delextra
Goto (ent)

  *save
SetEqual(x=)
If (&k)=(No) Then Goto (stsave)
If (&v)=(Yes) Then Goto (stsave)
If (&q)=(10) Then Goto (stsave)
Say(&CR&&3&Would you like to attach a file to this message? &9&[   ]&14&*)
Back(4)
YesNoAsk(*)
If (%RESP%)=(No) Then Goto (stsave1)
loadsub(control\EnterAtt.ctl)

  *stsave
InpLine(varr.%NODE%,1)
SetEqual(r=%ARESP%)

  *stsave1
Say(&CR&&11&Saving your message, please wait...*)
if (%Msgfpvt%)=(Y) then setequal(k=Y)
if (&z)=(15) then kill(quote.%node%)
NotIf (&z)=(15) Then writemsg(/:LASTMSG/,%var%a,%NAME%,%var%b,%var%c,%var%k,0,%var%v,%var%x)
If (&z)=(15) Then writemsg(/:LASTMSG/,%var%a,%NAME%,%var%b,%var%c,%var%k,%var%y,%var%v,%var%x)
himsg(/:LASTMSG/)
notif (&z)=(15) then log(--,Message (%ARESP%) entered in area #/:LASTMSG/)
if (&z)=(15) then log (--,Reply (%aresp%) to #%var%y entered in area #/:lastmsg/)
if (&z)=(15) then himsg(/:lastmsg/)
If (&z)=(15) Then SetEqual(f=%ARESP%)
If (&z)=(15) Then lowmsg(/:LASTMSG/)
If (&z)=(15) Then SetEqual(n=%ARESP%)
NotIf (&k)=(20) Then Goto (smsg)
himsg(/:LASTMSG/)
redo (/:LASTMSG/,%var%q,%ARESP%)

  *smsg
Say(Saved!)
Goto (abt)

  *list
linefeed(1)
showtxtl(11,3) ;showtxtL is the same as showtxt except shows line numbers...
linefeed(1)
enter
Goto (ent)

  *abort
Say(&CR&&12&Your message has been thrown away.)

  *abt
inittxt
SetMode(reg)
return

  *notfound
eline(70)
SetEqual(c=0)
Say(Their name couldn't be found.  )
Say(    &3&Would you like to send the message anyway? &9&[   ]&14&*)
Back(4)
YesNoAsk(*)
If (%RESP%)=(No) Then Goto (abt)
Goto (ent)

  *stedit
showtxt2(15,7) ;same as showtxtL except doesnt show last line #...
gettext(15,7,%var%p,99)
Goto (ent)

  *notenufs
display(display\nospce)
Goto (stsave)

  *aborted
SetEqual(x=)
FlushOut
Log(--,Attach upload aborted (%var%x))
Display(display\attabt)
Goto (stsave)

  *alreadyhere
Display (display\HERENOW)
Goto (pok)

  *fmode
LoadSub(control\macros\fulledit.ctl)
Goto (ent)