home *** CD-ROM | disk | FTP | other *** search
/ Beijing Paradise BBS Backup / PARADISE.ISO / software / BBSDOORW / FOXMAIL.ZIP / FOXMAIL.PRG next >
Encoding:
Text File  |  1994-01-26  |  10.3 KB  |  291 lines
  1. *************************************************************
  2. *
  3. * Copyright (C) 1994,   Tom Snell
  4. *                       (408) 475-8667
  5. *                                               860 Pine Tree Lane
  6. *                                               Aptos, CA 95003
  7. *                                               tcs@netcom.com
  8. *
  9. * Not for commercial use.
  10. * You may modify this code for your own use as desired.
  11. * 
  12. * !!! WARNING:  YOU MUST READ THIS FIRST.  THIS WILL NOT RUN 
  13. * WITHOUT FIRST CREATING THE TWO .DBF FILES DESCRIBED BELOW !!!
  14. *
  15. * This has not been broadly tested, especially with other email systems.
  16. * Therefore It would be appreciated that, if others find that they have to make
  17. * changes for it to work in their environments, that they please send me
  18. * well commented code changes.  This should include a discussion of the
  19. * nature of the environment within which the change(s) were made.
  20. * Data samples for such changes would also be important for testing purposes.
  21. * If I get good code correcting common difficulties,
  22. * I will consider making at least one revision in a month or two.
  23. *
  24. * Thanks!  
  25. *
  26. * FOXMAIL.PRG
  27. *
  28. * This .PRG reads in a text file containing email items from
  29. * FOXPRO-L@polarbear.rankin-inlet.nt.ca .  What I do is save 
  30. * all fox email
  31. * messages for a single day in one text file.  If I am using
  32. * the Unix "mail" program, and messages 12 thru 28 were foxPro
  33. * messages I would do something like:
  34. *     &   s 12-28 foxpro.txt
  35. * I then download that file to my PC, in my case, 
  36. *     sz foxpro.txt
  37. *
  38. * Then, run FOXMAIL.PRG.  
  39. *
  40. * Note:  You may have to modify FOXMAIL to fit your needs.  What
  41. * I am giving you is VERY simple with no error checks, no network
  42. * capability, etc.  At the very least you may have to modify the
  43. * code that specifies which files are being USEd.
  44. *
  45. * I have tried to clearly mark the areas that you will want to recode
  46. * for yourselves.  (I'm just too lazy on this little project
  47. * to do the fancy stuff).
  48.  
  49. * FOXMAIL will ask you where the file is that you downloaded from
  50. * your email system.  It then loads the file into a line by line
  51. * dbf file (one field only of 120 characters, so that each line
  52. * of text is one record). 
  53.  
  54. * This is then processed to produce Foxmail.DBF which is where
  55. * all your information is kept.
  56.  
  57.  
  58.  
  59. * Two tables are required for this program, as shown below
  60.  
  61. * FOXMAIL.DBF
  62. * Structure for table:    d:\foxwork\software\dbfs\foxmail.dbf
  63. * Number of data records: 234     
  64. * Date of last update:    01/20/94
  65. * Memo file block size:   64
  66. * Field  Field Name  Type       Width    Dec    Index
  67. *     1  FROM        Character     80            Asc
  68. *     2  REPLY_TO    Character     10            
  69. *     3  REFERENCES  Character     80            Asc
  70. *     4  MESS_ID     Character     80            
  71. *     5  DATE        Character     20            
  72. *     6  SOURCE      Character     10            
  73. *     7  SUBJECT     Character     80            Asc
  74. *     8  X_MAILSERV  Character     10            
  75. *     9  X_ARTICLE   Character      6            
  76. *    10  MESSAGE     Memo          10            
  77. *    11  INPUT_DT    Date           8            
  78. * ** Total **                     395
  79.  
  80. * INDEXES:
  81. * first index tag is called SUBJECT and is coded as follows:
  82. *     IIF(UPPER(subject)="RE:",LTRIM(SUBSTR(subject,5)),subject)
  83. *
  84. * this index is very important because it keeps things organized
  85. * by subject, even if you have "Re: " in front of the subject
  86. * description.
  87.  
  88. * other useful index tags are the following fields:
  89. *     REFERENCES
  90. *     FROM
  91. * with no special coding.
  92.  
  93. * TEST120.DBF
  94. * Structure for table:    d:\foxwork\software\dbfs\text120.dbf
  95. * Number of data records: 740     
  96. * Date of last update:    01/20/94
  97. * Field  Field Name  Type       Width    Dec    Index
  98. *     1  TEXT        Character    120            
  99. * ** Total **                     121
  100. *
  101. ********************************************************************
  102.  
  103.  
  104.  
  105. PRIVATE FIRST_TIME, FILENAME, MY_TEXT, THE_TEXT, M.MESS, REC_FLAG, ;
  106.    MY_SAFETY, DBF_FILE
  107. REC_FLAG = .F.
  108. FIRST_TIME = .T.
  109. M.MESS = ""
  110.  
  111.  
  112. *****************************************************************
  113. * change the DEFAULT and PATH to where you have stored the .DBF files
  114. *****************************************************************
  115.  
  116. SET DEFAULT TO d:\foxwork\software\dbfs
  117. SET PATH TO d:\foxwork\software\dbfs
  118. CLEAR
  119.  
  120.  
  121. MY_SAFETY = SET('SAFETY')
  122. SET SAFETY OFF
  123. SELECT 0
  124. dbf_file = GETFILE('DBF', 'Please select FOXMAIL.DBF')
  125. DO CASE
  126.         CASE EMPTY(dbf_file)
  127.                 RETURN
  128.         OTHERWISE
  129.                 USE (dbf_file) ALIAS FOXMAIL EXCLUSIVE
  130. ENDCASE
  131.  
  132. INDEX ON IIF(UPPER(subject)="RE:",LTRIM(SUBSTR(subject,5)),subject) TAG Subject ADDITIVE
  133. SET ORDER TO
  134.  
  135. SELECT 0
  136. dbf_file = GETFILE('DBF', 'Please select TEXT120.DBF')
  137. DO CASE
  138.         CASE EMPTY(dbf_file)
  139.                 RETURN
  140.         OTHERWISE
  141.                 USE (dbf_file) ALIAS TEXT EXCLUSIVE
  142. ENDCASE
  143. ZAP
  144. SET SAFETY &MY_SAFETY
  145.  
  146.  
  147. FILENAME = LOCFILE('ANYFILE', 'TXT', 'Select email file to import')
  148. APPEND FROM (FILENAME) TYPE SDF
  149.  
  150.  
  151. SET EXACT OFF
  152. SELECT TEXT
  153. GO TOP
  154. DO WHILE .NOT. EOF()
  155.  
  156.    THE_TEXT = ALLTRIM(TEXT)
  157.    MY_TEXT  = UPPER(THE_TEXT)
  158.    
  159.    * throw away all the preliminary header stuff.
  160.    * when you get to the first real 'from:', start
  161.    * a new record in foxmail to hold the data for
  162.    * this email message.
  163.       
  164.    * start storing data in foxmail.
  165. ***   DO WHILE .NOT. EOF() .AND. MY_TEXT != "STATUS:"
  166.       DO CASE
  167.          CASE MY_TEXT = "FROM OWNER-FOXPRO"
  168.          CASE MY_TEXT = "RETURN-PATH:"
  169.          CASE MY_TEXT = "RECEIVED:"
  170.               * received lines may have additional lines after
  171.               * them to discard.  To check for this below, we
  172.               * must flag that a "Received: " line has just been
  173.               * processed.
  174.               REC_FLAG = .T.
  175.          CASE MY_TEXT = "SENDER:"
  176.          CASE MY_TEXT = "TO:"
  177.          CASE MY_TEXT = "STATUS:"
  178.          CASE MY_TEXT = "FROM:"
  179.               IF .NOT. ("NAME: " $ MY_TEXT)
  180.                  IF !FIRST_TIME
  181.                     REPLACE FOXMAIL.MESSAGE WITH M.MESS
  182.                  ELSE
  183.                     FIRST_TIME = .F.
  184.                  ENDIF
  185.                  SELECT FOXMAIL
  186.                  APPEND BLANK
  187.                  M.MESS = ""
  188.                  SELECT TEXT
  189.                  THE_TEXT = RIGHT(THE_TEXT, LEN(THE_TEXT)-6)
  190.                  REPLACE FOXMAIL.FROM WITH ALLTRIM(THE_TEXT), ;
  191.                     FOXMAIL.INPUT_DT WITH DATE()
  192.               ENDIF
  193.          CASE MY_TEXT = "NAME:"
  194.               THE_TEXT = RIGHT(THE_TEXT, LEN(THE_TEXT)-12)
  195.               REPLACE FOXMAIL.REFERENCES WITH ALLTRIM(THE_TEXT)
  196.          CASE MY_TEXT = "REPLY-TO:"
  197.               DO CASE
  198.                  CASE '"The FoxPro (tm) Mailing List"' $ THE_TEXT
  199.                      THE_TEXT = "FML" 
  200.                  OTHERWISE
  201.                      THE_TEXT = "???" 
  202.               ENDCASE
  203.               REPLACE FOXMAIL.REPLY_TO WITH ALLTRIM(THE_TEXT)
  204.          CASE MY_TEXT = "REFERENCES:"
  205.               THE_TEXT = RIGHT(THE_TEXT, LEN(THE_TEXT)-12)
  206.               REPLACE FOXMAIL.REFERENCES WITH ALLTRIM(THE_TEXT)
  207.          CASE MY_TEXT = "MESSAGE-ID:"
  208.               THE_TEXT = RIGHT(THE_TEXT, LEN(THE_TEXT)-12)
  209.               REPLACE FOXMAIL.MESS_ID WITH ALLTRIM(THE_TEXT)
  210.          CASE MY_TEXT = "DATE:"
  211.               THE_TEXT = RIGHT(THE_TEXT, LEN(THE_TEXT)-6)
  212.               THE_TEXT = LEFT(THE_TEXT, AT(':',THE_TEXT)-3)
  213.               REPLACE FOXMAIL.DATE WITH ALLTRIM(THE_TEXT)
  214.          CASE MY_TEXT = "ORGANIZATION:"
  215.               DO CASE
  216.                  CASE 'Polar Bear Heaven BBS' $ THE_TEXT
  217.                      THE_TEXT = "PBH" 
  218.                  OTHERWISE
  219.                      THE_TEXT = "???" 
  220.               ENDCASE
  221.               REPLACE FOXMAIL.SOURCE WITH ALLTRIM(THE_TEXT)
  222.          CASE MY_TEXT = "SUBJECT:"
  223.               THE_TEXT = ALLTRIM(RIGHT(THE_TEXT, LEN(THE_TEXT)-9))
  224.               * get rid of any extra RE:s in this line - 
  225.               * leave only one, if one exists.  For sorting
  226.               * purposes to keep subject messages together.
  227.               DO WHILE ATC("RE:", THE_TEXT, 2) > 0
  228.                  THE_TEXT = ALLTRIM(RIGHT(THE_TEXT, LEN(THE_TEXT)-3))
  229.               ENDDO
  230.               REPLACE FOXMAIL.SUBJECT WITH ALLTRIM(THE_TEXT)
  231.          CASE MY_TEXT = "X-MAILSERVER:"
  232.               DO CASE
  233.                  CASE 'Waffle File Server' $ THE_TEXT
  234.                      THE_TEXT = "WFS" 
  235.                  OTHERWISE
  236.                      THE_TEXT = "???" 
  237.               ENDCASE
  238.               REPLACE FOXMAIL.X_MAILSERV WITH ALLTRIM(THE_TEXT)
  239.          CASE MY_TEXT = "X-ARTICLE:"
  240.               THE_TEXT = RIGHT(THE_TEXT, LEN(THE_TEXT)-11)
  241.               REPLACE FOXMAIL.X_ARTICLE WITH ALLTRIM(THE_TEXT)
  242.          OTHERWISE
  243.               * "Received" lines sometimes have additional lines
  244.               * after them that should not appear in the output
  245.               * text.  This checks for those lines and by passes
  246.               * them.  They all start with either a tab or a space
  247.               * and come immediately after a "Received:".
  248.               IF REC_FLAG .AND. (LEFT(TEXT, 1) = " " ;
  249.                         .OR. LEFT(TEXT, 1) = CHR(9))
  250.                  REC_FLAG = .F.
  251.                  * check for a possible second line.
  252.                  SKIP
  253.                  IF !(LEFT(TEXT, 1) = " " ;
  254.                         .OR. LEFT(TEXT, 1) = CHR(9))
  255.                     SKIP -1     && no 2nd line, go back one.
  256.                  ENDIF
  257.               ELSE
  258.                  * now process the message itself
  259.                  M.MESS = M.MESS + THE_TEXT + CHR(13) + CHR(10)
  260.               ENDIF
  261.       ENDCASE
  262.       SKIP
  263. ENDDO
  264.  
  265. * don't forget to catch the last message!
  266. SKIP -1
  267. REPLACE FOXMAIL.MESSAGE WITH M.MESS
  268.  
  269.  
  270.  
  271. WAIT WINDOW 'scan the most recent items at the bottom of the file.'
  272. SELECT FOXMAIL
  273. SET ORDER TO 
  274. BROWSE LAST
  275.  
  276. WAIT WINDOW 'look at the list in SUBJECT index order.'
  277. SELECT FOXMAIL
  278. SET ORDER TO TAG SUBJECT
  279. BROWSE LAST
  280.  
  281. ***************************************************************************
  282. * you may want to change this so that your file stays open.
  283. ***************************************************************************
  284. * SELECT FOXMAIL
  285. * USE
  286. * SELECT TEXT
  287. * USE
  288.  
  289. RETURN
  290.  
  291.