home *** CD-ROM | disk | FTP | other *** search
/ MACD 7 / MACD7.iso / datatypes / akpng-datatype / install < prev   
Encoding:
Text File  |  1998-01-12  |  3.8 KB  |  117 lines
  1. ;$VER: akPNG_Installer 43.100 (16.10.1997) #DOS © Msi Software
  2.  
  3. FAILAT 21
  4.  
  5. ;Check OS version!
  6. c/akT OS 39
  7. IF WARN
  8.    ECHO "You need OS 3.0 or later!"
  9.    ASK "Press return!"
  10.    QUIT
  11. ENDIF
  12.  
  13. ;Display old and new dt version etc!
  14. c/akT >ENV:akver VER classes/Datatypes/akPNG.datatype
  15. c/akT >ENV:akverold VER Sys:Classes/Datatypes/akPNG.datatype
  16. IF NOT WARN
  17.    C:RequestChoice >NIL: "Andreas Ralph Kleinert presents:" "$akver" "Install/Update"
  18. ELSE
  19.    C:RequestChoice >NIL: "Andreas Ralph Kleinert presents:" "$akver*N(old: $akverold)" "Install/Update"
  20. ENDIF
  21. UNSETENV akver
  22. UNSETENV akverold
  23.  
  24. ;Create dt prefs drawer if not found!
  25. IF NOT EXISTS SYS:Prefs/DataTypes
  26.    C:Makedir >NIL: SYS:Prefs/DataTypes
  27.    C:Copy >NIL: prefs/datatypes.info SYS:Prefs/DataTypes.info CLONE
  28. ENDIF
  29.  
  30. ;Move any dtprefs to sys:prefs/datatypes!
  31. IF EXISTS sys:prefs/akPNGprefs
  32.    C:Rename >NIL: sys:prefs/akPNGprefs#? sys:prefs/datatypes
  33. ENDIF
  34.  
  35. ;Create ENV:Datatypes if not found!
  36. IF NOT EXISTS ENV:Datatypes
  37.    C:Makedir >NIL: ENV:Datatypes ENVARC:Datatypes
  38. ENDIF
  39.  
  40. ;Install dtprefs if not found or current one is old!
  41. c/akT CHK prefs/datatypes/akPNGPrefs SYS:prefs/datatypes/akPNGPrefs
  42. IF WARN
  43.    C:Copy >NIL: prefs/datatypes/akPNGPrefs SYS:prefs/datatypes CLONE
  44.    IF NOT EXISTS sys:prefs/datatypes/akPNGPrefs.info
  45.       C:Copy >NIL: prefs/datatypes/akPNGPrefs.info SYS:prefs/datatypes CLONE
  46.    ENDIF
  47. ENDIF
  48.  
  49. ;Install gui if not found or current one is old!
  50. c/akT CHK prefs/datatypes/akPNGPrefs_gui.wizard SYS:prefs/datatypes/akPNGPrefs_gui.wizard
  51. IF WARN
  52.    C:Copy >NIL: prefs/datatypes/akPNGPrefs_gui.wizard SYS:prefs/datatypes CLONE
  53. ENDIF
  54.  
  55. ;Install correct dt!
  56. c/akT CHK classes/datatypes/akPNG.datatype SYS:classes/datatypes/akPNG.datatype
  57. IF WARN
  58.    c/akT CPU 060
  59.    IF NOT WARN
  60.       C:Copy >NIL: classes/datatypes/akPNG.datatype.060 SYS:Classes/datatypes/akPNG.datatype CLONE
  61.    ELSE
  62.       c/akT CPU 040
  63.       IF NOT WARN
  64.          C:Copy >NIL: classes/datatypes/akPNG.datatype.040 SYS:Classes/datatypes/akPNG.datatype CLONE
  65.       ELSE
  66.          c/akT CPU 030
  67.          IF NOT WARN
  68.             C:Copy >NIL: classes/datatypes/akPNG.datatype.030 SYS:Classes/datatypes/akPNG.datatype CLONE
  69.          ELSE
  70.             c/akT CPU 020
  71.             IF NOT WARN
  72.                C:Copy >NIL: classes/datatypes/akPNG.datatype.030 SYS:Classes/datatypes/akPNG.datatype CLONE
  73.             ELSE
  74.                C:Copy >NIL: classes/datatypes/akPNG.datatype SYS:Classes/datatypes/akPNG.datatype CLONE
  75.             ENDIF
  76.          ENDIF
  77.       ENDIF
  78.    ENDIF
  79.  
  80.    ;Move any old dt headers to storage!
  81.    Rename >NIL: SYS:Devs/Datatypes/#?PNG SYS:Storage/Datatypes/
  82.  
  83.    ;Install new dt header!
  84.    C:Copy >NIL: devs/datatypes/PNG DEVS:DataTypes
  85.    IF NOT EXISTS DEVS:DataTypes/PNG.info
  86.       C:Copy >NIL: devs/datatypes/PNG.info DEVS:DataTypes
  87.    ENDIF
  88.  
  89.    ;If VMEM assign not found, assign it and add to user-startup!
  90.    c/akT ASN vmem
  91.    IF WARN
  92.       C:RequestChoice >NIL: "ak Installer" "The VMEM: assign was not found!*NIt is needed by this datatype,*Nto be used as temporary directory." "Assign"
  93.       C:RequestFile >ENV:akvmem "SYS:" TITLE="Please select temporary dir:" SAVEMODE DRAWERSONLY NOICONS
  94.       ECHO >>S:User-Startup "*N;BEGIN VMEM"
  95.       ECHO >>S:User-Startup "Assign >NIL: VMEM: $akvmem"
  96.       ECHO >>S:User-Startup ";END VMEM"
  97.       C:Assign >NIL: VMEM: $akvmem
  98.       UNSETENV akvmem
  99.    ENDIF
  100.  
  101.    ;Change dir to docs!
  102.    CD Docs
  103.  
  104.    ;Show guide and start dtprefs!
  105.    Run >NIL: MultiView akPNG.guide
  106.    Run >NIL: /Prefs/DataTypes/akPNGPrefs
  107.  
  108.    ;Install completed message!
  109.    C:RequestChoice >NIL: "ak Installer" "Install completed!*NPlease reboot the system,*Nto use the new datatype!" "Ok"
  110. ELSE
  111.    ;Install not needed message!
  112.    C:RequestChoice >NIL: "ak Installer" "Install not needed!*NYou have the same or a higher version!" "Ok"
  113. ENDIF
  114.  
  115. ;Clean up memory/free resources!
  116. C:Avail >NIL: FLUSH
  117.