home *** CD-ROM | disk | FTP | other *** search
/ CD Actual Thematic 7: Programming / CDAT7.iso / Share / Editores / Perl5 / perl / lib / Pod / perlre.pod < prev    next >
Encoding:
Text File  |  1997-08-10  |  23.5 KB  |  584 lines

  1. =head1 NAME
  2.  
  3. perlre - Perl regular expressions
  4.  
  5. =head1 DESCRIPTION
  6.  
  7. This page describes the syntax of regular expressions in Perl.  For a
  8. description of how to I<use> regular expressions in matching
  9. operations, plus various examples of the same, see C<m//> and C<s///> in
  10. L<perlop>.
  11.  
  12. The matching operations can have various modifiers.  The modifiers
  13. which relate to the interpretation of the regular expression inside
  14. are listed below.  For the modifiers that alter the behaviour of the
  15. operation, see L<perlop/"m//"> and L<perlop/"s//">.
  16.  
  17. =over 4
  18.  
  19. =item i
  20.  
  21. Do case-insensitive pattern matching.
  22.  
  23. If C<use locale> is in effect, the case map is taken from the current
  24. locale.  See L<perllocale>.
  25.  
  26. =item m
  27.  
  28. Treat string as multiple lines.  That is, change "^" and "$" from matching
  29. at only the very start or end of the string to the start or end of any
  30. line anywhere within the string,
  31.  
  32. =item s
  33.  
  34. Treat string as single line.  That is, change "." to match any character
  35. whatsoever, even a newline, which it normally would not match.
  36.  
  37. =item x
  38.  
  39. Extend your pattern's legibility by permitting whitespace and comments.
  40.  
  41. =back
  42.  
  43. These are usually written as "the C</x> modifier", even though the delimiter
  44. in question might not actually be a slash.  In fact, any of these
  45. modifiers may also be embedded within the regular expression itself using
  46. the new C<(?...)> construct.  See below.
  47.  
  48. The C</x> modifier itself needs a little more explanation.  It tells
  49. the regular expression parser to ignore whitespace that is neither
  50. backslashed nor within a character class.  You can use this to break up
  51. your regular expression into (slightly) more readable parts.  The C<#>
  52. character is also treated as a metacharacter introducing a comment,
  53. just as in ordinary Perl code.  This also means that if you want real
  54. whitespace or C<#> characters in the pattern that you'll have to either
  55. escape them or encode them using octal or hex escapes.  Taken together,
  56. these features go a long way towards making Perl's regular expressions
  57. more readable.  See the C comment deletion code in L<perlop>.
  58.  
  59. =head2 Regular Expressions
  60.  
  61. The patterns used in pattern matching are regular expressions such as
  62. those supplied in the Version 8 regexp routines.  (In fact, the
  63. routines are derived (distantly) from Henry Spencer's freely
  64. redistributable reimplementation of the V8 routines.)
  65. See L<Version 8 Regular Expressions> for details.
  66.  
  67. In particular the following metacharacters have their standard I<egrep>-ish
  68. meanings:
  69.  
  70.     \    Quote the next metacharacter
  71.     ^    Match the beginning of the line
  72.     .    Match any character (except newline)
  73.     $    Match the end of the line (or before newline at the end)
  74.     |    Alternation
  75.     ()    Grouping
  76.     []    Character class
  77.  
  78. By default, the "^" character is guaranteed to match at only the
  79. beginning of the string, the "$" character at only the end (or before the
  80. newline at the end) and Perl does certain optimizations with the
  81. assumption that the string contains only one line.  Embedded newlines
  82. will not be matched by "^" or "$".  You may, however, wish to treat a
  83. string as a multi-line buffer, such that the "^" will match after any
  84. newline within the string, and "$" will match before any newline.  At the
  85. cost of a little more overhead, you can do this by using the /m modifier
  86. on the pattern match operator.  (Older programs did this by setting C<$*>,
  87. but this practice is now deprecated.)
  88.  
  89. To facilitate multi-line substitutions, the "." character never matches a
  90. newline unless you use the C</s> modifier, which in effect tells Perl to pretend
  91. the string is a single line--even if it isn't.  The C</s> modifier also
  92. overrides the setting of C<$*>, in case you have some (badly behaved) older
  93. code that sets it in another module.
  94.  
  95. The following standard quantifiers are recognized:
  96.  
  97.     *       Match 0 or more times
  98.     +       Match 1 or more times
  99.     ?       Match 1 or 0 times
  100.     {n}    Match exactly n times
  101.     {n,}   Match at least n times
  102.     {n,m}  Match at least n but not more than m times
  103.  
  104. (If a curly bracket occurs in any other context, it is treated
  105. as a regular character.)  The "*" modifier is equivalent to C<{0,}>, the "+"
  106. modifier to C<{1,}>, and the "?" modifier to C<{0,1}>.  n and m are limited
  107. to integral values less than 65536.
  108.  
  109. By default, a quantified subpattern is "greedy", that is, it will match as
  110. many times as possible (given a particular starting location) while still
  111. allowing the rest of the pattern to match.  If you want it to match the
  112. minimum number of times possible, follow the quantifier with a "?".  Note
  113. that the meanings don't change, just the "greediness":
  114.  
  115.     *?       Match 0 or more times
  116.     +?       Match 1 or more times
  117.     ??       Match 0 or 1 time
  118.     {n}?   Match exactly n times
  119.     {n,}?  Match at least n times
  120.     {n,m}? Match at least n but not more than m times
  121.  
  122. Because patterns are processed as double quoted strings, the following
  123. also work:
  124.  
  125.     \t        tab                   (HT, TAB)
  126.     \n        newline               (LF, NL)
  127.     \r        return                (CR)
  128.     \f        form feed             (FF)
  129.     \a        alarm (bell)          (BEL)
  130.     \e        escape (think troff)  (ESC)
  131.     \033    octal char (think of a PDP-11)
  132.     \x1B    hex char
  133.     \c[        control char
  134.     \l        lowercase next char (think vi)
  135.     \u        uppercase next char (think vi)
  136.     \L        lowercase till \E (think vi)
  137.     \U        uppercase till \E (think vi)
  138.     \E        end case modification (think vi)
  139.     \Q        quote regexp metacharacters till \E
  140.  
  141. If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
  142. and <\U> is taken from the current locale.  See L<perllocale>.
  143.  
  144. In addition, Perl defines the following:
  145.  
  146.     \w    Match a "word" character (alphanumeric plus "_")
  147.     \W    Match a non-word character
  148.     \s    Match a whitespace character
  149.     \S    Match a non-whitespace character
  150.     \d    Match a digit character
  151.     \D    Match a non-digit character
  152.  
  153. Note that C<\w> matches a single alphanumeric character, not a whole
  154. word.  To match a word you'd need to say C<\w+>.  If C<use locale> is in
  155. effect, the list of alphabetic characters generated by C<\w> is taken
  156. from the current locale.  See L<perllocale>. You may use C<\w>, C<\W>,
  157. C<\s>, C<\S>, C<\d>, and C<\D> within character classes (though not as
  158. either end of a range).
  159.  
  160. Perl defines the following zero-width assertions:
  161.  
  162.     \b    Match a word boundary
  163.     \B    Match a non-(word boundary)
  164.     \A    Match at only beginning of string
  165.     \Z    Match at only end of string (or before newline at the end)
  166.     \G    Match only where previous m//g left off (works only with /g)
  167.  
  168. A word boundary (C<\b>) is defined as a spot between two characters that
  169. has a C<\w> on one side of it and a C<\W> on the other side of it (in
  170. either order), counting the imaginary characters off the beginning and
  171. end of the string as matching a C<\W>.  (Within character classes C<\b>
  172. represents backspace rather than a word boundary.)  The C<\A> and C<\Z> are
  173. just like "^" and "$" except that they won't match multiple times when the
  174. C</m> modifier is used, while "^" and "$" will match at every internal line
  175. boundary.  To match the actual end of the string, not ignoring newline,
  176. you can use C<\Z(?!\n)>.  The C<\G> assertion can be used to chain global
  177. matches (using C<m//g>), as described in
  178. L<perlop/"Regexp Quote-Like Operators">.
  179.  
  180. It is also useful when writing C<lex>-like scanners, when you have several
  181. regexps which you want to match against consequent substrings of your
  182. string, see the previous reference.
  183. The actual location where C<\G> will match can also be influenced
  184. by using C<pos()> as an lvalue.  See L<perlfunc/pos>.
  185.  
  186. When the bracketing construct C<( ... )> is used, \E<lt>digitE<gt> matches the
  187. digit'th substring.  Outside of the pattern, always use "$" instead of "\"
  188. in front of the digit.  (While the \E<lt>digitE<gt> notation can on rare occasion work
  189. outside the current pattern, this should not be relied upon.  See the
  190. WARNING below.) The scope of $E<lt>digitE<gt> (and C<$`>, C<$&>, and C<$'>)
  191. extends to the end of the enclosing BLOCK or eval string, or to the next
  192. successful pattern match, whichever comes first.  If you want to use
  193. parentheses to delimit a subpattern (e.g., a set of alternatives) without
  194. saving it as a subpattern, follow the ( with a ?:.
  195.  
  196. You may have as many parentheses as you wish.  If you have more
  197. than 9 substrings, the variables $10, $11, ... refer to the
  198. corresponding substring.  Within the pattern, \10, \11, etc. refer back
  199. to substrings if there have been at least that many left parentheses before
  200. the backreference.  Otherwise (for backward compatibility) \10 is the
  201. same as \010, a backspace, and \11 the same as \011, a tab.  And so
  202. on.  (\1 through \9 are always backreferences.)
  203.  
  204. C<$+> returns whatever the last bracket match matched.  C<$&> returns the
  205. entire matched string.  (C<$0> used to return the same thing, but not any
  206. more.)  C<$`> returns everything before the matched string.  C<$'> returns
  207. everything after the matched string.  Examples:
  208.  
  209.     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
  210.  
  211.     if (/Time: (..):(..):(..)/) {
  212.     $hours = $1;
  213.     $minutes = $2;
  214.     $seconds = $3;
  215.     }
  216.  
  217. Once perl sees that you need one of C<$&>, C<$`> or C<$'> anywhere in
  218. the program, it has to provide them on each and every pattern match.
  219. This can slow your program down.  The same mechanism that handles
  220. these provides for the use of $1, $2, etc., so you pay the same price
  221. for each regexp that contains capturing parentheses. But if you never
  222. use $&, etc., in your script, then regexps I<without> capturing
  223. parentheses won't be penalized. So avoid $&, $', and $` if you can,
  224. but if you can't (and some algorithms really appreciate them), once
  225. you've used them once, use them at will, because you've already paid
  226. the price.
  227.  
  228. You will note that all backslashed metacharacters in Perl are
  229. alphanumeric, such as C<\b>, C<\w>, C<\n>.  Unlike some other regular expression
  230. languages, there are no backslashed symbols that aren't alphanumeric.
  231. So anything that looks like \\, \(, \), \E<lt>, \E<gt>, \{, or \} is always
  232. interpreted as a literal character, not a metacharacter.  This makes it
  233. simple to quote a string that you want to use for a pattern but that
  234. you are afraid might contain metacharacters.  Quote simply all the
  235. non-alphanumeric characters:
  236.  
  237.     $pattern =~ s/(\W)/\\$1/g;
  238.  
  239. You can also use the builtin quotemeta() function to do this.
  240. An even easier way to quote metacharacters right in the match operator
  241. is to say
  242.  
  243.     /$unquoted\Q$quoted\E$unquoted/
  244.  
  245. Perl defines a consistent extension syntax for regular expressions.
  246. The syntax is a pair of parentheses with a question mark as the first
  247. thing within the parentheses (this was a syntax error in older
  248. versions of Perl).  The character after the question mark gives the
  249. function of the extension.  Several extensions are already supported:
  250.  
  251. =over 10
  252.  
  253. =item (?#text)
  254.  
  255. A comment.  The text is ignored.  If the C</x> switch is used to enable
  256. whitespace formatting, a simple C<#> will suffice.
  257.  
  258. =item (?:regexp)
  259.  
  260. This groups things like "()" but doesn't make backreferences like "()" does.  So
  261.  
  262.     split(/\b(?:a|b|c)\b/)
  263.  
  264. is like
  265.  
  266.     split(/\b(a|b|c)\b/)
  267.  
  268. but doesn't spit out extra fields.
  269.  
  270. =item (?=regexp)
  271.  
  272. A zero-width positive lookahead assertion.  For example, C</\w+(?=\t)/>
  273. matches a word followed by a tab, without including the tab in C<$&>.
  274.  
  275. =item (?!regexp)
  276.  
  277. A zero-width negative lookahead assertion.  For example C</foo(?!bar)/>
  278. matches any occurrence of "foo" that isn't followed by "bar".  Note
  279. however that lookahead and lookbehind are NOT the same thing.  You cannot
  280. use this for lookbehind: C</(?!foo)bar/> will not find an occurrence of
  281. "bar" that is preceded by something which is not "foo".  That's because
  282. the C<(?!foo)> is just saying that the next thing cannot be "foo"--and
  283. it's not, it's a "bar", so "foobar" will match.  You would have to do
  284. something like C</(?!foo)...bar/> for that.   We say "like" because there's
  285. the case of your "bar" not having three characters before it.  You could
  286. cover that this way: C</(?:(?!foo)...|^..?)bar/>.  Sometimes it's still
  287. easier just to say:
  288.  
  289.     if (/foo/ && $` =~ /bar$/)
  290.  
  291.  
  292. =item (?imsx)
  293.  
  294. One or more embedded pattern-match modifiers.  This is particularly
  295. useful for patterns that are specified in a table somewhere, some of
  296. which want to be case sensitive, and some of which don't.  The case
  297. insensitive ones need to include merely C<(?i)> at the front of the
  298. pattern.  For example:
  299.  
  300.     $pattern = "foobar";
  301.     if ( /$pattern/i )
  302.  
  303.     # more flexible:
  304.  
  305.     $pattern = "(?i)foobar";
  306.     if ( /$pattern/ )
  307.  
  308. =back
  309.  
  310. The specific choice of question mark for this and the new minimal
  311. matching construct was because 1) question mark is pretty rare in older
  312. regular expressions, and 2) whenever you see one, you should stop
  313. and "question" exactly what is going on.  That's psychology...
  314.  
  315. =head2 Backtracking
  316.  
  317. A fundamental feature of regular expression matching involves the notion
  318. called I<backtracking>.  which is used (when needed) by all regular
  319. expression quantifiers, namely C<*>, C<*?>, C<+>, C<+?>, C<{n,m}>, and
  320. C<{n,m}?>.
  321.  
  322. For a regular expression to match, the I<entire> regular expression must
  323. match, not just part of it.  So if the beginning of a pattern containing a
  324. quantifier succeeds in a way that causes later parts in the pattern to
  325. fail, the matching engine backs up and recalculates the beginning
  326. part--that's why it's called backtracking.
  327.  
  328. Here is an example of backtracking:  Let's say you want to find the
  329. word following "foo" in the string "Food is on the foo table.":
  330.  
  331.     $_ = "Food is on the foo table.";
  332.     if ( /\b(foo)\s+(\w+)/i ) {
  333.     print "$2 follows $1.\n";
  334.     }
  335.  
  336. When the match runs, the first part of the regular expression (C<\b(foo)>)
  337. finds a possible match right at the beginning of the string, and loads up
  338. $1 with "Foo".  However, as soon as the matching engine sees that there's
  339. no whitespace following the "Foo" that it had saved in $1, it realizes its
  340. mistake and starts over again one character after where it had the
  341. tentative match.  This time it goes all the way until the next occurrence
  342. of "foo". The complete regular expression matches this time, and you get
  343. the expected output of "table follows foo."
  344.  
  345. Sometimes minimal matching can help a lot.  Imagine you'd like to match
  346. everything between "foo" and "bar".  Initially, you write something
  347. like this:
  348.  
  349.     $_ =  "The food is under the bar in the barn.";
  350.     if ( /foo(.*)bar/ ) {
  351.     print "got <$1>\n";
  352.     }
  353.  
  354. Which perhaps unexpectedly yields:
  355.  
  356.   got <d is under the bar in the >
  357.  
  358. That's because C<.*> was greedy, so you get everything between the
  359. I<first> "foo" and the I<last> "bar".  In this case, it's more effective
  360. to use minimal matching to make sure you get the text between a "foo"
  361. and the first "bar" thereafter.
  362.  
  363.     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
  364.   got <d is under the >
  365.  
  366. Here's another example: let's say you'd like to match a number at the end
  367. of a string, and you also want to keep the preceding part the match.
  368. So you write this:
  369.  
  370.     $_ = "I have 2 numbers: 53147";
  371.     if ( /(.*)(\d*)/ ) {                # Wrong!
  372.     print "Beginning is <$1>, number is <$2>.\n";
  373.     }
  374.  
  375. That won't work at all, because C<.*> was greedy and gobbled up the
  376. whole string. As C<\d*> can match on an empty string the complete
  377. regular expression matched successfully.
  378.  
  379.     Beginning is <I have 2 numbers: 53147>, number is <>.
  380.  
  381. Here are some variants, most of which don't work:
  382.  
  383.     $_ = "I have 2 numbers: 53147";
  384.     @pats = qw{
  385.     (.*)(\d*)
  386.     (.*)(\d+)
  387.     (.*?)(\d*)
  388.     (.*?)(\d+)
  389.     (.*)(\d+)$
  390.     (.*?)(\d+)$
  391.     (.*)\b(\d+)$
  392.     (.*\D)(\d+)$
  393.     };
  394.  
  395.     for $pat (@pats) {
  396.     printf "%-12s ", $pat;
  397.     if ( /$pat/ ) {
  398.         print "<$1> <$2>\n";
  399.     } else {
  400.         print "FAIL\n";
  401.     }
  402.     }
  403.  
  404. That will print out:
  405.  
  406.     (.*)(\d*)    <I have 2 numbers: 53147> <>
  407.     (.*)(\d+)    <I have 2 numbers: 5314> <7>
  408.     (.*?)(\d*)   <> <>
  409.     (.*?)(\d+)   <I have > <2>
  410.     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
  411.     (.*?)(\d+)$  <I have 2 numbers: > <53147>
  412.     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
  413.     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
  414.  
  415. As you see, this can be a bit tricky.  It's important to realize that a
  416. regular expression is merely a set of assertions that gives a definition
  417. of success.  There may be 0, 1, or several different ways that the
  418. definition might succeed against a particular string.  And if there are
  419. multiple ways it might succeed, you need to understand backtracking to know which variety of success you will achieve.
  420.  
  421. When using lookahead assertions and negations, this can all get even
  422. tricker.  Imagine you'd like to find a sequence of non-digits not
  423. followed by "123".  You might try to write that as
  424.  
  425.     $_ = "ABC123";
  426.     if ( /^\D*(?!123)/ ) {                # Wrong!
  427.         print "Yup, no 123 in $_\n";
  428.     }
  429.  
  430. But that isn't going to match; at least, not the way you're hoping.  It
  431. claims that there is no 123 in the string.  Here's a clearer picture of
  432. why it that pattern matches, contrary to popular expectations:
  433.  
  434.     $x = 'ABC123' ;
  435.     $y = 'ABC445' ;
  436.  
  437.     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/ ;
  438.     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/ ;
  439.  
  440.     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/ ;
  441.     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/ ;
  442.  
  443. This prints
  444.  
  445.     2: got ABC
  446.     3: got AB
  447.     4: got ABC
  448.  
  449. You might have expected test 3 to fail because it seems to a more
  450. general purpose version of test 1.  The important difference between
  451. them is that test 3 contains a quantifier (C<\D*>) and so can use
  452. backtracking, whereas test 1 will not.  What's happening is
  453. that you've asked "Is it true that at the start of $x, following 0 or more
  454. non-digits, you have something that's not 123?"  If the pattern matcher had
  455. let C<\D*> expand to "ABC", this would have caused the whole pattern to
  456. fail.
  457. The search engine will initially match C<\D*> with "ABC".  Then it will
  458. try to match C<(?!123> with "123" which, of course, fails.  But because
  459. a quantifier (C<\D*>) has been used in the regular expression, the
  460. search engine can backtrack and retry the match differently
  461. in the hope of matching the complete regular expression.
  462.  
  463. Well now,
  464. the pattern really, I<really> wants to succeed, so it uses the
  465. standard regexp back-off-and-retry and lets C<\D*> expand to just "AB" this
  466. time.  Now there's indeed something following "AB" that is not
  467. "123".  It's in fact "C123", which suffices.
  468.  
  469. We can deal with this by using both an assertion and a negation.  We'll
  470. say that the first part in $1 must be followed by a digit, and in fact, it
  471. must also be followed by something that's not "123".  Remember that the
  472. lookaheads are zero-width expressions--they only look, but don't consume
  473. any of the string in their match.  So rewriting this way produces what
  474. you'd expect; that is, case 5 will fail, but case 6 succeeds:
  475.  
  476.     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/ ;
  477.     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/ ;
  478.  
  479.     6: got ABC
  480.  
  481. In other words, the two zero-width assertions next to each other work like
  482. they're ANDed together, just as you'd use any builtin assertions:  C</^$/>
  483. matches only if you're at the beginning of the line AND the end of the
  484. line simultaneously.  The deeper underlying truth is that juxtaposition in
  485. regular expressions always means AND, except when you write an explicit OR
  486. using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
  487. although the attempted matches are made at different positions because "a"
  488. is not a zero-width assertion, but a one-width assertion.
  489.  
  490. One warning: particularly complicated regular expressions can take
  491. exponential time to solve due to the immense number of possible ways they
  492. can use backtracking to try match.  For example this will take a very long
  493. time to run
  494.  
  495.     /((a{0,5}){0,5}){0,5}/
  496.  
  497. And if you used C<*>'s instead of limiting it to 0 through 5 matches, then
  498. it would take literally forever--or until you ran out of stack space.
  499.  
  500. =head2 Version 8 Regular Expressions
  501.  
  502. In case you're not familiar with the "regular" Version 8 regexp
  503. routines, here are the pattern-matching rules not described above.
  504.  
  505. Any single character matches itself, unless it is a I<metacharacter>
  506. with a special meaning described here or above.  You can cause
  507. characters which normally function as metacharacters to be interpreted
  508. literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
  509. character; "\\" matches a "\").  A series of characters matches that
  510. series of characters in the target string, so the pattern C<blurfl>
  511. would match "blurfl" in the target string.
  512.  
  513. You can specify a character class, by enclosing a list of characters
  514. in C<[]>, which will match any one of the characters in the list.  If the
  515. first character after the "[" is "^", the class matches any character not
  516. in the list.  Within a list, the "-" character is used to specify a
  517. range, so that C<a-z> represents all the characters between "a" and "z",
  518. inclusive.  If you want "-" itself to be a member of a class, put it
  519. at the start or end of the list, or escape it with a backslash.  (The
  520. following all specify the same class of three characters: C<[-az]>,
  521. C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
  522. specifies a class containing twenty-six characters.)
  523.  
  524. Characters may be specified using a metacharacter syntax much like that
  525. used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
  526. "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
  527. of octal digits, matches the character whose ASCII value is I<nnn>.
  528. Similarly, \xI<nn>, where I<nn> are hexadecimal digits, matches the
  529. character whose ASCII value is I<nn>. The expression \cI<x> matches the
  530. ASCII character control-I<x>.  Finally, the "." metacharacter matches any
  531. character except "\n" (unless you use C</s>).
  532.  
  533. You can specify a series of alternatives for a pattern using "|" to
  534. separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
  535. or "foe" in the target string (as would C<f(e|i|o)e>).  Note that the
  536. first alternative includes everything from the last pattern delimiter
  537. ("(", "[", or the beginning of the pattern) up to the first "|", and
  538. the last alternative contains everything from the last "|" to the next
  539. pattern delimiter.  For this reason, it's common practice to include
  540. alternatives in parentheses, to minimize confusion about where they
  541. start and end.  Note however that "|" is interpreted as a literal with
  542. square brackets, so if you write C<[fee|fie|foe]> you're really only
  543. matching C<[feio|]>.
  544.  
  545. Within a pattern, you may designate subpatterns for later reference by
  546. enclosing them in parentheses, and you may refer back to the I<n>th
  547. subpattern later in the pattern using the metacharacter \I<n>.
  548. Subpatterns are numbered based on the left to right order of their
  549. opening parenthesis.  Note that a backreference matches whatever
  550. actually matched the subpattern in the string being examined, not the
  551. rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
  552. match "0x1234 0x4321",but not "0x1234 01234", because subpattern 1
  553. actually matched "0x", even though the rule C<0|0x> could
  554. potentially match the leading 0 in the second number.
  555.  
  556. =head2 WARNING on \1 vs $1
  557.  
  558. Some people get too used to writing things like
  559.  
  560.     $pattern =~ s/(\W)/\\\1/g;
  561.  
  562. This is grandfathered for the RHS of a substitute to avoid shocking the
  563. B<sed> addicts, but it's a dirty habit to get into.  That's because in
  564. PerlThink, the righthand side of a C<s///> is a double-quoted string.  C<\1> in
  565. the usual double-quoted string means a control-A.  The customary Unix
  566. meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
  567. of doing that, you get yourself into trouble if you then add an C</e>
  568. modifier.
  569.  
  570.     s/(\d+)/ \1 + 1 /eg;
  571.  
  572. Or if you try to do
  573.  
  574.     s/(\d+)/\1000/;
  575.  
  576. You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
  577. C<${1}000>.  Basically, the operation of interpolation should not be confused
  578. with the operation of matching a backreference.  Certainly they mean two
  579. different things on the I<left> side of the C<s///>.
  580.  
  581. =head2 SEE ALSO
  582.  
  583. "Mastering Regular Expressions" (see L<perlbook>) by Jeffrey Friedl.
  584.