home *** CD-ROM | disk | FTP | other *** search
/ CD Actual 15 / CDACTUAL15.iso / cdactual / program / asm / LTOA.ZIP / LTOA.ASM
Encoding:
Assembly Source File  |  1987-12-15  |  3.4 KB  |  104 lines
  1.         name    ltoa
  2.         title   LTOA - long integer to ASCII
  3.         page    55,132
  4.  
  5. ;
  6. ; LTOA.ASM --- Convert long integer to ASCII
  7. ;
  8. ; Copyright (c) 1987 Ziff Communications Co.
  9. ; Ray Duncan
  10. ;
  11. ; Call with:    DX:AX = 32-bit integer
  12. ;               DS:SI = buffer to receive string,
  13. ;                       must be at least 11 bytes long
  14. ;               CX    = radix
  15. ;
  16. ; Returns:      DS:SI = address of converted string
  17. ;               AX    = length of string
  18. ; 
  19. ; Since test for value = zero is made after a digit
  20. ; has been stored, the resulting string will always
  21. ; contain at least one significant digit.
  22.  
  23. _TEXT   segment word public 'CODE'
  24.  
  25.         assume  cs:_TEXT
  26.  
  27.         public  ltoa            ; make LTOA available to Linker
  28.  
  29. ltoa    proc    near            ; convert long int to ASCII.
  30.  
  31.         add     si,11           ; advance to end of buffer
  32.         push    si              ; and save that address.
  33.         or      dx,dx           ; test sign of 32 bit value,
  34.         pushf                   ; and save sign on stack.
  35.         jns     ltoa1           ; jump if value was positive.
  36.         not     dx              ; it was negative, take 2's 
  37.         not     ax              ; complement of the value. 
  38.         add     ax,1
  39.         adc     dx,0
  40.  
  41. ltoa1:                          ; divide value by radix to extract
  42.                                 ; next digit for forming string.
  43.         call    divide          ; no, divide by radix.
  44.         add     bl,'0'          ; convert remainder to ASCII digit
  45.         cmp     bl,'9'          ; in case converting to hex ASCII,
  46.         jle     ltoa2           ; jump if in range 0-9,
  47.         add     bl,'A'-'9'-1    ; correct digit if in range A-F.
  48.  
  49. ltoa2:  dec     si              ; back up through buffer
  50.         mov     [si],bl         ; store this character into string.
  51.         mov     bx,ax           ; is value = zero yet?
  52.         or      bx,dx
  53.         jnz     ltoa1           ; no, convert another digit.
  54.  
  55.         popf                    ; was original value negative?
  56.         jns     ltoa3           ; no, jump
  57.  
  58.         dec     si              ; yes,store sign into output string.
  59.         mov     byte ptr [si],'-'
  60.  
  61. ltoa3:  pop     ax              ; calculate length of string
  62.         sub     ax,si
  63.         ret                     ; back to caller.
  64.  
  65. ltoa    endp
  66.  
  67.  
  68. ; General purpose 32 bit by 16 bit unsigned divide.
  69. ; This routine must be used instead of the machine's 
  70. ; usual unsigned divide for cases where the quotient 
  71. ; may overflow 16 bits (for example, 100,000 / 2 ).  
  72. ; If called with a zero divisor, this routine returns the 
  73. ; dividend unchanged and gives no warning.
  74. ;
  75. ; Call with:    DX:AX = 32 bit dividend
  76. ;               CX    = divisor
  77. ;
  78. ; Returns:      DX:AX = quotient
  79. ;               BX    = remainder
  80. ;               CX    = divisor (unchanged)
  81. ;
  82.  
  83. divide  proc    near            ; Divide DX:AX by CX
  84.  
  85.         jcxz    div1            ; exit if divide by zero
  86.         push    ax              ; 0:dividend_hi/divisor
  87.         mov     ax,dx
  88.         xor     dx,dx
  89.         div     cx
  90.         mov     bx,ax           ; BX = quotient1
  91.         pop     ax              ; remainder1:dividend_lo/divisor
  92.         div     cx
  93.         xchg    bx,dx           ; DX:AX = quotient1:quotient2
  94.  
  95. div1:   ret                     ; BX = remainder2
  96.  
  97. divide  endp
  98.  
  99. _TEXT   ends
  100.  
  101.         end
  102.  
  103.  
  104.