home *** CD-ROM | disk | FTP | other *** search
/ CD Actual 13 / CDA13.ISO / cdactual / demobin / share / program / Asm / ASM_0_M.ZIP / DUMP.ASM < prev    next >
Encoding:
Assembly Source File  |  1989-09-18  |  7.5 KB  |  257 lines
  1.  
  2.  
  3.         title   DUMP --- display file contents
  4.         page    55,132
  5.         .386
  6.  
  7. ; DUMP.ASM      Display contents of file in hex and ASCII.
  8. ;               80386 version for Phar Lap tools.
  9. ;               Also requires 80386 versions of ARGV.ASM,
  10. ;               ARGC.ASM, and HEXASC.ASM.
  11. ;
  12. ; Copyright (C) 1989 Ziff Communications Co.
  13. ; PC Magazine * Ray Duncan
  14. ;
  15. ; Build:        C>386ASM  DUMP
  16. ;               C>386ASM  ARGC  
  17. ;               C>386ASM  ARGV  
  18. ;               C>386ASM  HEXASC
  19. ;               C>386LINK DUMP ARGC ARGV HEXASC  -EXE DUMP
  20. ; 
  21. ; MAKE File:    argc.obj : argc.asm
  22. ;          386asm argc
  23. ;
  24. ;        argv.obj : argv.asm
  25. ;          386asm argv
  26. ;
  27. ;        hexasc.obj : hexasc.asm
  28. ;          386asm hexasc
  29. ;
  30. ;        dump.obj : dump.asm
  31. ;          386asm dump
  32. ;
  33. ;        dump.exe : dump.obj argv.obj argc.obj hexasc.obj
  34. ;          386link dump,argc,argv hexasc -exe dump
  35. ;          bind386 c:\tools\run386b.exe dump.exp
  36. ;
  37. ;
  38. ; Usage:        C>DUMP unit:\path\filename.exe [ >device ]
  39.  
  40. cr      equ     0dh        ; ASCII carriage return
  41. lf      equ     0ah         ; ASCII line feed
  42. tab     equ     09h        ; ASCII tab code
  43. blank   equ     20h        ; ASCII space code
  44.  
  45. blksize equ     16        ; input file record size
  46.  
  47. stdin   equ     0        ; standard input handle
  48. stdout  equ     1        ; standard output handle
  49. stderr  equ     2        ; standard error handle
  50.  
  51.  
  52. _TEXT   segment dword use32 public 'CODE'
  53.  
  54.         assume  cs:_TEXT,ds:_DATA,es:_DATA,ss:STACK
  55.  
  56.         extrn   argc:near    ; get no. of command line args.
  57.         extrn   argv:near    ; get addr. of command line arg.
  58.         extrn   d2asc:near    ; convert dword to hex ASCII
  59.         extrn   b2asc:near    ; convert byte to hex ASCII
  60.  
  61. dump    proc    far        ; entry point from MS-DOS
  62.  
  63.         call    argc        ; count command arguments
  64.         cmp     eax,2        ; are there 2 arguments?
  65.         je      dump1        ; yes, proceed
  66.  
  67.         mov     edx,offset msg1    ; missing or illegal filespec.
  68.         mov     ecx,msg1_len
  69.         jmp     dump7        ; display error message and exit
  70.  
  71. dump1:                    ; copy filename from command
  72.             ; tail to local buffer
  73.  
  74.         mov     eax,1        ; get pointer to command
  75.         call    argv        ; tail argument in ES:EBX
  76.  
  77.         mov     ecx,eax    ; let ECX = length
  78.         mov     edi,offset fname; DS:EDI = local buffer address
  79.  
  80. dump2:  mov     al,es:[ebx]    ; copy filename byte by byte
  81.         mov     [edi],al
  82.         inc     ebx
  83.         inc     edi
  84.         loop    dump2
  85.  
  86.         mov     ax,ds        ; make our data segment
  87.         mov     es,ax        ; addressable by ES too
  88.  
  89.             ; now open the file...
  90.         mov     eax,3d00h    ; Fxn 3DH = open file
  91.             ; mode 0 = read only
  92.         mov     edx,offset fname; DS:EDX = filename
  93.         int     21h        ; transfer to MS-DOS
  94.         mov     fhandle,eax    ; save file handle if any
  95.         jnc     dump3        ; jump, open successful
  96.  
  97.         mov     edx,offset msg2    ; open failed, display 
  98.         mov     ecx,msg2_len    ; error message and exit
  99.         jmp     dump7
  100.  
  101. dump3:            ; read block of file data...
  102.         mov     ebx,fhandle    ; EBX = file handle
  103.         mov     ecx,blksize    ; ECX = record length
  104.         mov     edx,offset fbuff; DS:EDX = buffer
  105.         mov     ah,3fh        ; Fxn 3FH = read
  106.         int     21h        ; transfer to MS-DOS
  107.  
  108.         mov     flen,eax    ; save actual length of data
  109.         or      eax,eax    ; end of file reached?
  110.         jne     dump4        ; no, proceed
  111.  
  112.         cmp     dword ptr fptr,0; was this the first record?
  113.         jne     dump6        ; no, exit normally
  114.  
  115.         mov     edx,offset msg3    ; display "empty file"
  116.         mov     ecx,msg3_len    ; error message and exit
  117.         jmp     dump7
  118.  
  119. dump4:  test    fptr,07fh    ; heading needed?
  120.         jnz     dump5        ; jump, not 128-byte boundary
  121.  
  122.             ; display heading...
  123.         mov     edx,offset hdg    ; ES:EDX = heading address
  124.         mov     ecx,hdg_len    ; ECX = heading length
  125.         mov     ebx,stdout    ; EBX = standard output handle
  126.         mov     ah,40h    ; Fxn 40H = write
  127.         int     21h        ; transfer to MS-DOS
  128.  
  129. dump5:  call    cnvblk    ; convert record to ASCII
  130.         
  131.             ; display formatted output...
  132.         mov     edx,offset fout    ; DX:EDX = output address
  133.         mov     ecx,fout_len    ; ECX = output length
  134.         mov     ebx,stdout    ; EBX = standard output
  135.         mov     ah,40h    ; Fxn 40H = write
  136.         int     21h        ; transfer to MS-DOS
  137.  
  138.         jmp     dump3        ; go get another record
  139.  
  140. dump6:            ; close input file...
  141.         mov     ebx,fhandle    ; EBX = file handle
  142.         mov     ah,3eh    ; Fxn 3EH = close file
  143.         int     21h        ; transfer to MS-DOS
  144.  
  145.         mov     eax,4c00h    ; Fxn 4CH = terminate,
  146.             ; return code = 0
  147.         int     21h        ; transfer to MS-DOS
  148.  
  149. dump7:            ; common error exit point...
  150.             ; DS:EDX = message address
  151.             ; ECX = message length
  152.         mov     ebx,stderr    ; standard error handle
  153.         mov     ah,40h    ; Fxn 40H = write
  154.         int     21h        ; transfer to MS-DOS
  155.  
  156.         mov     eax,4c01h    ; Fxn 4CH = terminate,
  157.             ; return code = 1
  158.         int     21h        ; transfer to MS-DOS
  159.         
  160. dump    endp
  161.  
  162.  
  163. cnvblk  proc    near        ; convert record to ASCII
  164.  
  165.         mov     edi,offset fout    ; clear output format 
  166.         mov     ecx,fout_len-2    ; area to blanks
  167.         mov     al,blank
  168.         rep stosb
  169.  
  170.         mov     edi,offset fout    ; convert file offset
  171.         mov     eax,fptr    ; to ASCII for output
  172.         call    d2asc
  173.  
  174.         xor     ebx,ebx    ; reset buffer pointer
  175.  
  176. cb1:    mov     al,[fbuff+bx]    ; fetch byte from buffer
  177.         lea     edi,[ebx+foutb]    ; point to output area
  178.                         
  179.             ; format ASCII part...
  180.         mov     byte ptr [edi],'.'; store '.' as default
  181.         cmp     al,blank    ; in range 20H - 7EH?
  182.         jb      cb2        ; jump, not alphanumeric.
  183.         cmp     al,7eh    ; in range 20H - 7EH?
  184.         ja      cb2        ; jump, not alphanumeric.
  185.         mov     [edi],al    ; store ASCII character.
  186.  
  187. cb2:            ; format hex part...
  188.         mov     edi,ebx    ; calculate output address
  189.         imul    edi,edi,3    ; (position*3) + base address   
  190.         add     edi,offset fouta        
  191.         call    b2asc        ; convert byte to hex 
  192.  
  193.         inc     ebx        ; advance through record
  194.         cmp     ebx,flen    ; entire record converted?
  195.         jne     cb1        ; no, get another byte
  196.  
  197.         add     dword ptr fptr,blksize; update file pointer
  198.  
  199.         ret        ; back to caller
  200.  
  201. cnvblk  endp
  202.  
  203. _TEXT   ends
  204.  
  205.  
  206. _DATA   segment dword use32 public 'DATA'
  207.  
  208. fname   db      64 dup (0)    ; buffer for input filespec
  209.  
  210. fhandle dd      0        ; token from PCDOS for input file.
  211.  
  212. flen    dd      0        ; actual length read
  213.  
  214. fptr    dd      0        ; relative address in file 
  215.  
  216. fbuff   db      blksize dup (?)    ; data from input file
  217.  
  218. fout    db      'nnnnnnnn'    ; formatted output area
  219.         db      blank,blank
  220. fouta   db      16 dup ('nn',blank)
  221.         db      blank
  222. foutb   db      16 dup (blank),cr,lf
  223. fout_len equ    $-fout
  224.  
  225. hdg     db      cr,lf        ; heading for each 128 bytes
  226.         db      11 dup (blank)    ; of formatted output
  227.         db      '0  1  2  3  4  5  6  7  '
  228.         db      '8  9  A  B  C  D  E  F',cr,lf
  229. hdg_len equ     $-hdg
  230.  
  231. msg1    db      cr,lf
  232.         db      'dump: missing file name'
  233.         db      cr,lf
  234. msg1_len equ    $-msg1
  235.  
  236. msg2    db      cr,lf
  237.         db      'dump: file not found'
  238.         db      cr,lf
  239. msg2_len equ    $-msg2
  240.  
  241. msg3    db      cr,lf
  242.         db      'dump: empty file'
  243.         db      cr,lf
  244. msg3_len equ    $-msg3
  245.  
  246. _DATA   ends    
  247.  
  248.  
  249. STACK   segment dword use32 stack 'STACK'
  250.  
  251.         dd      64 dup (?)
  252.  
  253. STACK   ends
  254.  
  255.         end     dump
  256.  
  257.