home *** CD-ROM | disk | FTP | other *** search
/ CD Actual 13 / CDA13.ISO / cdactual / demobin / share / program / Asm / ASM.ZIP / FREECOPY.ASM < prev    next >
Encoding:
Assembly Source File  |  1987-06-26  |  82.6 KB  |  2,577 lines
  1.  
  2. Page    55,132
  3. Title    FREECOPY Version 1.0 (C)Copyright 1984
  4. ;***********************  F R E E C O P Y  ******************************
  5. ;*                                    *
  6. ;*    Program: FREECOPY                        *
  7. ;*                                    *
  8. ;*    Author: Donald L. Buresh, C.D.P.                *
  9. ;*        Squire Buresh Associates, Inc.                *
  10. ;*        Post Office Box 112                    *
  11. ;*        Millbury, MA  01527                    *
  12. ;*        (617) 865-3435                        *
  13. ;*                                    *
  14. ;*    !!!!!!!!!!!!!!!!!!!!!!   N O T I C E   !!!!!!!!!!!!!!!!!!!!!!     *
  15. ;*                                    *
  16. ;*    A limited license is granted to all users of this program to    *
  17. ;*    make copies of this source code and to distribute them to    *
  18. ;*    other users under the following conditions:            *
  19. ;*                                    *
  20. ;*    1. The notice contained in the variable MES00_Copy_Notice    *
  21. ;*       is not to be altered, bypassed or removed.            *
  22. ;*                                    *
  23. ;*    2. The program is not to be distributed to others in        *
  24. ;*       modified form.                        *
  25. ;*                                    *
  26. ;*    3. If you think that this program has helped you, we request    *
  27. ;*       a $25.00 contribution.                    *
  28. ;*                                    *
  29. ;*    4. No other fee is to be charged or any consideration received    *
  30. ;*       for copying or distributing the program without the        *
  31. ;*       expressed written permission of Squire Buresh Assoc, Inc.    *
  32. ;*                                    *
  33. ;*                                    *
  34. ;*  (C) Copyright  1984        Squire Buresh Associates, Inc.        *
  35. ;*                                    *
  36. ;************************************************************************
  37. Page
  38. ;************************************************************************
  39. ;*                                    *
  40. ;*    EQUATES                                *
  41. ;*                                    *
  42. ;*    The constants defined below are used to to specify:        *
  43. ;*                                    *
  44. ;*            o Disk commands,                *
  45. ;*                                    *
  46. ;*            o Keyboard commands,                *
  47. ;*                                    *
  48. ;*            o Video commands                *
  49. ;*                                    *
  50. ;*            o Miscellaneous parameters,            *
  51. ;*                                    *
  52. ;*            o Various ASCII characters.            *
  53. ;*                                    *
  54. ;************************************************************************
  55. ;
  56. Disk_Parameter_Addr    Equ    001EH*4    ; Address of Disk Parameter Table
  57. ;
  58. Reset_Command        Equ    0000D    ; Diskette reset command
  59. Status_Command        Equ    0001D    ; Diskette status command
  60. Read_Command        Equ    0002D    ; Diskette read command
  61. Write_Command        Equ    0003D    ; Diskette write command
  62. Verify_Command        Equ    0004D    ; Diskette verify command
  63. Format_Command         Equ    0005D    ; Diskette format command
  64. ;
  65. Time_Out_Error        Equ    0080H    ; Diskette error codes
  66. Seek_Error        Equ    0040H    ; .
  67. Controller_Error    Equ    0020H    ; .
  68. CRC_Error        Equ    0010H    ; .
  69. DMA_Boundary_Error    Equ    0009H    ; .
  70. DMA_Error        Equ    0008H    ; .
  71. Sector_Error        Equ    0004H    ; .
  72. Write_Protect_Error    Equ    0003H    ; .
  73. Address_Mark_Error    Equ    0002H    ; .
  74. Command_Error        Equ    0001H    ; ..End
  75. ;
  76. Video_Address        Equ    0A000H    ; Starting segment addr of Video RAM
  77. ;
  78. Set_Mode_Command    Equ    0000D    ; Set the video mode
  79. Set_CType_Command    Equ    0001D    ; Set the cursor type
  80. Set_CPos_Command    Equ    0002D    ; Set the cursor position
  81. Read_Cursor_Command    Equ    0003D    ; Get cursor position and attributes
  82. Read_LPen_Command    Equ    0004D    ; Get the light pen position
  83. Set_ADPage_Command    Equ    0005D    ; Set the active display page
  84. Scroll_Up_Command    Equ    0006D    ; Scrool up or blank a portion of
  85.                     ; . the video display
  86. ;
  87. Page
  88. ;************************************************************************
  89. ;*                                    *
  90. ;*    EQUATES        Page 2                        *
  91. ;*                                    *
  92. ;************************************************************************
  93. ;
  94. Scroll_Down_Command    Equ    0007D    ; Scroll down or blank a portion
  95.                     ; . of the video display
  96. Read_AChar_Command    Equ    0008D    ; Read the attribute and character
  97. Write_AChar_command    Equ    0009D    ; Write the attribute and character
  98. Write_Char_Command    Equ    0010D    ; Write the character only
  99. Set_Color_Command    Equ    0011D    ; Set the color pallette
  100. Write_Dot_Command    Equ    0012D    ; Write a pixel to a graphics screen
  101. Read_Dot_Command    Equ    0013D    ; Read a pixel from a graphics screen
  102. Write_TTY_Command    Equ    0014D    ; Write a character with automatic
  103.                     ; . processing for LF, CR, Bell & BS
  104. Video_State_Command    Equ    0015D    ; Get the current video state
  105. ;
  106. Read_Keyboard_Command    Equ    0007D    ; Reads character from the keyboard
  107. ;
  108. Default_Drive_Command    Equ    0025D    ; Get PC DOS default drive number
  109. ;
  110. Video_Interrupt        Equ    0010H    ; Interrupt 10H for video calls
  111. Equipment_Interrupt    Equ    0011H    ; Interrupt 11H for equipment
  112. Disk_Interrupt        Equ    0013H    ; Interrupt 13H for disk calls
  113. PC_DOS_Interrupt    Equ    0021H    ; Interrupt 21H for PC DOS calls
  114. ;
  115. Parallel_Ports_Mask    Equ    0C000H    ; Equipment masks
  116. Game_Adapters_Mask    Equ    00100H    ; .
  117. RS232_Ports_Mask    Equ    00E00H    ; .
  118. Disk_Drives_Mask    Equ    000C0H    ; .
  119. Init_Video_Mask        Equ    00030H    ; .
  120. Planar_RAM_Mask        Equ    0000CH    ; .
  121. IPL_Diskette_Mask    Equ    00001H    ; ..End
  122. ;
  123. Page
  124. ;************************************************************************
  125. ;*                                    *
  126. ;*    EQUATES        Page 3                        *
  127. ;*                                    *
  128. ;************************************************************************
  129. ;
  130. Command_Com_Size    Equ    1125D    ; Size of various tables and programs
  131. CHRN_Table_Size        Equ    0180D    ; in 16 byte paragraphs
  132.                     ; .
  133.                     ; .
  134. ESBX_Table_Size        Equ    0020D    ; .
  135.                     ; .
  136.                     ; .
  137. FAT_Sector_Size        Equ    0032D    ; ..End
  138. ;
  139. DMA_Boundary_Mask    Equ    0FFFH    ; Mask to isolate the high nibble of
  140.                     ; . the ES segment address
  141. ;
  142. Invalid_Drive        Equ    0255D    ; Invalid drive parameter
  143. Maximum_Drives        Equ    0003D    ; Maximum number of floppy drives 
  144. Minimum_Drives        Equ    0000D    ; Minimum number of floppy drives
  145. ;
  146. Sector_Size        Equ    0512D    ; Number of bytes per sector
  147. Paragraph_Size        Equ    0016D    ; Number of bytes per paragraph
  148. Number_of_Retries    Equ    0005D    ; Number of attempts to copy 
  149.                     ; . a track before admitting failure
  150. Final_Track        Equ    0039D    ; The last track on a PC DOS diskette
  151. ;
  152. One_Side_Eight_Sectors    Equ    00FEH    ; First entry in the File Allocation
  153. Two_Sides_Eight_Sectors    Equ    00FFH    ; Table (FAT)
  154. One_Side_Nine_Sectors    Equ    00FCH    ; .
  155. Two_Sides_Nine_Sectors    Equ    00FDH    ; .
  156. Fixed_Disk        Equ    00F8H    ; ..End
  157. ;
  158. Keyboard_Buffer_Size    Equ    0080D    ; Maximum number of characters in
  159.                     ; . the keyboard buffer
  160. ;
  161. Minimum_Memory_Size    Equ    0288D    ; Minimum memory size in 16 byte
  162.                     ; . paragraphs to hold a nine
  163.                     ; . sectored track
  164. ;
  165. Blank_Cursor        Equ    0F0FH    ; Blank cursor value
  166. Underline_Cursor    Equ    0D0DH    ; Underline cursor value
  167. ;
  168. True            Equ    0001D    ; Correct processing occured
  169. False            Equ    0000D    ; Incorrect processing occured
  170. ;
  171. Page
  172. ;************************************************************************
  173. ;*                                    *
  174. ;*    EQUATES        Page 4                        *
  175. ;*                                    *
  176. ;************************************************************************
  177. ;
  178. NUL            Equ    0000D    ; Null character
  179. SOH            Equ    0001D    ; SOH character
  180. STX            Equ    0002D    ; STX character
  181. ETX            Equ    0003D    ; Control Break character
  182. Bell            Equ    0007D    ; Bell character
  183. BS            Equ    0008D    ; Backspace character
  184. LF            Equ    0010D    ; Line feed character
  185. CR            Equ    0013D    ; Carriage return character
  186. Space            Equ    0032D    ; Space or blank character
  187. Slash            Equ    0047D    ; Slash character
  188. Zero_Digit        Equ    0048D    ; Digit Zero
  189. One_Digit        Equ    0049D    ; Digit One
  190. Capital_Letter_A    Equ    0065D    ; Capital letter A
  191. Capital_Letter_N    Equ    0078D    ; Capital letter N
  192. Capital_Letter_Y    Equ    0089D    ; Capital letter Y
  193. Small_Letter_n        Equ    0110D    ; Small letter n
  194. Small_Letter_y        Equ    0121D    ; Small letter y
  195. EOT            Equ    0255D    ; End of text character
  196. ;
  197. Minus_One        Equ      -1D    ; Numbers used in FREECOPY
  198. Zero            Equ    0000D    ; .
  199. One            Equ    0001D    ; .
  200. Two            Equ    0002D    ; .
  201. Three            Equ    0003D    ; .
  202. Four            Equ    0004D    ; .
  203. Six            Equ    0006D    ; .
  204. Eight            Equ    0008D    ; .
  205. Nine            Equ    0009D    ; .
  206. Ten            Equ    0010D    ; .
  207. Eleven            Equ    0011D    ; .
  208. Twelve            Equ    0012D    ; .
  209. Fourteen        Equ    0014D    ;.
  210. Fifteen            Equ    0015D    ; .
  211. Twenty_Four        Equ    0024D    ; .
  212. Twenty_Five        Equ    0025D    ; .
  213. Thirty_Four        Equ    0034D    ; .
  214. Thirty_Six        Equ    0036D    ; .
  215. Thirty_Nine        Equ    0039D    ; .
  216. Seventy_Nine        Equ    0079D    ; ..End
  217. ;
  218. Page
  219. ;************************************************************************
  220. ;*                                    *
  221. ;*    CSEG Segment                            *
  222. ;*                                    *
  223. ;*    This segment contains all of the code of the program.  It is    *
  224. ;*    named CSEG because this name conforms with ASM-86.        *
  225. ;*                                    *
  226. ;************************************************************************
  227. ;
  228. CSEG    Segment Para Public 'CSEG'
  229.     Assume CS:CSEG,DS:CSEG,ES:CSEG,SS:Nothing
  230. ;
  231. Page
  232. ;************************************************************************
  233. ;*                                    *
  234. ;*    PROGRAM SEGMENT PREFIX                        *
  235. ;*                                    *
  236. ;*    The first 256 bytes of every program executed under PC DOS    *
  237. ;*    contains a Program Segment Prefix control block.  The data    *
  238. ;*    stored in this block of memory is used by FREECOPY to process    *
  239. ;*    the parameters when invoking the program.            *
  240. ;*                                    *
  241. ;************************************************************************
  242. ;
  243.     Org    05CH
  244. Source_Drive        Label Byte    ; Source diskette drive number
  245.     Org    05DH
  246. Source_Filename        Label Byte    ; Source diskette filename
  247.     Org    068H
  248. Source_Filler_Area    Label Byte
  249.     Org    06CH
  250. Target_Drive        Label Byte    ; Target diskette drive number
  251.     Org    06DH
  252. Target_Filename        Label Byte    ; Target diskette filename
  253.     Org    078H
  254. Target_Filler_Area    Label Byte
  255.     Org    080H
  256. Parameter_Count        Label Byte    ; Number of parameters
  257.     Org    081H
  258. Parameter_String    Label Byte    ; String entered by the user
  259. ;
  260. Page
  261. ;************************************************************************
  262. ;*                                    *
  263. ;*    A1000_MAIN_MODULE                        *
  264. ;*                                    *
  265. ;*    This is the top level of FREECOPY and it controls the flow of    *
  266. ;*    the program.  The first sequence of commands in the routine    *
  267. ;*    preserve the state of the machine.  Next, there is a set of    *
  268. ;*    three (3) calls to sub-modules that control the initial        *
  269. ;*    processing, detail processing and final processing.  Finally,    *
  270. ;*    FREECOPY restores the state of the machine an returns to     *
  271. ;*    PC DOS via INT 20H.                        *
  272. ;*                                    *
  273. ;************************************************************************
  274. ;
  275.     Org    0100H
  276. ;
  277. Public    A1000_Main_Module
  278. ;
  279. A1000_Main_Module Proc Far
  280. ;
  281. A1001:
  282.     Cli                ; Set up the top of the stack
  283.     Mov    SP,Offset MEM04_Top_of_the_Stack
  284.     Sti                ; ..End
  285. ; 
  286.     Push    BP            ; Save the state of the machine
  287.     Push    DS            ; .
  288.     Push    ES            ; .
  289.     Push    SS            ; .
  290.     Push    AX            ; .
  291.     Push    BX            ; .
  292.     Push    CX            ; .
  293.     Push    DX            ; .
  294.     Push    SI            ; .
  295.     Push    DI            ; .
  296.     Pushf                ; ..End
  297. ;
  298.     Cli                ; Save the current stack pointer
  299.     Mov    Word Ptr SYS15_Stack_Pointer,SP
  300.     Sti                ; ..End
  301. ;
  302.     Call    B1000_Initial_Process    ; Main flow of control
  303.     Cmp    Byte Ptr FLG01_Good_Command,False
  304.     Je    A1002            ; .
  305.     Cmp    Byte Ptr FLG03_Default_Drive,False
  306.     Je    A1002            ; .
  307.     Call    B1100_Detail_Process    ; .
  308. A1002:                    ; .
  309.     Call    B1200_Final_Process    ; ..End
  310. A1090:
  311.     Popf                ; Restore the state of the machine
  312.     Pop    DI            ; .
  313.     Pop    SI            ; .
  314.     Pop    DX            ; .
  315.     Pop    CX            ; .
  316.     Pop    BX            ; .
  317.     Pop    AX            ; .
  318.     Pop    SS            ; .
  319.     Pop    ES            ; .
  320.     Pop    DS            ; .
  321.     Pop    BP            ; ..End
  322. A1099:
  323.     Int    20H            ; Return to PC DOS
  324. ;
  325. A1000_Main_Module Endp
  326. ;
  327. Page
  328. ;************************************************************************
  329. ;*                                    *
  330. ;*    B1000_INITIAL_PROCESS                        *
  331. ;*                                    *
  332. ;*    This module performs the following functions after control    *
  333. ;*    passess to FREECOPY:                        *
  334. ;*                                    *
  335. ;*     1. Sets up the Disk Parameter Table.                *
  336. ;*                                    *
  337. ;*     2. Initializes various parameters.                *
  338. ;*                                    *
  339. ;*     3. Gets and sets the video mode.                *
  340. ;*                                    *
  341. ;*     4. Displays the intiial message.                *
  342. ;*                                    *
  343. ;*     5. Parses the command line entered by a user.            *
  344. ;*                                    *
  345. ;*     6. Determines the amount of equipment on the machine.        *
  346. ;*                                    *
  347. ;*     7. Validates the number of disk drives on the system.        *
  348. ;*                                    *
  349. ;*     8. Displays the appropriate disk copying message.        *
  350. ;*                                    *
  351. ;*     9. Gets the amount of available memory.            *
  352. ;*                                    *
  353. ;*    10. Calculates the number and position of the entries in the    *
  354. ;*        ES:BX buffer address table.                    *
  355. ;*                                    *
  356. ;************************************************************************
  357. ;
  358. Page
  359. ;
  360. Public    B1000_Initial_Process
  361. ;
  362. B1000_Initial_Process Proc Near
  363. ;
  364. B1001:
  365.     Call    S1000_Setup_Disk_Param_Table
  366. ;
  367.     Mov    Byte Ptr FLG01_Good_Command,True
  368.     Mov    Byte Ptr FLG02_Double_Side,True
  369.     Mov    Byte Ptr FLG03_Default_Drive,True
  370.     Mov    Byte Ptr FLG04_Single_Drive,True
  371.     Mov    Byte Ptr FLG07_First_Time,True
  372. B1002:
  373.     Call    C1000_Get_And_Set_Video    ; Get and set current video state
  374.     Call    C1100_Display_Intro    ; Display the intial screen
  375.     Call    C1200_Parse_Commands    ; Parse the command line entered
  376.                     ; . by the user
  377.     Cmp    Byte Ptr FLG01_Good_Command,False
  378.     Je    B1099            ; If false, go to end of the module
  379.     Call    C1300_Get_Equipment    ; Find out the equipment on the PC
  380.     Call    C1400_Validate_Drives    ; Validate the drive numbers
  381.     Cmp    Byte Ptr FLG03_Default_Drive,False
  382.     Je    B1099            ; If false, go to end of the module
  383.     Call    C1500_Diskette_Messages    ; Display the appropriate messages
  384.     Call    C1600_Get_Free_Memory    ; Get the available memory in 16
  385.                     ; . byte paragraphs
  386.     Cmp    Byte Ptr FLG01_Good_Command,False
  387.     Je    B1099            ; If false, go to end of the module
  388.     Call    C1700_Create_ESBX_Table    ; Create the ES:BX table for the disk
  389.                     ; reads and writes
  390. B1099:
  391.     Ret
  392. ;
  393. B1000_Initial_Process Endp
  394. ;
  395. Page
  396. ;************************************************************************
  397. ;*                                    *
  398. ;*    B1100_DETAIL_PROCESS                        *
  399. ;*                                    *
  400. ;*    This module performs the following functions when copying one    *
  401. ;*    or more diskettes:                        *
  402. ;*                                    *
  403. ;*    1. Initializes various parameters.                *
  404. ;*                                    *
  405. ;*    2. Validates the contents of the source diskette.        *
  406. ;*                                    *
  407. ;*    3. Creates all of the entries of the CHRN table used in        *
  408. ;*       formatting the target diskette.                *
  409. ;*                                    *
  410. ;*    4. Reads the tracks of the source diskette.            *
  411. ;*                                    *
  412. ;*    5. If the diskette is being copied on only one drive, the    *
  413. ;*       routines asks the user to enter the target diskette.        *
  414. ;*                                    *
  415. ;*    6. Writes the tracks on the target diskette.            *
  416. ;*                                    *
  417. ;*    7. If FREECOPY is finished copying the source diskette, the    *
  418. ;*       program asks whether wants to copy another one.  If not,    *
  419. ;*       the module returns to A1000_Main_Module.  If so, control    *
  420. ;*       transfers to 1.                        *
  421. ;*                                    *
  422. ;*    8. If FREECOPY is not completed copying the source diskette,    *
  423. ;*       control transfers to 4.                    *
  424. ;*                                    *
  425. ;************************************************************************
  426. ;
  427. Page
  428. ;
  429. Public    B1100_Detail_Process
  430. ;
  431. B1100_Detail_Process Proc Near
  432. ;
  433. B1101:
  434.     Mov    Byte Ptr WRK20_Current_Source_Head,Zero
  435.     Mov    Byte Ptr WRK21_Current_Source_Track,Zero
  436.     Mov    Byte Ptr WRK22_Current_Target_Head,Zero
  437.     Mov    Byte Ptr WRK23_Current_Target_Track,Zero
  438.     Mov    Word Ptr WRK33_CHRN_Table_Address,Offset MEM02_CHRN_Table
  439.     Mov    Byte Ptr FLG13_First_Read_Write,True
  440.     Mov    Byte Ptr FLG14_Copy_Complete,False
  441.     Mov    Byte Ptr FLG15_IO_Error,Three
  442. B1102:
  443.     Call    C1800_Validate_Source_Disk
  444.     Cmp    Byte Ptr FLG08_Good_Read,True
  445.     Je    B1103            ; If it is a valid source, continue
  446.     Mov    SI,Offset MES07_Correct_And_Press_Key
  447.     Call    U1000_Display_Message    ; Display the message on the screen
  448.     Mov    Byte Ptr FLG05_Store_Buffer,False
  449.     Call    U1100_Get_Response    ; Get the user's response
  450.     Jmp    B1101            ; Go back and try again
  451. B1103:
  452.     Call    C1900_Create_CHRN_Table
  453. B1104:
  454.     Call    C2000_Read_Source_Disk
  455.     Cmp    Byte Ptr FLG08_Good_Read,True
  456.     Je    B1105            ; If read disk correctly, continue
  457.     Mov    SI,Offset MES07_Correct_And_Press_Key
  458.     Call    U1000_Display_Message    ; Display the message on the screen
  459.     Mov    Byte Ptr FLG05_Store_Buffer,False
  460.     Call    U1100_Get_Response    ; Get the user's response
  461.     Jmp    B1101            ; Go back and try again
  462. B1105:
  463.     Cmp    Byte Ptr FLG04_Single_Drive,False
  464.     Je    B1106            ; If a single drive copy, continue
  465.     Mov    SI,Offset MES10_Insert_Target
  466.     Mov    AL,Byte Ptr WRK02_Target_Drive
  467.     Add    AL,Capital_Letter_A    ; Put drive letter into AL
  468.     Mov    [SI+Thirty_Four],AL    ; Put the drive letter into the
  469.                     ; . correct position in the message
  470.     Call    U1000_Display_Message    ; Display the message on the screen
  471.     Mov    SI,Offset MES16_Press_Any_Key
  472.     Call    U1000_Display_Message    ; Display the message on the screen
  473.     Mov    Byte Ptr FLG05_Store_Buffer,False
  474.     Call    U1100_Get_Response    ; Get the user's response
  475. B1106:
  476.     Call    C2100_Write_Format_Target_Disk
  477.     Cmp    Byte Ptr FLG09_Good_Write,False
  478.     Je    B1110            ; If bad write, go to bottom of loop
  479.     Cmp    Byte Ptr FLG11_Good_Format,False
  480.     Je    B1110            ; If bad format, go to bottom of loop
  481. B1107:
  482.     Cmp    Byte Ptr FLG14_Copy_Complete,True
  483.     Je    B1109            ; If copy done, go to bottom of loop
  484.     Cmp    Byte Ptr FLG04_Single_Drive,False
  485.     Je    B1108            ; If double drive copy, continue
  486.     Mov    SI,Offset MES09_Insert_Source
  487.     Mov    AL,Byte Ptr WRK01_Source_Drive
  488.     Add    AL,Capital_Letter_A    ; Put the drive letter into AL
  489.     Mov    [SI+Thirty_Four],AL    ; Put the drive letter into the
  490.                     ; . correct position in the message
  491.     Call    U1000_Display_Message    ; Display the message on the screen
  492.     Mov    SI,Offset MES16_Press_Any_Key
  493.     Call    U1000_Display_Message    ; Display the message on the screen
  494.     Mov    Byte Ptr FLG05_Store_Buffer,False
  495.     Call    U1100_Get_Response    ; Get the user's response
  496. B1108:
  497.     Call    C2200_Check_File_Alloc_Table
  498.     Cmp    Byte Ptr FLG12_Good_FAT,False
  499.     Je    B1110            ; If bad FAT, go to bottom of loop
  500.     Mov    Byte Ptr FLG13_First_Read_Write,False
  501.     Jmp    B1104            ; Go back and read some more
  502. B1109:
  503.     Mov    Byte Ptr FLG07_First_Time,False
  504.     Mov    SI,Offset MES02_Copy_Complete
  505.     Call    U1000_Display_Message
  506. B1110:
  507.     Mov    SI,Offset MES01_Copy_Another
  508.     Call    U1000_Display_Message
  509.     Call    U1200_Get_Yes_or_No
  510.     Cmp    Byte Ptr FLG06_Yes_or_No,False
  511.     Je    B1199            ; Go to the end of the module
  512.     Call    C1500_Diskette_Messages    ; Print out the messages on screen
  513.     Jmp    B1101            ; Start copying a diskette again
  514. B1199:
  515.     Ret
  516. ;
  517. B1100_Detail_Process Endp
  518. ;
  519. Page
  520. ;************************************************************************
  521. ;*                                    *
  522. ;*    B1200_FINAL_PROCESS                        *
  523. ;*                                    *
  524. ;*    This module performs the following functions before returning     *
  525. ;*    control to PC DOS:                        *
  526. ;*                                    *
  527. ;*    1. Restores the value of the stack pointer.            *
  528. ;*                                    *
  529. ;*    2. Displays the final message of the program.            *
  530. ;*                                    *
  531. ;*    3. Restores the underline cursor.                *
  532. ;*                                    *
  533. ;*    4. Restores the settings in the Disk Parameter Table.        *
  534. ;*                                    *
  535. ;*    5. Returns control to A1000_Main_Module.            *
  536. ;*                                    *
  537. ;************************************************************************
  538. ;
  539. Page
  540. ;
  541. Public    B1200_Final_Process
  542. ;
  543. B1200_Final_Process Proc Near
  544. ;
  545. B1201:
  546.     Cli                ; Establish the stack pointer
  547.     Mov    SP,Word Ptr SYS15_Stack_Pointer
  548.     Sti                ; ..End
  549. ;
  550.     Mov    SI,Offset MES99_Freecopy_Finished
  551.     Call    U1000_Display_Message    ; Display the message on the screen
  552. ;
  553.     Mov    AH,Set_CType_Command    ; Restore the underline cursor
  554.     Mov    CX,Underline_Cursor    ; .
  555.     Int    Video_Interrupt        ; ..End
  556. ;
  557.     Call    S1100_Restore_Disk_Param_Table
  558. ;
  559.     Mov    AX,Offset A1090        ; Setup to return to the main module
  560.     Push    CS            ; .
  561.     Push    AX            ; ..End
  562. B1299:
  563.     Ret
  564. ;
  565. B1200_Final_Process Endp
  566. ;
  567. Page
  568. ;************************************************************************
  569. ;*                                    *
  570. ;*    C1000_GET_AND_SET_VIDEO                        *
  571. ;*                                    *
  572. ;*    This module gets the current video state and saves this        *
  573. ;*    information in the various SYStem variables.            *
  574. ;*                                    *
  575. ;************************************************************************
  576. ;
  577. Public    C1000_Get_And_Set_Video
  578. ;
  579. C1000_Get_And_Set_Video Proc Near
  580. ;
  581. C1001:
  582.     Push    AX            ; Save the registers
  583.     Push    BX            ; .
  584.     Push    CX            ; ..End
  585. C1002:
  586.     Mov    AH,Video_State_Command    ; Get the current video state
  587.     Int    Video_Interrupt        ; ..End
  588.     Mov    Byte Ptr SYS01_Number_Columns,AH
  589.     Mov    Byte Ptr SYS02_Current_Mode,AL
  590.     Mov    Byte Ptr SYS03_Active_Page,BH
  591. C1003:
  592.     Mov    AH,Set_CType_Command    ; Set the cursor to blanks
  593.     Mov    CX,Blank_Cursor        ; .
  594.     Int    Video_Interrupt        ; ..End
  595. C1090:
  596.     Pop    CX            ; Restore the registers
  597.     Pop    BX            ; .
  598.     Pop    AX            ; ..End
  599. C1099:
  600.     Ret
  601. ;
  602. C1000_Get_And_Set_Video Endp
  603. ;
  604. Page
  605. ;************************************************************************
  606. ;*                                    *
  607. ;*    C1100_DISPLAY_INTRO                        *
  608. ;*                                    *
  609. ;*    This module displays the introductory message to FREECOPY.    *
  610. ;*    Please do not disable this message, since it states the        *
  611. ;*    conditions under which a person may copy this program.        *
  612. ;*                                    *
  613. ;************************************************************************
  614. ;
  615. Public    C1100_Display_Intro
  616. ;
  617. C1100_Display_Intro Proc Near
  618. ;
  619. C1101:
  620.     Mov    SI,Offset MES00_Copy_Notice    ; Display the copy notice
  621.     Call    U1000_Display_Message        ; ..End
  622. C1199:
  623.     Ret
  624. C1100_Display_Intro Endp
  625. ;
  626. Page
  627. ;************************************************************************
  628. ;*                                    *
  629. ;*    C1200_PARSE_COMMANDS                        *
  630. ;*                                    *
  631. ;*    This module parses the command line entered by the user        *
  632. ;*    by checking the following conditions:                *
  633. ;*                                    *
  634. ;*    1. The source and/or the target drives do not exist.        *
  635. ;*                                    *
  636. ;*    2. The command line contains any characters other than two    *
  637. ;*       drive letters (e.g., a filename).                *
  638. ;*                                    *
  639. ;*    3. The /1 (single side) parameter is on the command line.    *
  640. ;*                                    *
  641. ;************************************************************************
  642. ;
  643. Public    C1200_Parse_Commands
  644. ;
  645. C1200_Parse_Commands Proc Near
  646. ;
  647. C1201:
  648.     Cmp    AH,Invalid_Drive    ; Compare for invalid drive parms
  649.     Jne    C1202            ; .
  650.     Mov    Byte Ptr FLG01_Good_Command,False
  651.     Mov    SI,Offset MES14_Invalid_Drive
  652.     Call    U1000_Display_Message
  653.     Jmp    C1299            ; .
  654. C1202:                    ; .
  655.     Cmp    AL,Invalid_Drive    ; .
  656.     Jne    C1203            ; .
  657.     Mov    Byte Ptr FLG01_Good_Command,False
  658.     Mov    SI,Offset MES14_Invalid_Drive
  659.     Call    U1000_Display_Message
  660.     Jmp    C1299            ; ..End
  661. C1203:
  662.     Mov    AL,Byte Ptr Source_Drive
  663.     Mov    Byte Ptr WRK01_Source_Drive,AL
  664.     Mov    AL,Byte Ptr Target_Drive
  665.     Mov    Byte Ptr WRK02_Target_Drive,AL
  666. C1204:
  667.     Mov    SI,Offset Source_Filename
  668.     Mov    DI,Offset WRK03_Valid_Filename
  669.     Mov    CX,Eleven        ; Set CX to compare 11 characters 
  670. C1205:
  671.     Mov    AL,[SI]            ; Compare for valid source diskette
  672.     Mov    AH,[DI]            ; filename in the FCB at 05DH
  673.     Cmp    AH,AL            ; .
  674.     Je    C1206            ; .
  675.     Mov    Byte Ptr FLG01_Good_Command,False
  676.     Mov    SI,Offset MES12_Invalid_Parameter
  677.     Call    U1000_Display_Message
  678.     Jmp    C1299            ; .
  679. C1206:                    ; .
  680.     Inc    SI            ; .
  681.     Inc    DI            ; .
  682.     Loop    C1205            ; ..End
  683. C1207:
  684.     Mov    SI,Offset Target_Filename
  685.     Mov    DI,Offset WRK03_Valid_Filename
  686.     Mov    CX,Eleven        ; Set CX to comapre 11 characters
  687. C1208:
  688.     Mov    AL,[SI]            ; Compare for valid target diskette
  689.     Mov    AH,[DI]            ; . filename in the FCB at 06DH
  690.     Cmp    AH,AL            ; .
  691.     Je    C1209            ; .
  692.     Mov    Byte Ptr FLG01_Good_Command,False
  693.     Mov    SI,Offset MES12_Invalid_Parameter
  694.     Call    U1000_Display_Message
  695.     Jmp    C1299            ; .
  696. C1209:                    ; .
  697.     Inc    SI            ; .
  698.     Inc    DI            ; .
  699.     Loop    C1208            ; ..End
  700. C1210:
  701.     Mov    AL,Byte Ptr Parameter_Count
  702.     Mov    Byte Ptr WRK04_Parameter_Count,AL
  703.     Mov    SI,Offset Parameter_String
  704.     Inc    Byte Ptr WRK04_Parameter_Count
  705. C1211:
  706.     Dec    Byte Ptr WRK04_Parameter_Count
  707.     Jz    C1299            ; Go to the end of the module
  708.     Mov    AL,[SI]            ; Put the character into AL
  709.     Cmp    AL,Slash        ; Compare character with a slash
  710.     Je    C1212            ; If so, then continue processing
  711.     Inc    SI            ; Increment the command string addr
  712.     Jmp    C1211            ; Go back and try again
  713. C1212:
  714.     Inc    SI            ; Increment the command string addr
  715.     Mov    AL,[SI]            ; Get the next char after the slash
  716.     Cmp    AL,One_Digit        ; Compare with the char 1
  717.     Je    C1214            ; Set double side flag to false
  718. C1213:
  719.     Mov    Byte Ptr FLG01_Good_Command,False
  720.     Mov    SI,Offset MES12_Invalid_Parameter
  721.     Call    U1000_Display_Message
  722.     Jmp    C1299            ; Go to the end of the module
  723. C1214:
  724.     Mov    Byte Ptr FLG02_Double_Side,False
  725.     Dec    Byte Ptr WRK04_Parameter_Count
  726.     Jz    C1299            ; Go to the end of the module
  727. C1215:
  728.     Dec    Byte Ptr WRK04_Parameter_Count
  729.     Jz    C1299            ; Go to the end of the module
  730.     Inc    SI            ; Increment the command string addr
  731.     Mov    AL,[SI]            ; Get the next char in command line
  732.     Cmp    AL,Space        ; Check for spaces
  733.     Je    C1215            ; If equal to a space, continue
  734. C1216:
  735.     Mov    Byte Ptr FLG01_Good_Command,False
  736.     Mov    SI,Offset MES12_Invalid_Parameter
  737.     Call    U1000_Display_Message
  738. C1299:
  739.     Ret
  740. ;
  741. C1200_Parse_Commands Endp
  742. ;
  743. Page
  744. ;************************************************************************
  745. ;*                                    *
  746. ;*    C1300_GET_EQUIPMENT                        *
  747. ;*                                    *
  748. ;*    This module determines the peripheral devices on the machine.    *
  749. ;*    It invokes the equipment status interrupt and places the    *
  750. ;*    information into the appropriate SYStem parameters.        *
  751. ;*                                    *
  752. ;************************************************************************
  753. ;
  754. Public    C1300_Get_Equipment
  755.  
  756.  
  757. C1300_Get_Equipment Proc Near
  758. ;
  759. C1301:
  760.     Int    Equipment_Interrupt    ; Get the equipment on machine
  761.     Mov    BX,AX            ; Save the result for future use
  762. ;
  763.     And    AX,Parallel_Ports_Mask    ; Get the number of parallel ports
  764.     Mov    CL,Fourteen        ; .
  765.     Shr    AX,CL            ; .
  766.     Mov    Byte Ptr SYS07_No_Parallel_Ports,AL
  767. ;
  768.     Mov    AX,BX            ; Get the game adapter attachments
  769.     And    AX,Game_Adapters_Mask    ; .
  770.     Mov    CL,Twelve        ; .
  771.     Shr    AX,CL            ; .
  772.     Mov    Byte Ptr SYS08_Game_Adapters,AL
  773. ;
  774.     Mov    AX,BX            ; Get the number of RS-232 ports
  775.     And    AX,RS232_Ports_Mask    ; .
  776.     Mov    CL,Nine            ; .
  777.     Shr    AX,CL            ; .
  778.     Mov    Byte Ptr SYS09_No_RS232_Ports,AL
  779. ;
  780.     Mov    AX,BX            ; Get the number of diskette drives
  781.     And    AX,Disk_Drives_Mask    ; .
  782.     Mov    CL,Six            ; .
  783.     Shr    AX,CL            ; .
  784.     Mov    Byte Ptr SYS10_No_Disk_Drives,AL
  785. ;
  786.     Mov    AX,BX            ; Get the initial video mode
  787.     And    AX,Init_Video_Mask    ; .
  788.     Mov    CL,Four            ; .
  789.     Shr    AX,CL            ; .
  790.     Mov    Byte Ptr SYS11_Init_Video_Mode,AL
  791. ;
  792.     Mov    AX,BX            ; Get planar RAM size
  793.     And    AX,Planar_RAM_Mask    ; .
  794.     Mov    CL,Two            ; .
  795.     Shr    AX,CL            ; .
  796.     Mov    Byte Ptr SYS12_Planar_RAM_Size,AL
  797. ;
  798.     Mov    AX,BX            ; Get IPL from diskette flag
  799.     And    AX,IPL_Diskette_Mask    ; .
  800.     Mov    Byte Ptr SYS13_IPL_From_Diskette,AL
  801. ;
  802. C1399:
  803.     Ret
  804. ;
  805. C1300_Get_Equipment Endp
  806. ; 
  807. Page
  808. ;************************************************************************
  809. ;*                                    *
  810. ;*    C1400_VALIDATE_DRIVES                        *
  811. ;*                                    *
  812. ;*    This module determines if the drives specified in the        *
  813. ;*    command line are floppy disk drives or RAM disk drives.        *
  814. ;*    It also checks if copying the source diskette takes place    *
  815. ;*    on a single drive.                        *
  816. ;*                                    *
  817. ;************************************************************************
  818. ;
  819. Public    C1400_Validate_Drives
  820. ;
  821. C1400_Validate_Drives Proc Near
  822. ;
  823. C1401:
  824.     Mov    AH,Default_Drive_Command; Get the PC DOS default drive
  825.     Int    PC_DOS_Interrupt    ; .
  826.     Mov    Byte Ptr SYS14_Default_Drive,AL
  827. C1402:
  828.     Cmp    Byte Ptr SYS10_No_Disk_Drives,Minimum_Drives
  829.     Ja    C1403            ; If not single drive copy, set
  830.                     ; . FLG04 to false
  831.     Mov    Byte Ptr SYS14_Default_Drive,Minimum_Drives
  832.     Mov    Byte Ptr WRK01_Source_Drive,Minimum_Drives
  833.     Mov    Byte Ptr WRK02_Target_Drive,Minimum_Drives
  834.     Jmp    C1499            ; Go to the end of the module
  835. C1403:
  836.     Mov    Byte Ptr FLG04_Single_Drive,False
  837. C1404:
  838.     Cmp    Byte Ptr SYS14_Default_Drive,Maximum_Drives
  839.     Jbe    C1405            ; If below maximum, continue
  840.     Mov    Byte Ptr FLG03_Default_Drive,False
  841.     Mov    SI,Offset MES13_Invalid_Default
  842.     Call    U1000_Display_Message
  843.     Jmp    C1499            ; Go to the end of the module
  844. C1405:
  845.     Dec    Byte Ptr WRK01_Source_Drive
  846.     Cmp    Byte Ptr WRK01_Source_Drive,Minus_One
  847.     Jne    C1406
  848.     Mov    AL,Byte Ptr SYS14_Default_Drive
  849.     Mov    Byte Ptr WRK01_Source_Drive,AL
  850. C1406:
  851.     Dec    Byte Ptr WRK02_Target_Drive
  852.     Cmp    Byte Ptr WRK02_Target_Drive,Minus_One
  853.     Jne    C1407
  854.     Mov    AL,Byte Ptr SYS14_Default_Drive
  855.     Mov    Byte Ptr WRK02_Target_Drive,AL
  856. C1407:
  857.     Mov    AL,Byte Ptr WRK01_Source_Drive
  858.     Mov    AH,Byte Ptr WRK02_Target_Drive
  859.     Cmp    AH,AL            ; Check source drive = target drive
  860.     Jne    C1499            ; If so, then continue
  861.     Mov    Byte Ptr FLG04_Single_Drive,True
  862. C1499:
  863.     Ret
  864. ;
  865. C1400_Validate_Drives Endp
  866. ;
  867. Page
  868. ;************************************************************************
  869. ;*                                    *
  870. ;*    C1500_DISKETTE_MESSAGES                        *
  871. ;*                                    *
  872. ;*    This module displays the appropriate source and target        *
  873. ;*    insertion diskette messages on the screen.            *
  874. ;*                                    *
  875. ;************************************************************************
  876. ;
  877. Public    C1500_Diskette_Messages
  878. ;
  879. C1500_Diskette_Messages Proc Near
  880. ;
  881. C1501:
  882.     Cmp    Byte Ptr FLG07_First_Time,False
  883.     Je    C1502            ; If not first time, continue
  884.     Cmp    Byte Ptr FLG04_Single_Drive,False
  885.     Je    C1502            ; If false, then continue
  886.     Mov    SI,Offset MES15_Single_Drive_Copy
  887.     Call    U1000_Display_Message
  888. C1502:
  889.     Mov    SI,Offset MES09_Insert_Source
  890.     Mov    AL,Byte Ptr WRK01_Source_Drive
  891.     Add    AL,Capital_Letter_A    ; Put the drive letter into AL
  892.     Mov    [SI+Thirty_Four],AL    ; Put the drive letter into the
  893.                     ; . correct position in the message
  894.     Call    U1000_Display_Message    ; Display the message on the screen
  895. C1503:
  896.     Cmp    Byte Ptr FLG04_Single_Drive,True
  897.     Je    C1505            ; If true, go to the message to press
  898.                     ; . any key to continue
  899. C1504:
  900.     Mov    SI,Offset MES10_Insert_Target
  901.     Mov    AL,Byte Ptr WRK02_Target_Drive
  902.     Add    AL,Capital_Letter_A    ; Put the drive letter into AL
  903.     Mov    [SI+Thirty_Four],AL    ; Put the drive letter into the
  904.                     ; . correct position in the message
  905.     Call    U1000_Display_Message    ; Display the message on the screen
  906. C1505:
  907.     Mov    SI,Offset MES16_Press_Any_Key
  908.     Call    U1000_Display_Message
  909.     Mov    Byte Ptr FLG05_Store_Buffer,False
  910.     Call    U1100_Get_Response
  911. C1599:
  912.     Ret
  913. ;
  914. C1500_Diskette_Messages Endp
  915. ;
  916. Page
  917. ;************************************************************************
  918. ;*                                    *
  919. ;*    C1600_GET_FREE_MEMORY                        *
  920. ;*                                    *
  921. ;*    This module calculates the amount of free 16 byte paragraphs    *
  922. ;*    available on the machine. The segment address of the beginning    *
  923. ;*    of free memory is obtained by setting DX to:            *
  924. ;*                                    *
  925. ;*        1. The contents of the stack segment SS plus        *
  926. ;*                                    *
  927. ;*        2. 256 bytes for the Program Segment Prefix plus    *
  928. ;*                                    *
  929. ;*        3. 128 bytes for the stack.                *
  930. ;*                                    *
  931. ;*    After saving the ES segment register on the stack and        *
  932. ;*    initializing both the offset register BX and the 16 byte    *
  933. ;*    counter register CX to zero, the routine begins the looping    *
  934. ;*    through memory 16 bytes at a time (incrementing the segment    *
  935. ;*    register ES by one) until either the module encounters one    *
  936. ;*    of the two (2) conditions:                    *
  937. ;*                                    *
  938. ;*        1. The beginning of Video RAM at the segment address    *
  939. ;*           specified in Video_Address.                *
  940. ;*                                    *
  941. ;*        2. The memory pattern defined by the machine that    *
  942. ;*           indicates no more memory.                *
  943. ;*                                    *
  944. ;*    When either of these two (2) conditions occur, CX contains    *
  945. ;*    the  number of 16 bytes paragraphs of free memory.        *
  946. ;*                                    *
  947. ;*    Since we do not know the size of the transient portion of    *
  948. ;*    COMMAND.COM, FREECOPY makes the worst case assumption that    *
  949. ;*    all of the bytes in COMMAND.COM reside in high memory.        *
  950. ;*                                    *
  951. ;*    This module also allocates space for the ES:BX table, the    *
  952. ;*    CHRN table, the File Allocation Table (FAT) of the source    *
  953. ;*    diskette and at least one track (4608 bytes).            *
  954. ;*                                    *
  955. ;************************************************************************
  956. ;
  957. Page
  958. ;
  959. Public    C1600_Get_Free_Memory
  960. ;
  961. C1600_Get_Free_Memory Proc Near
  962. ;
  963. C1601:
  964.     Mov    DX,SS            ; Calculate the segment address for
  965.                     ; . the beginning of free memory
  966.     Add    DX,Offset MEM04_Top_of_the_Stack
  967. ;
  968.     Push    ES            ; Save ES on the stack for a moment
  969.     Mov    BX,NUL            ; Initialize BX and CX registers
  970.     Mov    CX,NUL            ; ..End
  971. C1602:
  972.     Mov    ES,DX            ; Set ES to the appropriate value
  973.     Cli                ; Turn off interrupts for a moment
  974.     Mov    AX,ES:[BX]        ; Read a word from memory into AX
  975.     Mov    Word Ptr ES:[BX],SOH    ; Put the test pattern into memory
  976.     Cmp    Word Ptr ES:[BX],SOH    ; Compare memory with test pattern
  977.     Mov    ES:[BX],AX        ; Restore the contents of memory
  978.     Sti                ; Turn on the interrupts
  979.     Jne    C1603            ; If not equal, stop looping
  980.     Inc    DX            ; Increment DX segment register
  981.     Cmp    DX,Video_Address    ; Compare for start of Video RAM
  982.     Jae    C1603            ; If so, stop looping
  983.     Inc    CX            ; Increment 16 byte counter CX
  984.     Jmp    C1602            ; Go back and try again
  985. C1603:
  986.     Pop    ES            ; Restore the ES register
  987.     Cmp    CX,Command_Com_Size    ; Compare the paragraph size of
  988.                     ; . free memory with the paragraph
  989.                     ; . size of COMMAND.COM.
  990.     Ja    C1604            ; If greater, continue
  991. ;
  992.     Mov    Byte Ptr FLG01_Good_Command,False
  993.     Mov    SI,Offset MES11_Insufficient_Memory
  994.     Call    U1000_Display_Message    ; Display the message on the screen
  995.     Jmp    C1699            ; Go to the end of the module
  996. C1604:
  997.     Sub    CX,Command_Com_Size    ; Subtract the size of COMMAND.COM
  998.     Cmp    CX,ESBX_Table_Size    ; Compare the paragraph size of the
  999.                     ; . free memory with the paragraph
  1000.                     ; . size of the ES:BX table
  1001.     Ja    C1605            ; If greater, continue
  1002.     Mov    Byte Ptr FLG01_Good_Command,False
  1003.     Mov    SI,Offset MES11_Insufficient_Memory
  1004.     Call    U1000_Display_Message    ; Display the message on the screen
  1005.     Jmp    C1699            ; Go to the end of the module
  1006. C1605:
  1007.     Sub    CX,ESBX_Table_Size    ; Subtract the size of ES:BX table
  1008.     Cmp    CX,CHRN_Table_Size    ; Compare the paragraph size of the
  1009.                     ; . free memory with the paragraph
  1010.                     ; . size of the CHRN table
  1011.     Ja    C1606            ; If greater, continue
  1012. ;
  1013.     Mov    Byte Ptr FLG01_Good_Command,False
  1014.     Mov    SI,Offset MES11_Insufficient_Memory
  1015.     Call    U1000_Display_Message    ; Display the message on the screen
  1016.     Jmp    C1699            ; Go to the end of the module
  1017. C1606:
  1018.     Sub    CX,CHRN_Table_Size    ; Subtract the size of CHRN Table
  1019.     Cmp    CX,FAT_Sector_Size    ; Determine if there is enough memory
  1020.     Jae    C1607            ; to read the File Allocation Table
  1021.     Mov    Byte Ptr FLG01_Good_Command,False
  1022.     Mov    SI,Offset MES11_Insufficient_Memory
  1023.     Call    U1000_Display_Message    ; Display the message on the screen
  1024.     Jmp    C1699            ; Go to the end of the module
  1025. C1607:
  1026.     Sub    CX,FAT_Sector_Size    ; Subtract the size of the source FAT
  1027.     Cmp    CX,Minimum_Memory_Size    ; Determine if the amount of memory
  1028.     Jae    C1608            ; can hold a nine sectored track
  1029. ;
  1030.     Mov    Byte Ptr FLG01_Good_Command,False
  1031.     Mov    SI,Offset MES11_Insufficient_Memory
  1032.     Call    U1000_Display_Message    ; Display the message on the screen
  1033.     Jmp    C1699            ; Go to the end of the module
  1034. C1608:
  1035.     Mov    Word Ptr SYS05_Para_RAM_Size,CX
  1036. C1699:
  1037.     Ret
  1038. ;
  1039. C1600_Get_Free_Memory Endp
  1040. ;
  1041. Page
  1042. ;************************************************************************
  1043. ;*                                    *
  1044. ;*    C1700_CREATE_ESBX_TABLE                        *
  1045. ;*                                    *
  1046. ;*    This module creates the correct ES:BX addresses that are    *
  1047. ;*    used when storing tracks read from the source diskette.        *
  1048. ;*    The routine allocates at most 80 entries in the table for    *
  1049. ;*    double sided diskettes.                        *
  1050. ;*                                    *
  1051. ;************************************************************************
  1052. ;
  1053. Public    C1700_Create_ESBX_Table
  1054. ;
  1055. C1700_Create_ESBX_Table Proc Near
  1056. ;
  1057. C1701:
  1058.     Mov    Word Ptr WRK18_Counter_ESBX_Entries,Zero
  1059.     Mov    AX,Nine            ; Calculate DI = the number of bytes
  1060.     Mov    BX,Sector_Size        ; per track and BX = the number of
  1061.     Mul    BX            ; paragraphs per track
  1062.     Mov    DI,AX            ; .
  1063.     Mov    BX,Paragraph_Size    ; .
  1064.     Div    BX            ; .
  1065.     Mov    BX,AX            ; ..End
  1066. ;
  1067.     Mov    AX,CS            ; Calculate the address of the 1st
  1068.     Mov    CL,Four            ; that will be copied into memory
  1069.     Shl    AX,CL            ; .
  1070.     Add    AX,Offset MEM00_Bottom_Free_Memory
  1071.     Shr    AX,CL            ; .
  1072.     Inc    AX            ; ..End
  1073. ;
  1074.     Mov    SI,Offset MEM03_ESBX_Table
  1075.     Mov    Word Ptr [SI],Zero    ; Put the 1st entry into the table
  1076.     Mov    Word Ptr [SI+Two],AX    ; ..End
  1077. C1702:
  1078.     Cmp    Word Ptr WRK18_Counter_ESBX_Entries,Seventy_Nine
  1079.     Jae    C1705            ; Calculate the ES:BX valid entries
  1080.     Add    SI,Four            ; Get the next ES:BX table address
  1081. ;
  1082.     Mov    AX,[SI-Two]        ; Check for DMA overflow error
  1083.     And    AX,DMA_Boundary_Mask    ; .
  1084.     Shl    AX,CL            ; .
  1085.     Add    AX,DI            ; .
  1086.     Jnc    C1703            ; ..End
  1087. ;
  1088.     Mov    AX,[SI-Two]        ; Correction for DMA overflow
  1089.     Add    AX,BX            ; .
  1090.     Mov    [SI-Two],AX        ; ..End
  1091. C1703:
  1092.     Mov    AX,[SI-Two]        ; Increment the ES segment address
  1093.     Add    AX,BX            ; ..End
  1094. C1704:
  1095.     Mov    Word Ptr [SI],Zero    ; Put the address into the table
  1096.     Mov    Word Ptr [SI+Two],AX    ; ..End
  1097.     Inc    Word Ptr WRK18_Counter_ESBX_Entries
  1098.     Jmp    C1702            ; Go back and find another entry
  1099. C1705:
  1100.     Mov    AX,Word Ptr SYS05_Para_RAM_Size
  1101.     Div    BX            ; Divide by the paragraphs per track
  1102.     Mov    Word Ptr WRK19_Number_ESBX_Entries,AX
  1103.     Cmp    Word Ptr WRK19_Number_ESBX_Entries,Seventy_Nine
  1104.     Jbe    C1799            ; If less than 79, continue
  1105.     Mov    Word Ptr WRK19_Number_ESBX_Entries,Seventy_Nine
  1106. C1799:
  1107.     Ret
  1108. ;
  1109. C1700_Create_ESBX_Table Endp
  1110. ;
  1111. Page
  1112. ;************************************************************************
  1113. ;*                                    *
  1114. ;*    C1800_VALIDATE_SOURCE_DISK                    *
  1115. ;*                                    *
  1116. ;*    This module determines if the source diskette is readable    *
  1117. ;*    and whether it was formatted under PC DOS 1.0, 1.1, 2.0 or    *
  1118. ;*    2.1.  The routine also reads the first copy of the File        *
  1119. ;*    Allocation Table (FAT) storing it for future comparisons    *
  1120. ;*    as well as analyzing it first entry.                *
  1121. ;*                                    *
  1122. ;*    A series of comparisons for the number of sectors per track    *
  1123. ;*    is done for the following reasons.  All diskettes formatted    *
  1124. ;*    under PC DOS 2.0 and 2.1 really have nine sectors.  In order    *
  1125. ;*    to obtain an eight sectored diskette, the operating system    *
  1126. ;*    sets the first byte of the File Allocation Table (FAT)        *
  1127. ;*    accordingly.  In contrast, PC DOS 1.0 and 1.1 formats a track    *
  1128. ;*    to have exactly eight sectors.                    *
  1129. ;*                                    *
  1130. ;************************************************************************
  1131. ;
  1132. Public    C1800_Validate_Source_Disk
  1133. ;
  1134. C1800_Validate_Source_Disk Proc Near
  1135. ;
  1136. C1801:
  1137.     Mov    Byte Ptr FLG08_Good_Read,True
  1138. ;
  1139.     Mov    AL,Byte Ptr WRK01_Source_Drive
  1140.     Mov    Byte Ptr WRK06_Drive_Number,AL
  1141.     Mov    Byte Ptr WRK07_Head_Number,Zero
  1142.     Mov    Byte Ptr WRK08_Track_Number,Zero
  1143.     Mov    Byte Ptr WRK09_Sector_Number,Nine
  1144.     Mov    Byte Ptr WRK10_Number_of_Sectors,One
  1145.     Push    CS            ; Establish the address ES:BX
  1146.     Pop    ES            ; ..End
  1147.     Mov    BX,Offset MEM01_File_Allocation_Table
  1148. ;
  1149.     Call    D1000_Read_Diskette
  1150. ;
  1151.     Cli                ; Set the number of sectors to nine
  1152.     Mov    Byte Ptr SYS18_Disk_Parameter_Table[Four],Nine
  1153.     Sti                ; .
  1154.     Mov    Byte Ptr WRK17_Maximum_Sectors,Nine
  1155. ;                
  1156.     Cmp    Byte Ptr FLG08_Good_Read,True
  1157.     Je    C1803            ; Check for good read of sector nine
  1158.     Cmp    Byte Ptr WRK14_Status_Operation,Sector_Error
  1159.     Je    C1802            ; If so, continue
  1160.     Mov    Byte Ptr FLG15_IO_Error,One
  1161.     Call    D1200_Disk_IO_Error    ; Process the error
  1162.     Jmp    C1899            ; ..End
  1163. C1802:
  1164.     Cli                ; Set the number of sectors to eight
  1165.     Mov    Byte Ptr SYS18_Disk_Parameter_Table[Four],Eight
  1166.     Sti                ; .
  1167.     Mov    Byte Ptr WRK17_Maximum_Sectors,Eight
  1168. C1803:                    ; .
  1169.     Mov    Byte Ptr FLG08_Good_Read,True
  1170. ;
  1171.     Mov    AL,Byte Ptr WRK01_Source_Drive
  1172.     Mov    Byte Ptr WRK06_Drive_Number,AL
  1173.     Mov    Byte Ptr WRK07_Head_Number,Zero
  1174.     Mov    Byte Ptr WRK08_Track_Number,Zero
  1175.     Mov    Byte Ptr WRK09_Sector_Number,Two
  1176.     Mov    Byte Ptr WRK10_Number_of_Sectors,One
  1177.     Push    CS            ; Establish the address ES:BX
  1178.     Pop    ES            ; ..End
  1179.     Mov    BX,Offset MEM01_File_Allocation_Table
  1180. ;
  1181.     Call    D1000_Read_Diskette
  1182. ;
  1183.     Cmp    Byte Ptr FLG08_Good_Read,True
  1184.     Je    C1804            ; If the read operation was
  1185.                     ; . successful, continue
  1186.     Mov    Byte Ptr FLG15_IO_Error,One
  1187.     Call    D1200_Disk_IO_Error    ; Display appropriate error message
  1188.     Jmp    C1899            ; Go to the end of the module
  1189. C1804:
  1190.     Mov    AL,Byte Ptr MEM01_File_Allocation_Table[Zero]
  1191. ;
  1192.     Cmp    AL,One_Side_Eight_Sectors
  1193.     Jne    C1805            ; If not, continue
  1194.     Mov    Byte Ptr WRK15_Maximum_Heads,Zero
  1195.     Mov    Byte Ptr WRK16_Maximum_Tracks,Thirty_Nine
  1196.     Mov    SI,Offset MES03_Copy81_Sectors
  1197.     Jmp    C1809            ; Continue the processing
  1198. C1805:
  1199.     Cmp    AL,Two_Sides_Eight_Sectors
  1200.     Jne    C1806            ; If not, continue
  1201.     Mov    Byte Ptr WRK15_Maximum_Heads,One
  1202.     Mov    Byte Ptr WRK16_Maximum_Tracks,Seventy_Nine
  1203.     Mov    SI,Offset MES04_Copy82_Sectors
  1204.     Jmp    C1809            ; Continue the processing
  1205. C1806:
  1206.     Cmp    AL,One_Side_Nine_Sectors
  1207.     Jne    C1807            ; If not, continue
  1208.     Mov    Byte Ptr WRK15_Maximum_Heads,Zero
  1209.     Mov    Byte Ptr WRK16_Maximum_Tracks,Thirty_Nine
  1210.     Mov    SI,Offset MES05_Copy91_Sectors
  1211.     Jmp    C1809            ; Continue the processing
  1212. C1807:
  1213.     Cmp    AL,Two_Sides_Nine_Sectors
  1214.     Jne    C1808            ; If not, continue
  1215.     Mov    Byte Ptr WRK15_Maximum_Heads,One
  1216.     Mov    Byte Ptr WRK16_Maximum_Tracks,Seventy_Nine
  1217.     Mov    SI,Offset MES06_Copy92_Sectors
  1218.     Jmp    C1809            ; Continue the processing
  1219. C1808:
  1220.     Mov    Byte Ptr FLG08_Good_Read,False
  1221.     Mov    SI,Offset MES19_Unrecoverable_Read
  1222.     Call    U1000_Display_Message    ; Display the message on the screen
  1223.     Mov    SI,Offset MES90_Unknown_FAT_Error
  1224.     Call    U1000_Display_Message    ; Display the message on the screen
  1225.     Jmp    C1899            ; Go to display the message
  1226. C1809:
  1227.     Cmp    Byte Ptr WRK15_Maximum_Heads,Zero
  1228.     Je    C1810            ; If the diskette is single sided,
  1229.                     ; . display the diskette message
  1230.     Cmp    Byte Ptr FLG02_Double_Side,True
  1231.     Je    C1810            ; If the flag indicates to copy 
  1232.                     ; . both sides of the diskette,
  1233.                     ; . then continue
  1234.     Mov    Byte Ptr WRK15_Maximum_Heads,Zero
  1235.     Mov    Byte Ptr WRK16_Maximum_Tracks,Thirty_Nine
  1236. C1810:
  1237.     Mov    AL,Byte Ptr WRK01_Source_Drive
  1238.     Mov    Byte Ptr WRK06_Drive_Number,AL
  1239.     Mov    Byte Ptr WRK07_Head_Number,One
  1240.     Mov    Byte Ptr WRK08_Track_Number,Zero
  1241.     Mov    Byte Ptr WRK09_Sector_Number,One
  1242.     Mov    Byte Ptr WRK10_Number_of_Sectors,One
  1243.     Push    CS            ; Establish the ES segment register
  1244.     Pop    ES            ; ..End
  1245.     Mov    BX,Offset MEM00_Bottom_Free_Memory
  1246. ;
  1247.     Call    D1000_Read_Diskette
  1248. ;
  1249.     Cmp    Byte Ptr FLG08_Good_Read,True
  1250.     Je    C1812            ; Go to display the message
  1251.     Cmp    Byte Ptr WRK15_Maximum_Heads,One
  1252.     Je    C1811            ; If double sided diskette, error!!!
  1253.     Mov    Byte Ptr FLG08_Good_Read,True
  1254.     Mov    Byte Ptr FLG02_Double_Side,False
  1255.     Jmp    C1812            ; Display the appropriate message
  1256. C1811:
  1257.     Mov    SI,Offset MES19_Unrecoverable_Read
  1258.     Call    U1000_Display_Message    ; Display the message on the screen
  1259.     Mov    SI,Offset MES91_Single_Side_Error
  1260.     Call    U1000_Display_Message    ; Display the message on the screen
  1261.     Jmp    C1899            ; Go to the end of the module
  1262. C1812:
  1263.     Call    U1000_Display_Message    ; Display the message on the screen
  1264. C1899:
  1265.     Ret
  1266. ;
  1267. C1800_Validate_Source_Disk Endp
  1268. ;
  1269. Page
  1270. ;************************************************************************
  1271. ;*                                    *
  1272. ;*    C1900_CREATE_CHRN_TABLE                        *
  1273. ;*                                    *
  1274. ;*    This module creates the CHRN table to be used in case the    *
  1275. ;*    target diskette needs to be formatted.    The abbreviation    *
  1276. ;*    stands for C = track number, H = head number, R = sector    *
  1277. ;*    number and N = a code for the number of bytes per sector.    *
  1278. ;*                                    *
  1279. ;************************************************************************
  1280. ;
  1281. Public    C1900_Create_CHRN_Table
  1282. ;
  1283. C1900_Create_CHRN_Table Proc Near
  1284. ;
  1285. C1901:
  1286.     Mov    BH,Byte Ptr WRK15_Maximum_Heads
  1287.     Mov    BL,Byte Ptr WRK16_Maximum_Tracks
  1288.     Mov    AL,Nine
  1289. ;
  1290.     Mov    CL,BH            ; Establish correct track number
  1291.     Shr    BL,CL            ; ..End
  1292. ;
  1293.     Mov    DL,Two            ; . DL = number of sectors
  1294.     Mov    DH,Zero            ; . DH = head number
  1295.     Mov    CH,Zero            ; . CH = track number
  1296.     Mov    CL,One            ; . CL = sector number
  1297.     Mov    SI,Offset MEM02_CHRN_Table; Set up initial registers
  1298. C1902:
  1299.     Mov    [SI],CH            ; Establish an entry in the CHRN
  1300.     Mov    [SI+One],DH        ; . table
  1301.     Mov    [SI+Two],CL        ; .
  1302.     Mov    [SI+Three],DL        ; ..End
  1303. ;
  1304.     Add    SI,Four            ; Get the addr of next CHRN entry
  1305.     Inc    CL            ; Increment the sector number
  1306.     Cmp    CL,AL            ; Compare for maximum sectors
  1307.     Jbe    C1902            ; If not, go back and try again
  1308. ;
  1309.     Mov    CL,One            ; Initialize sector number
  1310.     Inc    DH            ; Increment the head number
  1311.     Cmp    DH,BH            ; Compare for maximum heads
  1312.     Jbe    C1902            ; If not, go back and try again
  1313. ;
  1314.     Mov    CL,One            ; Initialize sector number
  1315.     Mov    DH,Zero            ; Initialize head number
  1316.     Inc    CH            ; Increment the track number
  1317.     Cmp    CH,BL            ; Compare for maximum tracks
  1318.     Jbe    C1902            ; If not, go back and try again
  1319. C1999:
  1320.     Ret
  1321. ;
  1322. C1900_Create_CHRN_Table Endp
  1323. ;
  1324. Page
  1325. ;************************************************************************
  1326. ;*                                    *
  1327. ;*    C2000_READ_SOURCE_DISK                        *
  1328. ;*                                    *
  1329. ;*    This module reads a diskette track by track until it fills    *
  1330. ;*    all of available memory specified by the ES:BX table.  The    *
  1331. ;*    processing sequence is:                        *
  1332. ;*                                    *
  1333. ;*    1. Initializes the SI resgister to point to the correct entry    *
  1334. ;*       in the ES:BX table.                        *
  1335. ;*                                    *
  1336. ;*    2. Prints the initial read message on the screen.        *
  1337. ;*                                    *
  1338. ;*    3. Compares for the end of the ES:BX table and/or the number    *
  1339. ;*       of tracks on the diskette.  If not, continue.  If so,    *
  1340. ;*       return to B1100_Detail_Processing.                *
  1341. ;*                                    *
  1342. ;*    4. Reads a track from the source diskette.            *
  1343. ;*                                    *
  1344. ;*    5. Displays the track and head numbers on the screen.        *
  1345. ;*                                    *
  1346. ;*    6. Transfers control to 3.                    *
  1347. ;*                                    *
  1348. ;************************************************************************
  1349. ;
  1350. Page
  1351. ;
  1352. Public    C2000_Read_Source_Disk
  1353. ;
  1354. C2000_Read_Source_Disk Proc Near
  1355. ;
  1356. C2001:
  1357.     Mov    Byte Ptr FLG08_Good_Read,True
  1358. ;
  1359.     Mov    SI,Offset MEM03_ESBX_Table
  1360.     Mov    Word Ptr WRK18_Counter_ESBX_Entries,Zero
  1361. ;
  1362.     Cmp    Byte Ptr FLG13_First_Read_Write,False
  1363.     Je    C2002            ; If not first time, continue
  1364.     Mov    Byte Ptr WRK31_Track_Read_Counter,Zero
  1365.     Jmp    C2003            ; Go to display the message
  1366. C2002:
  1367.     Cmp    Byte Ptr FLG04_Single_Drive,False
  1368.     Je    C2004            ; If double drive copy, continue
  1369. C2003:
  1370.     Push    SI            ; Save SI = Addr of ES:BX table
  1371.     Mov    SI,Offset MES97_Return_Linefeed
  1372.     Call    U1000_Display_Message    ; Display a return and linefeed
  1373.     Mov    SI,Offset MES17_Reading_Track
  1374.     Mov    AL,Byte Ptr WRK21_Current_Source_Track
  1375.     Call    U1300_Convert_Binary_to_ASCII
  1376.     Mov    [SI+Fifteen],AX        ; Put the track number into message
  1377.     Mov    AL,Byte Ptr WRK20_Current_Source_Head
  1378.     Call    U1300_Convert_Binary_to_ASCII
  1379.     Mov    [SI+Twenty_Five],AL    ; Put the head number into message
  1380.     Call    U1000_Display_Message    ; Display the message on the screeen
  1381. ;
  1382.     Mov    AH,Read_Cursor_Command    ; Get the current cursor position
  1383.     Mov    BH,Byte Ptr SYS03_Active_Page
  1384.     Int    Video_Interrupt        ; ..End
  1385. ;
  1386.     Dec    DH            ; Save the row of the read track and
  1387.     Mov    Byte Ptr WRK24_Read_Message_Row,DH; . head message
  1388. ;
  1389.     Pop    SI            ; Restore SI = Addr of ES:BX table
  1390. C2004:
  1391.     Mov    AX,Word Ptr WRK18_Counter_ESBX_Entries
  1392.     Cmp    AX,Word Ptr WRK19_Number_ESBX_Entries
  1393.     Jbe    C2005            ; If more memory exists, continue
  1394.     Jmp    C2099            ; Go to the end of the module
  1395. C2005:
  1396.     Mov    AL,Byte Ptr WRK31_Track_Read_Counter
  1397.     Cmp    AL,Byte Ptr WRK16_Maximum_Tracks
  1398.     Jbe    C2006            ; If more tracks, then continue
  1399.     Jmp    C2099            ; Go to the end of the module
  1400. C2006:
  1401. ;                    ; Display the current track and head
  1402.     Mov    AL,Byte Ptr WRK24_Read_Message_Row
  1403.     Mov    Byte Ptr WRK28_Current_Message_Row,AL
  1404.     Mov    AL,Byte Ptr WRK20_Current_Source_Head
  1405.     Mov    Byte Ptr WRK29_Current_Head,AL
  1406.     Mov    AL,Byte Ptr WRK21_Current_Source_Track
  1407.     Mov    Byte Ptr WRK30_Current_Track,AL
  1408. ;
  1409.     Call    U1400_Display_Head_and_Track
  1410. ;
  1411.                     ; Establish the disk parameters
  1412.     Mov    AL,Byte Ptr WRK01_Source_Drive
  1413.     Mov    Byte Ptr WRK06_Drive_Number,AL
  1414.     Mov    AL,Byte Ptr WRK20_Current_Source_Head
  1415.     Mov    Byte Ptr WRK07_Head_Number,AL
  1416.     Mov    AL,Byte Ptr WRK21_Current_Source_Track
  1417.     Mov    Byte Ptr WRK08_Track_Number,AL
  1418.     Mov    Byte Ptr WRK09_Sector_Number,One
  1419.     Mov    AL,Byte Ptr WRK17_Maximum_Sectors
  1420.     Mov    Byte Ptr WRK10_Number_of_Sectors,AL
  1421.     Mov    AX,DS:[SI]        ; .
  1422.     Mov    BX,AX            ; .
  1423.     Mov    AX,DS:[SI+Two]        ; .
  1424.     Mov    ES,AX            ; ..End
  1425. ;
  1426.     Call    D1000_Read_Diskette    ; Read the source diskette
  1427. C2007:
  1428.     Cmp    Byte Ptr FLG08_Good_Read,True
  1429.     Je    C2008            ; If the read operation was 
  1430.                     ; . successful, then continue
  1431.     Mov    Byte Ptr FLG15_IO_Error,One
  1432.     Call    D1200_Disk_IO_Error    ; Display appropriate error message
  1433.     Jmp    C2099            ; Go to the end of the module
  1434. C2008:
  1435.     Inc    Byte Ptr WRK31_Track_Read_Counter
  1436.     Inc    Word Ptr WRK18_Counter_ESBX_Entries
  1437.     Add    SI,Four            ; Increment addr of the ES:BX table
  1438.     Cmp    Byte Ptr FLG02_Double_Side,False
  1439.     Je    C2009            ; If single sided, then continue
  1440.     Inc    Byte Ptr WRK20_Current_Source_Head
  1441.     Cmp    Byte Ptr WRK20_Current_Source_Head,One
  1442.     Jbe    C2010            ; If the head number is less than or
  1443.                     ; . equal to one, then continue
  1444.     Mov    Byte Ptr WRK20_Current_Source_Head,Zero
  1445. C2009:
  1446.     Inc    Byte Ptr WRK21_Current_Source_Track
  1447. C2010:
  1448.     Jmp    C2004            ; Go back and read another track
  1449. C2099:
  1450.     Ret
  1451. ;
  1452. C2000_Read_Source_Disk Endp
  1453. ;
  1454. Page
  1455. ;************************************************************************
  1456. ;*                                    *
  1457. ;*    C2100_WRITE_FORMAT_TARGET_DISK                    *
  1458. ;*                                    *
  1459. ;*    This module formats and writes  a diskette track by track    *
  1460. ;*    until it fills all of available memory specified by the        *
  1461. ;*    ES:BX table.  The processing sequence is:            *
  1462. ;*                                    *
  1463. ;*    1. Initializes the SI resgister to point to the correct entry    *
  1464. ;*       in the ES:BX table.                        *
  1465. ;*                                    *
  1466. ;*    2. Prints the initial write message on the screen.        *
  1467. ;*                                    *
  1468. ;*    3. Compares for the end of the ES:BX table and/or the number    *
  1469. ;*       of tracks on the diskette.  If not, continue.  If so,    *
  1470. ;*       return to B1100_Detail_Processing.                *
  1471. ;*                                    *
  1472. ;*    4. Writes a track from the source diskette.            *
  1473. ;*                                    *
  1474. ;*    5. Displays the track and head numbers on the screen.        *
  1475. ;*                                    *
  1476. ;*    6. Transfers control to 3.                    *
  1477. ;*                                    *
  1478. ;************************************************************************
  1479. ;
  1480. Public    C2100_Write_Format_Target_Disk
  1481. ;
  1482. C2100_Write_Format_Target_Disk Proc Near
  1483. ;
  1484. C2101:
  1485.     Mov    Byte Ptr FLG09_Good_Write,True
  1486.     Mov    Byte Ptr FLG11_Good_Format,True
  1487. ;
  1488.     Mov    Byte Ptr WRK13_Retry_Counter,Number_of_Retries
  1489. ;
  1490.     Mov    SI,Offset MEM03_ESBX_Table
  1491.     Mov    Word Ptr WRK18_Counter_ESBX_Entries,Zero
  1492. ;
  1493.     Cmp    Byte Ptr FLG13_First_Read_Write,False
  1494.     Je    C2102            ; If not first time, continue
  1495.     Mov    Byte Ptr WRK32_Track_Write_Counter,Zero
  1496.     Jmp    C2103            ; Go to display the message
  1497. C2102:
  1498.     Cmp    Byte Ptr FLG04_Single_Drive,False
  1499.     Je    C2104            ; If double drive copy, continue
  1500. C2103:
  1501.     Push    SI            ; Save SI = Addr of ES:BX table
  1502. ;
  1503.     Mov    SI,Offset MES97_Return_Linefeed
  1504.     Call    U1000_Display_Message    ; Display return and line feed
  1505.     Mov    SI,Offset MES23_Writing_Track
  1506.     Call    U1000_Display_Message    ; Display write track message
  1507. ;
  1508.     Mov    AH,Read_Cursor_Command    ; Get the current cursor position
  1509.     Mov    BH,Byte Ptr SYS03_Active_Page
  1510.     Int    Video_Interrupt        ; ..End
  1511. ;
  1512.     Dec    DH            ; Save the row of the I/O track and
  1513.     Mov    Byte Ptr WRK27_Write_Message_Row,DH; . head information
  1514.     Sub    DH,Two            ; .
  1515.     Mov    Byte Ptr WRK24_Read_Message_Row,DH
  1516. ;
  1517.     Pop    SI            ; Restore SI = Addr of ES:BX table
  1518. C2104:
  1519.     Mov    AX,Word Ptr WRK18_Counter_ESBX_Entries
  1520.     Cmp    AX,Word Ptr WRK19_Number_ESBX_Entries
  1521.     Jbe    C2105            ; If more memory exists, continue
  1522.     Jmp    C2199            ; Go to the end of the module
  1523. C2105:
  1524.     Mov    AL,Byte Ptr WRK32_Track_Write_Counter
  1525.     Cmp    AL,Byte Ptr WRK16_Maximum_Tracks
  1526.     Jbe    C2106            ; If more tracks, then continue
  1527.     Mov    Byte Ptr FLG14_Copy_Complete,True
  1528.     Jmp    C2199            ; Go to the end of the module
  1529. C2106:
  1530. ;                    ; Establish the disk parameters
  1531.     Mov    AL,Byte Ptr WRK02_Target_Drive
  1532.     Mov    Byte Ptr WRK06_Drive_Number,AL
  1533.     Mov    AL,Byte Ptr WRK22_Current_Target_Head
  1534.     Mov    Byte Ptr WRK07_Head_Number,AL
  1535.     Mov    AL,Byte Ptr WRK23_Current_Target_Track
  1536.     Mov    Byte Ptr WRK08_Track_Number,AL
  1537.     Mov    Byte Ptr WRK09_Sector_Number,One
  1538.     Mov    AL,Byte Ptr WRK17_Maximum_Sectors
  1539.     Mov    Byte Ptr WRK10_Number_of_Sectors,AL
  1540.     Mov    AX,DS:[SI+Two]        ; .
  1541.     Mov    Word Ptr WRK11_Segment_Address,AX
  1542.     Mov    AX,DS:[SI]        ; .
  1543.     Mov    Word Ptr WRK12_Offset_Address,AX
  1544. ;
  1545.     Call    D1100_Write_Format_Diskette
  1546. ;
  1547.     Cmp    Byte Ptr FLG11_Good_Format,True
  1548.     Je    C2107            ; If a good format, continue
  1549.     Cmp    Byte Ptr FLG09_Good_Write,True
  1550.     Je    C2107            ; If a good write, continue
  1551.     Call    D1200_Disk_IO_Error    ; Display appropriate error message
  1552.     Jmp    C2199            ; Go to the end of the module
  1553. C2107:
  1554.     Inc    Byte Ptr WRK32_Track_Write_Counter
  1555.     Inc    Word Ptr WRK18_Counter_ESBX_Entries
  1556.     Add    SI,Four            ; Increment addr of the ES:BX table
  1557.     Cmp    Byte Ptr FLG02_Double_Side,False
  1558.     Je    C2108            ; If single sided, then continue
  1559.     Inc    Byte Ptr WRK22_Current_Target_Head
  1560.     Cmp    Byte Ptr WRK22_Current_Target_Head,One
  1561.     Jbe    C2109            ; If the head number is less than or
  1562.                     ; . equal to one, then continue
  1563.     Mov    Byte Ptr WRK22_Current_Target_Head,Zero
  1564. C2108:
  1565.     Inc    Byte Ptr WRK23_Current_Target_Track
  1566. C2109:
  1567.     Jmp    C2104            ; Go back and write another track
  1568. C2199:
  1569.     Ret
  1570. ;
  1571. C2100_Write_Format_Target_Disk Endp
  1572. ;
  1573. Page
  1574. ;************************************************************************
  1575. ;*                                    *
  1576. ;*    C2200_CHECK_FILE_ALLOC_TABLE                    *
  1577. ;*                                    *
  1578. ;*    This module checks the File Allocation Table (FAT) of the    *
  1579. ;*    diskette in the source drive and compares it with the File    *
  1580. ;*    Allocation Table (FAT) of the original source diskette.  If    *
  1581. ;*    there are any differences, the program sets the flag        *
  1582. ;*    FLG12_Good_FAT to False; otherwise, the flag is True.        *
  1583. ;*                                    *
  1584. ;************************************************************************
  1585. ;
  1586. Public    C2200_Check_File_Alloc_Table
  1587. ;
  1588. C2200_Check_File_Alloc_Table Proc Near
  1589. ;
  1590. C2201:
  1591.     Mov    Byte Ptr FLG12_Good_FAT,True
  1592. ;
  1593.     Mov    AL,Byte Ptr WRK01_Source_Drive
  1594.     Mov    Byte Ptr WRK06_Drive_Number,AL
  1595.     Mov    Byte Ptr WRK07_Head_Number,Zero
  1596.     Mov    Byte Ptr WRK08_Track_Number,Zero
  1597.     Mov    Byte Ptr WRK09_Sector_Number,Two
  1598.     Mov    Byte Ptr WRK10_Number_of_Sectors,One
  1599.     Push    CS            ; Establish the ES segment register
  1600.     Pop    ES            ; ..End
  1601.     Mov    BX,Offset MEM00_Bottom_Free_Memory
  1602. ;
  1603.     Call    D1000_Read_Diskette    ; Read the File Allocation Table
  1604. ;
  1605.     Cmp    Byte Ptr FLG08_Good_Read,True
  1606.     Je    C2202            ; If the read operation was
  1607.                     ; . successful, continue
  1608.     Mov    Byte Ptr FLG15_IO_Error,One
  1609.     Call    D1200_Disk_IO_Error    ; Display appropriate error message
  1610.     Jmp    C2299            ; Go to the end of the module
  1611. C2202:
  1612.     Mov    SI,Offset MEM01_File_Allocation_Table
  1613.     Mov    DI,Offset MEM00_Bottom_Free_Memory
  1614.     Mov    CX,Sector_Size        ; Set counter CX to compare the
  1615.                     ; . sector size in words
  1616.     Shr    CX,1            ; ..End
  1617.     Cld                ; Clear the direction flag
  1618.     Rep    Cmpsw            ; Compare all of the 512 bytes
  1619.     Jne    C2203            ; If there is a discrepancy, go to
  1620.                     ; . the error message routine
  1621.     Jmp    C2299            ; Go to the end of the module
  1622. C2203:
  1623.     Mov    Byte Ptr FLG12_Good_FAT,False
  1624.     Mov    SI,Offset MES19_Unrecoverable_Read
  1625.     Call    U1000_Display_Message    ; Display the message on the screen
  1626.     Mov    SI,Offset MES90_Unknown_FAT_Error
  1627.     Call    U1000_Display_Message    ; Display the message on the screen
  1628. C2299:
  1629.     Ret
  1630. ;
  1631. C2200_Check_File_Alloc_Table Endp
  1632. ;
  1633. Page
  1634. ;************************************************************************
  1635. ;*                                    *
  1636. ;*    D1000_READ_DISKETTE                        *
  1637. ;*                                    *
  1638. ;*    This module reads a track at a time from a diskette. If it    *
  1639. ;*    fails to read the diskette it tries Number_of_Retries = 5    *
  1640. ;*    times.                                *
  1641. ;*                                    *
  1642. ;************************************************************************
  1643. ;
  1644. Public    D1000_Read_Diskette
  1645. ;
  1646. D1000_Read_Diskette Proc Near
  1647. ;
  1648. D1001:
  1649.     Mov    Byte Ptr WRK13_Retry_Counter,Number_of_Retries
  1650. D1002:
  1651.     Clc                ; Clear the carry flag
  1652.     Mov    AH,Read_Command        ; Read the data on the diskette
  1653.     Mov    DL,Byte Ptr WRK06_Drive_Number
  1654.     Mov    DH,Byte Ptr WRK07_Head_Number
  1655.     Mov    CH,Byte Ptr WRK08_Track_Number
  1656.     Mov    CL,Byte Ptr WRK09_Sector_Number
  1657.     Mov    AL,Byte Ptr WRK10_Number_of_Sectors
  1658.     Int    Disk_Interrupt        ; ..End
  1659. ;
  1660.     Mov    Byte Ptr WRK14_Status_Operation,AH
  1661.     Jnc    D1099            ; Go to the end of the module
  1662. D1003:
  1663.     Dec    Byte Ptr WRK13_Retry_Counter
  1664.     Jz    D1004            ; Could not read the diskette
  1665.     Clc                ; Clear the carry flag
  1666.     Mov    AH,Reset_Command    ; Initialize the disk controller
  1667.     Int    Disk_Interrupt        ; .
  1668.     Mov    Byte Ptr WRK14_Status_Operation,AH
  1669.     Jnc    D1002            ; .
  1670.     Jmp    D1003            ; ..End
  1671. D1004:
  1672.     Mov    Byte Ptr FLG08_Good_Read,False
  1673. D1099:
  1674.     Ret
  1675. ;
  1676. D1000_Read_Diskette Endp
  1677. ;
  1678. Page
  1679. ;************************************************************************
  1680. ;*                                    *
  1681. ;*    D1100_WRITE_FORMAT_DISKETTE                    *
  1682. ;*                                    *
  1683. ;*    This module formats and writes a track at a time to a         *
  1684. ;*    diskette.  If it fails to format or a write a track, it tries    *
  1685. ;*    Number_of_Retries = 5 times.                    *
  1686. ;*                                    *
  1687. ;************************************************************************
  1688. ;
  1689. Public    D1100_Write_Format_Diskette
  1690. ;
  1691. D1100_Write_Format_Diskette Proc Near
  1692. ;
  1693. D1101:
  1694.     Mov    Byte Ptr WRK13_Retry_Counter,Number_of_Retries
  1695. D1102:
  1696.     Clc                ; Clear the carry flag
  1697.     Mov    AH,Format_Command    ; Format the diskette
  1698.     Mov    DL,Byte Ptr WRK06_Drive_Number
  1699.     Mov    DH,Byte Ptr WRK07_Head_Number
  1700.     Mov    CH,Byte Ptr WRK08_Track_Number
  1701.     Mov    CL,Byte Ptr WRK09_Sector_Number
  1702.     Mov    AL,Byte Ptr WRK10_Number_of_Sectors
  1703.     Push    CS            ; .
  1704.     Pop    ES            ; .
  1705.     Mov    BX,Word Ptr WRK33_CHRN_Table_Address
  1706.     Int    Disk_Interrupt        ; ..End
  1707.     Mov    Byte Ptr WRK14_Status_Operation,AH
  1708.     Jnc    D1105            ; Formatted the diskette
  1709. D1103:
  1710.     Dec    Byte Ptr WRK13_Retry_Counter
  1711.     Jz    D1104            ; Go to format error processing
  1712.     Clc                ; Clear the carry flag
  1713.     Mov    AH,Reset_Command    ; Initialize the disk controller
  1714.     Int    Disk_Interrupt        ; .
  1715.     Mov    Byte Ptr WRK14_Status_Operation,AH
  1716.     Jnc    D1102            ; Try to format the disk again
  1717.     Jmp    D1103            ; Try to initialize the disk again
  1718. D1104:
  1719.     Mov    Byte Ptr FLG15_IO_Error,Zero
  1720.     Mov    Byte Ptr FLG11_Good_Format,False
  1721.     Jmp    D1199            ; Go to the end of the module
  1722. D1105:
  1723.     Mov    Byte Ptr WRK13_Retry_Counter,Number_of_Retries
  1724. D1106:
  1725.     Clc                ; Clear the carry flag
  1726.     Mov    AH,Write_Command    ; Write the diskette
  1727.     Mov    ES,Word Ptr WRK11_Segment_Address
  1728.     Mov    BX,Word Ptr WRK12_Offset_Address
  1729.     Mov    AL,Byte Ptr WRK10_Number_of_Sectors
  1730.     Int    Disk_Interrupt        ; .
  1731.     Mov    Byte Ptr WRK14_Status_Operation,AH
  1732.     Jnc    D1109            ; ..End
  1733. D1107:
  1734.     Dec    Byte Ptr WRK13_Retry_Counter
  1735.     Jz    D1108            ; Go to write error processing
  1736.     Clc                ; Clear the carry flag
  1737.     Mov    AH,Reset_Command    ; Initialize the disk controller
  1738.     Int    Disk_Interrupt        ; .
  1739.     Mov    Byte Ptr WRK14_Status_Operation,AH
  1740.     Jnc    D1106            ; .
  1741.     Jmp    D1107            ; ..End
  1742. D1108:
  1743.     Mov    Byte Ptr FLG15_IO_Error,Two
  1744.     Mov    Byte Ptr FLG09_Good_Write,False
  1745.     Jmp    D1199            ; Go to the end of the module
  1746. D1109:
  1747.     Add    Word Ptr WRK33_CHRN_Table_Address,Thirty_Six
  1748. ;
  1749.     Mov    AL,Byte Ptr WRK27_Write_Message_Row
  1750.     Mov    Byte Ptr WRK28_Current_Message_Row,AL
  1751.     Mov    AL,Byte Ptr WRK22_Current_Target_Head
  1752.     Mov    Byte Ptr WRK29_Current_Head,AL
  1753.     Mov    AL,Byte Ptr WRK23_Current_Target_Track
  1754.     Mov    Byte Ptr WRK30_Current_Track,AL
  1755.     Call    U1400_Display_Head_and_Track
  1756. D1199:
  1757.     Ret
  1758. ;
  1759. D1100_Write_Format_Diskette Endp
  1760. ;
  1761. Page
  1762. ;************************************************************************
  1763. ;*                                    *
  1764. ;*    D1200_DISK_IO_ERROR                        *
  1765. ;*                                    *
  1766. ;*    This module fans out a disk error.  It tells a user if it    *
  1767. ;*    occured on a read, format or write operation.  If it cannot    *
  1768. ;*    determine the nature of the error, the routine displays an    *
  1769. ;*    unknown disk error message.                    *
  1770. ;*                                    *
  1771. ;************************************************************************
  1772. ;
  1773. Public    D1200_Disk_IO_Error
  1774. ;
  1775. D1200_Disk_IO_Error Proc Near
  1776. ;
  1777. D1201:
  1778.     Cmp    Byte Ptr WRK14_Status_Operation,Time_Out_Error
  1779.     Jne    D1202            ; If not time out error, continue
  1780.     Mov    SI,Offset MES08_Drive_Not_Ready
  1781.     Mov    AL,Byte Ptr WRK06_Drive_Number
  1782.     Add    AL,Capital_Letter_A    ; Convert drive number to a letter
  1783.     Mov    [SI+Twenty_Four],AL    ; Put the drive letter into position
  1784.     Call    U1000_Display_Message
  1785.     Jmp    D1299            ; Go to the end of the module
  1786. D1202:
  1787.     Cmp    Byte Ptr FLG15_IO_Error,Zero
  1788.     Jne    D1203            ; If not a format error, continue
  1789.     Mov    SI,Offset MES18_Unrecoverable_Format
  1790.     Jmp    D1206            ; Continue processing
  1791. D1203:
  1792.     Cmp    Byte Ptr FLG15_IO_Error,One
  1793.     Jne    D1204            ; If not a read error, continue
  1794.     Mov    SI,Offset MES19_Unrecoverable_Read
  1795.     Jmp    D1206            ; Continue processing
  1796. D1204:
  1797.     Cmp    Byte Ptr FLG15_IO_Error,Two
  1798.     Jne    D1205            ; If not a write error, continue
  1799.     Mov    SI,Offset MES21_Unrecoverable_Write
  1800.     Jmp    D1206            ; Continue processing
  1801. D1205:
  1802.     Mov    SI,Offset MES22_Unrecoverable_IO
  1803. D1206:
  1804.     Call    U1000_Display_Message    ; Display the message on the screen
  1805. D1207:
  1806.     Cmp    Byte Ptr WRK14_Status_Operation,Seek_Error
  1807.     Jne    D1208            ; If not a seek error, continue
  1808.     Mov    SI,Offset MES80_Seek_Error
  1809.     Jmp    D1217            ; Continue processing
  1810. D1208:
  1811.     Cmp    Byte Ptr WRK14_Status_Operation,Controller_Error
  1812.     Jne    D1209            ; If not a controller error, continue
  1813.     Mov    SI,Offset MES81_Controller_Error
  1814.     Jmp    D1217            ; Continue processing
  1815. D1209:
  1816.     Cmp    Byte Ptr WRK14_Status_Operation,CRC_Error
  1817.     Jne    D1210            ; If not a CRC error, continue
  1818.     Mov    SI,Offset MES82_CRC_Error
  1819.     Jmp    D1217            ; Continue processing
  1820. D1210:
  1821.     Cmp    Byte Ptr WRK14_Status_Operation,DMA_Boundary_Error
  1822.     Jne    D1211            ; If not DMA boundary error, continue
  1823.     Mov    SI,Offset MES83_DMA_Boundary_Error
  1824.     Jmp    D1217            ; Continue processing
  1825. D1211:
  1826.     Cmp    Byte Ptr WRK14_Status_Operation,DMA_Error
  1827.     Jne    D1212            ; If not a DMA error, continue
  1828.     Mov    SI,Offset MES84_DMA_Error
  1829.     Jmp    D1217            ; Continue processing
  1830. D1212:
  1831.     Cmp    Byte Ptr WRK14_Status_Operation,Sector_Error
  1832.     Jne    D1213            ; If not a sector error, continue
  1833.     Mov    SI,Offset MES85_Sector_Error
  1834.     Jmp    D1217            ; Continue processing
  1835. D1213:
  1836.     Cmp    Byte Ptr WRK14_Status_Operation,Write_Protect_Error
  1837.     Jne    D1214            ; If not write protected, continue
  1838.     Mov    SI,Offset MES86_Write_Protect_Error
  1839.     Jmp    D1217            ; Continue processing
  1840. D1214:
  1841.     Cmp    Byte Ptr WRK14_Status_Operation,Address_Mark_Error
  1842.     Jne    D1215            ; If not addr mark error, continue
  1843.     Mov    SI,Offset MES87_Address_Mark_Error
  1844.     Jmp    D1217            ; Continue processing
  1845. D1215:
  1846.     Cmp    Byte Ptr WRK14_Status_Operation,Command_Error
  1847.     Jne    D1216            ; If not a command error, continue
  1848.     Mov    SI,Offset MES88_Command_Error
  1849.     Jmp    D1217            ; Continue processing
  1850. D1216:
  1851.     Mov    SI,Offset MES89_Unknown_Error
  1852. D1217:
  1853.     Call    U1000_Display_Message    ; Display the message on the screen
  1854. D1299:
  1855.     Ret
  1856. ;
  1857. D1200_Disk_IO_Error Endp
  1858. ;
  1859. Page
  1860. ;************************************************************************
  1861. ;*                                    *
  1862. ;*    S1000_SETUP_DISK_PARAM_TABLE                    *
  1863. ;*                                    *
  1864. ;*    This module sets up the Disk Parameter Table (Int 1EH) so that    *
  1865. ;*    it points to the disk parameters for PC DOS 2.1 contained in    *
  1866. ;*    this program.                            *
  1867. ;*                                    *
  1868. ;************************************************************************
  1869. ;
  1870. Public    S1000_Setup_Disk_Param_Table
  1871. ;
  1872. S1000_Setup_Disk_Param_Table Proc Near
  1873. ;
  1874. S1001:
  1875.     Cli                ; Turn off the interrupts
  1876. ;
  1877.     Push    AX            ; Save the registers
  1878.     Push    BX            ; .
  1879.     Push    DS            ; ..End
  1880. ;
  1881.     Sub    AX,AX            ; Initialize DS to Absolute Zero
  1882.     Mov    DS,AX            ; ..End
  1883. ;
  1884.     Mov    BX,Disk_Parameter_Addr    ; Save and redirect the address
  1885.     Mov    AX,[BX]            ; .
  1886.     Mov    Word Ptr CS:SYS16_Save_DPT_Offset,AX
  1887.     Mov    AX,[BX+Two]        ; .
  1888.     Mov    Word Ptr CS:SYS17_Save_DPT_Segment,AX
  1889.                     ; .
  1890.     Mov    AX,Offset SYS18_Disk_Parameter_Table
  1891.     Mov    [BX],AX            ; .
  1892.     Mov    AX,CS            ; .
  1893.     Mov    [BX+Two],AX        ; ..End
  1894. ;
  1895.     Pop    DS            ; Restore the registers
  1896.     Pop    BX            ; .
  1897.     Pop    AX            ; ..End
  1898. ;
  1899.     Sti                ; Turn on the interrupts
  1900. S1099:
  1901.     Ret
  1902. ;
  1903. S1000_Setup_Disk_Param_Table Endp
  1904. ;
  1905. Page
  1906. ;************************************************************************
  1907. ;*                                    *
  1908. ;*    S1100_RESTORE_DISK_PARAM_TABLE                    *
  1909. ;*                                    *
  1910. ;*    This module restores the Disk Parameter Table to its original    *
  1911. ;*    address in PC DOS.                        *
  1912. ;*                                    *
  1913. ;************************************************************************
  1914. ;
  1915. Public    S1100_Restore_Disk_Param_Table
  1916. ;
  1917. S1100_Restore_Disk_Param_Table Proc Near
  1918. ;
  1919. S1101:
  1920.     Cli                ; Turn off the interrupts
  1921. ;
  1922.     Push    AX            ; Save the registers
  1923.     Push    BX            ; .
  1924.     Push    DS            ; ..End
  1925. ;
  1926.     Sub    AX,AX            ; Initialize DS to Absolute Zero
  1927.     Mov    DS,AX            ; ..End
  1928. ;
  1929.     Mov    BX,Disk_Parameter_Addr    ; Restore Disk Parameter Address
  1930.     Mov    AX,Word Ptr CS:SYS16_Save_DPT_Offset
  1931.     Mov    [BX],AX            ; .
  1932.     Mov    AX,Word Ptr CS:SYS17_Save_DPT_Segment
  1933.     Mov    [BX+Two],AX        ; ..End
  1934. ;
  1935.     Pop    DS            ; Restore the registers
  1936.     Pop    BX            ; .
  1937.     Pop    AX            ; ..End
  1938. ;
  1939.     Sti                ; Turn on the interrupts
  1940. S1199:
  1941.     Ret
  1942. ;
  1943. S1100_Restore_Disk_Param_Table Endp
  1944. ;
  1945. Page
  1946. ;************************************************************************
  1947. ;*                                    *
  1948. ;*    U1000_DISPLAY_MESSAGE                        *
  1949. ;*                                    *
  1950. ;*    This module displays a message on the screen. Before calling    *
  1951. ;*    this module, the offset of the message should be in SI         *
  1952. ;*    relative to the DS register.  This routine preserves the    *
  1953. ;*    registers and the flags.                    *
  1954. ;*                                    *
  1955. ;************************************************************************
  1956. ;
  1957. Public    U1000_Display_Message
  1958. ;
  1959. U1000_Display_Message Proc Near
  1960. ;
  1961. U1001:
  1962.     Push    AX            ; Save the registers and flags
  1963.     Push    BX            ; .
  1964.     Push    SI            ; .
  1965.     Pushf                ; ..End
  1966. U1002:
  1967.     Mov    AL,[SI]            ; Put the character into AL
  1968.     Cmp    AL,EOT            ; Compare for the end of the string
  1969.     Je    U1090            ; If so, go to end of the module
  1970.     Mov    AH,Write_TTY_Command    ; Write the Character
  1971.     Mov    BH,Byte Ptr SYS03_Active_Page
  1972.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  1973.     Int    Video_Interrupt        ; ..End
  1974.     Inc    SI            ; Increment the SI counter
  1975.     Jmp    U1002            ; Go back and try again
  1976. U1090:
  1977.     Popf                ; Restore the registers and flags
  1978.     Pop    SI            ; .
  1979.     Pop    BX            ; .
  1980.     Pop    AX            ; ..End
  1981. U1099:
  1982.     Ret
  1983. ;
  1984. U1000_Display_Message Endp
  1985. ;
  1986. Page
  1987. ;************************************************************************
  1988. ;*                                    *
  1989. ;*    U1100_GET_RESPONSE                        *
  1990. ;*                                    *
  1991. ;*    This module gets the response from the keyboard and displays    *
  1992. ;*    the information on the video display unit.  The keyboard    *
  1993. ;*    buffer is WRK05_Keyboard_Buffer.  The first byte of this    *
  1994. ;*    buffer contains the length of the buffer and must be less    *
  1995. ;*    than or equal to 80 characters.  The next 80 characters are    *
  1996. ;*    the acutal buffer. The character EOT denotes the end of the    *
  1997. ;*    buffer and can occur in any one of the 80 characters.        *
  1998. ;*                                    *
  1999. ;************************************************************************
  2000. ;
  2001. Public    U1100_Get_Response
  2002. ;
  2003. U1100_Get_Response Proc Near
  2004. ;
  2005. U1101:
  2006.     Push    AX            ; Save the registers and flags
  2007.     Push    BX            ; .
  2008.     Push    CX            ; .
  2009.     Push    SI            ; .
  2010.     Pushf                ; ..End
  2011. U1102:
  2012.     Mov    SI,Offset WRK05_Keyboard_Buffer+1
  2013.     Mov    CX,NUL            ; Initialize the CX counter register
  2014. U1103:
  2015.     Mov    AH,Read_Keyboard_Command; Read the character from keyboard
  2016.     Int    PC_DOS_Interrupt    ; ..End
  2017.     Cmp    AL,ETX            ; Compare for a control break
  2018.     Jne    U1104            ; If not, then continue
  2019.     Mov    SI,Offset MES98_Control_Break
  2020.     Call    U1000_Display_Message    ; Display the message on the screen
  2021.     Jmp    B1201            ; Go to B1200_Final_Process
  2022. U1104:
  2023.     Cmp    Byte Ptr FLG05_Store_Buffer,True
  2024.     Je    U1105            ; If store keyboard entries, continue
  2025.     Jmp    U1190            ; If not, go to end of the module
  2026. U1105:
  2027.     Cmp    AL,BS            ; Is AL a backspace character???
  2028.     Jne    U1106            ; If not, continue processing AL
  2029.     Cmp    CX,NUL            ; Is the cursor at column zero????
  2030.     Je    U1103            ; Yes, so get another character
  2031.     Dec    CX            ; Decrement CX to point to the
  2032.                     ; . previous cursor location
  2033.     Dec    SI            ; Decrement SI to go back to the
  2034.                     ; . previos buffer location
  2035. ;
  2036.     Mov    AH,Write_TTY_Command    ; Write a backspace to the screen
  2037.     Mov    AL,BS            ; .
  2038.     Mov    BH,Byte Ptr SYS03_Active_Page
  2039.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2040.     Int    Video_Interrupt        ; ..End
  2041. ;
  2042.     Mov    AH,Write_TTY_Command    ; Write a space to the screen
  2043.     Mov    AL,Space        ; .
  2044.     Mov    BH,Byte Ptr SYS03_Active_Page
  2045.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2046.     Int    Video_Interrupt        ; ..End
  2047. ;
  2048.     Mov    AH,Write_TTY_Command    ; Write a backspace to the screen
  2049.     Mov    AL,BS            ; .
  2050.     Mov    BH,Byte Ptr SYS03_Active_Page
  2051.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2052.     Int    Video_Interrupt        ; ..End
  2053. ;
  2054.     Jmp    U1103            ; Go back and get another character
  2055. U1106:
  2056.     Cmp    AL,CR            ; Compare char for a carriage return
  2057.     Je    U1108            ; If so, insert an EOT into buffer
  2058.     Cmp    CX,Keyboard_Buffer_Size    ; Check for keyboard buffer full
  2059.     Jae    U1107            ; If so, sound bell and get new char
  2060.     Mov    [SI],AL            ; Put the character into the buffer
  2061.     Inc    SI            ; Increment the keyboard address
  2062.     Inc    CX            ; Increment the CX character counter
  2063.     Jmp    U1103            ; Go back and get another character
  2064. U1107:
  2065.     Mov    AH,Write_TTY_Command    ; Sound the beep from the screen
  2066.     Mov    AL,Bell            ; .
  2067.     Mov    BH,Byte Ptr SYS03_Active_Page
  2068.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2069.     Int    Video_Interrupt        ; ..End
  2070.     Jmp    U1103            ; Go back and get another character
  2071. U1108:
  2072.     Mov    AL,EOT            ; Put an EOT into the buffer
  2073.     Mov    [SI],AL            ; ..End
  2074. ;
  2075.     Mov    AH,Write_TTY_Command    ; Write a carriage return to the
  2076.     Mov    AL,CR            ; . screen
  2077.     Mov    BH,Byte Ptr SYS03_Active_Page
  2078.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2079.     Int    Video_Interrupt        ; ..End
  2080. ;
  2081.     Mov    AH,Write_TTY_Command    ; Write a line feed to the screen
  2082.     Mov    AL,LF            ; .
  2083.     Mov    BH,Byte Ptr SYS03_Active_Page
  2084.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2085.     Int    Video_Interrupt        ; ..End
  2086. ;
  2087.     Mov    WRK05_Keyboard_Buffer[0],CL; Set the length accrodingly
  2088. U1190:
  2089.     Popf                ; Restore the registers and flags
  2090.     Pop    SI            ; .
  2091.     Pop    CX            ; .
  2092.     Pop    BX            ; .
  2093.     Pop    AX            ; ..End
  2094. U1199:
  2095.     Ret
  2096. U1100_Get_Response Endp
  2097. ;
  2098. Page
  2099. ;************************************************************************
  2100. ;*                                    *
  2101. ;*    U1200_GET_YES_OR_NO                        *
  2102. ;*                                    *
  2103. ;*    This module asks for a [Yy]es or [Nn]o answer from a user.  The    *
  2104. ;*    routine accepts only a [Yy] or [Nn] and exists with the flag    *
  2105. ;*    FLG06_Yes_or_No set to True for YES and False for NO.        *
  2106. ;*                                    *
  2107. ;************************************************************************
  2108. ;
  2109. Public    U1200_Get_Yes_or_No
  2110. ;
  2111. U1200_Get_Yes_or_No Proc Near
  2112. ;
  2113. U1201:
  2114.     Push    AX            ; Save the registers and flags
  2115.     Push    SI            ; .
  2116.     Pushf                ; ..End
  2117. U1202:
  2118.     Mov    AH,Read_Keyboard_Command; Get a character from keyboard
  2119.     Int    PC_DOS_Interrupt    ; ..End
  2120.     Cmp    AL,ETX            ; Compare for control break
  2121.     Jne    U1203            ; If not, then continue
  2122.     Mov    SI,Offset MES98_Control_Break
  2123.     Call    U1000_Display_Message    ; Display the message on the screen
  2124.     Jmp    B1201            ; Go to B1200_Final_Process
  2125. U1203:
  2126.     Cmp    AL,Capital_Letter_Y    ; Check for capital letter Y
  2127.     Jne    U1204            ; ..End
  2128.     Mov    Byte Ptr FLG06_Yes_or_No,True
  2129.     Mov    SI,Offset MES24_Yes    ; Display YES on the screen
  2130.     Call    U1000_Display_Message    ; ..End
  2131.     Jmp    U1290            ; Go to the end of the module
  2132. U1204:
  2133.     Cmp    AL,Small_Letter_y    ; Check for small letter y
  2134.     Jne    U1205            ; ..End
  2135.     Mov    Byte Ptr FLG06_Yes_or_No,True
  2136.     Mov    SI,Offset MES24_Yes    ; Display YES on the screen
  2137.     Call    U1000_Display_Message    ; ..End
  2138.     Jmp    U1290            ; Go to the end of the module
  2139. U1205:
  2140.     Cmp    AL,Capital_Letter_N    ; Check for capital letter N
  2141.     Jne    U1206            ; ..End
  2142.     Mov    Byte Ptr FLG06_Yes_or_No,False
  2143.     Mov    SI,Offset MES25_No    ; Display NO on the screen
  2144.     Call    U1000_Display_Message    ; ..End
  2145.     Jmp    U1290            ; Go to the end of the module
  2146. U1206:
  2147.     Cmp    AL,Small_Letter_n    ; Check for small letter n
  2148.     Jne    U1207            ; ..End
  2149.     Mov    Byte Ptr FLG06_Yes_or_No,False
  2150.     Mov    SI,Offset MES25_No    ; Display NO on the screen
  2151.     Call    U1000_Display_Message    ; ..End
  2152.     Jmp    U1290            ; Go to the end of the module
  2153. U1207:
  2154.     Jmp    U1202            ; Go back and get another character
  2155. U1290:
  2156.     Popf                ; Restore the registers and flags
  2157.     Pop    SI            ; .
  2158.     Pop    AX            ; ..End
  2159. U1299:
  2160.     Ret
  2161. ;
  2162. U1200_Get_Yes_or_No Endp
  2163. ;
  2164. Page
  2165. ;************************************************************************
  2166. ;*                                    *
  2167. ;*    U1300_CONVERT_BINARY_TO_ASCII                    *
  2168. ;*                                    *
  2169. ;*    This module BCD contained in the AL register into an ASCII    *
  2170. ;*    character.  The output is returned in the AX register.        *
  2171. ;*                                    *
  2172. ;************************************************************************
  2173. ;
  2174. Public    U1300_Convert_Binary_to_ASCII
  2175. ;
  2176. U1300_Convert_Binary_to_ASCII Proc Near
  2177. ;
  2178. U1301:
  2179.     Push    DX            ; Save the registers
  2180.     Pushf                ; ..End
  2181. ;
  2182.     Cbw                ; Perform sign extension for division
  2183.     Mov    DL,Ten            ; Set DL disvisor to 10D
  2184.     Div    DL            ; Divide AL by 10D remainder in AH
  2185.     Add    AL,Zero_Digit        ; Setup the characters in AL & AH
  2186.     Add    AH,Zero_Digit        ; ..End
  2187. ;
  2188.     Popf                ; Restore the registers
  2189.     Pop    DX            ; ..End
  2190. U1399:
  2191.     Ret
  2192. ;
  2193. U1300_Convert_Binary_to_ASCII Endp
  2194. ;
  2195. Page
  2196. ;************************************************************************
  2197. ;*                                    *
  2198. ;*    U1400_DISPLAY_HEAD_AND_TRACK                    *
  2199. ;*                                    *
  2200. ;*    This module displays the current track and head number that    *
  2201. ;*    is being read from the source diskette or written to the     *
  2202. ;*    target diskette.                        *
  2203. ;*                                    *
  2204. ;************************************************************************
  2205. ;
  2206. Public    U1400_Display_Head_and_Track
  2207. ;
  2208. U1400_Display_Head_and_Track Proc Near
  2209. ;
  2210. U1401:
  2211.     Push    AX            ; Save the registers
  2212.     Push    BX            ; .
  2213.     Push    DX            ; .
  2214.     Pushf                ; ..End
  2215. ;
  2216.     Mov    AH,Set_CPos_Command    ; Set cursor to track position
  2217.     Mov    BH,Byte Ptr SYS03_Active_Page
  2218.     Mov    DH,Byte Ptr WRK28_Current_Message_Row
  2219.     Mov    DL,Fifteen        ; .
  2220.     Int    Video_Interrupt        ; ..End
  2221. ;
  2222.                     ; Write the current track number
  2223.     Mov    AL,Byte Ptr WRK30_Current_Track
  2224.     Call    U1300_Convert_Binary_to_ASCII
  2225.     Push    AX            ; .
  2226.     Mov    AH,Write_TTY_Command    ; .
  2227.     Mov    BH,Byte Ptr SYS03_Active_Page
  2228.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2229.     Int    Video_Interrupt        ; .
  2230.     Pop    AX            ; .
  2231.     Mov    AL,AH            ; .
  2232.     Mov    AH,Write_TTY_Command    ; .
  2233.     Mov    BH,Byte Ptr SYS03_Active_Page
  2234.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2235.     Int    Video_Interrupt        ; ..End
  2236. ;
  2237.     Mov    AH,Set_CPos_Command    ; Set cursor to head position
  2238.     Mov    BH,Byte Ptr SYS03_Active_Page
  2239.     Mov    DH,Byte Ptr WRK28_Current_Message_Row
  2240.     Mov    DL,Twenty_Five        ; .
  2241.     Int    Video_Interrupt        ; ..End
  2242. ;                    ; Write the current head number
  2243.     Mov    AL,Byte Ptr WRK29_Current_Head
  2244.     Call    U1300_Convert_Binary_to_ASCII
  2245.     Mov    AL,AH            ;.
  2246.     Mov    AH,Write_TTY_Command    ;.
  2247.     Mov    BH,Byte Ptr SYS03_Active_Page
  2248.     Mov    BL,Byte Ptr SYS04_Foreground_Color
  2249.     Int    Video_Interrupt        ; ..End
  2250. ;
  2251.     Mov    AH,Set_CPos_Command    ; Set cursor to the next line
  2252.     Mov    BH,Byte Ptr SYS03_Active_Page
  2253.     Mov    DH,Byte Ptr WRK28_Current_Message_Row
  2254.     Inc    DH            ; .
  2255.     Mov    DL,Zero            ; .
  2256.     Int    Video_Interrupt        ; ..End
  2257. U1490:
  2258.     Popf                ; Restore the registers
  2259.     Pop    DX            ; 
  2260.     Pop    BX            ; .
  2261.     Pop    AX            ; ..End
  2262. U1499:
  2263.     Ret
  2264. ;
  2265. U1400_Display_Head_and_Track Endp
  2266. ;
  2267. Page
  2268. ;************************************************************************
  2269. ;*                                    *
  2270. ;*    FLAGS                                *
  2271. ;*                                    *
  2272. ;*    This portion of FREECOPY contains the definitions of all of    *
  2273. ;*    flags defined in the program.                    *
  2274. ;*                                    *
  2275. ;************************************************************************
  2276. ;
  2277. FLG01_Good_Command    DB (?)        ; Establishes any errors in the
  2278.                     ; . command line entered by a user
  2279. FLG02_Double_Side    DB (?)        ; Points out whether the user wants
  2280.                     ; . to copy only the top side of a
  2281.                     ; . floppy diskette
  2282. FLG03_Default_Drive    DB (?)        ; Shows if the default drive is a
  2283.                     ; . valid floppy disk drive
  2284. FLG04_Single_Drive    DB (?)        ; Determines if the machine is a
  2285.                     ; . single drive system
  2286. FLG05_Store_Buffer    DB (?)        ; Establishes whether to put the
  2287.                     ; . characters entered from the
  2288.                     ; . keyboard into the buffer
  2289. FLG06_Yes_or_No        DB (?)        ; Points out the user's response
  2290.                     ; . NO = False   YES = True
  2291. FLG07_First_Time    DB (?)        ; Shows the number of times the user
  2292.                     ; . copies a diskette
  2293.                     ; . ONCE = True  MORE = False
  2294. FLG08_Good_Read        DB (?)        ; Flags establish whether the
  2295. FLG09_Good_Write    DB (?)        ; . operation was performed correctly
  2296. FLG10_Good_Verify      DB (?)        ; . YES = True    NO = False
  2297. FLG11_Good_Format    DB (?)        ; ..End
  2298. FLG12_Good_FAT        DB (?)        ; Establishes a good FAT when reading
  2299.                     ; . source diskette more than once
  2300. FLG13_First_Read_Write    DB (?)        ; Shows if a diskette is being read
  2301.                     ; . or written for the first time
  2302.                     ; . YES = True    NO  = False
  2303. FLG14_Copy_Complete    DB (?)        ; Points out if a diskette has been
  2304.                     ; . copied completely
  2305.                     ; . YES = True    NO = False
  2306. FLG15_IO_Error        DB (?)        ; Establishes the type of IO error
  2307.                     ; . Zero = Format error
  2308.                     ; . One  = Read error
  2309.                     ; . Two  = Write error
  2310.                     ; ..End
  2311. ;
  2312. Page
  2313. ;************************************************************************
  2314. ;*                                    *
  2315. ;*    MESSAGES                            *
  2316. ;*                                    *
  2317. ;*    This portion of FREECOPY contains the definitions of all of    *
  2318. ;*    messages defined in the program.                *
  2319. ;*                                    *
  2320. ;************************************************************************
  2321. ;
  2322. MES00_Copy_Notice        Label Byte
  2323.     DB    CR,LF
  2324.     DB    'FREECOPY Disk Utility',CR,LF
  2325.     DB    'IBM Personal Computer/Jr.',CR,LF
  2326.     DB    'Version 1.0 (C)Copyright 1984',CR,LF
  2327.     DB    CR,LF
  2328.     DB    'Squire Buresh Assoc., Inc.',CR,LF
  2329.     DB    'Post Office Box 112',CR,LF
  2330.     DB    'Millbury, MA 01527',CR,LF
  2331.     DB    CR,LF
  2332.     DB    '$25.00 requested contribution.',CR,LF,EOT
  2333. MES01_Copy_Another        Label Byte
  2334.     DB    CR,LF
  2335.     DB    'Copy another diskette (Y/N)? ',EOT
  2336. MES02_Copy_Complete        Label Byte
  2337.     DB    CR,LF
  2338.     DB    'Copy complete.',CR,LF,EOT
  2339. MES03_Copy81_Sectors        Label Byte
  2340.     DB    CR,LF
  2341.     DB    'Copying 8 sectors per track, 1 side.',CR,LF,EOT
  2342. MES04_Copy82_Sectors        Label Byte
  2343.     DB    CR,LF
  2344.     DB    'Copying 8 sectors per track, 2 sides.',CR,LF,EOT
  2345. MES05_Copy91_Sectors        Label Byte
  2346.     DB    CR,LF
  2347.     DB    'Copying 9 sectors per track, 1 side.',CR,LF,EOT
  2348. MES06_Copy92_Sectors        Label Byte
  2349.     DB    CR,LF
  2350.     DB    'Copying 9 sectors per track, 2 sides.',CR,LF,EOT
  2351. MES07_Correct_And_Press_Key    Label Byte
  2352.     DB    CR,LF
  2353.     DB    'Correct, and press any key to continue',CR,LF,EOT
  2354. MES08_Drive_Not_Ready        Label Byte
  2355.     DB    CR,LF
  2356.     DB    'Diskette not in drive  :.',CR,LF,EOT
  2357. MES09_Insert_Source        Label Byte
  2358.     DB    CR,LF
  2359.     DB    'Insert source diskette in drive  :.',CR,LF,EOT
  2360. MES10_Insert_Target        Label Byte
  2361.     DB    CR,LF
  2362.     DB    'Insert target diskette in drive  :.',CR,LF,EOT
  2363. MES11_Insufficient_Memory    Label Byte
  2364.     DB    CR,LF
  2365.     DB    'Insufficient memory.',Bell,CR,LF,EOT
  2366. MES12_Invalid_Parameter        Label Byte
  2367.     DB    CR,LF
  2368.     DB    'Invalid parameter(s) specified.',CR,LF,EOT
  2369. MES13_Invalid_Default        Label Byte
  2370.     DB    CR,LF
  2371.     DB    'Invalid default floppy disk drive',CR,LF,EOT
  2372. MES14_Invalid_Drive        Label Byte
  2373.     DB    CR,LF
  2374.     DB    'Invalid drive specification.',CR,LF,EOT
  2375. MES15_Single_Drive_Copy        Label Byte
  2376.     DB    CR,LF
  2377.     DB    'NOTE: Copying diskette on single drive.',Bell,CR,LF,EOT
  2378. MES16_Press_Any_Key        Label Byte
  2379.     DB    CR,LF
  2380.     DB    'Press any key when ready.',CR,LF,EOT
  2381. MES17_Reading_Track        Label Byte
  2382.     DB    'Reading track (  ) head ( ).',CR,LF,EOT
  2383. MES18_Unrecoverable_Format    Label Byte
  2384.     DB    CR,LF
  2385.     DB    'Unrecoverable format error on target.',CR,LF,EOT
  2386. MES19_Unrecoverable_Read    Label Byte
  2387.     DB    CR,LF
  2388.     DB    'Unrecoverable read error on source.',CR,LF,EOT
  2389. MES20_Unrecoverable_Verify    Label Byte
  2390.     DB    CR,LF
  2391.     DB    'Unrecoverable verify error on target.',CR,LF,EOT
  2392. MES21_Unrecoverable_Write    Label Byte
  2393.     DB    CR,LF
  2394.     DB    'Unrecoverable write error on target.',CR,LF,EOT
  2395. MES22_Unrecoverable_IO        Label Byte
  2396.     DB    CR,LF
  2397.     DB    'Unrecoverable IO error.',CR,LF,EOT
  2398. MES23_Writing_Track        Label Byte
  2399.     DB    'Writing track (  ) head ( ).',CR,LF,EOT
  2400. MES24_Yes            Label Byte
  2401.     DB    'YES',CR,LF,EOT
  2402. MES25_No            Label Byte
  2403.     DB    'NO',CR,LF,EOT
  2404. MES80_Seek_Error        Label Byte
  2405.     DB    'Seek operation has failed.',CR,LF,EOT
  2406. MES81_Controller_Error        Label Byte
  2407.     DB    'Disk controller has failed.',CR,LF,EOT
  2408. MES82_CRC_Error            Label Byte
  2409.     DB    'Cyclic redundancy check (CRC) error.',CR,LF,EOT
  2410. MES83_DMA_Boundary_Error    Label Byte
  2411.     DB    'Attempted to DMA across a 64K boundary.',CR,LF,EOT
  2412. MES84_DMA_Error            Label Byte
  2413.     DB    'DMA overrun on I/O operation.',CR,LF,EOT
  2414. MES85_Sector_Error        Label Byte
  2415.     DB    'Requested sector not found.',CR,LF,EOT
  2416. MES86_Write_Protect_Error    Label Byte
  2417.     DB    'Output diskette is write protected.',CR,LF,EOT
  2418. MES87_Address_Mark_Error    Label Byte
  2419.     DB    'Address mark was not found.',CR,LF,EOT
  2420. MES88_Command_Error        Label Byte
  2421.     DB    'Bad command passed to the disk interrupt 13H.',CR,LF,EOT
  2422. MES89_Unknown_Error        Label Byte
  2423.     DB    'Unknown diskette error encountered.',CR,LF,EOT
  2424. MES90_Unknown_FAT_Error        Label Byte
  2425.     DB    'First byte of the FAT does not',CR,LF
  2426.     DB    'match any known diskette type.',CR,LF,EOT
  2427. MES91_Single_Side_Error        Label byte
  2428.     DB    'Double sided diskette in a',CR,LF
  2429.     DB    'single sided disk drive.',CR,LF,EOT
  2430. MES97_Return_Linefeed        Label Byte
  2431.     DB    CR,LF,EOT
  2432. MES98_Control_Break        Label Byte
  2433.     DB    '^C',CR,LF,EOT
  2434. MES99_Freecopy_Finished        Label Byte
  2435.     DB    CR,LF
  2436.     DB    'Returning to PC DOS.',CR,LF,EOT
  2437. ;
  2438. Page
  2439. ;************************************************************************
  2440. ;*                                    *
  2441. ;*    WORK VARIABLES                            *
  2442. ;*                                    *
  2443. ;*    This portion of FREECOPY contains the definitions of the work    *
  2444. ;*    variables that are used by the program.                *
  2445. ;*                                    *
  2446. ;************************************************************************
  2447. ;
  2448. WRK01_Source_Drive        DB (?)    ; Source diskette drive number
  2449. WRK02_Target_Drive        DB (?)    ; Target diskette drive number
  2450. WRK03_Valid_Filename        DB 11 Dup (32D); Valid diskette file name
  2451. WRK04_Parameter_Count        DB (?)    ; Valid diskette filler area
  2452. ;
  2453. WRK05_Keyboard_Buffer        Label Byte
  2454.                 DB 80D    ; Length of the keyboard buffer
  2455.                 DB 80 Dup (?); Actual keyboard buffer
  2456.                 DB EOT    ; Last char denotes the end of text
  2457. ;
  2458. WRK06_Drive_Number        DB (?)    ; Drive number of a disk drive
  2459. WRK07_Head_Number        DB (?)    ; Head number of a disk drive
  2460. WRK08_Track_Number        DB (?)    ; Track number of a diskette
  2461. WRK09_Sector_Number        DB (?)    ; Sector number of a diskette
  2462. WRK10_Number_of_Sectors        DB (?)    ; Number of sectors on a track
  2463. WRK11_Segment_Address        DW (?)    ; ES segment address
  2464. WRK12_Offset_Address        DW (?)    ; BX offset address
  2465. WRK13_Retry_Counter        DB (?)    ; Number of retrys to make
  2466. WRK14_Status_Operation        DB (?)    ; Result of the operation
  2467. ;
  2468. WRK15_Maximum_Heads        DB (?)    ; Maximum heads, tracks and sectors
  2469. WRK16_Maximum_Tracks        DB (?)    ; .
  2470. WRK17_Maximum_Sectors        DB (?)    ; ..End
  2471. ;
  2472. WRK18_Counter_ESBX_Entries    DW (?)    ; Counter to calculate ES:BX entries
  2473. WRK19_Number_ESBX_Entries    DW (?)    ; Maximum ES:BX table entires
  2474. ;
  2475. Page
  2476. ;************************************************************************
  2477. ;*                                    *
  2478. ;*    WORK VARIABLES    Page 2                        *
  2479. ;*                                    *
  2480. ;************************************************************************
  2481. ;
  2482. WRK20_Current_Source_Head    DB (?)    ; Current source head & track number
  2483. WRK21_Current_Source_Track    DB (?)    ; ..End
  2484. WRK22_Current_Target_Head    DB (?)    ; Current target head & track number
  2485. WRK23_Current_Target_Track    DB (?)    ; . End
  2486. ;
  2487. WRK24_Read_Message_Row        DB (?)    ; Cursor row of read, verify, format
  2488. WRK25_Verify_Message_Row    DB (?)    ; and write message
  2489. WRK26_Format_Message_Row    DB (?)    ; .
  2490. WRK27_Write_Message_Row        DB (?)    ; .
  2491. WRK28_Current_Message_Row    DB (?)    ; ..End
  2492. ;
  2493. WRK29_Current_Head        DB (?)    ; Current head and track to display
  2494. WRK30_Current_Track        DB (?)    ; . on the screen
  2495. ;
  2496. WRK31_Track_Read_Counter        DB (?)    ; Counter of tracks processed
  2497. WRK32_Track_Write_Counter       DB (?)  ; ..End
  2498. ;
  2499. WRK33_CHRN_Table_Address    DW (?)    ; Current address of the CHRN table
  2500. ;
  2501. Page
  2502. ;************************************************************************
  2503. ;*                                    *
  2504. ;*    SYSTEM VARIABLES                        *
  2505. ;*                                    *
  2506. ;*    This portion of FREECOPY contains the definitions of all of    *
  2507. ;*    the system variables used by the program.            *
  2508. ;*                                    *
  2509. ;************************************************************************
  2510. ;
  2511. SYS01_Number_Columns    DB (?)        ; Number of columns in current mode
  2512. SYS02_Current_Mode    DB (?)        ; Current video mode
  2513. SYS03_Active_Page    DB (?)        ; Active display page
  2514. SYS04_Foreground_Color    DB (?)        ; Foreground color number
  2515. SYS05_Para_RAM_Size    DW (?)        ; Number of free 16 byte paragraphs
  2516. SYS06_Monitor_Flag    DB (?)        ; 0 = monochrome  1 = graphics
  2517. SYS07_No_Parallel_Ports    DB (?)        ; Number of parallel ports
  2518. SYS08_Game_Adapters    DB (?)        ; Number of RS-232 ports
  2519. SYS09_No_RS232_Ports    DB (?)        ; 0 = no adapter  1 = has adapter
  2520. SYS10_No_Disk_Drives    DB (?)        ; Number of floppy disk drives
  2521. SYS11_Init_Video_Mode    DB (?)        ; Initial video mode when powering
  2522.                     ; up the machine
  2523. SYS12_Planar_RAM_Size    DB (?)        ; Planar RAM size
  2524. SYS13_IPL_From_Diskette    DB (?)        ; Location of initial program load
  2525. SYS14_Default_Drive    DB (?)        ; Default disk drive
  2526. ;
  2527. SYS15_Stack_Pointer    DW (?)        ; Stack pointer value when entering
  2528.                     ; . FREECOPY from PC DOS
  2529. SYS16_Save_DPT_Offset    DW (?)        ; Address of Disk Parameter Table
  2530. SYS17_Save_DPT_Segment    DW (?)        ; ..End
  2531. ;
  2532. SYS18_Disk_Parameter_Table    Label Byte
  2533.             DB 11011111B    ; SRT = 0D & Head Unload = 0FH
  2534.             DB 002H        ; Head Load = 1 Mode = DMA
  2535.             DB 025H        ; Wait to turn the motor off
  2536.             DB 002H        ; 512 bytes per sector
  2537.             DB 009H        ; 9 sectors per track
  2538.             DB 02AH        ; PC DOS gap length for I/O
  2539.             DB 0FFH        ; Data length parameter
  2540.             DB 050H        ; PC DOS gap length for format
  2541.             DB 0F6H        ; Fille byte for format
  2542.             DB 00FH        ; Head Settle time in milliseconds
  2543.             DB 002H        ; Motor start-up time (1/8 sec.)
  2544. ;
  2545. Page
  2546. ;************************************************************************
  2547. ;*                                    *
  2548. ;*    SETUP STACK POINTER AND MEMORY                    *
  2549. ;*                                    *
  2550. ;*    This portion of FREECOPY is contains the stack and the label    *
  2551. ;*    that indicates the beginning of available memory.        *
  2552. ;*                                    *
  2553. ;************************************************************************
  2554. ;
  2555. MEM05_Bottom_of_the_Stack    Label Word
  2556.             DW 64 Dup (?)
  2557. MEM04_Top_of_the_Stack        Label Word
  2558. ;
  2559. MEM03_ESBX_Table        Equ MEM04_Top_of_the_Stack+2
  2560. ;
  2561. MEM02_CHRN_Table        Equ MEM03_ESBX_Table+320
  2562. ;
  2563. MEM01_File_Allocation_Table    Equ MEM02_CHRN_Table+2880
  2564. ;
  2565. MEM00_Bottom_Free_Memory    Equ MEM01_File_Allocation_Table+512
  2566. ;
  2567. Page
  2568. ;************************************************************************
  2569. ;*                                    *
  2570. ;*    END OF THE PROGRAM                        *
  2571. ;*                                    *
  2572. ;************************************************************************
  2573. ;
  2574. CSEG    Ends
  2575.     End   A1000_Main_Module
  2576.  
  2577.  
  2578.