home *** CD-ROM | disk | FTP | other *** search
/ CD Actual 13 / CDA13.ISO / cdactual / demobin / share / program / Asm / ARGC.ZIP / ARGC.ASM
Encoding:
Assembly Source File  |  1987-12-15  |  1.9 KB  |  59 lines
  1.          name      argc
  2.          title     ARGC --- return argument count
  3. ;
  4. ; ARGC.ASM: return count of command line arguments.
  5. ; Treats blanks and tabs as whitespace, carriage 
  6. ; return as terminator.
  7. ;
  8. ; (C) 1987 Ray Duncan
  9. ; 
  10. ; Call with:  ES:BX = command line
  11. ;
  12. ; Returns:    AX    = argument count (always >=1)
  13. ;             Other registers preserved
  14. ;
  15.  
  16. cr      equ     0dh             ; ASCII carriage return
  17. lf      equ     0ah             ; ASCII line feed
  18. tab     equ     09h             ; ASCII tab
  19. blank   equ     20h             ; ASCII space character
  20.  
  21. _TEXT   segment word public 'CODE'
  22.  
  23.         assume  cs:_TEXT
  24.  
  25.         public  argc            ; make ARGC available to Linker
  26.  
  27. argc    proc    near            ; count command line arguments
  28.  
  29.         push    bx              ; save original BX and CX 
  30.         push    cx              ;  for later
  31.         mov     ax,1            ; force count >= 1
  32.  
  33. argc1:  mov     cx,-1           ; set flag = outside argument
  34.  
  35. argc2:  inc     bx              ; point to next character 
  36.         cmp     byte ptr es:[bx],cr
  37.         je      argc3           ; exit if carriage return
  38.         cmp     byte ptr es:[bx],blank
  39.         je      argc1           ; outside argument if ASCII blank
  40.         cmp     byte ptr es:[bx],tab    
  41.         je      argc1           ; outside argument if ASCII tab
  42.  
  43.                                 ; otherwise not blank or tab,
  44.         jcxz    argc2           ; jump if already inside argument
  45.  
  46.         inc     ax              ; else found argument, count it
  47.         not     cx              ; set flag = inside argument
  48.         jmp     argc2           ; and look at next character
  49.  
  50. argc3:  pop     cx              ; restore original BX and CX
  51.         pop     bx
  52.         ret                     ; return AX = argument count
  53.  
  54. argc    endp
  55.  
  56. _TEXT   ends
  57.  
  58.         end     
  59.