home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
sh5x
/
sh55b.d64
/
changeadress
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
2KB
|
84 lines
1 REM STARTADRESSE AUF DISKETTE
2 REM AENDERN (4/90 H.BEILER)
3 REM =========================
10 GOSUB1000
20 L=1:P=3:X=8:D=5:F=2:FL=0:F2=0
40 OPEN1,8,15
50 OPEN2,8,2,"#"
60 PRINT#1,"U1";2;0;18;0
70 PRINT#1,"B-P";2;144
90 FORI=0TO15:GET#2,A$:PRINTA$;:NEXT:PRINTCHR$(32);
100 PRINT#1,"B-P";2;162
110 FORI=0TO4:GET#2,A$:PRINTA$;:NEXT:PRINTCHR$(13);
112 PRINT"ADRESSE FILENAME":PRINTLN$
120 PRINT#1,"U1";2;0;18;L
130 PRINT#1,"B-P";2;1
140 GET#2,C$:SE=ASC(C$):SA=SE-L
150 PRINT#1,"U1";2;0;18;L
160 PRINT#1,"B-P";2;F
170 GET#2,D$:IFD$=""THEND$=CHR$(0)
171 IFASC(D$)=0ANDFL=0THEN300
181 IFASC(D$)<>130THEN300
190 PRINT#1,"B-P";2;P
200 GET#2,A$:T=ASC(A$)
202 GET#2,A$:IFA$=""THENA$=CHR$(0)
203 S=ASC(A$)
210 PRINT#1,"U1";2;0;T;S
220 PRINT#1,"B-P";2;2
230 GET#2,A$:IFA$=""THENA$=CHR$(0)
232 LO=ASC(A$)
234 GET#2,A$:IFA$=""THENA$=CHR$(0)
236 HI=ASC(A$)
238 GOSUB1300
240 PRINTLO+256*HI;
250 PRINT#1,"U1";2;0;18;L
260 PRINT#1,"B-P";2;D
270 FORI=0TO15
280 GET#2,A$:PRINTTAB(9)A$;
290 NEXT:GOTO500
300 PRINTCHR$(13);:X=X-1:D=D+32:P=P+32:F=F+32
301 IFX=0ANDFL=1THEN350
310 IFX=0ANDFL=0THENL=L+SA:X=8:P=3:D=5:F=2:GOTO120
320 IFSE=255ANDFL=0THENFL=1:L=SE-SA:GOTO120
340 GOTO150
350 CLOSE2:CLOSE1:RUN
500 GETT$
505 IFT$="X"ANDFL=0THENCLOSE2:CLOSE1:RUN
506 IFT$="E"THENCLOSE2:CLOSE1:PRINTCHR$(147):POKE808,237:END
510 IFT$=CHR$(32)THEN300
520 IFT$="A"THENGOSUB600:GOTO300
530 GOTO500
600 GOSUB700:PRINTCHR$(32);:POKE19,64:INPUTLA:POKE19,0:PRINT
610 HI=INT(LA/256):LO=LA-(HI*256)
630 PRINT#1,"U1";2;0;T;S
640 PRINT#1,"B-P";2;2
650 PRINT#2,CHR$(LO);:PRINT#2,CHR$(HI);
660 PRINT#1,"U2";2;0;T;S
665 GOSUB1300
670 RETURN
700 REM
710 PRINT:PRINT"NEUE LADEADRESSE:[146]";
720 RETURN
1000 FORI=1TO39:LN$=LN$+"[192]":LR$=LR$+CHR$(32):NEXT
1005 POKE53280,0:POKE53281,0:POKE646,15
1011 PRINT"[147]"CHR$(142)LN$
1020 PRINT" CHANGE LOAD-ADRESS "
1021 PRINTLN$
1031 PRINTLN$
1040 PRINT" A=AENDERN SPACE=WEITER X=ABBRUCH "
1041 PRINTTAB(12)"E=PROGRAMMENDE"
1042 PRINTLN$
1060 PRINTLN$
1070 PRINTTAB(5)"RICHTIGE DISKETTE EINLEGEN UND"
1080 PRINTTAB(10)"<RETURN> DRUECKEN !"
1090 PRINTLN$:PRINT
1100 GETT$:IFT$=CHR$(13)THEN1110
1101 IFT$="E"THENPOKE808,237:PRINT"[147]":END
1102 GOTO1100
1110 GOSUB1200
1120 FORI=1TO10:PRINTLR$:NEXT:GOSUB1200
1130 RETURN
1200 POKE214,8:POKE211,0:SYS58640:RETURN
1300 POKE214,12:POKE211,0:SYS58640:FORI=1TO3:PRINTLR$:NEXT
1400 POKE214,12:POKE211,0:SYS58640:PRINTLR$:RETURN