home *** CD-ROM | disk | FTP | other *** search
/ 64'er / 64ER_CD.iso / 87xx / 8710.d64 / fr.baeume (.txt) < prev    next >
Commodore BASIC  |  1995-03-30  |  2KB  |  58 lines
  1. 10 REM ****************************
  2. 20 REM *      FRAKTALE BAEUME     *
  3. 30 REM * 1987 BY STEFAN VILSMEIER *
  4. 40 REM ****************************
  5. 50 :
  6. 60 IF A=0 THEN A=1:LOAD "FRACTAL.OBJ",8,1
  7. 70 OPEN 1,8,15,"U9":CLOSE 1: REM DIESE ZEEILE KANN BEI PROBLEMEN MIT DEM
  8. 80 REM FLOPPYSPEEDER WEGGELASSEN WERDEN!
  9. 90 POKE53280,0:POKE53281,0
  10. 100 INPUT "[147]GRAD ";GR
  11. 110 INPUT "WINKEL,FAKTOR ";WI,F
  12. 120 SE=40:XP=160:YP=150:W=-90
  13. 130 SYS 50176,14,0:SYS 50179,1:SYS 50194:REM GRAFIK EIN
  14. 140 :
  15. 150 GOSUB 300: REM 'BAUM' AUFRUFEN
  16. 160 SYS 50185,0,0,319,0,1:SYS 50185,319,0,319,199,1
  17. 170 SYS 50185,319,199,0,199,1:SYS 50185,0,199,0,0,1
  18. 180 GET A$:IF A$="" GOTO 180
  19. 190 SYS 50179,0:IF A$="S" THEN GOSUB 700: REM 'GRAFIK SPEICHERN'
  20. 200 GOTO 70: REM NEUSTART
  21. 260 :
  22. 270 :
  23. 280 REM ***************************
  24. 290 REM *        'BAUM'           *
  25. 300 REM ***************************
  26. 310 :
  27. 320 T=T+1:IF GR<=0 GOTO 420
  28. 330 W=W-WI/2:  REM 'DREHE'
  29. 340 S=SE:GOSUB 500: REM 'SCHREITE'
  30. 350 G(T)=GR:GR=GR-1:SE=SE/F:GOSUB300:SE=SE*F:REM 'BAUM'
  31. 360 S=-SE:GOSUB 500: REM 'SCHREITE'
  32. 370 W=W+WI:    REM 'DREHE'
  33. 380 S=SE:GOSUB 500: REM 'SCHREITE'
  34. 390 G(T)=GR:GR=GR-1:SE=SE/F:GOSUB300:SE=SE*F:REM 'BAUM'
  35. 400 S=-SE:GOSUB 500: REM 'SCHREITE'
  36. 410 W=W-WI/2: REM 'DREHE'
  37. 420 T=T-1:GR=G(T):RETURN
  38. 450 :
  39. 460 :
  40. 470 REM ***************************
  41. 480 REM *      'SCHREITE'         *
  42. 490 REM ***************************
  43. 500 :
  44. 510 XS=S*COS(W*(null)/180)
  45. 520 YS=S*SIN(W*(null)/180)
  46. 530 XP=XP+XS:YP=YP+YS
  47. 540 SYS 50185,XP-XS,YP-YS,XP,YP,1:REM LINIE
  48. 550 RETURN
  49. 650 :
  50. 660 :
  51. 670 REM ***************************
  52. 680 REM *   'GRAFIK SPEICHERN'    *
  53. 690 REM ***************************
  54. 700 :
  55. 710 INPUT "GRAFIK-NAME ";N$
  56. 720 OPEN 2,8,2,"PI."+N$+",P,W":SYS 50191:CLOSE 2
  57. 730 RETURN
  58.