home *** CD-ROM | disk | FTP | other *** search
/ 64'er / 64ER_CD.iso / 87xx / 8709a.d64 / quadrat (.txt) < prev    next >
Commodore BASIC  |  1995-03-30  |  1KB  |  60 lines
  1. 10 REM ****************************
  2. 20 REM *  QUDRATISCHE KOCH-KURVE  *
  3. 30 REM ****************************
  4. 40 :
  5. 50 IF A=0 THEN A=1:LOAD "FRACTAL.OBJ"
  6. 60 :
  7. 70 OPEN 1,8,15,"U9":CLOSE 1: REM DIESE ZEEILE KANN BEI PROBLEMEN MIT DEM
  8. 80 REM FLOPPYSPEEDER WEGGELASSEN WERDEN!
  9. 90 POKE53280,0:POKE53281,0
  10. 100 INPUT "[147]GRAD ";GR
  11. 110 SE=300:XP=10:YP=175:W=0
  12. 120 :
  13. 130 SYS 50176,14,0:SYS 50179,1:SYS 50194:REM GRAFIK EIN
  14. 140 :
  15. 150 GOSUB 300: REM 'QUADRAT' AUFRUFEN
  16. 160 SYS 50185,0,0,319,0,1:SYS 50185,319,0,319,199,1
  17. 170 SYS 50185,319,199,0,199,1:SYS 50185,0,199,0,0,1
  18. 180 GET A$:IF A$="" GOTO 180
  19. 190 SYS 50179,0:IF A$="S" THEN GOSUB 700: REM 'GRAFIK SPEICHERN'
  20. 200 GOTO 60: REM NEUSTART
  21. 260 :
  22. 270 :
  23. 280 REM ***************************
  24. 290 REM *      'QUADRAT'          *
  25. 300 REM ***************************
  26. 310 :
  27. 320 IF GR=0 THEN S=SE:GOSUB 500:RETURN: REM 'SCHREITE'
  28. 330 GR=GR-1:SE=SE/3
  29. 340 GOSUB 300: REM 'QUADRAT'
  30. 350 W=W-90:    REM 'DREHE'
  31. 360 GOSUB 300: REM 'QUADRAT'
  32. 370 W=W+90:    REM 'DREHE'
  33. 380 GOSUB 300: REM 'QUADRAT'
  34. 390 W=W+90:    REM 'DREHE'
  35. 400 GOSUB 300: REM 'QUADRAT'
  36. 410 W=W-90:    REM 'DREHE'
  37. 420 GOSUB 300: REM 'QUADRAT'
  38. 430 GR=GR+1:SE=SE*3
  39. 440 RETURN
  40. 450 :
  41. 460 :
  42. 470 REM ***************************
  43. 480 REM *      'SCHREITE'         *
  44. 490 REM ***************************
  45. 500 :
  46. 510 XS=S*COS(W*(null)/180)
  47. 520 YS=S*SIN(W*(null)/180)
  48. 530 XP=XP+XS:YP=YP+YS
  49. 540 SYS 50185,XP-XS,YP-YS,XP,YP,1:REM LINIE
  50. 550 RETURN
  51. 650 :
  52. 660 :
  53. 670 REM ***************************
  54. 680 REM *   'GRAFIK SPEICHERN'    *
  55. 690 REM ***************************
  56. 700 :
  57. 710 INPUT "GRAFIK-NAME ";N$
  58. 720 OPEN 2,8,2,"PI."+N$+",P,W":SYS 50191:CLOSE 2
  59. 730 RETURN
  60.