home *** CD-ROM | disk | FTP | other *** search
/ The Best of Mecomp Multimedia 2 / MECOMP-CD-II.iso / amiga / sound / install-euterpe / install < prev    next >
Encoding:
Text File  |  1998-03-14  |  20.7 KB  |  743 lines
  1. ; -------------------------------------------------------------------------
  2. ; Euterpe Installation script
  3. ; ===========================
  4. ;
  5. ;$VER: Install 1.16 (8.3.98)
  6. ; -------------------------------------------------------------------------
  7.  
  8. (complete 0)
  9.  
  10. ; -------------------------------------------------------------------------
  11. ; default msgs setting
  12. ; -------------------------------------------------------------------------
  13.  
  14. (set #introduction
  15. (cat "\n\nInstallation of Euterpe.\n"
  16. ))
  17.  
  18. (set #quel-disque
  19. (cat "Where do you want to install Euterpe\n(A drawer will be created) ?"
  20. ))
  21.  
  22. (set #quel-disque-aide
  23. (cat "Select the drawer or volume where the installation should be made."
  24. ))
  25. (set #oui-prompt
  26. (cat "Installation of OBJECT USER INTERFACE catalog files."
  27. ))
  28. (set #asyncio-prompt
  29. (cat "Installation of AsyncIO.library."
  30. ))
  31.  
  32. (set #startup-prompt
  33. (cat "Adding Assign Euterpe: in user-startup."
  34. ))
  35.  
  36. (set #fix-error-asyncio
  37. (cat "Fixing previous incorrect installation of AsyncIO.library."
  38. ))
  39.  
  40. (set #docs-msg
  41. (cat "Do you want to install the docs files ?"
  42. ))
  43.  
  44. (set #docs-help
  45. (cat "The docs files are produced by a conversion of the guide files and "
  46.      "are ANSI text files.\n"
  47.      "Select \"Yes\" if your version of amigaguide is unable to display "
  48.      "the help or if you want to print the doc."
  49. ))
  50. (set #developer-msg
  51. (cat "Do you want to install the developer files ?"
  52. ))
  53. (set #developer-help
  54. (cat "The developer files are provided for people interested in the development of XApps."
  55. ))
  56.  
  57. (set #camd-default
  58. (cat "Do you want to use camd.library for MIDI accesses ?"
  59. ))
  60. (set #camd-help
  61. (cat "Installer has recognised the camd.library (Midi support routines).\n"
  62.      "Select \"Yes\" if you want to use it by default.\n"
  63.      "Select \"No\" if you want to use a serial device.\n"
  64.      "Note that this is only of interest for the default settings.\n"
  65.      "Midi instruments settings are independent from this choice.\n"
  66. ))
  67.  
  68. (set #help-sel
  69. (cat "Select one or more languages for the online help."
  70. ))
  71.  
  72. (set #doc-sel
  73. (cat "Select one or more languages for the doc files."
  74. ))
  75.  
  76. (set #msg-mkdir
  77. (cat "Creating directory structure."
  78. ))
  79.  
  80. (set #prg-sel
  81. (cat "Select the executable files wanted."
  82. ))
  83.  
  84. (set #prg-help
  85. (cat "If you are not a registered user, you may only choose Euterpe.\n"
  86.      "Other choices are optimized versions of Euterpe."
  87. ))
  88.  
  89. (set #metro-msg
  90. (cat "Install the example voice metronome files ?"
  91. ))
  92.  
  93. (set #metro-help
  94. (cat "For demonstrating how to use the metronome instruments one example "
  95.      "is provided which count the beats with human voice.\n"
  96.      "Select \"Yes\" if you are interested."
  97. ))
  98.  
  99. (set #rexx-msg
  100. (cat "Select the additional REXX scripts to install."
  101. ))
  102.  
  103. (set #rexx-help
  104. (cat "The scripts needed by Euterpe are already installed. "
  105.      "You can choose here other scripts provided as examples."
  106. ))
  107.  
  108. (set #cat-sel
  109. (cat "Select one or more languages for the catalogs."
  110. ))
  111. (set #cat-msg
  112. (cat "Do you wish to install the translator files ?"
  113. ))
  114. (set #cat-help
  115. (cat "These files are not necessary for using Euterpe but are needed by translators."
  116. ))
  117.  
  118. ; -------------------------------------------------------------------------
  119. ; french msgs setting
  120. ; -------------------------------------------------------------------------
  121.  
  122. (if (= @language "français")
  123. (
  124. (set #introduction
  125. (cat "\n\nInstallation d'Euterpe.\n"
  126. ))
  127.  
  128. (set #quel-disque
  129. (cat "Où voulez-vous installer Euterpe\n(Un répertoire sera créé) ?"
  130. ))
  131.  
  132. (set #quel-disque-aide
  133. (cat "Sélectionnez le disque ou répertoire où l'installation doit être effectuée."
  134. ))
  135.  
  136. (set #oui-prompt
  137. (cat "Installation des catalogues pour l'interface OUI."
  138. ))
  139.  
  140. (set #asyncio-prompt
  141. (cat "Installation de l'AsyncIO.library."
  142. ))
  143.  
  144. (set #startup-prompt
  145. (cat "Ajout de l'assignation Euterpe: dans le fichier user-startup."
  146. ))
  147.  
  148. (set #fix-error-asyncio
  149. (cat "Correction d'une installation précédente erronée de l'AsyncIO.library."
  150. ))
  151.  
  152. (set #docs-msg
  153. (cat "Voulez-vous installer la documentation ?"
  154. ))
  155. (set #docs-help
  156. (cat "La documentation est une conversion du fichier d'aide au "
  157.      "format texte ANSI.\n"
  158.      "Choisissez \"Oui\" si votre version d'amigaguide est incapable "
  159.      "d'afficher l'aide en ligne ou bien si vous désirez "
  160.      "imprimer la documentation."
  161. ))
  162. (set #developer-msg
  163. (cat "Voulez-vous installer les fichiers développeurs ?"
  164. ))
  165. (set #developer-help
  166. (cat "Les fichiers développeurs sont nécessaire à ceux qui sont intéressés par la conception de XApps."
  167. ))
  168.  
  169. (set #camd-default
  170. (cat "Voulez-vous utiliser la camd.library pour vos accès MIDI ?"
  171. ))
  172. (set #camd-help
  173. (cat "Installer a détecté la présence de la camd.library (routines de support MIDI).\n"
  174.      "Choisissez \"Oui\" pour que les accès Midi par défaut l'utilisent.\n"
  175.      "Choisissez \"Non\" pour que vos accès par défaut utilisent un serial.device.\n"
  176.      "Remarquez que ceci ne concerne que les accès par défaut.\n"
  177.      "Les instruments Midi peuvent être réglés indépendamment de ce choix.\n"
  178. ))
  179.  
  180. (set #help-sel
  181. (cat "Sélectionnez une ou plusieurs langues pour l'aide en ligne."
  182. ))
  183.  
  184. (set #doc-sel
  185. (cat "Sélectionnez une ou plusieurs langues pour la documentation."
  186. ))
  187.  
  188. (set #msg-mkdir
  189. (cat "Création de l'arborescence des répertoires."
  190. ))
  191. (set #prg-sel
  192. (cat "Sélectionnez les fichiers exécutables désirés\n"
  193. ))
  194.  
  195. (set #prg-help
  196. (cat "Si vous n'êtes pas un utilisateur enregistré, seul le programme "
  197.      "Euterpe sera utilisable.\n"
  198.      "Les autres choix correspondent à des versions optimisées du logiciel."
  199. ))
  200.  
  201. (set #metro-msg
  202. (cat "Installation des fichiers du métronome vocal ?"
  203. ))
  204.  
  205. (set #metro-help
  206. (cat "Pour vous montrer comment utiliser les instruments métronome, "
  207.      "un exemple est fourni qui compte les temps avec la voix.\n"
  208.      "Sélectionnez \"Oui\" si vous êtes intéressé."
  209. ))
  210.  
  211. (set #rexx-msg
  212. (cat "Sélectionnez les scripts REXX additionnels à installer."
  213. ))
  214.  
  215. (set #rexx-help
  216. (cat "Les scripts utilisés par Euterpe sont séjà installés. "
  217.      "Vous pouvez choisir ici des scripts additionnels fournis comme exemples."
  218. ))
  219.  
  220. (set #cat-sel
  221. (cat "Sélectionnez une ou plusieurs langues pour les catalogues."
  222. ))
  223. (set #cat-msg
  224. (cat "Voulez-vous installer les fichiers traducteur ?"
  225. ))
  226. (set #cat-help
  227. (cat "Ces fichiers ne sont pas nécessaires pour l'utilisation d'Euterpe mais "
  228.      "sont utiles aux traducteurs."
  229. ))
  230. ))
  231.  
  232. ; -------------------------------------------------------------------------
  233. ; german msgs setting
  234. ; -------------------------------------------------------------------------
  235.  
  236. (if (= @language "deutsch")
  237. (
  238. (set #introduction
  239. (cat "\n\nInstallation von Euterpe.\n"
  240. ))
  241.  
  242. (set #quel-disque
  243. (cat "Wohin möchtest du Euterpe installieren\n(Ein Verzeichnis wird erstellt) ?"
  244. ))
  245.  
  246. (set #quel-disque-aide
  247. (cat "Wähle eine Schublade oder ein Laufwerk für die Installation."
  248. ))
  249. (set #oui-prompt
  250. (cat "Installation der OBJECT USER INTERFACE Kataloge."
  251. ))
  252. (set #asyncio-prompt
  253. (cat "Installation der AsyncIO.library."
  254. ))
  255.  
  256. (set #startup-prompt
  257. (cat "Assign Euterpe: wird in die user-startup aufgenommen."
  258. ))
  259.  
  260. (set #fix-error-asyncio
  261. (cat "Frühere fehlerhafte Installation der AsyncIO.library wird bereinigt."
  262. ))
  263.  
  264. (set #docs-msg
  265. (cat "Möchtest du die Dok-Dateien installieren ?"
  266. ))
  267.  
  268. (set #docs-help
  269. (cat "Die Dok-Dateien sind durch Konvertieren der Guide-Dateien "
  270.      "in ANSI Texte entstanden.\n"
  271.      "Wähle \"Ja\", wenn deine Version von Amigaguide die Online-Hilfe "
  272.      "nicht darstellen kann oder du die Dokumentation ausdrucken möchtest."
  273. ))
  274. (set #developer-msg
  275. (cat "Möchtest du die Entwicklerdateien installieren ?"
  276. ))
  277. (set #developer-help
  278. (cat "Die Entwicklerdateien sind für Leute interessant, welche XApps entwickeln wollen."
  279. ))
  280.  
  281. (set #camd-default
  282. (cat "Möchtest du die camd.library für den MIDI-Zugriff benutzen ?"
  283. ))
  284. (set #camd-help
  285. (cat "Der Installer hat die camd.library (Midi-Unterstützungsroutine) erkannt.\n"
  286.      "Wähle \"Ja\", wenn du diese als Standard nutzen möchtest.\n"
  287.      "Wähle \"Nein\", wenn du stattdessen das serial device nutzen möchtest.\n"
  288.      "Beachte, daß dies nur für die Standardeinstellungen von Interesse ist.\n"
  289.      "Die Einstellungen der Midi-Instrumente sind davon unabhängig.\n"
  290. ))
  291.  
  292. (set #help-sel
  293. (cat "Wähle eine oder mehrere Sprachen für die Online-Hilfe."
  294. ))
  295.  
  296. (set #doc-sel
  297. (cat "Wähle eine oder mehrere Sprachen für die Dok-Dateien."
  298. ))
  299.  
  300. (set #msg-mkdir
  301. (cat "Erstelle die Verzeichnisstruktur..."
  302. ))
  303.  
  304. (set #prg-sel
  305. (cat "Wähle die gewünschten Dateien."
  306. ))
  307.  
  308. (set #prg-help
  309. (cat "Falls du nicht registrierter Nutzer bist, kannst du nur Euterpe benutzen.\n"
  310.      "Die optimierten Versionen bleiben den registrierten Nutzern vorbehalten."
  311. ))
  312.  
  313. (set #metro-msg
  314. (cat "Sollen die Beispieldateien für Voice Metronome installiert werden ?"
  315. ))
  316.  
  317. (set #metro-help
  318. (cat "Zur Demonstration, wie Metronome-Instrumente zu benutzen sind, steht ein Beispiel,"
  319.      "welches die Schläge einer menschlichen Stimme zählt, zur Verfügung.\n"
  320.      "Wähle \"Ja\", falls es dich interessiert."
  321. ))
  322.  
  323. (set #rexx-msg
  324. (cat "Wähle die zusätzlich zu installierenden REXX-Skripte."
  325. ))
  326.  
  327. (set #rexx-help
  328. (cat "Die von Euterpe benötigten Skripte wurden bereits installiert. "
  329.      "Du kannst hier noch weitere auswählen, welche als Beispiele gedacht sind."
  330. ))
  331.  
  332. (set #cat-sel
  333. (cat "Wähle eine oder mehrere Sprachen für die Kataloge."
  334. ))
  335. (set #cat-msg
  336. (cat "Möchtest du die Übersetzerdateien installieren ?"
  337. ))
  338. (set #cat-help
  339. (cat "Diese Dateien sind für die Benutzung von Euterpe nicht notwendig, aber für die Übersetzung der Kataloge."
  340. ))
  341. ))
  342.  
  343. ; -------------------------------------------------------------------------
  344. ; path settings
  345. ; -------------------------------------------------------------------------
  346.  
  347. (set #installLoc (pathonly @icon)
  348.      #installEuterpe (tackon #installLoc "Euterpe")
  349.      #installInstruments (tackon #installEuterpe "Instruments")
  350.      #installRexx (tackon #installEuterpe "Rexx")
  351.      #installDeveloper (tackon #installLoc "Developer")
  352.      #installDocs (tackon #installLoc "Docs")
  353.      #installHelp (tackon #installLoc "Help")
  354.      #installFonts (tackon #installLoc "fonts")
  355.      #installCat (tackon #installLoc "Catalogs")
  356.      #installLibs (tackon #installLoc "Libs/AsyncIO.library")
  357.      #installOuiCat (tackon (tackon (tackon #installLoc "OUI_Catalogs") @language) "oui.catalog")
  358.      #targetOuiCat (tackon "LOCALE:Catalogs" @language)
  359.      #targetLibs "LIBS:"
  360. )
  361.  
  362. ; -------------------------------------------------------------------------
  363. ; intro
  364. ; -------------------------------------------------------------------------
  365.  
  366. (message #introduction)
  367. (welcome)
  368.  
  369. ; -------------------------------------------------------------------------
  370. ; destination settings
  371. ; -------------------------------------------------------------------------
  372.  
  373. (set #target (tackon (askdir (prompt #quel-disque)
  374.              (help #quel-disque-aide)
  375.              (default @default-dest)
  376.              (disk)
  377.              ) "Euterpe")
  378. )
  379. (makedir #target (infos))
  380.  
  381. ; -------------------------------------------------------------------------
  382. ; optional path settings
  383. ; -------------------------------------------------------------------------
  384.  
  385. (set #targetDeveloper (tackon #target "Developer"))
  386. (set #targetDocs (tackon #target "Docs"))
  387. (set #targetHelp (tackon #target "Help"))
  388. (set #targetInstruments (tackon #target "Instruments"))
  389. (set #targetRexx (tackon #target "Rexx"))
  390. (set #targetCat (tackon #target "Catalogs"))
  391. (set #targetFonts (tackon #target "fonts"))
  392.  
  393. (set @default-dest #target)
  394. (complete 10)
  395.  
  396. ; -------------------------------------------------------------------------
  397. ; main files copy
  398. ; -------------------------------------------------------------------------
  399.  
  400. (working #msg-mkdir)
  401. (makedir (tackon #target "Sequences") (infos))
  402. (makedir (tackon #target "Tracks") (infos))
  403. (makedir (tackon #target "Patterns") (infos))
  404. (makedir (tackon #target "Samples") (infos))
  405. (makedir (tackon #target "SoundBanks") (infos))
  406. (makedir (tackon #target "XApps") (infos))
  407. (makedir (tackon #target "Rexx") (infos))
  408. (makedir (tackon #target "Pictures") (infos))
  409. (makedir #targetFonts)
  410. (makedir #targetInstruments (infos))
  411. (makedir (tackon #targetInstruments "Midi") (infos))
  412. (makedir (tackon #targetInstruments "DrumKits") (infos))
  413. (makedir (tackon #targetInstruments "Audio") (infos))
  414. (makedir (tackon #targetInstruments "DrumAudio") (infos))
  415. (makedir (tackon #targetInstruments "Pictures") (infos))
  416. (makedir (tackon #targetInstruments "Texts") (infos))
  417. (makedir (tackon #targetInstruments "ARexx") (infos))
  418. (makedir #targetRexx (infos))
  419. (complete 20)
  420.  
  421. (copyfiles (source #installEuterpe)
  422.            (dest #target)
  423.            (pattern "Euterpe#?")
  424.            (infos)
  425.            (files)
  426.            (confirm)
  427.            (prompt #prg-sel)
  428.            (help #prg-help)
  429. )
  430. (complete 25)
  431. (copyfiles (source #installEuterpe)
  432.            (dest #target)
  433.            (pattern "Registration")
  434.            (infos)
  435.            (files)
  436. )
  437. (complete 30)
  438.  
  439. (if (askbool (prompt #metro-msg)
  440.             (help #metro-help)
  441.             (default 1)
  442.    )
  443. (
  444.     (copyfiles (source (tackon #installEuterpe "SoundBanks"))
  445.                (dest (tackon #target "SoundBanks"))
  446.                (pattern "#?")
  447.                (infos)
  448.                (files)
  449.     )
  450.     (copyfiles (source (tackon #installInstruments "DrumAudio"))
  451.                (dest (tackon #targetInstruments "DrumAudio"))
  452.                (pattern "Metronome")
  453.                (infos)
  454.                (files)
  455.     )
  456. ))
  457. (complete 35)
  458. (copyfiles (source #installRexx)
  459.            (dest #targetRexx)
  460.            (choices "default.muse" "shell.muse")
  461.            (infos)
  462.            (files)
  463. )
  464.  
  465. (complete 40)
  466. (copyfiles (source #installRexx)
  467.            (dest #targetRexx)
  468.            (pattern  "~(default|shell).muse")
  469.            (confirm)
  470.            (prompt #rexx-msg)
  471.            (help #rexx-help)
  472.            (infos)
  473.            (files)
  474. )
  475.  
  476. (copyfiles (source #installFonts)
  477.            (dest #targetFonts)
  478.            (all)
  479. )
  480.  
  481. (copyfiles (source (tackon #installInstruments "Midi"))
  482.            (dest (tackon #targetInstruments "Midi"))
  483.            (pattern "#?")
  484.            (infos)
  485.            (files)
  486. )
  487. (copyfiles (source (tackon #installEuterpe "XApps"))
  488.            (dest (tackon #target "XApps"))
  489.            (pattern "#?")
  490.            (infos)
  491.            (files)
  492. )
  493. (complete 45)
  494.  
  495. ; -------------------------------------------------------------------------
  496. ; previous installation bug correction
  497. ; -------------------------------------------------------------------------
  498.  
  499. (if (exists "libs:asyncio.library/asyncio.library")
  500.     (
  501.       (message #fix-error-asyncio)
  502.       (rename "libs:asyncio.library" "libs:asynciodir" (safe))
  503.       (rename "libs:asynciodir/AsyncIO.library" "libs:AsyncIO.library" (safe))
  504.       (delete "libs:asynciodir" (optional (safe)))
  505.     )
  506. )
  507. (complete 50)
  508.  
  509. ; -------------------------------------------------------------------------
  510. ; asyncio installation
  511. ; -------------------------------------------------------------------------
  512.  
  513. (copylib (prompt #asyncio-prompt)
  514.          (source #installLibs)
  515.          (dest #targetLibs)
  516.          (confirm)
  517.          (help @copylib-help)
  518. )
  519. (complete 55)
  520.  
  521. ; -------------------------------------------------------------------------
  522. ; OUI catalogs installation
  523. ; -------------------------------------------------------------------------
  524.  
  525. (copylib (prompt #oui-prompt)
  526.          (source #installOuiCat)
  527.          (dest #targetOuiCat)
  528.          (confirm)
  529.          (optional nofail askuser)
  530.          (help @copylib-help)
  531. )
  532. (complete 60)
  533.  
  534.  
  535. ; -------------------------------------------------------------------------
  536. ; catalogs installation
  537. ; -------------------------------------------------------------------------
  538.  
  539. (set #cat-lang (askoptions (prompt #cat-sel)
  540.                 (help @askoptions-help)
  541.                 (choices "français" "deutsch")
  542. ))
  543.  
  544. (if (> #cat-lang 0)
  545.     (makedir #targetCat (infos))
  546. )
  547. (if (IN #cat-lang 0)
  548.     (
  549.         (set #lang-src (tackon #installCat "français"))
  550.         (set #lang-dst (tackon #targetCat  "français"))
  551.         (makedir #lang-dst)
  552.         (copyfiles (source #lang-src)
  553.                    (dest #lang-dst)
  554.                    (all)
  555.         )
  556.     )
  557. )
  558.  
  559. (if (IN #cat-lang 1)
  560.     (
  561.         (set #lang-src (tackon #installCat "deutsch"))
  562.         (set #lang-dst (tackon #targetCat  "deutsch"))
  563.         (makedir #lang-dst)
  564.         (copyfiles (source #lang-src)
  565.                    (dest #lang-dst)
  566.                    (all)
  567.         )
  568.     )
  569. )
  570.  
  571. (if (askbool (prompt #cat-msg)
  572.              (help #cat-help)
  573.              (default 0)
  574.     )
  575.     (copyfiles (source #installCat)
  576.                (dest #targetCat)
  577.                (pattern  "#?")
  578.                (infos)
  579.                (files)
  580.     )
  581. )
  582.  
  583. (complete 65)
  584.  
  585. ; -------------------------------------------------------------------------
  586. ; help installation
  587. ; -------------------------------------------------------------------------
  588.  
  589. (set #help-lang (askoptions (prompt #help-sel)
  590.                 (help @askoptions-help)
  591.                 (choices "english" "français" "deutsch")
  592. ))
  593.  
  594. (if (> #help-lang 0)
  595.     (makedir #targetHelp (infos))
  596. )
  597. (if (IN #help-lang 0)
  598.     (
  599.         (set #lang-src (tackon #installHelp "english"))
  600.         (set #lang-dst (tackon #targetHelp "english"))
  601.         (makedir #lang-dst (infos))
  602.         (copyfiles (source #lang-src)
  603.                    (dest #lang-dst)
  604.                    (all)
  605.         )
  606.     )
  607. )
  608. (if (IN #help-lang 1)
  609.     (
  610.         (set #lang-src (tackon #installHelp "français"))
  611.         (set #lang-dst (tackon #targetHelp "français"))
  612.         (makedir #lang-dst (infos))
  613.         (copyfiles (source #lang-src)
  614.                    (dest #lang-dst)
  615.                    (all)
  616.         )
  617.     )
  618. )
  619. (if (IN #help-lang 2)
  620.     (
  621.         (set #lang-src (tackon #installHelp "deutsch"))
  622.         (set #lang-dst (tackon #targetHelp "deutsch"))
  623.         (makedir #lang-dst (infos))
  624.         (copyfiles (source #lang-src)
  625.                    (dest #lang-dst)
  626.                    (all)
  627.         )
  628.     )
  629. )
  630. (complete 70)
  631.  
  632. ; -------------------------------------------------------------------------
  633. ; docs installation
  634. ; -------------------------------------------------------------------------
  635.  
  636. (if (askbool (prompt #docs-msg)
  637.             (help #docs-help)
  638.             (default 1)
  639.    )
  640.    (
  641.         (set #docs-lang (askoptions (prompt #doc-sel)
  642.                         (help @askoptions-help)
  643.                         (choices "english" "français" "deutsch")
  644.         ))
  645.  
  646.         (if (> #docs-lang 0)
  647.             (makedir #targetDocs (infos))
  648.         )
  649.         (if (IN #docs-lang 0)
  650.             (
  651.                 (set #lang-src (tackon #installDocs "english"))
  652.                 (set #lang-dst (tackon #targetDocs "english"))
  653.                 (makedir #lang-dst (infos))
  654.                 (copyfiles (source #lang-src)
  655.                            (dest #lang-dst)
  656.                            (all)
  657.                 )
  658.             )
  659.         )
  660.         (if (IN #docs-lang 1)
  661.             (
  662.                 (set #lang-src (tackon #installDocs "français"))
  663.                 (set #lang-dst (tackon #targetDocs "français"))
  664.                 (makedir #lang-dst (infos))
  665.                 (copyfiles (source #lang-src)
  666.                            (dest #lang-dst)
  667.                            (all)
  668.                 )
  669.             )
  670.         )
  671.         (if (IN #docs-lang 2)
  672.             (
  673.                 (set #lang-src (tackon #installDocs "deutsch"))
  674.                 (set #lang-dst (tackon #targetDocs "deutsch"))
  675.                 (makedir #lang-dst (infos))
  676.                 (copyfiles (source #lang-src)
  677.                            (dest #lang-dst)
  678.                            (all)
  679.                 )
  680.             )
  681.         )
  682.    )
  683. )
  684. (complete 80)
  685.  
  686.  
  687. ; -------------------------------------------------------------------------
  688. ; developer files installation
  689. ; -------------------------------------------------------------------------
  690.  
  691. (if (askbool (prompt #developer-msg)
  692.             (help #developer-help)
  693.             (default 0)
  694.    )
  695.    (
  696.         (makedir #targetDeveloper (infos))
  697.         (copyfiles (source #installDeveloper)
  698.                    (dest #targetDeveloper)
  699.                    (all)
  700.         )
  701.    )
  702. )
  703. (complete 90)
  704.  
  705. ; -------------------------------------------------------------------------
  706. ; assign Euterpe: now
  707. ; -------------------------------------------------------------------------
  708.  
  709. (makeassign "Euterpe" #target)
  710. (run "Assign FONTS: Euterpe:fonts ADD")
  711.  
  712. ; -------------------------------------------------------------------------
  713. ; camd tooltype setting
  714. ; -------------------------------------------------------------------------
  715.  
  716. (if (exists "LIBS:camd.library")
  717.     (if (askbool (prompt #camd-default)
  718.                  (help #camd-help)
  719.                  (default 1)
  720.         )
  721.         (set #camd-flag "TRUE")
  722.         (set #camd-flag "FALSE")
  723.     )
  724.     (set #camd-flag "FALSE")
  725. )
  726.  
  727.  
  728. (tooltype (dest "Euterpe:Euterpe")
  729.           (settooltype "USECAMD" #camd-flag)
  730. )
  731. (complete 95)
  732.  
  733. ; -------------------------------------------------------------------------
  734. ; startup modifications
  735. ; -------------------------------------------------------------------------
  736.  
  737. (startup "Euterpe" (prompt #startup-prompt)
  738.          (help @startup-help)
  739.          (command (cat "Assign Euterpe: " #target "\n"
  740.          "Assign FONTS: Euterpe:fonts ADD"))
  741. )
  742. (complete 100)
  743.