home *** CD-ROM | disk | FTP | other *** search
/ The Best of Mecomp Multimedia 2 / MECOMP-CD-II.iso / amiga / emulation / shapeshifter / videodrivers / turboevd / sources / c2p4.s < prev    next >
Encoding:
Text File  |  1996-11-23  |  8.6 KB  |  289 lines
  1. * $VER: c2p4.s (22.11.96) 33.1
  2. *
  3. * - c2p for chunky nybbles
  4. * - this routine is public domain, use it as you want
  5. * - based on the excellent merge rout by Mikael Kalms
  6. *
  7. * Version history:
  8. * 
  9. * 33.1  22.11.96    Aki Laukkanen (amlaukka@cc.helsinki.fi)
  10. *
  11. *       created
  12. *
  13.  
  14.     xdef    _c2p4
  15.  
  16. ; from:
  17. ; 0        4        8        12       16       20       24       28
  18. ; a3a2a1a0 b3b2b1b0 c3c2c1c0 d3d2d1d0 e3e2e1e0 f3f2f1f0 g3g2g1g0 h3h2h1h0 
  19. ; i3i2i1i0 j3j2j1j0 k3k2k1k0 l3l2l1l0 m3m2m1m0 n3n2n1n0 o3o2o1o0 p3p2p1p0
  20. ; q3q2q1q0 r3r2r1r0 s3s2s1s0 t3t2t1t0 u3u2u1u0 v3v2v1v0 w3w2w1w0 x3x2x1x0
  21. ; y3y2y1y0 z3z2z1z0 A3A2A1A0 B3B2B1B0 C3C2C1C0 D3D2D1D0 E3E2E1E0 F3F2F1F0
  22.  
  23. ; 1st pass
  24. ; 8x1
  25. ; a3a2a1a0 b3b2b1b0 i3i2i1i0 j3j2j1j0 e3e2e1e0 f3f2f1f0 m3m2m1m0 n3n2n1n0
  26. ; c3c2c1c0 d3d2d1d0 k3k2k1k0 l3l2l1l0 g3g2g1g0 h3h2h1h0 o3o2o1o0 p3p2p1p0
  27. ; q3q2q1q0 r3r2r1r0 y3y2y1y0 z3z2z1z0 u3u2u1u0 v3v2v1v0 C3C2C1C0 D3D2D1D0
  28. ; s3s2s1s0 t3t2t1t0 A3A2A1A0 B3B2B1B0 w3w2w1w0 x3x2x1x0 E3E2E1E0 F3F2F1F0
  29.  
  30. ; 2nd pass
  31. ; 16x2
  32. ; a3a2a1a0 b3b2b1b0 i3i2i1i0 j3j2j1j0 q3q2q1q0 r3r2r1r0 y3y2y1y0 z3z2z1z0
  33. ; c3c2c1c0 d3d2d1d0 k3k2k1k0 l3l2l1l0 s3s2s1s0 t3t2t1t0 A3A2A1A0 B3B2B1B0
  34. ; e3e2e1e0 f3f2f1f0 m3m2m1m0 n3n2n1n0 u3u2u1u0 v3v2v1v0 C3C2C1C0 D3D2D1D0
  35. ; g3g2g1g0 h3h2h1h0 o3o2o1o0 p3p2p1p0 w3w2w1w0 x3x2x1x0 E3E2E1E0 F3F2F1F0
  36.  
  37. ; 3rd pass
  38. ; 4x2
  39. ; a3a2a1a0 e3e2e1e0 i3i2i1i0 m3m2m1m0 q3q2q1q0 u3u2u1u0 y3y2y1y0 C3C2C1C0
  40. ; c3c2c1c0 g3g2g1g0 k3k2k1k0 o3o2o1o0 s3s2s1s0 w3w2w1w0 A3A2A1A0 E3E2E1E0
  41. ; b3b2b1b0 f3f2f1f0 j3j2j1j0 n3n2n1n0 r3r2r1r0 v3v2v1v0 z3z2z1z0 D3D2D1D0
  42. ; d3d2d1d0 h3h2h1h0 l3l2l1l0 p3p2p1p0 t3t2t1t0 x3x2x1x0 B3B2B1B0 F3F2F1F0
  43.  
  44. ; 4th pass
  45. ; 2x1
  46. ; a3a2c3c2 e3e2g3g2 i3i1k3k2 m3m2o3o2 q3q2s3s2 u3u2w3w2 y3y2A3A2 C3C2E3E2
  47. ; a1a0c1c0 e1e0g1g0 i1i0k1k0 m1m0o1o0 q1q0s1s0 u1u0w1w0 y1y0A1A0 C1C0E1E0
  48. ; b3b2d3d2 f3f2h3h2 j3j2l3l2 n3n2p3p2 r3r2t3t2 v3v2x3x2 z3z2B3B2 D3D2F3F2
  49. ; b1b0d1d0 f1f0h1h0 j1j0l1l0 n1n0p1p0 r1r0t1t0 v1v0x1x0 z1z0B1B0 D1D0F1F0
  50.  
  51. ; to (5th pass)
  52. ; 1x2
  53. ; a3b3c3d3 e3f2g3h3 i3j3k3l3 m3n3o3p3 q3r3s3t3 u3v3w3x3 y3z3A3B3 C3D3E3F3
  54. ; a1b1c1d1 e1f1g1h1 i1j1k1l1 m1n1o1p1 q1r1s1t1 u1v1w1x1 y1z1A1B1 C1D1E1F1
  55. ; a2b2c2d2 e2f2g2h2 i2j2k2l2 m2n2o2p2 q2r2s2t2 u2v2w2x2 y2z2A2B2 C2D2E2F2
  56. ; a0b0c0d0 e0f0g0h0 i0j0k0l0 m0n0o0p0 q0r0s0t0 u0v0w0x0 y0z0A0B0 C0D0E0F0
  57.  
  58.     include "exec/types.i"
  59.     include "graphics/gfx.i"
  60.  
  61. ; a0 - source chunky
  62. ; a1 - keep as temp bpl pointer
  63. ; a2 - chunky end
  64. ; a3 - BitMap structure
  65. _c2p4
  66.     movem.l d2-d7/a2-a6,-(sp)
  67.  
  68.     subq.l  #8,sp
  69.     subq.l  #8,sp
  70.     move.l  (bm_Planes,a3),(sp)
  71.     move.l  (bm_Planes+4,a3),(4,sp)
  72.     move.l  (bm_Planes+8,a3),(8,sp)
  73.     move.l  (bm_Planes+12,a3),(12,sp)
  74.     move.l  #$00FF00FF,d7
  75. .start
  76.     move.l  (a0)+,d0                        ; source data
  77.     move.l  (a0)+,d1
  78.     move.l  (a0)+,d2
  79.     move.l  (a0)+,d3
  80.  
  81.     move.l  d1,d5                           ; 1st pass (8x1)
  82.     move.l  d3,d6
  83.     lsr.l   #8,d5
  84.     lsr.l   #8,d6
  85.     eor.l   d0,d5
  86.     eor.l   d2,d6
  87.     and.l   d7,d5  
  88.     and.l   d7,d6
  89.     eor.l   d5,d0
  90.     eor.l   d6,d2
  91.     lsl.l   #8,d5
  92.     lsl.l   #8,d6
  93.     eor.l   d6,d3
  94.     eor.l   d5,d1
  95.  
  96.     swap    d2                              ; 2nd pass (16x2)
  97.     swap    d3
  98.     move.w  d2,d5
  99.     move.w  d3,d6
  100.     move.w  d0,d2
  101.     move.w  d1,d3
  102.     move.w  d5,d0
  103.     move.w  d6,d1
  104.     swap    d2
  105.     swap    d3
  106.  
  107.     move.l  #$0F0F0F0F,d4
  108.  
  109.     move.l  d2,d5                           ; 3rd pass (4x2)
  110.     move.l  d3,d6
  111.     lsr.l   #4,d5
  112.     lsr.l   #4,d6
  113.     eor.l   d0,d5
  114.     eor.l   d1,d6
  115.     and.l   d4,d5  
  116.     and.l   d4,d6
  117.     eor.l   d5,d0
  118.     eor.l   d6,d1
  119.     lsl.l   #4,d5
  120.     lsl.l   #4,d6
  121.     eor.l   d6,d3
  122.     eor.l   d5,d2
  123.  
  124.     move.l  #$33333333,d4
  125.  
  126.     move.l  d1,d5                           ; 4th pass (2x1)
  127.     move.l  d3,d6
  128.     lsr.l   #2,d5
  129.     lsr.l   #2,d6
  130.     eor.l   d0,d5
  131.     eor.l   d2,d6
  132.     and.l   d4,d5  
  133.     and.l   d4,d6
  134.     eor.l   d5,d0
  135.     eor.l   d6,d2
  136.     lsl.l   #2,d5
  137.     lsl.l   #2,d6
  138.     eor.l   d6,d3
  139.     eor.l   d5,d1
  140.  
  141.     move.l  #$55555555,d4
  142.  
  143.     move.l  d2,d5                           ; 5th pass (1x2)
  144.     move.l  d3,d6
  145.     lsr.l   #1,d5
  146.     lsr.l   #1,d6
  147.     eor.l   d0,d5
  148.     eor.l   d1,d6
  149.     and.l   d4,d5  
  150.     and.l   d4,d6
  151.     eor.l   d5,d0                           ; plane 3 
  152.     eor.l   d6,d1                           ; plane 1
  153.     lsl.l   #1,d5
  154.     lsl.l   #1,d6
  155.     eor.l   d6,d3                           ; plane 2
  156.     eor.l   d5,d2                           ; plane 0
  157.  
  158.     move.l  d3,a3
  159.     move.l  d1,a4
  160.     move.l  d2,a5
  161.     move.l  d0,a6
  162.  
  163.     cmp.l   a0,a2
  164.     beq     .end
  165. .loop
  166.     move.l  (a0)+,d0                        ; source data       pOEP (special case,
  167.     move.l  (a0)+,d1                        ;                   sOEP see M68060UM/AD
  168.     move.l  (a0)+,d2                        ;                   pOEP section 10 for
  169.     move.l  (a0)+,d3                        ;                   sOEP reference)
  170.  
  171.     move.l  (sp),a1                         ; write plane 0     pOEP
  172.     move.l  a3,(a1)                         ;                   pOEP
  173.  
  174.     move.l  d1,d5                           ; 1st pass (8x1)    pOEP
  175.     move.l  d3,d6                           ;                   sOEP
  176.     lsr.l   #8,d5                           ;                   pOEP
  177.     lsr.l   #8,d6                           ;                   sOEP
  178.     eor.l   d0,d5                           ;                   pOEP
  179.     eor.l   d2,d6                           ;                   sOEP
  180.     and.l   d7,d5                           ;                   pOEP
  181.     and.l   d7,d6                           ;                   pOEP (be careful and
  182.     eor.l   d5,d0                           ;                   sOEP so these things don't
  183.     eor.l   d6,d2                           ;                   pOEP stall the pipeline)
  184.     lsl.l   #8,d5                           ;                   sOEP
  185.     lsl.l   #8,d6                           ;                   pOEP
  186.     eor.l   d6,d3                           ;                   sOEP
  187.     eor.l   d5,d1                           ;                   pOEP
  188.  
  189.     swap    d2                              ; 2nd pass (16x2)   pOEP only (well you can't have all)
  190.     swap    d3                              ;                   pOEP only
  191.     move.w  d2,d5                           ;                   pOEP
  192.     move.w  d3,d6                           ;                   sOEP
  193.     move.w  d0,d2                           ;                   pOEP
  194.  
  195.     move.l  (4,sp),a1                       ; write plane 1     sOEP = 12 cycles between chip writes
  196.     move.l  a4,(a1)                         ;                   pOEP
  197.  
  198.     move.w  d1,d3                           ;                   sOEP
  199.     move.w  d5,d0                           ;                   pOEP
  200.     move.w  d6,d1                           ;                   sOEP
  201.     swap    d2                              ;                   pOEP only
  202.     swap    d3                              ;                   pOEP only
  203.  
  204.     move.l  #$0F0F0F0F,d4
  205.  
  206.     move.l  d2,d5                           ; 3rd pass (4x2)
  207.     move.l  d3,d6
  208.     lsr.l   #4,d5
  209.     lsr.l   #4,d6
  210.     eor.l   d0,d5
  211.     eor.l   d1,d6
  212.     and.l   d4,d5  
  213.     and.l   d4,d6
  214.     eor.l   d5,d0
  215.     eor.l   d6,d1
  216.     lsl.l   #4,d5
  217.     lsl.l   #4,d6
  218.     eor.l   d6,d3
  219.     eor.l   d5,d2
  220.  
  221.     move.l  #$33333333,d4
  222.  
  223.     move.l  (8,sp),a1                       ; write plane 2
  224.     move.l  a5,(a1)
  225.  
  226.     move.l  d1,d5                           ; 4th pass (2x1)
  227.     move.l  d3,d6
  228.     lsr.l   #2,d5
  229.     lsr.l   #2,d6
  230.     eor.l   d0,d5
  231.     eor.l   d2,d6
  232.     and.l   d4,d5  
  233.     and.l   d4,d6
  234.     eor.l   d5,d0
  235.     eor.l   d6,d2
  236.     lsl.l   #2,d5
  237.     lsl.l   #2,d6
  238.     eor.l   d6,d3
  239.     eor.l   d5,d1
  240.  
  241.     move.l  #$55555555,d4
  242.  
  243.     move.l  (12,sp),a1                      ; write plane 3
  244.     move.l  a6,(a1)
  245.  
  246.     move.l  d2,d5                           ; 5th pass (1x2)
  247.     move.l  d3,d6
  248.     lsr.l   #1,d5
  249.     lsr.l   #1,d6
  250.     eor.l   d0,d5
  251.     eor.l   d1,d6
  252.     and.l   d4,d5  
  253.     and.l   d4,d6
  254.     eor.l   d5,d0                           ; plane 3 
  255.     eor.l   d6,d1                           ; plane 1
  256.     lsl.l   #1,d5 
  257.     lsl.l   #1,d6
  258.     eor.l   d6,d3                           ; plane 2
  259.     eor.l   d5,d2                           ; plane 0
  260.  
  261.     move.l  d3,a3                           ; save planar data
  262.     move.l  d1,a4
  263.     move.l  d2,a5
  264.     move.l  d0,a6
  265.  
  266.     addq.l  #4,(sp)                         ; update bitmap pointers
  267.     addq.l  #4,(4,sp)
  268.     addq.l  #4,(8,sp)
  269.     addq.l  #4,(12,sp)
  270.  
  271.     cmp.l   a0,a2
  272.     bne     .loop
  273. .end
  274.     move.l  (sp),a1                         ; save data
  275.     move.l  a3,(a1)
  276.     move.l  (4,sp),a1
  277.     move.l  a4,(a1)
  278.     move.l  (8,sp),a1
  279.     move.l  a5,(a1)
  280.     move.l  (12,sp),a1
  281.     move.l  a6,(a1)
  282.  
  283.     addq.l  #8,sp
  284.     addq.l  #8,sp
  285.  
  286.     movem.l (sp)+,d2-d7/a2-a6
  287.  
  288.     rts
  289.