home *** CD-ROM | disk | FTP | other *** search
/ Amiga Elysian Archive / AmigaElysianArchive.iso / commod / altmenu.lha / Arg.Asm < prev    next >
Assembly Source File  |  1992-05-23  |  9KB  |  388 lines
  1. *
  2. * C initial startup procedure under AmigaDOS
  3. * Adapted by Jorrit Tyberghein
  4. * 
  5. * Use the following command line to make the cli/workbench startup
  6. * asm -iINCLUDE: Arg.asm
  7. *
  8. * Use the following command line to make the resident startup
  9. * asm -dRESIDENT -iINCLUDE: -oArgR.o Arg.asm
  10. *
  11. * Use the following command line to make the cli startup
  12. * asm -dCLI -iINCLUDE: Arg.asm
  13. *
  14. * (Tab size 3)
  15. *
  16.  
  17. offsetv    set    -30
  18.  
  19. FUNCDEF    macro
  20. _LVO\1    equ    offsetv
  21. offsetv    set    offsetv-6
  22.             endm
  23.  
  24.  
  25.     INCLUDE    "exec/types.i"
  26.     INCLUDE    "exec/alerts.i"
  27.     INCLUDE    "exec/nodes.i"
  28.     INCLUDE    "exec/lists.i"
  29.     INCLUDE    "exec/ports.i"
  30.     INCLUDE    "exec/libraries.i"
  31.     INCLUDE    "exec/tasks.i"
  32.     INCLUDE    "exec/memory.i"
  33.     INCLUDE    "exec/execbase.i"
  34.     INCLUDE    "libraries/dos.i"
  35.     INCLUDE    "libraries/dosextens.i"
  36.     INCLUDE    "workbench/startup.i"
  37. ;    INCLUDE    "exec/funcdef.i"
  38.     INCLUDE    "exec/exec_lib.i"
  39.     INCLUDE    "libraries/dos_lib.i"
  40.  
  41. MEMFLAGS            EQU    MEMF_CLEAR+MEMF_PUBLIC
  42. AbsExecBase        EQU    4
  43.  
  44. * some usefull macros:
  45.  
  46. callsys    macro
  47.             CALLLIB _LVO\1
  48.             endm
  49.     
  50.         xdef        _XCEXIT                * exit(code) is standard way to leave C.
  51.         xdef        _@XCEXIT
  52.     
  53.         xref        _LinkerDB            * linker defined base value
  54.         xref        __BSSBAS                * linker defined base of BSS
  55.         xref        __BSSLEN                * linker defined length of BSS
  56.     IFD RESIDENT
  57.         xref        _RESLEN
  58.         xref        _RESBASE
  59.         xref        _NEWDATAL
  60.         xref        __stack
  61.     ENDC
  62.     
  63. *       library references
  64.  
  65.         section text,code
  66.  
  67.         xref        _argmain                * Name of C program to start with.
  68.     
  69. start:
  70.         movem.l d1-d6/a0-a6,-(a7)
  71.  
  72.         move.l    a0,a2                    * save command pointer
  73.         move.l    d0,d2                    * and command length
  74.         lea        _LinkerDB,a4        * load base register
  75.         move.l    AbsExecBase.W,a6
  76.  
  77.     IFND RESIDENT
  78. ;We do not have to clear BSS because AmigaDOS 2.0 does this for us.
  79. ;        lea        __BSSBAS,a3            * get base of BSS
  80. ;        moveq        #0,d1
  81. ;        move.l    #__BSSLEN,d0        * get length of BSS in longwords
  82. ;        bra.s        clr_lp                * and clear for length given
  83. ;clr_bss:
  84. ;        move.l    d1,(a3)+
  85. ;clr_lp:
  86. ;        dbf        d0,clr_bss
  87.         move.l    a7,__StackPtr(A4)    * Save stack ptr
  88.         move.l    a6,_SysBase(A4)
  89.     ENDC
  90.     
  91.  
  92.     IFD RESIDENT
  93.         movem.l    d2,-(a7)
  94.         movem.l    a0-a2,-(a7)
  95.  
  96. *------ get the size of the stack,    if CLI use cli_DefaultStack
  97. *------                                        if WB use a7 - TC_SPLOWER
  98.         move.l    ThisTask(a6),A3
  99.         move.l    pr_CLI(A3),d1
  100.     IFND CLI
  101.         beq.s        fromwb
  102.     ENDC
  103.         lsl.l        #2,d1
  104.         move.l    d1,a0
  105.         move.l    cli_DefaultStack(a0),d1
  106.         lsl.l        #2,d1                    * # longwords -> # bytes
  107.     IFND CLI
  108.         bra.s        dostack
  109. fromwb:
  110.         move.l    a7,d1             
  111.         sub.l        TC_SPLOWER(a3),d1     
  112.     ENDC
  113. dostack:
  114.         moveq        #0,d2                    * use d2 as flag for newstack or not
  115.         move.l    #_RESLEN,d0
  116.         cmp.l        __stack(a4),d1        * This a4 is in the original 
  117.                     * set of data
  118.         bcc.s        nochange    
  119.         move.l    __stack(a4),d1
  120.         add.l        d1,d0                    * increase size of mem for new stack
  121.         moveq        #1,d2                    * set flag
  122.         
  123. nochange:
  124.         move.l    d1,a3                    * save stacksize to set up stack checking
  125.         move.l    #MEMFLAGS,d1
  126.         callsys    AllocMem
  127.         tst.l        d0
  128.         bne.s        ok1
  129.         movem.l    (a7)+,d2/a0-a2
  130.         rts
  131.  
  132. ok1:    move.l    d0,a0
  133.         move.l    d0,a2
  134.  
  135. ;a2 now has difference
  136.         move.l    d0,a1
  137.         move.l    #_NEWDATAL,d0
  138.         sub.l        #_RESBASE,a4
  139. ;copy data over
  140. cpy:
  141.         move.l    (a4)+,(a0)+
  142.         subq.l    #1,d0
  143.         bne.s        cpy
  144. ;a4 now points at number of relocs
  145.         move.l    (a4)+,d0
  146. reloc:
  147.         beq.s        nreloc
  148.         move.l    a1,a0
  149.         add.l        (a4)+,a0                * a0 now has add of reloc
  150.         add.l        (a0),a2
  151.         move.l    a2,(a0) 
  152.         move.l    a1,a2                    * restore offset
  153.         subq.l    #1,d0
  154.         bra.s        reloc
  155.  
  156. nreloc:
  157.         move.l    a1,a4                    * set up new base register
  158.         add.l        #_RESBASE,a4
  159.  
  160.         move.l    #_RESLEN,realdatasize(a4)
  161.         movem.l    (a7)+,a0-a2
  162.  
  163.         move.l    a6,_SysBase(A4)
  164.         tst.b        d2
  165.         movem.l    (a7)+,d2                * restore d2 
  166.         movem.l    a7,__StackPtr(A4)    * Save stack ptr (movem doesn't
  167.                                             * change flags)
  168.         beq.s        nochg2
  169.  
  170. *------ set up new stack
  171.         move.l    a4,d0
  172.         sub.l        #_RESBASE,d0
  173.         add.l        #_RESLEN,d0
  174.         add.l        __stack(a4),d0        * here a4 will be pointing at the
  175.                                             * new data, but _stack will be the
  176.                                             * same if all goes well
  177.  
  178.         sub.l        #128,d0                * 128 down for good measure
  179.         move.l    d0,a7
  180.         move.l    __stack(a4),d0
  181.         move.l    d0,4(a7)                * fill in size of new stack    
  182.         add.l        d0,realdatasize(a4)* need to know how much to free later
  183.  
  184. nochg2:
  185.  
  186.     ENDC
  187.  
  188. clrwb:
  189.     IFND CLI
  190.         clr.l        _WBenchMsg(A4)
  191.     ENDC
  192.  
  193. *-----  clear any pending signals
  194.         moveq        #0,d0
  195.         move.l    #$00003000,d1
  196.         callsys    SetSignal
  197.     
  198. *------ attempt to open DOS library:
  199.         lea        DOSName(PC),A1
  200.         moveq.l    #0,D0
  201.         callsys    OpenLibrary
  202.         move.l    D0,_DOSBase(A4)
  203.         bne.s        ok2
  204.         moveq.l    #100,d0
  205.         bra.w        exit2
  206.  
  207. ok2:
  208. *------ are we running as a son of Workbench?
  209.         move.l    ThisTask(a6),A3
  210.     IFND CLI
  211.         tst.l        pr_CLI(A3)
  212.         beq.s        fromWorkbench
  213.     ENDC
  214.     
  215. *=======================================================================
  216. *====== CLI Startup Code ===============================================
  217. *=======================================================================
  218. *
  219. * Entry: D2 = command length
  220. *            A2 = Command pointer
  221. fromCLI:
  222.     
  223. *------ find command name:
  224.         move.l    pr_CLI(a3),a0
  225.         add.l        a0,a0                    * bcpl pointer conversion
  226.         add.l        a0,a0
  227.         move.l    cli_CommandName(a0),a1
  228.         add.l        a1,a1                    * bcpl pointer conversion
  229.         add.l        a1,a1
  230.  
  231. *------ collect parameters:
  232.         move.l    d2,d0                    * get command line length
  233.         moveq.l    #0,d1
  234.         move.b    (a1)+,d1
  235.         move.l    a1,_ProgramName(A4)
  236.         add.l        d1,d0                    * add length of command name
  237.         addq.l    #1,d0                    * allow for space after command 
  238.  
  239.         clr.w        -(A7)                    * set null terminator for command line
  240.         addq.l    #3,D0                    * force to longword alligned number of bytes
  241.         andi.w    #$fffc,D0            * (round up)
  242.         addq.l    #2,d0                    * one extra word
  243.         sub.l        D0,A7                    * make room on stack for command line
  244.         subq.l    #6,D0
  245.         clr.l        0(A7,D0)
  246.  
  247. *------ copy command line onto stack
  248.         move.l    d2,d0                    * get command line length
  249.         subq.l    #1,d0
  250.         add.l        d1,d2
  251.  
  252. copy_line:
  253.         move.b    0(A2,D0.W),0(A7,D2.W)    * copy command line to stack
  254.         subq.l    #1,d2
  255.         dbf        d0,copy_line
  256.         move.b    #' ',0(a7,d2.w)    * add space between command and parms
  257.         subq.l    #1,d2
  258.  
  259. copy_cmd:
  260.         move.b    0(a1,d2.w),0(a7,d2.w)    * copy command name to stack
  261.         dbf        d2,copy_cmd
  262.         move.l    A7,A1
  263.         move.l    A1,-(A7)                * push command line address
  264.     IFND CLI
  265.         bra.s        main                    * call C entrypoint
  266.  
  267. *=======================================================================
  268. *====== Workbench Startup Code =========================================
  269. *=======================================================================
  270.  
  271. fromWorkbench:
  272.  
  273. *------ we are now set up.  wait for a message from our starter
  274.         lea        pr_MsgPort(A3),a0    * our process base
  275.         callsys    WaitPort
  276.         lea        pr_MsgPort(A3),a0    * our process base
  277.         callsys    GetMsg
  278.         move.l    d0,_WBenchMsg(a4)
  279.         move.l    d0,-(SP)
  280. *
  281.         move.l    d0,a2                    * get first argument
  282.         move.l    sm_ArgList(a2),d0
  283.         beq.s        do_cons
  284.         move.l    _DOSBase(a4),a6
  285.         move.l    d0,a0
  286.         move.l    wa_Lock(a0),d1
  287.         callsys    CurrentDir
  288. do_cons:
  289.         move.l    sm_ToolWindow(a2),d1    * get the window argument
  290.         beq.s        do_main
  291.         move.l    #MODE_OLDFILE,d2
  292.         callsys    Open
  293.         move.l    d0,stdin(a4)
  294.         beq.s        do_main
  295.         lsl.l        #2,d0
  296.         move.l    d0,a0
  297.         move.l    fh_Type(a0),pr_ConsoleTask(A3)
  298. do_main:
  299.         move.l    _WBenchMsg(A4),a0    * get address of workbench message
  300.         move.l    a0,-(a7)                * push argv
  301.         moveq        #0,d0
  302.         move.l    d0,-(a7)                * push argc
  303.         move.l    sm_ArgList(a0),a0    * get address of arguments
  304.         move.l    wa_Name(a0),_ProgramName(A4)    * get name of program
  305.     ENDC
  306.  
  307. *=============================================
  308. *------ common code --------
  309. *=============================================
  310.  
  311. main
  312.         jsr        _argmain(PC)        * call C entrypoint
  313.         moveq.l    #0,d0                    * set successful status
  314.         bra.s        exit2
  315. *
  316.  
  317. _XCEXIT:
  318.         move.l    4(SP),d0                * extract return code
  319. _@XCEXIT:
  320. exit2:
  321.         move.l    d0,-(a7)
  322.         move.l    AbsExecBase.W,a6
  323.         move.l    _DOSBase(A4),a1
  324.         callsys    CloseLibrary        * close Dos library
  325.  
  326. done_1c:
  327. *------ if we ran from CLI, skip workbench cleanup:
  328.     IFND CLI
  329.         tst.l        _WBenchMsg(A4)
  330.         beq.s        exitToDOS
  331.         move.l    stdin(a4),d1
  332.         beq.s        done_4
  333.         callsys    Close
  334. done_4:
  335.  
  336. *------ return the startup message to our parent
  337. *       we forbid so workbench can't UnLoadSeg() us
  338. *       before we are done:
  339.         move.l    AbsExecBase.W,A6
  340.         callsys    Forbid
  341.         move.l    _WBenchMsg(a4),a1
  342.         callsys    ReplyMsg
  343.     ENDC
  344.  
  345. *------ this rts sends us back to DOS:
  346. exitToDOS:
  347.     IFD RESIDENT
  348.         move.l    realdatasize(a4),d0
  349.         move.l    a4,a1
  350.         sub.l        #_RESBASE,a1
  351.         move.l    AbsExecBase.W,a6
  352.         move.l    (A7)+,d6
  353.         movea.l    __StackPtr(a4),a5
  354.         callsys    FreeMem
  355.         move.l    d6,d0
  356.         movea.l    a5,sp
  357.     ELSE
  358.         move.l    (A7)+,D0
  359.         movea.l    __StackPtr(a4),SP    * restore stack ptr
  360.     ENDC
  361.  
  362.         movem.l    (a7)+,d1-d6/a0-a6
  363.         rts
  364.  
  365.  
  366. DOSName
  367.         dc.b        'dos.library',0
  368.  
  369.         section __MERGED,BSS
  370. *
  371.         xdef        _SysBase,_WBenchMsg
  372.         xdef        _ProgramName,__StackPtr,_DOSBase
  373.  
  374. *
  375.     ifd RESIDENT
  376. realdatasize
  377.         ds.b        4                        * size of memory allocated for data +
  378.                                             * possible stack
  379.     endc
  380.  
  381. _SysBase            ds.b    4
  382. _WBenchMsg        ds.b    4
  383. __StackPtr        ds.b    4
  384. stdin                ds.b    4
  385. _DOSBase            ds.b    4
  386. _ProgramName    ds.b    4
  387.         END
  388.